| 1 | ;;; mim-syntax.el --- syntax checker for Mim (MDL). |
| 2 | |
| 3 | ;; Copyright (C) 1985 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: K. Shane Hartman |
| 6 | ;; Maintainer: FSF |
| 7 | ;; Keywords: languages |
| 8 | |
| 9 | ;; This file is part of GNU Emacs. |
| 10 | |
| 11 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 12 | ;; it under the terms of the GNU General Public License as published by |
| 13 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 14 | ;; any later version. |
| 15 | |
| 16 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | ;; GNU General Public License for more details. |
| 20 | |
| 21 | ;; You should have received a copy of the GNU General Public License |
| 22 | ;; along with GNU Emacs; see the file COPYING. If not, write to |
| 23 | ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA. |
| 24 | |
| 25 | ;;; Code: |
| 26 | |
| 27 | (require 'mim-mode) |
| 28 | |
| 29 | (defun slow-syntax-check-mim () |
| 30 | "Check Mim syntax slowly. |
| 31 | Points out the context of the error, if the syntax is incorrect." |
| 32 | (interactive) |
| 33 | (message "checking syntax...") |
| 34 | (let ((stop (point-max)) point-stack current last-bracket whoops last-point) |
| 35 | (save-excursion |
| 36 | (goto-char (point-min)) |
| 37 | (while (and (not whoops) |
| 38 | (re-search-forward "\\s(\\|\\s)\\|\"\\|[\\]" stop t)) |
| 39 | (setq current (preceding-char)) |
| 40 | (cond ((= current ?\") |
| 41 | (condition-case nil |
| 42 | (progn (re-search-forward "[^\\]\"") |
| 43 | (setq current nil)) |
| 44 | (error (setq whoops (point))))) |
| 45 | ((= current ?\\) |
| 46 | (condition-case nil (forward-char 1) (error nil))) |
| 47 | ((= (char-syntax current) ?\)) |
| 48 | (if (or (not last-bracket) |
| 49 | (not (= (logand (lsh (aref (syntax-table) last-bracket) -8) |
| 50 | ?\177) |
| 51 | current))) |
| 52 | (setq whoops (point)) |
| 53 | (setq last-point (car point-stack)) |
| 54 | (setq last-bracket (if last-point (char-after (1- last-point)))) |
| 55 | (setq point-stack (cdr point-stack)))) |
| 56 | (t |
| 57 | (if last-point (setq point-stack (cons last-point point-stack))) |
| 58 | (setq last-point (point)) |
| 59 | (setq last-bracket current))))) |
| 60 | (cond ((not (or whoops last-point)) |
| 61 | (message "Syntax correct")) |
| 62 | (whoops |
| 63 | (goto-char whoops) |
| 64 | (cond ((equal current ?\") |
| 65 | (error "Unterminated string")) |
| 66 | ((not last-point) |
| 67 | (error "Extraneous %s" (char-to-string current))) |
| 68 | (t |
| 69 | (error "Mismatched %s with %s" |
| 70 | (save-excursion |
| 71 | (setq whoops (1- (point))) |
| 72 | (goto-char (1- last-point)) |
| 73 | (buffer-substring (point) |
| 74 | (min (progn (end-of-line) (point)) |
| 75 | whoops))) |
| 76 | (char-to-string current))))) |
| 77 | (t |
| 78 | (goto-char last-point) |
| 79 | (error "Unmatched %s" (char-to-string last-bracket)))))) |
| 80 | |
| 81 | (defun fast-syntax-check-mim () |
| 82 | "Checks Mim syntax quickly. |
| 83 | Answers correct or incorrect, cannot point out the error context." |
| 84 | (interactive) |
| 85 | (save-excursion |
| 86 | (goto-char (point-min)) |
| 87 | (let (state) |
| 88 | (while (and (not (eobp)) |
| 89 | (equal (car (setq state (parse-partial-sexp (point) (point-max) 0))) |
| 90 | 0))) |
| 91 | (if (equal (car state) 0) |
| 92 | (message "Syntax correct") |
| 93 | (error "Syntax incorrect"))))) |
| 94 | |
| 95 | ;;; mim-syntax.el ends here |