| 1 | ;;; outline.el --- outline mode commands for Emacs |
| 2 | |
| 3 | ;; Copyright (C) 1986, 1993, 1994, 1995, 1997, 2000, 2001, 2002, |
| 4 | ;; 2003, 2004, 2005, 2006 Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Maintainer: FSF |
| 7 | ;; Keywords: outlines |
| 8 | |
| 9 | ;; This file is part of GNU Emacs. |
| 10 | |
| 11 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 12 | ;; it under the terms of the GNU General Public License as published by |
| 13 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 14 | ;; any later version. |
| 15 | |
| 16 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | ;; GNU General Public License for more details. |
| 20 | |
| 21 | ;; You should have received a copy of the GNU General Public License |
| 22 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 23 | ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, |
| 24 | ;; Boston, MA 02110-1301, USA. |
| 25 | |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; This package is a major mode for editing outline-format documents. |
| 29 | ;; An outline can be `abstracted' to show headers at any given level, |
| 30 | ;; with all stuff below hidden. See the Emacs manual for details. |
| 31 | |
| 32 | ;;; Todo: |
| 33 | |
| 34 | ;; - subtree-terminators |
| 35 | ;; - better handle comments before function bodies (i.e. heading) |
| 36 | ;; - don't bother hiding whitespace |
| 37 | |
| 38 | ;;; Code: |
| 39 | |
| 40 | (defvar font-lock-warning-face) |
| 41 | |
| 42 | |
| 43 | (defgroup outlines nil |
| 44 | "Support for hierarchical outlining." |
| 45 | :prefix "outline-" |
| 46 | :group 'editing) |
| 47 | |
| 48 | (defcustom outline-regexp "[*\^L]+" |
| 49 | "Regular expression to match the beginning of a heading. |
| 50 | Any line whose beginning matches this regexp is considered to start a heading. |
| 51 | Note that Outline mode only checks this regexp at the start of a line, |
| 52 | so the regexp need not (and usually does not) start with `^'. |
| 53 | The recommended way to set this is with a Local Variables: list |
| 54 | in the file it applies to. See also `outline-heading-end-regexp'." |
| 55 | :type '(choice regexp (const nil)) |
| 56 | :group 'outlines) |
| 57 | ;;;###autoload(put 'outline-regexp 'safe-local-variable 'string-or-null-p) |
| 58 | |
| 59 | (defcustom outline-heading-end-regexp "\n" |
| 60 | "Regular expression to match the end of a heading line. |
| 61 | You can assume that point is at the beginning of a heading when this |
| 62 | regexp is searched for. The heading ends at the end of the match. |
| 63 | The recommended way to set this is with a `Local Variables:' list |
| 64 | in the file it applies to." |
| 65 | :type 'regexp |
| 66 | :group 'outlines) |
| 67 | |
| 68 | (defvar outline-mode-prefix-map |
| 69 | (let ((map (make-sparse-keymap))) |
| 70 | (define-key map "@" 'outline-mark-subtree) |
| 71 | (define-key map "\C-n" 'outline-next-visible-heading) |
| 72 | (define-key map "\C-p" 'outline-previous-visible-heading) |
| 73 | (define-key map "\C-i" 'show-children) |
| 74 | (define-key map "\C-s" 'show-subtree) |
| 75 | (define-key map "\C-d" 'hide-subtree) |
| 76 | (define-key map "\C-u" 'outline-up-heading) |
| 77 | (define-key map "\C-f" 'outline-forward-same-level) |
| 78 | (define-key map "\C-b" 'outline-backward-same-level) |
| 79 | (define-key map "\C-t" 'hide-body) |
| 80 | (define-key map "\C-a" 'show-all) |
| 81 | (define-key map "\C-c" 'hide-entry) |
| 82 | (define-key map "\C-e" 'show-entry) |
| 83 | (define-key map "\C-l" 'hide-leaves) |
| 84 | (define-key map "\C-k" 'show-branches) |
| 85 | (define-key map "\C-q" 'hide-sublevels) |
| 86 | (define-key map "\C-o" 'hide-other) |
| 87 | (define-key map "\C-^" 'outline-move-subtree-up) |
| 88 | (define-key map "\C-v" 'outline-move-subtree-down) |
| 89 | (define-key map [(control ?<)] 'outline-promote) |
| 90 | (define-key map [(control ?>)] 'outline-demote) |
| 91 | (define-key map "\C-m" 'outline-insert-heading) |
| 92 | ;; Where to bind outline-cycle ? |
| 93 | map)) |
| 94 | |
| 95 | (defvar outline-mode-menu-bar-map |
| 96 | (let ((map (make-sparse-keymap))) |
| 97 | |
| 98 | (define-key map [hide] (cons "Hide" (make-sparse-keymap "Hide"))) |
| 99 | |
| 100 | (define-key map [hide hide-other] '("Hide Other" . hide-other)) |
| 101 | (define-key map [hide hide-sublevels] '("Hide Sublevels" . hide-sublevels)) |
| 102 | (define-key map [hide hide-subtree] '("Hide Subtree" . hide-subtree)) |
| 103 | (define-key map [hide hide-entry] '("Hide Entry" . hide-entry)) |
| 104 | (define-key map [hide hide-body] '("Hide Body" . hide-body)) |
| 105 | (define-key map [hide hide-leaves] '("Hide Leaves" . hide-leaves)) |
| 106 | |
| 107 | (define-key map [show] (cons "Show" (make-sparse-keymap "Show"))) |
| 108 | |
| 109 | (define-key map [show show-subtree] '("Show Subtree" . show-subtree)) |
| 110 | (define-key map [show show-children] '("Show Children" . show-children)) |
| 111 | (define-key map [show show-branches] '("Show Branches" . show-branches)) |
| 112 | (define-key map [show show-entry] '("Show Entry" . show-entry)) |
| 113 | (define-key map [show show-all] '("Show All" . show-all)) |
| 114 | |
| 115 | (define-key map [headings] |
| 116 | (cons "Headings" (make-sparse-keymap "Headings"))) |
| 117 | |
| 118 | (define-key map [headings demote-subtree] |
| 119 | '(menu-item "Demote subtree" outline-demote)) |
| 120 | (define-key map [headings promote-subtree] |
| 121 | '(menu-item "Promote subtree" outline-promote)) |
| 122 | (define-key map [headings move-subtree-down] |
| 123 | '(menu-item "Move subtree down" outline-move-subtree-down)) |
| 124 | (define-key map [headings move-subtree-up] |
| 125 | '(menu-item "Move subtree up" outline-move-subtree-up)) |
| 126 | (define-key map [headings copy] |
| 127 | '(menu-item "Copy to kill ring" outline-headers-as-kill |
| 128 | :enable mark-active)) |
| 129 | (define-key map [headings outline-insert-heading] |
| 130 | '("New heading" . outline-insert-heading)) |
| 131 | (define-key map [headings outline-backward-same-level] |
| 132 | '("Previous Same Level" . outline-backward-same-level)) |
| 133 | (define-key map [headings outline-forward-same-level] |
| 134 | '("Next Same Level" . outline-forward-same-level)) |
| 135 | (define-key map [headings outline-previous-visible-heading] |
| 136 | '("Previous" . outline-previous-visible-heading)) |
| 137 | (define-key map [headings outline-next-visible-heading] |
| 138 | '("Next" . outline-next-visible-heading)) |
| 139 | (define-key map [headings outline-up-heading] |
| 140 | '("Up" . outline-up-heading)) |
| 141 | map)) |
| 142 | |
| 143 | (defvar outline-minor-mode-menu-bar-map |
| 144 | (let ((map (make-sparse-keymap))) |
| 145 | (define-key map [outline] |
| 146 | (cons "Outline" |
| 147 | (nconc (make-sparse-keymap "Outline") |
| 148 | ;; Remove extra separator |
| 149 | (cdr |
| 150 | ;; Flatten the major mode's menus into a single menu. |
| 151 | (apply 'append |
| 152 | (mapcar (lambda (x) |
| 153 | (if (consp x) |
| 154 | ;; Add a separator between each |
| 155 | ;; part of the unified menu. |
| 156 | (cons '(--- "---") (cdr x)))) |
| 157 | outline-mode-menu-bar-map)))))) |
| 158 | map)) |
| 159 | |
| 160 | |
| 161 | (defvar outline-mode-map |
| 162 | (let ((map (make-sparse-keymap))) |
| 163 | (define-key map "\C-c" outline-mode-prefix-map) |
| 164 | (define-key map [menu-bar] outline-mode-menu-bar-map) |
| 165 | map)) |
| 166 | |
| 167 | (defvar outline-font-lock-keywords |
| 168 | '(;; |
| 169 | ;; Highlight headings according to the level. |
| 170 | (eval . (list (concat "^\\(?:" outline-regexp "\\).+") |
| 171 | 0 '(outline-font-lock-face) nil t))) |
| 172 | "Additional expressions to highlight in Outline mode.") |
| 173 | |
| 174 | (defface outline-1 |
| 175 | '((t :inherit font-lock-function-name-face)) |
| 176 | "Level 1." |
| 177 | :group 'outlines) |
| 178 | |
| 179 | (defface outline-2 |
| 180 | '((t :inherit font-lock-variable-name-face)) |
| 181 | "Level 2." |
| 182 | :group 'outlines) |
| 183 | |
| 184 | (defface outline-3 |
| 185 | '((t :inherit font-lock-keyword-face)) |
| 186 | "Level 3." |
| 187 | :group 'outlines) |
| 188 | |
| 189 | (defface outline-4 |
| 190 | '((t :inherit font-lock-builtin-face)) |
| 191 | "Level 4." |
| 192 | :group 'outlines) |
| 193 | |
| 194 | (defface outline-5 |
| 195 | '((t :inherit font-lock-comment-face)) |
| 196 | "Level 5." |
| 197 | :group 'outlines) |
| 198 | |
| 199 | (defface outline-6 |
| 200 | '((t :inherit font-lock-constant-face)) |
| 201 | "Level 6." |
| 202 | :group 'outlines) |
| 203 | |
| 204 | (defface outline-7 |
| 205 | '((t :inherit font-lock-type-face)) |
| 206 | "Level 7." |
| 207 | :group 'outlines) |
| 208 | |
| 209 | (defface outline-8 |
| 210 | '((t :inherit font-lock-string-face)) |
| 211 | "Level 8." |
| 212 | :group 'outlines) |
| 213 | |
| 214 | (defvar outline-font-lock-faces |
| 215 | [outline-1 outline-2 outline-3 outline-4 |
| 216 | outline-5 outline-6 outline-7 outline-8]) |
| 217 | |
| 218 | (defvar outline-font-lock-levels nil) |
| 219 | (make-variable-buffer-local 'outline-font-lock-levels) |
| 220 | |
| 221 | (defun outline-font-lock-face () |
| 222 | ;; (save-excursion |
| 223 | ;; (outline-back-to-heading t) |
| 224 | ;; (let* ((count 0) |
| 225 | ;; (start-level (funcall outline-level)) |
| 226 | ;; (level start-level) |
| 227 | ;; face-level) |
| 228 | ;; (while (not (setq face-level |
| 229 | ;; (if (or (bobp) (eq level 1)) 0 |
| 230 | ;; (cdr (assq level outline-font-lock-levels))))) |
| 231 | ;; (outline-up-heading 1 t) |
| 232 | ;; (setq count (1+ count)) |
| 233 | ;; (setq level (funcall outline-level))) |
| 234 | ;; ;; Remember for later. |
| 235 | ;; (unless (zerop count) |
| 236 | ;; (setq face-level (+ face-level count)) |
| 237 | ;; (push (cons start-level face-level) outline-font-lock-levels)) |
| 238 | ;; (condition-case nil |
| 239 | ;; (aref outline-font-lock-faces face-level) |
| 240 | ;; (error font-lock-warning-face)))) |
| 241 | (save-excursion |
| 242 | (goto-char (match-beginning 0)) |
| 243 | (looking-at outline-regexp) |
| 244 | (condition-case nil |
| 245 | (aref outline-font-lock-faces (1- (funcall outline-level))) |
| 246 | (error font-lock-warning-face)))) |
| 247 | |
| 248 | (defvar outline-view-change-hook nil |
| 249 | "Normal hook to be run after outline visibility changes.") |
| 250 | |
| 251 | (defvar outline-mode-hook nil |
| 252 | "*This hook is run when outline mode starts.") |
| 253 | |
| 254 | (defvar outline-blank-line nil |
| 255 | "*Non-nil means to leave unhidden blank line before heading.") |
| 256 | |
| 257 | ;;;###autoload |
| 258 | (define-derived-mode outline-mode text-mode "Outline" |
| 259 | "Set major mode for editing outlines with selective display. |
| 260 | Headings are lines which start with asterisks: one for major headings, |
| 261 | two for subheadings, etc. Lines not starting with asterisks are body lines. |
| 262 | |
| 263 | Body text or subheadings under a heading can be made temporarily |
| 264 | invisible, or visible again. Invisible lines are attached to the end |
| 265 | of the heading, so they move with it, if the line is killed and yanked |
| 266 | back. A heading with text hidden under it is marked with an ellipsis (...). |
| 267 | |
| 268 | Commands:\\<outline-mode-map> |
| 269 | \\[outline-next-visible-heading] outline-next-visible-heading move by visible headings |
| 270 | \\[outline-previous-visible-heading] outline-previous-visible-heading |
| 271 | \\[outline-forward-same-level] outline-forward-same-level similar but skip subheadings |
| 272 | \\[outline-backward-same-level] outline-backward-same-level |
| 273 | \\[outline-up-heading] outline-up-heading move from subheading to heading |
| 274 | |
| 275 | \\[hide-body] make all text invisible (not headings). |
| 276 | \\[show-all] make everything in buffer visible. |
| 277 | \\[hide-sublevels] make only the first N levels of headers visible. |
| 278 | |
| 279 | The remaining commands are used when point is on a heading line. |
| 280 | They apply to some of the body or subheadings of that heading. |
| 281 | \\[hide-subtree] hide-subtree make body and subheadings invisible. |
| 282 | \\[show-subtree] show-subtree make body and subheadings visible. |
| 283 | \\[show-children] show-children make direct subheadings visible. |
| 284 | No effect on body, or subheadings 2 or more levels down. |
| 285 | With arg N, affects subheadings N levels down. |
| 286 | \\[hide-entry] make immediately following body invisible. |
| 287 | \\[show-entry] make it visible. |
| 288 | \\[hide-leaves] make body under heading and under its subheadings invisible. |
| 289 | The subheadings remain visible. |
| 290 | \\[show-branches] make all subheadings at all levels visible. |
| 291 | |
| 292 | The variable `outline-regexp' can be changed to control what is a heading. |
| 293 | A line is a heading if `outline-regexp' matches something at the |
| 294 | beginning of the line. The longer the match, the deeper the level. |
| 295 | |
| 296 | Turning on outline mode calls the value of `text-mode-hook' and then of |
| 297 | `outline-mode-hook', if they are non-nil." |
| 298 | (make-local-variable 'line-move-ignore-invisible) |
| 299 | (setq line-move-ignore-invisible t) |
| 300 | ;; Cause use of ellipses for invisible text. |
| 301 | (add-to-invisibility-spec '(outline . t)) |
| 302 | (set (make-local-variable 'paragraph-start) |
| 303 | (concat paragraph-start "\\|\\(?:" outline-regexp "\\)")) |
| 304 | ;; Inhibit auto-filling of header lines. |
| 305 | (set (make-local-variable 'auto-fill-inhibit-regexp) outline-regexp) |
| 306 | (set (make-local-variable 'paragraph-separate) |
| 307 | (concat paragraph-separate "\\|\\(?:" outline-regexp "\\)")) |
| 308 | (set (make-local-variable 'font-lock-defaults) |
| 309 | '(outline-font-lock-keywords t nil nil backward-paragraph)) |
| 310 | (setq imenu-generic-expression |
| 311 | (list (list nil (concat "^\\(?:" outline-regexp "\\).*$") 0))) |
| 312 | (add-hook 'change-major-mode-hook 'show-all nil t)) |
| 313 | |
| 314 | (defcustom outline-minor-mode-prefix "\C-c@" |
| 315 | "*Prefix key to use for Outline commands in Outline minor mode. |
| 316 | The value of this variable is checked as part of loading Outline mode. |
| 317 | After that, changing the prefix key requires manipulating keymaps." |
| 318 | :type 'string |
| 319 | :group 'outlines) |
| 320 | |
| 321 | ;;;###autoload |
| 322 | (define-minor-mode outline-minor-mode |
| 323 | "Toggle Outline minor mode. |
| 324 | With arg, turn Outline minor mode on if arg is positive, off otherwise. |
| 325 | See the command `outline-mode' for more information on this mode." |
| 326 | nil " Outl" (list (cons [menu-bar] outline-minor-mode-menu-bar-map) |
| 327 | (cons outline-minor-mode-prefix outline-mode-prefix-map)) |
| 328 | :group 'outlines |
| 329 | (if outline-minor-mode |
| 330 | (progn |
| 331 | ;; Turn off this mode if we change major modes. |
| 332 | (add-hook 'change-major-mode-hook |
| 333 | (lambda () (outline-minor-mode -1)) |
| 334 | nil t) |
| 335 | (set (make-local-variable 'line-move-ignore-invisible) t) |
| 336 | ;; Cause use of ellipses for invisible text. |
| 337 | (add-to-invisibility-spec '(outline . t))) |
| 338 | (setq line-move-ignore-invisible nil) |
| 339 | ;; Cause use of ellipses for invisible text. |
| 340 | (remove-from-invisibility-spec '(outline . t)) |
| 341 | ;; When turning off outline mode, get rid of any outline hiding. |
| 342 | (show-all))) |
| 343 | \f |
| 344 | (defvar outline-level 'outline-level |
| 345 | "*Function of no args to compute a header's nesting level in an outline. |
| 346 | It can assume point is at the beginning of a header line and that the match |
| 347 | data reflects the `outline-regexp'.") |
| 348 | |
| 349 | (defvar outline-heading-alist () |
| 350 | "Alist associating a heading for every possible level. |
| 351 | Each entry is of the form (HEADING . LEVEL). |
| 352 | This alist is used two ways: to find the heading corresponding to |
| 353 | a given level and to find the level of a given heading. |
| 354 | If a mode or document needs several sets of outline headings (for example |
| 355 | numbered and unnumbered sections), list them set by set and sorted by level |
| 356 | within each set. For example in texinfo mode: |
| 357 | |
| 358 | (setq outline-heading-alist |
| 359 | '((\"@chapter\" . 2) (\"@section\" . 3) (\"@subsection\" . 4) |
| 360 | (\"@subsubsection\" . 5) |
| 361 | (\"@unnumbered\" . 2) (\"@unnumberedsec\" . 3) |
| 362 | (\"@unnumberedsubsec\" . 4) (\"@unnumberedsubsubsec\" . 5) |
| 363 | (\"@appendix\" . 2) (\"@appendixsec\" . 3)... |
| 364 | (\"@appendixsubsec\" . 4) (\"@appendixsubsubsec\" . 5) ..)) |
| 365 | |
| 366 | Instead of sorting the entries in each set, you can also separate the |
| 367 | sets with nil.") |
| 368 | (make-variable-buffer-local 'outline-heading-alist) |
| 369 | |
| 370 | ;; This used to count columns rather than characters, but that made ^L |
| 371 | ;; appear to be at level 2 instead of 1. Columns would be better for |
| 372 | ;; tab handling, but the default regexp doesn't use tabs, and anyone |
| 373 | ;; who changes the regexp can also redefine the outline-level variable |
| 374 | ;; as appropriate. |
| 375 | (defun outline-level () |
| 376 | "Return the depth to which a statement is nested in the outline. |
| 377 | Point must be at the beginning of a header line. |
| 378 | This is actually either the level specified in `outline-heading-alist' |
| 379 | or else the number of characters matched by `outline-regexp'." |
| 380 | (or (cdr (assoc (match-string 0) outline-heading-alist)) |
| 381 | (- (match-end 0) (match-beginning 0)))) |
| 382 | |
| 383 | (defun outline-next-preface () |
| 384 | "Skip forward to just before the next heading line. |
| 385 | If there's no following heading line, stop before the newline |
| 386 | at the end of the buffer." |
| 387 | (if (re-search-forward (concat "\n\\(?:" outline-regexp "\\)") |
| 388 | nil 'move) |
| 389 | (goto-char (match-beginning 0))) |
| 390 | (if (and (bolp) (or outline-blank-line (eobp)) (not (bobp))) |
| 391 | (forward-char -1))) |
| 392 | |
| 393 | (defun outline-next-heading () |
| 394 | "Move to the next (possibly invisible) heading line." |
| 395 | (interactive) |
| 396 | ;; Make sure we don't match the heading we're at. |
| 397 | (if (and (bolp) (not (eobp))) (forward-char 1)) |
| 398 | (if (re-search-forward (concat "^\\(?:" outline-regexp "\\)") |
| 399 | nil 'move) |
| 400 | (goto-char (match-beginning 0)))) |
| 401 | |
| 402 | (defun outline-previous-heading () |
| 403 | "Move to the previous (possibly invisible) heading line." |
| 404 | (interactive) |
| 405 | (re-search-backward (concat "^\\(?:" outline-regexp "\\)") |
| 406 | nil 'move)) |
| 407 | |
| 408 | (defsubst outline-invisible-p (&optional pos) |
| 409 | "Non-nil if the character after point is invisible." |
| 410 | (get-char-property (or pos (point)) 'invisible)) |
| 411 | |
| 412 | (defun outline-visible () |
| 413 | (not (outline-invisible-p))) |
| 414 | (make-obsolete 'outline-visible 'outline-invisible-p) |
| 415 | |
| 416 | (defun outline-back-to-heading (&optional invisible-ok) |
| 417 | "Move to previous heading line, or beg of this line if it's a heading. |
| 418 | Only visible heading lines are considered, unless INVISIBLE-OK is non-nil." |
| 419 | (beginning-of-line) |
| 420 | (or (outline-on-heading-p invisible-ok) |
| 421 | (let (found) |
| 422 | (save-excursion |
| 423 | (while (not found) |
| 424 | (or (re-search-backward (concat "^\\(?:" outline-regexp "\\)") |
| 425 | nil t) |
| 426 | (error "before first heading")) |
| 427 | (setq found (and (or invisible-ok (not (outline-invisible-p))) |
| 428 | (point))))) |
| 429 | (goto-char found) |
| 430 | found))) |
| 431 | |
| 432 | (defun outline-on-heading-p (&optional invisible-ok) |
| 433 | "Return t if point is on a (visible) heading line. |
| 434 | If INVISIBLE-OK is non-nil, an invisible heading line is ok too." |
| 435 | (save-excursion |
| 436 | (beginning-of-line) |
| 437 | (and (bolp) (or invisible-ok (not (outline-invisible-p))) |
| 438 | (looking-at outline-regexp)))) |
| 439 | |
| 440 | (defun outline-insert-heading () |
| 441 | "Insert a new heading at same depth at point." |
| 442 | (interactive) |
| 443 | (let ((head (save-excursion |
| 444 | (condition-case nil |
| 445 | (outline-back-to-heading) |
| 446 | (error (outline-next-heading))) |
| 447 | (if (eobp) |
| 448 | (or (caar outline-heading-alist) "") |
| 449 | (match-string 0))))) |
| 450 | (unless (or (string-match "[ \t]\\'" head) |
| 451 | (not (string-match (concat "\\`\\(?:" outline-regexp "\\)") |
| 452 | (concat head " ")))) |
| 453 | (setq head (concat head " "))) |
| 454 | (unless (bolp) (end-of-line) (newline)) |
| 455 | (insert head) |
| 456 | (unless (eolp) |
| 457 | (save-excursion (newline-and-indent))) |
| 458 | (run-hooks 'outline-insert-heading-hook))) |
| 459 | |
| 460 | (defun outline-invent-heading (head up) |
| 461 | (save-match-data |
| 462 | ;; Let's try to invent one by repeating or deleting the last char. |
| 463 | (let ((new-head (if up (substring head 0 -1) |
| 464 | (concat head (substring head -1))))) |
| 465 | (if (string-match (concat "\\`\\(?:" outline-regexp "\\)") |
| 466 | new-head) |
| 467 | ;; Why bother checking that it is indeed higher/lower level ? |
| 468 | new-head |
| 469 | ;; Didn't work, so ask what to do. |
| 470 | (read-string (format "%s heading for `%s': " |
| 471 | (if up "Parent" "Demoted") head) |
| 472 | head nil nil t))))) |
| 473 | |
| 474 | (defun outline-promote (&optional children) |
| 475 | "Promote headings higher up the tree. |
| 476 | If prefix argument CHILDREN is given, promote also all the children. |
| 477 | If the region is active in `transient-mark-mode', promote all headings |
| 478 | in the region." |
| 479 | (interactive |
| 480 | (list (if (and transient-mark-mode mark-active) 'region |
| 481 | (outline-back-to-heading) |
| 482 | (if current-prefix-arg nil 'subtree)))) |
| 483 | (cond |
| 484 | ((eq children 'region) |
| 485 | (outline-map-region 'outline-promote (region-beginning) (region-end))) |
| 486 | (children |
| 487 | (outline-map-region 'outline-promote |
| 488 | (point) |
| 489 | (save-excursion (outline-get-next-sibling) (point)))) |
| 490 | (t |
| 491 | (outline-back-to-heading t) |
| 492 | (let* ((head (match-string-no-properties 0)) |
| 493 | (level (save-match-data (funcall outline-level))) |
| 494 | (up-head (or (outline-head-from-level (1- level) head) |
| 495 | ;; Use the parent heading, if it is really |
| 496 | ;; one level less. |
| 497 | (save-excursion |
| 498 | (save-match-data |
| 499 | (outline-up-heading 1 t) |
| 500 | (and (= (1- level) (funcall outline-level)) |
| 501 | (match-string-no-properties 0)))) |
| 502 | ;; Bummer!! There is no lower level heading. |
| 503 | (outline-invent-heading head 'up)))) |
| 504 | |
| 505 | (unless (rassoc level outline-heading-alist) |
| 506 | (push (cons head level) outline-heading-alist)) |
| 507 | |
| 508 | (replace-match up-head nil t))))) |
| 509 | |
| 510 | (defun outline-demote (&optional children) |
| 511 | "Demote headings lower down the tree. |
| 512 | If prefix argument CHILDREN is given, demote also all the children. |
| 513 | If the region is active in `transient-mark-mode', demote all headings |
| 514 | in the region." |
| 515 | (interactive |
| 516 | (list (if (and transient-mark-mode mark-active) 'region |
| 517 | (outline-back-to-heading) |
| 518 | (if current-prefix-arg nil 'subtree)))) |
| 519 | (cond |
| 520 | ((eq children 'region) |
| 521 | (outline-map-region 'outline-demote (region-beginning) (region-end))) |
| 522 | (children |
| 523 | (outline-map-region 'outline-demote |
| 524 | (point) |
| 525 | (save-excursion (outline-get-next-sibling) (point)))) |
| 526 | (t |
| 527 | (let* ((head (match-string-no-properties 0)) |
| 528 | (level (save-match-data (funcall outline-level))) |
| 529 | (down-head |
| 530 | (or (outline-head-from-level (1+ level) head) |
| 531 | (save-excursion |
| 532 | (save-match-data |
| 533 | (while (and (progn (outline-next-heading) (not (eobp))) |
| 534 | (<= (funcall outline-level) level))) |
| 535 | (when (eobp) |
| 536 | ;; Try again from the beginning of the buffer. |
| 537 | (goto-char (point-min)) |
| 538 | (while (and (progn (outline-next-heading) (not (eobp))) |
| 539 | (<= (funcall outline-level) level)))) |
| 540 | (unless (eobp) |
| 541 | (looking-at outline-regexp) |
| 542 | (match-string-no-properties 0)))) |
| 543 | ;; Bummer!! There is no higher-level heading in the buffer. |
| 544 | (outline-invent-heading head nil)))) |
| 545 | |
| 546 | (unless (rassoc level outline-heading-alist) |
| 547 | (push (cons head level) outline-heading-alist)) |
| 548 | (replace-match down-head nil t))))) |
| 549 | |
| 550 | (defun outline-head-from-level (level head &optional alist) |
| 551 | "Get new heading with level LEVEL from ALIST. |
| 552 | If there are no such entries, return nil. |
| 553 | ALIST defaults to `outline-heading-alist'. |
| 554 | Similar to (car (rassoc LEVEL ALIST)). |
| 555 | If there are several different entries with same new level, choose |
| 556 | the one with the smallest distance to the assocation of HEAD in the alist. |
| 557 | This makes it possible for promotion to work in modes with several |
| 558 | independent sets of headings (numbered, unnumbered, appendix...)" |
| 559 | (unless alist (setq alist outline-heading-alist)) |
| 560 | (let ((l (rassoc level alist)) |
| 561 | ll h hl l2 l2l) |
| 562 | (cond |
| 563 | ((null l) nil) |
| 564 | ;; If there's no HEAD after L, any other entry for LEVEL after L |
| 565 | ;; can't be much better than L. |
| 566 | ((null (setq h (assoc head (setq ll (memq l alist))))) (car l)) |
| 567 | ;; If there's no other entry for LEVEL, just keep L. |
| 568 | ((null (setq l2 (rassoc level (cdr ll)))) (car l)) |
| 569 | ;; Now we have L, L2, and H: see if L2 seems better than L. |
| 570 | ;; If H is after L2, L2 is better. |
| 571 | ((memq h (setq l2l (memq l2 (cdr ll)))) |
| 572 | (outline-head-from-level level head l2l)) |
| 573 | ;; Now we have H between L and L2. |
| 574 | ;; If there's a separator between L and H, prefer L2. |
| 575 | ((memq h (memq nil ll)) |
| 576 | (outline-head-from-level level head l2l)) |
| 577 | ;; If there's a separator between L2 and H, prefer L. |
| 578 | ((memq l2 (memq nil (setq hl (memq h ll)))) (car l)) |
| 579 | ;; No separator between L and L2, check the distance. |
| 580 | ((< (* 2 (length hl)) (+ (length ll) (length l2l))) |
| 581 | (outline-head-from-level level head l2l)) |
| 582 | ;; If all else fails, just keep L. |
| 583 | (t (car l))))) |
| 584 | |
| 585 | (defun outline-map-region (fun beg end) |
| 586 | "Call FUN for every heading between BEG and END. |
| 587 | When FUN is called, point is at the beginning of the heading and |
| 588 | the match data is set appropriately." |
| 589 | (save-excursion |
| 590 | (setq end (copy-marker end)) |
| 591 | (goto-char beg) |
| 592 | (when (re-search-forward (concat "^\\(?:" outline-regexp "\\)") end t) |
| 593 | (goto-char (match-beginning 0)) |
| 594 | (funcall fun) |
| 595 | (while (and (progn |
| 596 | (outline-next-heading) |
| 597 | (< (point) end)) |
| 598 | (not (eobp))) |
| 599 | (funcall fun))))) |
| 600 | |
| 601 | ;; Vertical tree motion |
| 602 | |
| 603 | (defun outline-move-subtree-up (&optional arg) |
| 604 | "Move the currrent subtree up past ARG headlines of the same level." |
| 605 | (interactive "p") |
| 606 | (outline-move-subtree-down (- arg))) |
| 607 | |
| 608 | (defun outline-move-subtree-down (&optional arg) |
| 609 | "Move the currrent subtree down past ARG headlines of the same level." |
| 610 | (interactive "p") |
| 611 | (let ((movfunc (if (> arg 0) 'outline-get-next-sibling |
| 612 | 'outline-get-last-sibling)) |
| 613 | (ins-point (make-marker)) |
| 614 | (cnt (abs arg)) |
| 615 | beg end folded) |
| 616 | ;; Select the tree |
| 617 | (outline-back-to-heading) |
| 618 | (setq beg (point)) |
| 619 | (save-match-data |
| 620 | (save-excursion (outline-end-of-heading) |
| 621 | (setq folded (outline-invisible-p))) |
| 622 | (outline-end-of-subtree)) |
| 623 | (if (= (char-after) ?\n) (forward-char 1)) |
| 624 | (setq end (point)) |
| 625 | ;; Find insertion point, with error handling |
| 626 | (goto-char beg) |
| 627 | (while (> cnt 0) |
| 628 | (or (funcall movfunc) |
| 629 | (progn (goto-char beg) |
| 630 | (error "Cannot move past superior level"))) |
| 631 | (setq cnt (1- cnt))) |
| 632 | (if (> arg 0) |
| 633 | ;; Moving forward - still need to move over subtree |
| 634 | (progn (outline-end-of-subtree) |
| 635 | (if (= (char-after) ?\n) (forward-char 1)))) |
| 636 | (move-marker ins-point (point)) |
| 637 | (insert (delete-and-extract-region beg end)) |
| 638 | (goto-char ins-point) |
| 639 | (if folded (hide-subtree)) |
| 640 | (move-marker ins-point nil))) |
| 641 | |
| 642 | (defun outline-end-of-heading () |
| 643 | (if (re-search-forward outline-heading-end-regexp nil 'move) |
| 644 | (forward-char -1))) |
| 645 | |
| 646 | (defun outline-next-visible-heading (arg) |
| 647 | "Move to the next visible heading line. |
| 648 | With argument, repeats or can move backward if negative. |
| 649 | A heading line is one that starts with a `*' (or that |
| 650 | `outline-regexp' matches)." |
| 651 | (interactive "p") |
| 652 | (if (< arg 0) |
| 653 | (beginning-of-line) |
| 654 | (end-of-line)) |
| 655 | (while (and (not (bobp)) (< arg 0)) |
| 656 | (while (and (not (bobp)) |
| 657 | (re-search-backward (concat "^\\(?:" outline-regexp "\\)") |
| 658 | nil 'move) |
| 659 | (outline-invisible-p))) |
| 660 | (setq arg (1+ arg))) |
| 661 | (while (and (not (eobp)) (> arg 0)) |
| 662 | (while (and (not (eobp)) |
| 663 | (re-search-forward (concat "^\\(?:" outline-regexp "\\)") |
| 664 | nil 'move) |
| 665 | (outline-invisible-p (match-beginning 0)))) |
| 666 | (setq arg (1- arg))) |
| 667 | (beginning-of-line)) |
| 668 | |
| 669 | (defun outline-previous-visible-heading (arg) |
| 670 | "Move to the previous heading line. |
| 671 | With argument, repeats or can move forward if negative. |
| 672 | A heading line is one that starts with a `*' (or that |
| 673 | `outline-regexp' matches)." |
| 674 | (interactive "p") |
| 675 | (outline-next-visible-heading (- arg))) |
| 676 | |
| 677 | (defun outline-mark-subtree () |
| 678 | "Mark the current subtree in an outlined document. |
| 679 | This puts point at the start of the current subtree, and mark at the end." |
| 680 | (interactive) |
| 681 | (let ((beg)) |
| 682 | (if (outline-on-heading-p) |
| 683 | ;; we are already looking at a heading |
| 684 | (beginning-of-line) |
| 685 | ;; else go back to previous heading |
| 686 | (outline-previous-visible-heading 1)) |
| 687 | (setq beg (point)) |
| 688 | (outline-end-of-subtree) |
| 689 | (push-mark (point) nil t) |
| 690 | (goto-char beg))) |
| 691 | \f |
| 692 | |
| 693 | (put 'outline 'reveal-toggle-invisible 'outline-reveal-toggle-invisible) |
| 694 | (defun outline-flag-region (from to flag) |
| 695 | "Hide or show lines from FROM to TO, according to FLAG. |
| 696 | If FLAG is nil then text is shown, while if FLAG is t the text is hidden." |
| 697 | (remove-overlays from to 'invisible 'outline) |
| 698 | (when flag |
| 699 | (let ((o (make-overlay from to))) |
| 700 | (overlay-put o 'invisible 'outline) |
| 701 | (overlay-put o 'isearch-open-invisible 'outline-isearch-open-invisible))) |
| 702 | ;; Seems only used by lazy-lock. I.e. obsolete. |
| 703 | (run-hooks 'outline-view-change-hook)) |
| 704 | |
| 705 | (defun outline-reveal-toggle-invisible (o hidep) |
| 706 | (save-excursion |
| 707 | (goto-char (overlay-start o)) |
| 708 | (if hidep |
| 709 | ;; When hiding the area again, we could just clean it up and let |
| 710 | ;; reveal do the rest, by simply doing: |
| 711 | ;; (remove-overlays (overlay-start o) (overlay-end o) |
| 712 | ;; 'invisible 'outline) |
| 713 | ;; |
| 714 | ;; That works fine as long as everything is in sync, but if the |
| 715 | ;; structure of the document is changed while revealing parts of it, |
| 716 | ;; the resulting behavior can be ugly. I.e. we need to make |
| 717 | ;; sure that we hide exactly a subtree. |
| 718 | (progn |
| 719 | (let ((end (overlay-end o))) |
| 720 | (delete-overlay o) |
| 721 | (while (progn |
| 722 | (hide-subtree) |
| 723 | (outline-next-visible-heading 1) |
| 724 | (and (not (eobp)) (< (point) end)))))) |
| 725 | |
| 726 | ;; When revealing, we just need to reveal sublevels. If point is |
| 727 | ;; inside one of the sublevels, reveal will call us again. |
| 728 | ;; But we need to preserve the original overlay. |
| 729 | (let ((o1 (copy-overlay o))) |
| 730 | (overlay-put o 'invisible nil) ;Show (most of) the text. |
| 731 | (while (progn |
| 732 | (show-entry) |
| 733 | (show-children) |
| 734 | ;; Normally just the above is needed. |
| 735 | ;; But in odd cases, the above might fail to show anything. |
| 736 | ;; To avoid an infinite loop, we have to make sure that |
| 737 | ;; *something* gets shown. |
| 738 | (and (equal (overlay-start o) (overlay-start o1)) |
| 739 | (< (point) (overlay-end o)) |
| 740 | (= 0 (forward-line 1))))) |
| 741 | ;; If still nothing was shown, just kill the damn thing. |
| 742 | (when (equal (overlay-start o) (overlay-start o1)) |
| 743 | ;; I've seen it happen at the end of buffer. |
| 744 | (delete-overlay o1)))))) |
| 745 | |
| 746 | ;; Function to be set as an outline-isearch-open-invisible' property |
| 747 | ;; to the overlay that makes the outline invisible (see |
| 748 | ;; `outline-flag-region'). |
| 749 | (defun outline-isearch-open-invisible (overlay) |
| 750 | ;; We rely on the fact that isearch places point on the matched text. |
| 751 | (show-entry)) |
| 752 | \f |
| 753 | (defun hide-entry () |
| 754 | "Hide the body directly following this heading." |
| 755 | (interactive) |
| 756 | (save-excursion |
| 757 | (outline-back-to-heading) |
| 758 | (outline-end-of-heading) |
| 759 | (outline-flag-region (point) (progn (outline-next-preface) (point)) t))) |
| 760 | |
| 761 | (defun show-entry () |
| 762 | "Show the body directly following this heading. |
| 763 | Show the heading too, if it is currently invisible." |
| 764 | (interactive) |
| 765 | (save-excursion |
| 766 | (outline-back-to-heading t) |
| 767 | (outline-flag-region (1- (point)) |
| 768 | (progn (outline-next-preface) (point)) nil))) |
| 769 | |
| 770 | (defun hide-body () |
| 771 | "Hide all body lines in buffer, leaving all headings visible." |
| 772 | (interactive) |
| 773 | (hide-region-body (point-min) (point-max))) |
| 774 | |
| 775 | (defun hide-region-body (start end) |
| 776 | "Hide all body lines in the region, but not headings." |
| 777 | ;; Nullify the hook to avoid repeated calls to `outline-flag-region' |
| 778 | ;; wasting lots of time running `lazy-lock-fontify-after-outline' |
| 779 | ;; and run the hook finally. |
| 780 | (let (outline-view-change-hook) |
| 781 | (save-excursion |
| 782 | (save-restriction |
| 783 | (narrow-to-region start end) |
| 784 | (goto-char (point-min)) |
| 785 | (if (outline-on-heading-p) |
| 786 | (outline-end-of-heading) |
| 787 | (outline-next-preface)) |
| 788 | (while (not (eobp)) |
| 789 | (outline-flag-region (point) |
| 790 | (progn (outline-next-preface) (point)) t) |
| 791 | (unless (eobp) |
| 792 | (forward-char (if (looking-at "\n\n") 2 1)) |
| 793 | (outline-end-of-heading)))))) |
| 794 | (run-hooks 'outline-view-change-hook)) |
| 795 | |
| 796 | (defun show-all () |
| 797 | "Show all of the text in the buffer." |
| 798 | (interactive) |
| 799 | (outline-flag-region (point-min) (point-max) nil)) |
| 800 | |
| 801 | (defun hide-subtree () |
| 802 | "Hide everything after this heading at deeper levels." |
| 803 | (interactive) |
| 804 | (outline-flag-subtree t)) |
| 805 | |
| 806 | (defun hide-leaves () |
| 807 | "Hide the body after this heading and at deeper levels." |
| 808 | (interactive) |
| 809 | (save-excursion |
| 810 | (outline-back-to-heading) |
| 811 | ;; Turned off to fix bug reported by Otto Maddox on 22 Nov 2005. |
| 812 | ;; (outline-end-of-heading) |
| 813 | (hide-region-body (point) (progn (outline-end-of-subtree) (point))))) |
| 814 | |
| 815 | (defun show-subtree () |
| 816 | "Show everything after this heading at deeper levels." |
| 817 | (interactive) |
| 818 | (outline-flag-subtree nil)) |
| 819 | |
| 820 | (defun outline-show-heading () |
| 821 | "Show the current heading and move to its end." |
| 822 | (outline-flag-region (- (point) |
| 823 | (if (bobp) 0 |
| 824 | (if (and outline-blank-line |
| 825 | (eq (char-before (1- (point))) ?\n)) |
| 826 | 2 1))) |
| 827 | (progn (outline-end-of-heading) (point)) |
| 828 | nil)) |
| 829 | |
| 830 | (defun hide-sublevels (levels) |
| 831 | "Hide everything but the top LEVELS levels of headers, in whole buffer." |
| 832 | (interactive (list |
| 833 | (cond |
| 834 | (current-prefix-arg (prefix-numeric-value current-prefix-arg)) |
| 835 | ((save-excursion (beginning-of-line) |
| 836 | (looking-at outline-regexp)) |
| 837 | (funcall outline-level)) |
| 838 | (t 1)))) |
| 839 | (if (< levels 1) |
| 840 | (error "Must keep at least one level of headers")) |
| 841 | (let (outline-view-change-hook) |
| 842 | (save-excursion |
| 843 | (goto-char (point-min)) |
| 844 | ;; Skip the prelude, if any. |
| 845 | (unless (outline-on-heading-p t) (outline-next-heading)) |
| 846 | ;; First hide everything. |
| 847 | (outline-flag-region (point) (point-max) t) |
| 848 | ;; Then unhide the top level headers. |
| 849 | (outline-map-region |
| 850 | (lambda () |
| 851 | (if (<= (funcall outline-level) levels) |
| 852 | (outline-show-heading))) |
| 853 | (point) (point-max)))) |
| 854 | (run-hooks 'outline-view-change-hook)) |
| 855 | |
| 856 | (defun hide-other () |
| 857 | "Hide everything except current body and parent and top-level headings." |
| 858 | (interactive) |
| 859 | (hide-sublevels 1) |
| 860 | (let (outline-view-change-hook) |
| 861 | (save-excursion |
| 862 | (outline-back-to-heading t) |
| 863 | (show-entry) |
| 864 | (while (condition-case nil (progn (outline-up-heading 1 t) (not (bobp))) |
| 865 | (error nil)) |
| 866 | (outline-flag-region (1- (point)) |
| 867 | (save-excursion (forward-line 1) (point)) |
| 868 | nil)))) |
| 869 | (run-hooks 'outline-view-change-hook)) |
| 870 | |
| 871 | (defun outline-toggle-children () |
| 872 | "Show or hide the current subtree depending on its current state." |
| 873 | (interactive) |
| 874 | (save-excursion |
| 875 | (outline-back-to-heading) |
| 876 | (if (not (outline-invisible-p (line-end-position))) |
| 877 | (hide-subtree) |
| 878 | (show-children) |
| 879 | (show-entry)))) |
| 880 | |
| 881 | (defun outline-flag-subtree (flag) |
| 882 | (save-excursion |
| 883 | (outline-back-to-heading) |
| 884 | (outline-end-of-heading) |
| 885 | (outline-flag-region (point) |
| 886 | (progn (outline-end-of-subtree) (point)) |
| 887 | flag))) |
| 888 | |
| 889 | (defun outline-end-of-subtree () |
| 890 | (outline-back-to-heading) |
| 891 | (let ((first t) |
| 892 | (level (funcall outline-level))) |
| 893 | (while (and (not (eobp)) |
| 894 | (or first (> (funcall outline-level) level))) |
| 895 | (setq first nil) |
| 896 | (outline-next-heading)) |
| 897 | (if (bolp) |
| 898 | (progn |
| 899 | ;; Go to end of line before heading |
| 900 | (forward-char -1) |
| 901 | (if (and outline-blank-line (bolp)) |
| 902 | ;; leave blank line before heading |
| 903 | (forward-char -1)))))) |
| 904 | \f |
| 905 | (defun show-branches () |
| 906 | "Show all subheadings of this heading, but not their bodies." |
| 907 | (interactive) |
| 908 | (show-children 1000)) |
| 909 | |
| 910 | (defun show-children (&optional level) |
| 911 | "Show all direct subheadings of this heading. |
| 912 | Prefix arg LEVEL is how many levels below the current level should be shown. |
| 913 | Default is enough to cause the following heading to appear." |
| 914 | (interactive "P") |
| 915 | (setq level |
| 916 | (if level (prefix-numeric-value level) |
| 917 | (save-excursion |
| 918 | (outline-back-to-heading) |
| 919 | (let ((start-level (funcall outline-level))) |
| 920 | (outline-next-heading) |
| 921 | (if (eobp) |
| 922 | 1 |
| 923 | (max 1 (- (funcall outline-level) start-level))))))) |
| 924 | (let (outline-view-change-hook) |
| 925 | (save-excursion |
| 926 | (outline-back-to-heading) |
| 927 | (setq level (+ level (funcall outline-level))) |
| 928 | (outline-map-region |
| 929 | (lambda () |
| 930 | (if (<= (funcall outline-level) level) |
| 931 | (outline-show-heading))) |
| 932 | (point) |
| 933 | (progn (outline-end-of-subtree) |
| 934 | (if (eobp) (point-max) (1+ (point))))))) |
| 935 | (run-hooks 'outline-view-change-hook)) |
| 936 | |
| 937 | \f |
| 938 | |
| 939 | (defun outline-up-heading (arg &optional invisible-ok) |
| 940 | "Move to the visible heading line of which the present line is a subheading. |
| 941 | With argument, move up ARG levels. |
| 942 | If INVISIBLE-OK is non-nil, also consider invisible lines." |
| 943 | (interactive "p") |
| 944 | (and (eq this-command 'outline-up-heading) |
| 945 | (or (eq last-command 'outline-up-heading) (push-mark))) |
| 946 | (outline-back-to-heading invisible-ok) |
| 947 | (let ((start-level (funcall outline-level))) |
| 948 | (if (eq start-level 1) |
| 949 | (error "Already at top level of the outline")) |
| 950 | (while (and (> start-level 1) (> arg 0) (not (bobp))) |
| 951 | (let ((level start-level)) |
| 952 | (while (not (or (< level start-level) (bobp))) |
| 953 | (if invisible-ok |
| 954 | (outline-previous-heading) |
| 955 | (outline-previous-visible-heading 1)) |
| 956 | (setq level (funcall outline-level))) |
| 957 | (setq start-level level)) |
| 958 | (setq arg (- arg 1)))) |
| 959 | (looking-at outline-regexp)) |
| 960 | |
| 961 | (defun outline-forward-same-level (arg) |
| 962 | "Move forward to the ARG'th subheading at same level as this one. |
| 963 | Stop at the first and last subheadings of a superior heading." |
| 964 | (interactive "p") |
| 965 | (outline-back-to-heading) |
| 966 | (while (> arg 0) |
| 967 | (let ((point-to-move-to (save-excursion |
| 968 | (outline-get-next-sibling)))) |
| 969 | (if point-to-move-to |
| 970 | (progn |
| 971 | (goto-char point-to-move-to) |
| 972 | (setq arg (1- arg))) |
| 973 | (progn |
| 974 | (setq arg 0) |
| 975 | (error "No following same-level heading")))))) |
| 976 | |
| 977 | (defun outline-get-next-sibling () |
| 978 | "Move to next heading of the same level, and return point or nil if none." |
| 979 | (let ((level (funcall outline-level))) |
| 980 | (outline-next-visible-heading 1) |
| 981 | (while (and (not (eobp)) (> (funcall outline-level) level)) |
| 982 | (outline-next-visible-heading 1)) |
| 983 | (if (or (eobp) (< (funcall outline-level) level)) |
| 984 | nil |
| 985 | (point)))) |
| 986 | |
| 987 | (defun outline-backward-same-level (arg) |
| 988 | "Move backward to the ARG'th subheading at same level as this one. |
| 989 | Stop at the first and last subheadings of a superior heading." |
| 990 | (interactive "p") |
| 991 | (outline-back-to-heading) |
| 992 | (while (> arg 0) |
| 993 | (let ((point-to-move-to (save-excursion |
| 994 | (outline-get-last-sibling)))) |
| 995 | (if point-to-move-to |
| 996 | (progn |
| 997 | (goto-char point-to-move-to) |
| 998 | (setq arg (1- arg))) |
| 999 | (progn |
| 1000 | (setq arg 0) |
| 1001 | (error "No previous same-level heading")))))) |
| 1002 | |
| 1003 | (defun outline-get-last-sibling () |
| 1004 | "Move to previous heading of the same level, and return point or nil if none." |
| 1005 | (let ((level (funcall outline-level))) |
| 1006 | (outline-previous-visible-heading 1) |
| 1007 | (while (and (> (funcall outline-level) level) |
| 1008 | (not (bobp))) |
| 1009 | (outline-previous-visible-heading 1)) |
| 1010 | (if (< (funcall outline-level) level) |
| 1011 | nil |
| 1012 | (point)))) |
| 1013 | \f |
| 1014 | (defun outline-headers-as-kill (beg end) |
| 1015 | "Save the visible outline headers in region at the start of the kill ring. |
| 1016 | |
| 1017 | Text shown between the headers isn't copied. Two newlines are |
| 1018 | inserted between saved headers. Yanking the result may be a |
| 1019 | convenient way to make a table of contents of the buffer." |
| 1020 | (interactive "r") |
| 1021 | (save-excursion |
| 1022 | (save-restriction |
| 1023 | (narrow-to-region beg end) |
| 1024 | (goto-char (point-min)) |
| 1025 | (let ((buffer (current-buffer)) |
| 1026 | start end) |
| 1027 | (with-temp-buffer |
| 1028 | (with-current-buffer buffer |
| 1029 | ;; Boundary condition: starting on heading: |
| 1030 | (when (outline-on-heading-p) |
| 1031 | (outline-back-to-heading) |
| 1032 | (setq start (point) |
| 1033 | end (progn (outline-end-of-heading) |
| 1034 | (point))) |
| 1035 | (insert-buffer-substring buffer start end) |
| 1036 | (insert "\n\n"))) |
| 1037 | (let ((temp-buffer (current-buffer))) |
| 1038 | (with-current-buffer buffer |
| 1039 | (while (outline-next-heading) |
| 1040 | (unless (outline-invisible-p) |
| 1041 | (setq start (point) |
| 1042 | end (progn (outline-end-of-heading) (point))) |
| 1043 | (with-current-buffer temp-buffer |
| 1044 | (insert-buffer-substring buffer start end) |
| 1045 | (insert "\n\n")))))) |
| 1046 | (kill-new (buffer-string))))))) |
| 1047 | |
| 1048 | (provide 'outline) |
| 1049 | (provide 'noutline) |
| 1050 | |
| 1051 | ;; arch-tag: 1724410e-7d4d-4f46-b801-49e18171e874 |
| 1052 | ;;; outline.el ends here |