Merge from emacs-24; up to 2014-06-12T14:55:48Z!monnier@iro.umontreal.ca

[bpt/emacs.git] / nt / configure.bat

@echo off\r
rem   ----------------------------------------------------------------------\r
rem   Configuration script for MS Windows operating systems\r
rem   Copyright (C) 1999-2014 Free Software Foundation, Inc.\r
\r
rem   This file is part of GNU Emacs.\r
\r
rem   GNU Emacs is free software: you can redistribute it and/or modify\r
rem   it under the terms of the GNU General Public License as published by\r
rem   the Free Software Foundation, either version 3 of the License, or\r
rem   (at your option) any later version.\r
\r
rem   GNU Emacs is distributed in the hope that it will be useful,\r
rem   but WITHOUT ANY WARRANTY; without even the implied warranty of\r
rem   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the\r
rem   GNU General Public License for more details.\r
\r
rem   You should have received a copy of the GNU General Public License\r
rem   along with GNU Emacs.  If not, see http://www.gnu.org/licenses/.\r
\r
rem   ----------------------------------------------------------------------\r
rem   YOU'LL NEED THE FOLLOWING UTILITIES TO MAKE EMACS:\r
rem\r
rem   + MS Windows 95, NT or later\r
rem   + either MSVC 2.x or later, or gcc-2.95 or later (with GNU make 3.75\r
rem     or later) and the Mingw32 and Windows API headers and libraries.\r
rem   + Visual Studio 2005 is not supported at this time.\r
rem\r
rem For reference, here is a list of which builds of GNU make are known to\r
rem work or not, and whether they work in the presence and/or absence of\r
rem sh.exe.\r
rem\r
rem                                       sh exists     no sh\r
rem  cygwin b20.1 make (3.75):            fails[1,5]    fails[2,5]\r
rem  MSVC compiled gmake 3.77:            okay          okay\r
rem  MSVC compiled gmake 3.78.1:          okay          okay\r
rem  MSVC compiled gmake 3.79.1:          okay          okay\r
rem  mingw32/gcc-2.92.2 make (3.77):      okay          okay[4]\r
rem  cygwin compiled gmake 3.77:          fails[1,5]    fails[2,5]\r
rem  cygwin compiled gmake 3.78.1:        fails[5]      fails[2,5]\r
rem  cygwin compiled gmake 3.79.1:        fails[3,5]    fails[2?,5]\r
rem  cygwin compiled make 3.80:           okay[6]       fails?[7]\r
rem  cygwin compiled make 3.81:           fails         fails?[7]\r
rem  mingw32 compiled make 3.79.1:        okay          okay\r
rem  mingw32 compiled make 3.80:          okay          okay?[7]\r
rem  mingw32 compiled make 3.81:          okay          okay[8]\r
rem\r
rem [1] doesn't cope with makefiles with DOS line endings, so must mount\r
rem     emacs source with text!=binary.\r
rem [2] fails when needs to invoke shell commands; okay invoking gcc etc.\r
rem [3] requires LC_MESSAGES support to build; cannot build with early\r
rem     versions of cygwin.\r
rem [4] may fail on Windows 9X and Windows ME; if so, install Bash.\r
rem [5] fails when building leim due to the use of cygwin style paths.\r
rem     May work if building emacs without leim.\r
rem [6] need to uncomment 3 lines in nt/gmake.defs that invoke `cygpath';\r
rem    	look for "cygpath" near line 85 of gmake.defs.\r
rem [7] not recommended; please report if you try this combination.\r
rem [8] tested only on Windows XP.\r
rem\r
echo ****************************************************************\r
echo *** THIS METHOD OF BUILDING EMACS IS NO LONGER SUPPORTED.     **\r
echo *** INSTEAD, FOLLOW THE INSTRUCTIONS FROM INSTALL.            **\r
echo ****************************************************************\r
:confirm_continue\r
set /p answer=Continue running this script at your own risks ? (Y/N)\r
if x%answer% == xy (goto confirm_continue_y)\r
if x%answer% == xY (goto confirm_continue_y)\r
if x%answer% == xn (goto end)\r
if x%answer% == xN (goto end)\r
echo Please answer by Y or N\r
goto confirm_continue\r
\r
:confirm_continue_y\r
if exist config.log del config.log\r
\r
rem ----------------------------------------------------------------------\r
rem   See if the environment is large enough.  We need 43 (?) bytes.\r
set $foo$=123456789_123456789_123456789_123456789_123\r
if not "%$foo$%" == "123456789_123456789_123456789_123456789_123" goto SmallEnv\r
set $foo$=\r
\r
rem ----------------------------------------------------------------------\r
rem   Make sure we are running in the nt subdir\r
if exist configure.bat goto start\r
echo You must run configure from the nt subdirectory.\r
goto end\r
\r
:start\r
rem ----------------------------------------------------------------------\r
rem   Attempt to enable command extensions.  Set use_extensions to 1 if\r
rem   they are available and 0 if they are not available.\r
set use_extensions=1\r
setlocal ENABLEEXTENSIONS\r
if "%CMDEXTVERSION%" == "" set use_extensions=0\r
if "%use_extensions%" == "1" goto afterext\r
\r
echo. Command extensions are not available.  Using parameters that include the =\r
echo. character by enclosing them in quotes will not be supported.\r
\r
:afterext\r
\r
rem ----------------------------------------------------------------------\r
rem   Default settings.\r
set prefix=\r
set nodebug=N\r
set noopt=N\r
set enablechecking=N\r
set profile=N\r
set nocygwin=N\r
set COMPILER=\r
set usercflags=\r
set escusercflags=\r
set docflags=\r
set userldflags=\r
set escuserldflags=\r
set extrauserlibs=\r
set doldflags=\r
set doextralibs=\r
set sep1=\r
set sep2=\r
set sep3=\r
set sep4=\r
set distfiles=\r
\r
rem ----------------------------------------------------------------------\r
rem   Handle arguments.\r
:again\r
if "%1" == "-h" goto usage\r
if "%1" == "--help" goto usage\r
if "%1" == "--prefix" goto setprefix\r
if "%1" == "--with-gcc" goto withgcc\r
if "%1" == "--with-msvc" goto withmsvc\r
if "%1" == "--no-debug" goto nodebug\r
if "%1" == "--no-opt" goto noopt\r
if "%1" == "--enable-checking" goto enablechecking\r
if "%1" == "--profile" goto profile\r
if "%1" == "--no-cygwin" goto nocygwin\r
if "%1" == "--cflags" goto usercflags\r
if "%1" == "--ldflags" goto userldflags\r
if "%1" == "--lib" goto extrauserlibs\r
if "%1" == "--without-png" goto withoutpng\r
if "%1" == "--without-jpeg" goto withoutjpeg\r
if "%1" == "--without-gif" goto withoutgif\r
if "%1" == "--without-tiff" goto withouttiff\r
if "%1" == "--without-gnutls" goto withoutgnutls\r
if "%1" == "--without-libxml2" goto withoutlibxml2\r
if "%1" == "--without-xpm" goto withoutxpm\r
if "%1" == "--with-svg" goto withsvg\r
if "%1" == "--distfiles" goto distfiles\r
if "%1" == "" goto checkutils\r
\r
:usage\r
echo Usage: configure [options]\r
echo Options:\r
echo.   --prefix PREFIX         install Emacs in directory PREFIX\r
echo.   --with-gcc              use GCC to compile Emacs\r
echo.   --with-msvc             use MSVC to compile Emacs\r
echo.   --no-debug              exclude debug info from executables\r
echo.   --no-opt                disable optimization\r
echo.   --enable-checking       enable additional run-time checks\r
echo.   --profile               enable profiling\r
echo.   --no-cygwin             use -mno-cygwin option with GCC\r
echo.   --cflags FLAG           pass FLAG to compiler\r
echo.   --ldflags FLAG          pass FLAG to compiler when linking\r
echo.   --lib LIB               link to extra library LIB\r
echo.   --without-png           do not use PNG library even if it is installed\r
echo.   --without-jpeg          do not use JPEG library even if it is installed\r
echo.   --without-gif           do not use GIF library even if it is installed\r
echo.   --without-tiff          do not use TIFF library even if it is installed\r
echo.   --without-xpm           do not use XPM library even if it is installed\r
echo.   --without-gnutls        do not use GnuTLS library even if it is installed\r
echo.   --without-libxml2       do not use libxml2 library even if it is installed\r
echo.   --with-svg              use the RSVG library (experimental)\r
echo.   --distfiles             path to files for make dist, e.g. libXpm.dll\r
if "%use_extensions%" == "0" goto end\r
echo.\r
echo. The cflags and ldflags arguments support parameters that include the =\r
echo. character.  However, since the = character is normally treated as a\r
echo. separator character you will need to enclose any parameter that includes\r
echo. the = character in quotes.  For example, to include\r
echo. -DSITELOAD_PURESIZE_EXTRA=100000 as one of the cflags you would run\r
echo. configure.bat as follows:\r
echo. configure.bat --cflags "-DSITELOAD_PURESIZE_EXTRA=100000"\r
echo.\r
echo. Note that this capability of processing parameters that include the =\r
echo. character depends on command extensions.  This batch file attempts to\r
echo. enable command extensions.  If command extensions cannot be enabled, a\r
echo. warning message will be displayed.\r
echo.\r
echo. IMPORTANT: This method of building Emacs for MS-Windows is deprecated,\r
echo. and could be removed in a future version of Emacs.  The preferred way\r
echo  to build Emacs for MS-Windows from now on is using the MSYS environment\r
echo. and MinGW development tools.  Please see nt/INSTALL for details.\r
goto end\r
\r
rem ----------------------------------------------------------------------\r
\r
:setprefix\r
shift\r
set prefix=%1\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:withgcc\r
set COMPILER=gcc\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:withmsvc\r
set COMPILER=cl\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:nodebug\r
set nodebug=Y\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:noopt\r
set noopt=Y\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:enablechecking\r
set enablechecking=Y\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:profile\r
set profile=Y\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:nocygwin\r
set nocygwin=Y\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:usercflags\r
if "%use_extensions%" == "1" goto ucflagex\r
goto ucflagne\r
\r
:ucflagex\r
shift\r
set usercflags=%usercflags%%sep1%%~1\r
set escusercflags=%usercflags:"=\"%\r
set sep1= %nothing%\r
shift\r
goto again\r
\r
:ucflagne\r
shift\r
set usercflags=%usercflags%%sep1%%1\r
set escusercflags=%usercflags%\r
set sep1= %nothing%\r
shift\r
goto again\r
\r
:extrauserlibs\r
shift\r
echo. extrauserlibs: %extrauserlibs%\r
set extrauserlibs=%extrauserlibs%%sep4%%1\r
set sep4= %nothing%\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:userldflags\r
if "%use_extensions%" == "1" goto ulflagex\r
goto ulflagne\r
\r
:ulflagex\r
shift\r
set userldflags=%userldflags%%sep2%%~1\r
set escuserldflags=%userldflags:"=\"%\r
set sep2= %nothing%\r
shift\r
goto again\r
\r
:ulflagne\r
shift\r
set userldflags=%userldflags%%sep2%%1\r
set escuserldflags=%userldflags%\r
set sep2= %nothing%\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:withoutpng\r
set pngsupport=N\r
set HAVE_PNG=\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:withoutjpeg\r
set jpegsupport=N\r
set HAVE_JPEG=\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:withoutgif\r
set gifsupport=N\r
set HAVE_GIF=\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:withoutgnutls\r
set tlssupport=N\r
set HAVE_GNUTLS=\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:withoutlibxml2\r
set libxml2support=N\r
set HAVE_LIBXML2=\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:withouttiff\r
set tiffsupport=N\r
set HAVE_TIFF=\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:withoutxpm\r
set xpmsupport=N\r
set HAVE_XPM=\r
shift\r
goto again\r
\r
:withsvg\r
shift\r
set svgsupport=Y\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
\r
:distfiles\r
set HAVE_DISTFILES=1\r
shift\r
set distfiles=%distfiles%%sep3%%1\r
set sep3= %nothing%\r
shift\r
goto again\r
\r
rem ----------------------------------------------------------------------\r
rem    Check that necessary utilities (cp and rm) are present.\r
\r
:checkutils\r
echo Checking for 'cp'...\r
cp configure.bat junk.bat\r
if not exist junk.bat goto needcp\r
echo Checking for 'rm'...\r
rm junk.bat\r
if exist junk.bat goto needrm\r
goto checkcompiler\r
\r
:needcp\r
echo You need 'cp' (the Unix file copy program) to build Emacs.\r
goto end\r
\r
:needrm\r
del junk.bat\r
echo You need 'rm' (the Unix file delete program) to build Emacs.\r
goto end\r
\r
rem ----------------------------------------------------------------------\r
rem   Auto-detect compiler if not specified, and validate GCC if chosen.\r
\r
:checkcompiler\r
if (%COMPILER%)==(cl) goto compilercheckdone\r
if (%COMPILER%)==(gcc) goto checkgcc\r
\r
echo Checking whether 'gcc' is available...\r
echo main(){} >junk.c\r
gcc -c junk.c\r
if exist junk.o goto checkgcc\r
\r
echo Checking whether 'cl' is available...\r
cl -nologo -c junk.c\r
if exist junk.obj goto clOK\r
goto nocompiler\r
\r
:checkgcc\r
if exist junk.o del junk.o\r
Rem WARNING -- COMMAND.COM on some systems only looks at the first\r
Rem            8 characters of a label.  So do NOT be tempted to change\r
Rem            chkapi* into something fancier like checkw32api\r
Rem You HAVE been warned!\r
if (%nocygwin%) == (Y) goto chkapiN\r
echo Checking whether gcc requires '-mno-cygwin'...\r
echo #include "cygwin/version.h" >junk.c\r
echo main(){} >>junk.c\r
echo gcc -c junk.c >>config.log\r
gcc -c junk.c >>config.log 2>&1\r
if not exist junk.o goto chkapi\r
echo gcc -mno-cygwin -c junk.c >>config.log\r
gcc -mno-cygwin -c junk.c >>config.log 2>&1\r
if exist junk.o set nocygwin=Y\r
\r
:chkapi\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
\r
:chkapiN\r
rm -f junk.c junk.o\r
rem ----------------------------------------------------------------------\r
rem   Older versions of the Windows API headers either don't have any of\r
rem   the IMAGE_xxx definitions (the headers that come with Cygwin b20.1\r
rem   are like this), or have a typo in the definition of\r
rem   IMAGE_FIRST_SECTION (the headers with gcc/mingw32 2.95 have this\r
rem   problem).  The gcc/mingw32 2.95.2 headers are okay, as are distros\r
rem   of w32api-xxx.zip from Anders Norlander since 1999-11-18 at least.\r
rem   Beginning with Emacs 23, we need usp10.h.\r
rem\r
echo Checking whether Windows API headers are too old...\r
echo #include "windows.h" >junk.c\r
echo #include "usp10.h" >>junk.c\r
echo void test(PIMAGE_NT_HEADERS pHeader) >>junk.c\r
echo {PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader);} >>junk.c\r
if (%nocygwin%) == (Y) goto chkapi1\r
set cf=%usercflags%\r
goto chkapi2\r
\r
:chkapi1\r
set cf=%usercflags% -mno-cygwin\r
\r
:chkapi2\r
echo on\r
gcc %cf% -c junk.c\r
@echo off\r
@echo gcc %cf% -c junk.c >>config.log\r
gcc %cf% -c junk.c >>config.log 2>&1\r
set cf=\r
if exist junk.o goto chkuser\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
goto nocompiler\r
\r
:chkuser\r
rm -f junk.o\r
echo int main (int argc, char *argv[]) {>junk.c\r
echo char *usercflags = "%escusercflags%";>>junk.c\r
echo }>>junk.c\r
echo gcc -Werror -c junk.c >>config.log\r
gcc -Werror -c junk.c >>config.log 2>&1\r
if exist junk.o goto gccOk\r
echo.\r
echo Error in --cflags argument: %usercflags%\r
echo Backslashes and quotes cannot be used with --cflags.  Please use forward\r
echo slashes for filenames and paths (e.g. when passing directories to -I).\r
rm -f junk.c\r
goto end\r
\r
:nocompiler\r
echo.\r
echo Configure failed.\r
echo To configure Emacs for Windows, you need to have either\r
echo gcc-2.95 or later with Mingw32 and the Windows API headers,\r
echo or MSVC 2.x or later.\r
del junk.c\r
goto end\r
\r
:gccOk\r
set COMPILER=gcc\r
echo Using 'gcc'\r
rm -f junk.c junk.o\r
Rem It is not clear what GCC version began supporting -mtune\r
Rem and pentium4 on x86, so check this explicitly.\r
echo main(){} >junk.c\r
echo gcc -c -O2 -mtune=pentium4 junk.c >>config.log\r
gcc -c -O2 -mtune=pentium4 junk.c >>config.log 2>&1\r
if not errorlevel 1 goto gccMtuneOk\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set mf=-mcpu=i686\r
rm -f junk.c junk.o\r
goto gccdebug\r
\r
:gccMtuneOk\r
echo GCC supports -mtune=pentium4 >>config.log\r
set mf=-mtune=pentium4\r
rm -f junk.c junk.o\r
\r
:gccdebug\r
rem Check for DWARF-2 debug info support, else default to stabs\r
echo main(){} >junk.c\r
echo gcc -c -gdwarf-2 -g3 junk.c >>config.log\r
gcc -c -gdwarf-2 -g3 junk.c >>config.log 2>&1\r
if not errorlevel 1 goto gccdwarf\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set dbginfo=-gstabs+\r
rm -f junk.c junk.o\r
goto compilercheckdone\r
\r
:gccdwarf\r
echo GCC supports DWARF-2 >>config.log\r
set dbginfo=-gdwarf-2 -g3\r
rm -f junk.c junk.o\r
goto compilercheckdone\r
\r
:clOk\r
set COMPILER=cl\r
rm -f junk.c junk.obj\r
echo Using 'MSVC'\r
\r
:compilercheckdone\r
\r
rem ----------------------------------------------------------------------\r
rem   Check for external image libraries. Since they are loaded\r
rem   dynamically, the libraries themselves do not need to be present\r
rem   at compile time, but the header files are required.\r
\r
set mingwflag=\r
\r
if (%nocygwin%) == (N) goto flagsOK\r
set mingwflag=-mno-cygwin\r
\r
:flagsOK\r
\r
if (%pngsupport%) == (N) goto pngDone\r
\r
echo Checking for libpng...\r
echo #include "png.h" >junk.c\r
echo main (){} >>junk.c\r
rem   -o option is ignored with cl, but allows result to be consistent.\r
echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log\r
%COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log\r
if exist junk.obj goto havePng\r
\r
echo ...png.h not found, building without PNG support.\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set HAVE_PNG=\r
goto :pngDone\r
\r
:havePng\r
echo ...PNG header available, building with PNG support.\r
set HAVE_PNG=1\r
\r
:pngDone\r
rm -f junk.c junk.obj\r
\r
if (%tlssupport%) == (N) goto tlsDone\r
\r
rem this is a copy of the PNG detection\r
echo Checking for libgnutls...\r
echo #include "gnutls/gnutls.h" >junk.c\r
echo main (){} >>junk.c\r
rem   -o option is ignored with cl, but allows result to be consistent.\r
echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log\r
%COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log\r
if exist junk.obj goto haveTls\r
\r
echo ...gnutls.h not found, building without TLS support.\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set HAVE_GNUTLS=\r
goto :tlsDone\r
\r
:haveTls\r
echo ...GnuTLS header available, building with GnuTLS support.\r
set HAVE_GNUTLS=1\r
\r
:tlsDone\r
rm -f junk.c junk.obj\r
\r
if (%libxml2support%) == (N) goto xml2Done\r
\r
echo Checking for libxml2....\r
echo #include "libxml/HTMLparser.h" >junk.c\r
echo main(){} >>junk.c\r
echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log\r
%COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log\r
if exist junk.obj goto havelibxml2\r
\r
echo ...libxml/HTMLparser.h not found, building without libxml2 support\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set HAVE_LIBXML2=\r
goto xml2Done\r
\r
:havelibxml2\r
echo ...libxml2 header available, building with libxml2 support\r
set HAVE_LIBXML2=1\r
\r
:xml2Done\r
rm -f junk.c junk.obj\r
\r
if (%jpegsupport%) == (N) goto jpegDone\r
\r
echo Checking for jpeg-6b...\r
echo #include "jconfig.h" >junk.c\r
echo main (){} >>junk.c\r
rem   -o option is ignored with cl, but allows result to be consistent.\r
echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log\r
%COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log\r
if exist junk.obj goto haveJpeg\r
\r
echo ...jconfig.h not found, building without JPEG support.\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set HAVE_JPEG=\r
goto :jpegDone\r
\r
:haveJpeg\r
echo ...JPEG header available, building with JPEG support.\r
set HAVE_JPEG=1\r
\r
:jpegDone\r
rm -f junk.c junk.obj\r
\r
if (%gifsupport%) == (N) goto gifDone\r
\r
echo Checking for libgif...\r
rem giflib-5.0.0 needs size_t defined before gif_lib.h is included\r
rem redirection characters need to be protected from the shell\r
echo #include ^<stddef.h^> >junk.c\r
echo #include "gif_lib.h" >>junk.c\r
echo main (){} >>junk.c\r
rem   -o option is ignored with cl, but allows result to be consistent.\r
echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log\r
%COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log\r
if exist junk.obj goto haveGif\r
\r
echo ...gif_lib.h not found, building without GIF support.\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set HAVE_GIF=\r
goto :gifDone\r
\r
:haveGif\r
echo ...GIF header available, building with GIF support.\r
set HAVE_GIF=1\r
\r
:gifDone\r
rm -f junk.c junk.obj\r
\r
if (%tiffsupport%) == (N) goto tiffDone\r
\r
echo Checking for tiff...\r
echo #include "tiffio.h" >junk.c\r
echo main (){} >>junk.c\r
rem   -o option is ignored with cl, but allows result to be consistent.\r
echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log\r
%COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log\r
if exist junk.obj goto haveTiff\r
\r
echo ...tiffio.h not found, building without TIFF support.\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set HAVE_TIFF=\r
goto :tiffDone\r
\r
:haveTiff\r
echo ...TIFF header available, building with TIFF support.\r
set HAVE_TIFF=1\r
\r
:tiffDone\r
rm -f junk.c junk.obj\r
\r
if (%xpmsupport%) == (N) goto xpmDone\r
\r
echo Checking for libXpm...\r
echo #define FOR_MSW 1 >junk.c\r
echo #include "X11/xpm.h" >>junk.c\r
echo main (){} >>junk.c\r
rem   -o option is ignored with cl, but allows result to be consistent.\r
echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log\r
%COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log\r
if exist junk.obj goto haveXpm\r
\r
echo ...X11/xpm.h not found, building without XPM support.\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set HAVE_XPM=\r
goto :xpmDone\r
\r
:haveXpm\r
echo ...XPM header available, building with XPM support.\r
set HAVE_XPM=1\r
\r
:xpmDone\r
rm -f junk.c junk.obj\r
\r
if not (%svgsupport%) == (Y) goto :svgDone\r
echo Checking for librsvg...\r
echo #include "librsvg/rsvg.h" >junk.c\r
echo main (){} >>junk.c\r
rem   -o option is ignored with cl, but allows result to be consistent.\r
echo %COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >>config.log\r
%COMPILER% %usercflags% %mingwflag% -c junk.c -o junk.obj >junk.out 2>>config.log\r
if exist junk.obj goto haveSvg\r
\r
echo ...librsvg/rsvg.h or dependencies not found, building without SVG support.\r
echo The failed program was: >>config.log\r
type junk.c >>config.log\r
set HAVE_RSVG=\r
goto :svgDone\r
\r
:haveSvg\r
echo ...librsvg header available, building with SVG support (EXPERIMENTAL).\r
set HAVE_RSVG=1\r
\r
:svgDone\r
rm -f junk.c junk.obj junk.err junk.out\r
\r
rem Any distfiles provided for building distribution? If no, we're done.\r
if "(%HAVE_DISTFILES%)"=="()" goto :distFilesDone\r
\r
rem Any arguments to --distfiles specified? If no, we're done.\r
if not "%distfiles%"=="" goto :checkDistFiles\r
set distFilesOk=0\r
echo No arguments specified for option --distfiles!\r
goto distfilesDone\r
\r
:checkDistFiles\r
echo Checking for distfiles...\r
rem Check if all specified distfiles exist\r
set fileNotFound=\r
for %%d in (%distfiles%) do if not exist %%d set fileNotFound=%%d\r
if not "%fileNotFound%"=="" goto distFilesNotFound\r
\r
set distFilesOK=1\r
echo ...all distfiles found.\r
goto :distFilesDone\r
\r
:distFilesNotFound\r
set distFilesOk=0\r
echo ...%fileNotFound% not found.\r
set distfiles=\r
goto :distfilesDone\r
\r
:distFilesDone\r
set fileNotFound=\r
\r
rem ----------------------------------------------------------------------\r
\r
:genmakefiles\r
echo Generating makefiles\r
if %COMPILER% == gcc set MAKECMD=gmake\r
if %COMPILER% == cl set MAKECMD=nmake\r
\r
rem   Pass on chosen settings to makefiles.\r
rem\r
rem   The weird place we put the redirection is to make sure no extra\r
rem   whitespace winds up at the end of the Make variables, since some\r
rem   variables, e.g. INSTALL_DIR, cannot stand that.  Yes, echo will\r
rem   write the blanks between the end of command arguments and the\r
rem   redirection symbol to the file.  OTOH, we cannot put the\r
rem   redirection immediately after the last character of the command,\r
rem   because environment variable expansion can yield a digit there,\r
rem   which will then be misinterpreted as the file descriptor to\r
rem   redirect...\r
echo # Start of settings from configure.bat >config.settings\r
>>config.settings echo COMPILER=%COMPILER%\r
if not "(%mf%)" == "()" >>config.settings echo MCPU_FLAG=%mf%\r
if not "(%dbginfo%)" == "()" >>config.settings echo DEBUG_INFO=%dbginfo%\r
if (%nodebug%) == (Y) >>config.settings echo NODEBUG=1\r
if (%noopt%) == (Y) >>config.settings echo NOOPT=1\r
if (%profile%) == (Y) >>config.settings echo PROFILE=1\r
if (%nocygwin%) == (Y) >>config.settings echo NOCYGWIN=1\r
if not "(%prefix%)" == "()" >>config.settings echo INSTALL_DIR=%prefix%\r
if not "(%distfiles%)" == "()" >>config.settings echo DIST_FILES=%distfiles%\r
rem We go thru docflags because usercflags could be "-DFOO=bar" -something\r
rem and the if command cannot cope with this\r
for %%v in (%usercflags%) do if not (%%v)==() set docflags=Y\r
if (%docflags%)==(Y) >>config.settings echo USER_CFLAGS=%usercflags%\r
if (%docflags%)==(Y) >>config.settings echo ESC_USER_CFLAGS=%escusercflags%\r
for %%v in (%userldflags%) do if not (%%v)==() set doldflags=Y\r
if (%doldflags%)==(Y) >>config.settings echo USER_LDFLAGS=%userldflags%\r
for %%v in (%extrauserlibs%) do if not (%%v)==() set doextralibs=Y\r
if (%doextralibs%)==(Y) >>config.settings echo USER_LIBS=%extrauserlibs%\r
echo # End of settings from configure.bat>>config.settings\r
echo. >>config.settings\r
\r
copy config.nt config.tmp\r
echo. >>config.tmp\r
echo /* Start of settings from configure.bat.  */ >>config.tmp\r
rem   We write USER_CFLAGS and USER_LDFLAGS starting with a space to simplify\r
rem   processing of compiler options in w32.c:get_emacs_configuration_options\r
if (%docflags%) == (Y) echo #define USER_CFLAGS " %escusercflags%" >>config.tmp\r
if (%doldflags%) == (Y) echo #define USER_LDFLAGS " %escuserldflags%" >>config.tmp\r
if (%profile%) == (Y) echo #define PROFILING 1 >>config.tmp\r
if (%enablechecking%) == (Y) echo #define ENABLE_CHECKING 1 >>config.tmp\r
if not "(%HAVE_PNG%)" == "()" echo #define HAVE_PNG 1 >>config.tmp\r
if not "(%HAVE_GNUTLS%)" == "()" echo #define HAVE_GNUTLS 1 >>config.tmp\r
if not "(%HAVE_LIBXML2%)" == "()" echo #define HAVE_LIBXML2 1 >>config.tmp\r
if not "(%HAVE_JPEG%)" == "()" echo #define HAVE_JPEG 1 >>config.tmp\r
if not "(%HAVE_GIF%)" == "()" echo #define HAVE_GIF 1 >>config.tmp\r
if not "(%HAVE_TIFF%)" == "()" echo #define HAVE_TIFF 1 >>config.tmp\r
if not "(%HAVE_XPM%)" == "()" echo #define HAVE_XPM 1 >>config.tmp\r
if "(%HAVE_RSVG%)" == "(1)" echo #define HAVE_RSVG 1 >>config.tmp\r
\r
echo /* End of settings from configure.bat.  */ >>config.tmp\r
\r
Rem See if fc.exe returns a meaningful exit status.  If it does, we\r
Rem might as well avoid unnecessary overwriting of config.h and epaths.h,\r
Rem since this forces recompilation of every source file.\r
if exist foo.bar del foo.bar\r
fc /b foo.bar foo.bar >nul 2>&1\r
if not errorlevel 2 goto doCopy\r
fc /b config.tmp ..\src\config.h >nul 2>&1\r
if errorlevel 1 goto doCopy\r
fc /b paths.h ..\src\epaths.h >nul 2>&1\r
if not errorlevel 1 goto dontCopy\r
\r
:doCopy\r
copy config.tmp ..\src\config.h\r
copy paths.h ..\src\epaths.h\r
\r
:dontCopy\r
if exist config.tmp del config.tmp\r
copy /b config.settings+%MAKECMD%.defs+..\nt\makefile.w32-in ..\nt\makefile\r
if exist ..\admin\unidata copy /b config.settings+%MAKECMD%.defs+..\admin\unidata\makefile.w32-in ..\admin\unidata\makefile\r
copy /b config.settings+%MAKECMD%.defs+..\lib-src\makefile.w32-in ..\lib-src\makefile\r
copy /b config.settings+%MAKECMD%.defs+..\lib\makefile.w32-in ..\lib\makefile\r
copy /b config.settings+%MAKECMD%.defs+..\src\makefile.w32-in ..\src\makefile\r
copy /b config.settings+%MAKECMD%.defs+..\doc\emacs\makefile.w32-in ..\doc\emacs\makefile\r
copy /b config.settings+%MAKECMD%.defs+..\doc\misc\makefile.w32-in ..\doc\misc\makefile\r
copy /b config.settings+%MAKECMD%.defs+..\doc\lispref\makefile.w32-in ..\doc\lispref\makefile\r
copy /b config.settings+%MAKECMD%.defs+..\doc\lispintro\makefile.w32-in ..\doc\lispintro\makefile\r
if exist ..\lisp\makefile rm -f ../lisp/[Mm]akefile\r
copy /b config.settings+%MAKECMD%.defs+..\lisp\makefile.w32-in ..\lisp\makefile\r
rem   Use the default (no-op) Makefile.in if the nt version is not present.\r
if exist ..\leim\makefile.w32-in copy /b config.settings+%MAKECMD%.defs+..\leim\makefile.w32-in ..\leim\makefile\r
if not exist ..\leim\makefile.w32-in copy /b config.settings+%MAKECMD%.defs+..\leim\Makefile.in ..\leim\makefile\r
del config.settings\r
\r
Rem Some people use WinZip which doesn't create empty directories!\r
if not exist ..\site-lisp\nul mkdir ..\site-lisp\\r
Rem Update subdirs.el only if it is different or fc.exe doesn't work.\r
if exist foo.bar del foo.bar\r
fc /b foo.bar foo.bar >nul 2>&1\r
if not errorlevel 2 goto doUpdateSubdirs\r
fc /b subdirs.el ..\site-lisp\subdirs.el >nul 2>&1\r
if not errorlevel 1 goto dontUpdateSubdirs\r
\r
:doUpdateSubdirs\r
if exist ..\site-lisp\subdirs.el del ..\site-lisp\subdirs.el\r
copy subdirs.el ..\site-lisp\subdirs.el\r
\r
:dontUpdateSubdirs\r
echo.\r
\r
rem check that we have all the libraries we need.\r
set libsOK=1\r
\r
if not "(%HAVE_XPM%)" == "()" goto checkpng\r
if (%xpmsupport%) == (N) goto checkpng\r
 set libsOK=0\r
 echo XPM support is missing. It is required for color icons in the toolbar.\r
 echo   Install libXpm development files or use --without-xpm\r
\r
:checkpng\r
if not "(%HAVE_PNG%)" == "()" goto checkjpeg\r
if (%pngsupport%) == (N) goto checkjpeg\r
 set libsOK=0\r
 echo PNG support is missing.\r
 echo   Install libpng development files or use --without-png\r
\r
:checkjpeg\r
if not "(%HAVE_JPEG%)" == "()" goto checktiff\r
if (%jpegsupport%) == (N) goto checktiff\r
 set libsOK=0\r
 echo JPEG support is missing.\r
 echo   Install jpeg development files or use --without-jpeg\r
\r
:checktiff\r
if not "(%HAVE_TIFF%)" == "()" goto checkgif\r
if (%tiffsupport%) == (N) goto checkgif\r
 set libsOK=0\r
 echo TIFF support is missing.\r
 echo   Install libtiff development files or use --without-tiff\r
\r
:checkgif\r
if not "(%HAVE_GIF%)" == "()" goto checkdistfiles\r
if (%gifsupport%) == (N) goto checkdistfiles\r
 set libsOK=0\r
 echo GIF support is missing.\r
 echo   Install giflib or libungif development files or use --without-gif\r
\r
:checkdistfiles\r
if "(%HAVE_DISTFILES%)" == "()" goto donelibchecks\r
if (%distFilesOk%) == (1) goto donelibchecks\r
echo.\r
echo Files specified with option --distfiles could not be found.\r
echo   Fix these issues before running make dist\r
\r
:donelibchecks\r
if (%libsOK%) == (1) goto success\r
echo.\r
echo Important libraries are missing. Fix these issues before running make.\r
goto end\r
\r
:success\r
echo Emacs successfully configured.\r
echo Emacs successfully configured. >>config.log\r
if (%MAKECMD%) == (gmake) set MAKECMD=make\r
echo Run `%MAKECMD%' to build, then run `%MAKECMD% install' to install.\r
goto end\r
\r
:SmallEnv\r
echo Your environment size is too small.  Please enlarge it and rerun configure.\r
echo For example, type "command.com /e:2048" to have 2048 bytes available.\r
set $foo$=\r
\r
:end\r
set prefix=\r
set nodebug=\r
set noopt=\r
set enablechecking=\r
set profile=\r
set nocygwin=\r
set COMPILER=\r
set MAKECMD=\r
set usercflags=\r
set docflags=\r
set userldflags=\r
set doldflags=\r
set mingwflag=\r
set mf=\r
set distfiles=\r
set HAVE_DISTFILES=\r
set distFilesOk=\r
set pngsupport=\r
set tlssupport=\r
set libxml2support=\r
set jpegsupport=\r
set gifsupport=\r
set tiffsupport=\r
set xpmsupport=\r
set svgsupport=\r
set libsOK=\r
set HAVE_GIF=\r
set HAVE_JPEG=\r
set HAVE_PNG=\r
set HAVE_TIFF=\r
set HAVE_XPM=\r
set dbginfo=\r
endlocal\r
set use_extensions=\r