| 1 | ;;; master.el --- make a buffer the master over another buffer |
| 2 | |
| 3 | ;; Copyright (C) 1999-2012 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Alex Schroeder <alex@gnu.org> |
| 6 | ;; Maintainer: Alex Schroeder <alex@gnu.org> |
| 7 | ;; Version: 1.0.2 |
| 8 | ;; Keywords: comm |
| 9 | |
| 10 | ;; This file is part of GNU Emacs. |
| 11 | |
| 12 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 13 | ;; it under the terms of the GNU General Public License as published by |
| 14 | ;; the Free Software Foundation, either version 3 of the License, or |
| 15 | ;; (at your option) any later version. |
| 16 | |
| 17 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 18 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 19 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 20 | ;; GNU General Public License for more details. |
| 21 | |
| 22 | ;; You should have received a copy of the GNU General Public License |
| 23 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 24 | |
| 25 | ;;; Commentary: |
| 26 | |
| 27 | ;; master-mode is a minor mode which enables you to scroll another |
| 28 | ;; buffer (the slave) without leaving your current buffer (the master). |
| 29 | |
| 30 | ;; It can be used by sql.el, for example: The SQL buffer is the master |
| 31 | ;; and its SQLi buffer is the slave. This allows you to scroll the SQLi |
| 32 | ;; buffer containing the output from the SQL buffer containing the |
| 33 | ;; commands. |
| 34 | ;; |
| 35 | ;; This is how to use sql.el and master.el together: The variable |
| 36 | ;; sql-buffer contains the slave buffer. It is a local variable in the |
| 37 | ;; SQL buffer. |
| 38 | ;; |
| 39 | ;; (add-hook 'sql-mode-hook |
| 40 | ;; (function (lambda () |
| 41 | ;; (master-mode t) |
| 42 | ;; (master-set-slave sql-buffer)))) |
| 43 | ;; (add-hook 'sql-set-sqli-hook |
| 44 | ;; (function (lambda () |
| 45 | ;; (master-set-slave sql-buffer)))) |
| 46 | |
| 47 | ;;; Thanks to all the people who helped me out: |
| 48 | ;; |
| 49 | ;; Rob Riepel <networking.stanford.edu> |
| 50 | |
| 51 | ;;; History: |
| 52 | ;; |
| 53 | |
| 54 | ;;; Code: |
| 55 | |
| 56 | (defgroup master nil |
| 57 | "Support for master/slave relationships between buffers." |
| 58 | :version "22.1" |
| 59 | :group 'convenience) |
| 60 | |
| 61 | ;; Variables that don't need initialization. |
| 62 | |
| 63 | (defvar master-of nil |
| 64 | "Slave buffer of the current buffer. See `master-mode'. |
| 65 | You can set this variable using `master-set-slave'.") |
| 66 | |
| 67 | (defvar master-set-slave-hook nil |
| 68 | "Hook run after the slave is changed using \\[master-set-slave].") |
| 69 | |
| 70 | ;;; Define master mode. |
| 71 | |
| 72 | ;;;###autoload |
| 73 | (define-minor-mode master-mode |
| 74 | "Toggle Master mode. |
| 75 | With a prefix argument ARG, enable Master mode if ARG is |
| 76 | positive, and disable it otherwise. If called from Lisp, enable |
| 77 | the mode if ARG is omitted or nil. |
| 78 | |
| 79 | When Master mode is enabled, you can scroll the slave buffer |
| 80 | using the following commands: |
| 81 | |
| 82 | \\{master-mode-map} |
| 83 | |
| 84 | The slave buffer is stored in the buffer-local variable `master-of'. |
| 85 | You can set this variable using `master-set-slave'. You can show |
| 86 | yourself the value of `master-of' by calling `master-show-slave'." |
| 87 | :group 'master |
| 88 | :keymap |
| 89 | '(("\C-c\C-n" . master-says-scroll-up) |
| 90 | ("\C-c\C-p" . master-says-scroll-down) |
| 91 | ("\C-c<" . master-says-beginning-of-buffer) |
| 92 | ("\C-c>" . master-says-end-of-buffer) |
| 93 | ("\C-c\C-l" . master-says-recenter))) |
| 94 | |
| 95 | ;; Initialize Master mode by setting a slave buffer. |
| 96 | |
| 97 | (defun master-set-slave (buffer) |
| 98 | "Makes BUFFER the slave of the current buffer. |
| 99 | Use \\[master-mode] to toggle control of the slave buffer." |
| 100 | (interactive "bSlave: ") |
| 101 | (make-local-variable 'master-of) |
| 102 | (setq master-of buffer) |
| 103 | (run-hooks 'master-set-slave-hook)) |
| 104 | |
| 105 | (defun master-show-slave () |
| 106 | "Displays a message with the name of the slave buffer." |
| 107 | (interactive) |
| 108 | (message "This buffer is the master of %s. Master-mode is %S." |
| 109 | (or master-of "none") |
| 110 | master-mode)) |
| 111 | |
| 112 | \f |
| 113 | |
| 114 | ;;; Functions that the master buffer can call for the slave buffer. |
| 115 | |
| 116 | (defun master-says-scroll-up (&optional arg) |
| 117 | "Display and scroll the slave buffer up. |
| 118 | See `scroll-up'." |
| 119 | (interactive) |
| 120 | (master-says 'scroll-up arg)) |
| 121 | |
| 122 | (defun master-says-scroll-down (&optional arg) |
| 123 | "Display and scroll the slave buffer down. |
| 124 | See `scroll-down'." |
| 125 | (interactive) |
| 126 | (master-says 'scroll-down arg)) |
| 127 | |
| 128 | (defun master-says-beginning-of-buffer (&optional arg) |
| 129 | "Display and move to the beginning of the slave buffer. |
| 130 | See `beginning-of-buffer'." |
| 131 | (interactive) |
| 132 | (master-says 'beginning-of-buffer arg)) |
| 133 | |
| 134 | (defun master-says-end-of-buffer (&optional arg) |
| 135 | "Display and move to the end of the slave buffer. |
| 136 | See `end-of-buffer'." |
| 137 | (interactive) |
| 138 | (master-says 'end-of-buffer arg)) |
| 139 | |
| 140 | (defun master-says-recenter (&optional arg) |
| 141 | "Recenter the slave buffer. |
| 142 | See `recenter'." |
| 143 | (interactive) |
| 144 | (master-says 'recenter arg)) |
| 145 | |
| 146 | ;; The master function doing the stuff. |
| 147 | |
| 148 | (defun master-says (&optional command arg) |
| 149 | "Display slave buffer and execute COMMAND with ARG in its window." |
| 150 | (interactive) |
| 151 | (if (null (buffer-live-p (get-buffer master-of))) |
| 152 | (error "Slave buffer has disappeared") |
| 153 | (let ((window (selected-window))) |
| 154 | (if (not (eq (window-buffer window) (get-buffer master-of))) |
| 155 | (switch-to-buffer-other-window master-of)) |
| 156 | (if command (condition-case nil (apply command arg) (error nil))) |
| 157 | (select-window window)))) |
| 158 | |
| 159 | (provide 'master) |
| 160 | |
| 161 | ;;; master.el ends here |