| 1 | ;;; smie.el --- Simple Minded Indentation Engine -*- lexical-binding: t -*- |
| 2 | |
| 3 | ;; Copyright (C) 2010-2013 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Stefan Monnier <monnier@iro.umontreal.ca> |
| 6 | ;; Keywords: languages, lisp, internal, parsing, indentation |
| 7 | |
| 8 | ;; This file is part of GNU Emacs. |
| 9 | |
| 10 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 11 | ;; it under the terms of the GNU General Public License as published by |
| 12 | ;; the Free Software Foundation, either version 3 of the License, or |
| 13 | ;; (at your option) any later version. |
| 14 | |
| 15 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 16 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 17 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 18 | ;; GNU General Public License for more details. |
| 19 | |
| 20 | ;; You should have received a copy of the GNU General Public License |
| 21 | ;; along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 22 | |
| 23 | ;;; Commentary: |
| 24 | |
| 25 | ;; While working on the SML indentation code, the idea grew that maybe |
| 26 | ;; I could write something generic to do the same thing, and at the |
| 27 | ;; end of working on the SML code, I had a pretty good idea of what it |
| 28 | ;; could look like. That idea grew stronger after working on |
| 29 | ;; LaTeX indentation. |
| 30 | ;; |
| 31 | ;; So at some point I decided to try it out, by writing a new |
| 32 | ;; indentation code for Coq while trying to keep most of the code |
| 33 | ;; "table driven", where only the tables are Coq-specific. The result |
| 34 | ;; (which was used for Beluga-mode as well) turned out to be based on |
| 35 | ;; something pretty close to an operator precedence parser. |
| 36 | |
| 37 | ;; So here is another rewrite, this time following the actual principles of |
| 38 | ;; operator precedence grammars. Why OPG? Even though they're among the |
| 39 | ;; weakest kinds of parsers, these parsers have some very desirable properties |
| 40 | ;; for Emacs: |
| 41 | ;; - most importantly for indentation, they work equally well in either |
| 42 | ;; direction, so you can use them to parse backward from the indentation |
| 43 | ;; point to learn the syntactic context; |
| 44 | ;; - they work locally, so there's no need to keep a cache of |
| 45 | ;; the parser's state; |
| 46 | ;; - because of that locality, indentation also works just fine when earlier |
| 47 | ;; parts of the buffer are syntactically incorrect since the indentation |
| 48 | ;; looks at "as little as possible" of the buffer to make an indentation |
| 49 | ;; decision. |
| 50 | ;; - they typically have no error handling and can't even detect a parsing |
| 51 | ;; error, so we don't have to worry about what to do in case of a syntax |
| 52 | ;; error because the parser just automatically does something. Better yet, |
| 53 | ;; we can afford to use a sloppy grammar. |
| 54 | |
| 55 | ;; A good background to understand the development (especially the parts |
| 56 | ;; building the 2D precedence tables and then computing the precedence levels |
| 57 | ;; from it) can be found in pages 187-194 of "Parsing techniques" by Dick Grune |
| 58 | ;; and Ceriel Jacobs (BookBody.pdf available at |
| 59 | ;; http://dickgrune.com/Books/PTAPG_1st_Edition/). |
| 60 | ;; |
| 61 | ;; OTOH we had to kill many chickens, read many coffee grounds, and practice |
| 62 | ;; untold numbers of black magic spells, to come up with the indentation code. |
| 63 | ;; Since then, some of that code has been beaten into submission, but the |
| 64 | ;; smie-indent-keyword is still pretty obscure. |
| 65 | |
| 66 | ;; Conflict resolution: |
| 67 | ;; |
| 68 | ;; - One source of conflicts is when you have: |
| 69 | ;; (exp ("IF" exp "ELSE" exp "END") ("CASE" cases "END")) |
| 70 | ;; (cases (cases "ELSE" insts) ...) |
| 71 | ;; The IF-rule implies ELSE=END and the CASE-rule implies ELSE>END. |
| 72 | ;; This can be resolved simply with: |
| 73 | ;; (exp ("IF" expelseexp "END") ("CASE" cases "END")) |
| 74 | ;; (expelseexp (exp) (exp "ELSE" exp)) |
| 75 | ;; (cases (cases "ELSE" insts) ...) |
| 76 | ;; - Another source of conflict is when a terminator/separator is used to |
| 77 | ;; terminate elements at different levels, as in: |
| 78 | ;; (decls ("VAR" vars) (decls "," decls)) |
| 79 | ;; (vars (id) (vars "," vars)) |
| 80 | ;; often these can be resolved by making the lexer distinguish the two |
| 81 | ;; kinds of commas, e.g. based on the following token. |
| 82 | |
| 83 | ;; TODO & BUGS: |
| 84 | ;; |
| 85 | ;; - We could try to resolve conflicts such as the IFexpELSEexpEND -vs- |
| 86 | ;; CASE(casesELSEexp)END automatically by changing the way BNF rules such as |
| 87 | ;; the IF-rule is handled. I.e. rather than IF=ELSE and ELSE=END, we could |
| 88 | ;; turn them into IF<ELSE and ELSE>END and IF=END. |
| 89 | ;; - Using the structural information SMIE gives us, it should be possible to |
| 90 | ;; implement a `smie-align' command that would automatically figure out what |
| 91 | ;; there is to align and how to do it (something like: align the token of |
| 92 | ;; lowest precedence that appears the same number of times on all lines, |
| 93 | ;; and then do the same on each side of that token). |
| 94 | ;; - Maybe accept two juxtaposed non-terminals in the BNF under the condition |
| 95 | ;; that the first always ends with a terminal, or that the second always |
| 96 | ;; starts with a terminal. |
| 97 | ;; - Permit EBNF-style notation. |
| 98 | ;; - If the grammar has conflicts, the only way is to make the lexer return |
| 99 | ;; different tokens for the different cases. This extra work performed by |
| 100 | ;; the lexer can be costly and unnecessary: we perform this extra work every |
| 101 | ;; time we find the conflicting token, regardless of whether or not the |
| 102 | ;; difference between the various situations is relevant to the current |
| 103 | ;; situation. E.g. we may try to determine whether a ";" is a ";-operator" |
| 104 | ;; or a ";-separator" in a case where we're skipping over a "begin..end" pair |
| 105 | ;; where the difference doesn't matter. For frequently occurring tokens and |
| 106 | ;; rarely occurring conflicts, this can be a significant performance problem. |
| 107 | ;; We could try and let the lexer return a "set of possible tokens |
| 108 | ;; plus a refinement function" and then let parser call the refinement |
| 109 | ;; function if needed. |
| 110 | ;; - Make it possible to better specify the behavior in the face of |
| 111 | ;; syntax errors. IOW provide some control over the choice of precedence |
| 112 | ;; levels within the limits of the constraints. E.g. make it possible for |
| 113 | ;; the grammar to specify that "begin..end" has lower precedence than |
| 114 | ;; "Module..EndModule", so that if a "begin" is missing, scanning from the |
| 115 | ;; "end" will stop at "Module" rather than going past it (and similarly, |
| 116 | ;; scanning from "Module" should not stop at a spurious "end"). |
| 117 | |
| 118 | ;;; Code: |
| 119 | |
| 120 | ;; FIXME: |
| 121 | ;; - smie-indent-comment doesn't interact well with mis-indented lines (where |
| 122 | ;; the indent rules don't do what the user wants). Not sure what to do. |
| 123 | |
| 124 | (eval-when-compile (require 'cl-lib)) |
| 125 | |
| 126 | (defgroup smie nil |
| 127 | "Simple Minded Indentation Engine." |
| 128 | :group 'languages) |
| 129 | |
| 130 | (defvar comment-continue) |
| 131 | (declare-function comment-string-strip "newcomment" (str beforep afterp)) |
| 132 | |
| 133 | ;;; Building precedence level tables from BNF specs. |
| 134 | |
| 135 | ;; We have 4 different representations of a "grammar": |
| 136 | ;; - a BNF table, which is a list of BNF rules of the form |
| 137 | ;; (NONTERM RHS1 ... RHSn) where each RHS is a list of terminals (tokens) |
| 138 | ;; or nonterminals. Any element in these lists which does not appear as |
| 139 | ;; the `car' of a BNF rule is taken to be a terminal. |
| 140 | ;; - A list of precedences (key word "precs"), is a list, sorted |
| 141 | ;; from lowest to highest precedence, of precedence classes that |
| 142 | ;; have the form (ASSOCIATIVITY TERMINAL1 .. TERMINALn), where |
| 143 | ;; ASSOCIATIVITY can be `assoc', `left', `right' or `nonassoc'. |
| 144 | ;; - a 2 dimensional precedence table (key word "prec2"), is a 2D |
| 145 | ;; table recording the precedence relation (can be `<', `=', `>', or |
| 146 | ;; nil) between each pair of tokens. |
| 147 | ;; - a precedence-level table (key word "grammar"), which is an alist |
| 148 | ;; giving for each token its left and right precedence level (a |
| 149 | ;; number or nil). This is used in `smie-grammar'. |
| 150 | ;; The prec2 tables are only intermediate data structures: the source |
| 151 | ;; code normally provides a mix of BNF and precs tables, and then |
| 152 | ;; turns them into a levels table, which is what's used by the rest of |
| 153 | ;; the SMIE code. |
| 154 | |
| 155 | (defvar smie-warning-count 0) |
| 156 | |
| 157 | (defun smie-set-prec2tab (table x y val &optional override) |
| 158 | (cl-assert (and x y)) |
| 159 | (let* ((key (cons x y)) |
| 160 | (old (gethash key table))) |
| 161 | (if (and old (not (eq old val))) |
| 162 | (if (and override (gethash key override)) |
| 163 | ;; FIXME: The override is meant to resolve ambiguities, |
| 164 | ;; but it also hides real conflicts. It would be great to |
| 165 | ;; be able to distinguish the two cases so that overrides |
| 166 | ;; don't hide real conflicts. |
| 167 | (puthash key (gethash key override) table) |
| 168 | (display-warning 'smie (format "Conflict: %s %s/%s %s" x old val y)) |
| 169 | (cl-incf smie-warning-count)) |
| 170 | (puthash key val table)))) |
| 171 | |
| 172 | (put 'smie-precs->prec2 'pure t) |
| 173 | (defun smie-precs->prec2 (precs) |
| 174 | "Compute a 2D precedence table from a list of precedences. |
| 175 | PRECS should be a list, sorted by precedence (e.g. \"+\" will |
| 176 | come before \"*\"), of elements of the form \(left OP ...) |
| 177 | or (right OP ...) or (nonassoc OP ...) or (assoc OP ...). All operators in |
| 178 | one of those elements share the same precedence level and associativity." |
| 179 | (let ((prec2-table (make-hash-table :test 'equal))) |
| 180 | (dolist (prec precs) |
| 181 | (dolist (op (cdr prec)) |
| 182 | (let ((selfrule (cdr (assq (car prec) |
| 183 | '((left . >) (right . <) (assoc . =)))))) |
| 184 | (when selfrule |
| 185 | (dolist (other-op (cdr prec)) |
| 186 | (smie-set-prec2tab prec2-table op other-op selfrule)))) |
| 187 | (let ((op1 '<) (op2 '>)) |
| 188 | (dolist (other-prec precs) |
| 189 | (if (eq prec other-prec) |
| 190 | (setq op1 '> op2 '<) |
| 191 | (dolist (other-op (cdr other-prec)) |
| 192 | (smie-set-prec2tab prec2-table op other-op op2) |
| 193 | (smie-set-prec2tab prec2-table other-op op op1))))))) |
| 194 | prec2-table)) |
| 195 | |
| 196 | (put 'smie-merge-prec2s 'pure t) |
| 197 | (defun smie-merge-prec2s (&rest tables) |
| 198 | (if (null (cdr tables)) |
| 199 | (car tables) |
| 200 | (let ((prec2 (make-hash-table :test 'equal))) |
| 201 | (dolist (table tables) |
| 202 | (maphash (lambda (k v) |
| 203 | (if (consp k) |
| 204 | (smie-set-prec2tab prec2 (car k) (cdr k) v) |
| 205 | (if (and (gethash k prec2) |
| 206 | (not (equal (gethash k prec2) v))) |
| 207 | (error "Conflicting values for %s property" k) |
| 208 | (puthash k v prec2)))) |
| 209 | table)) |
| 210 | prec2))) |
| 211 | |
| 212 | (put 'smie-bnf->prec2 'pure t) |
| 213 | (defun smie-bnf->prec2 (bnf &rest resolvers) |
| 214 | "Convert the BNF grammar into a prec2 table. |
| 215 | BNF is a list of nonterminal definitions of the form: |
| 216 | \(NONTERM RHS1 RHS2 ...) |
| 217 | where each RHS is a (non-empty) list of terminals (aka tokens) or non-terminals. |
| 218 | Not all grammars are accepted: |
| 219 | - an RHS cannot be an empty list (this is not needed, since SMIE allows all |
| 220 | non-terminals to match the empty string anyway). |
| 221 | - an RHS cannot have 2 consecutive non-terminals: between each non-terminal |
| 222 | needs to be a terminal (aka token). This is a fundamental limitation of |
| 223 | the parsing technology used (operator precedence grammar). |
| 224 | Additionally, conflicts can occur: |
| 225 | - The returned prec2 table holds constraints between pairs of |
| 226 | token, and for any given pair only one constraint can be |
| 227 | present, either: T1 < T2, T1 = T2, or T1 > T2. |
| 228 | - A token can either be an `opener' (something similar to an open-paren), |
| 229 | a `closer' (like a close-paren), or `neither' of the two (e.g. an infix |
| 230 | operator, or an inner token like \"else\"). |
| 231 | Conflicts can be resolved via RESOLVERS, which is a list of elements that can |
| 232 | be either: |
| 233 | - a precs table (see `smie-precs->prec2') to resolve conflicting constraints, |
| 234 | - a constraint (T1 REL T2) where REL is one of = < or >." |
| 235 | ;; FIXME: Add repetition operator like (repeat <separator> <elems>). |
| 236 | ;; Maybe also add (or <elem1> <elem2>...) for things like |
| 237 | ;; (exp (exp (or "+" "*" "=" ..) exp)). |
| 238 | ;; Basically, make it EBNF (except for the specification of a separator in |
| 239 | ;; the repetition, maybe). |
| 240 | (let* ((nts (mapcar 'car bnf)) ;Non-terminals. |
| 241 | (first-ops-table ()) |
| 242 | (last-ops-table ()) |
| 243 | (first-nts-table ()) |
| 244 | (last-nts-table ()) |
| 245 | (smie-warning-count 0) |
| 246 | (prec2 (make-hash-table :test 'equal)) |
| 247 | (override |
| 248 | (let ((precs ()) |
| 249 | (over (make-hash-table :test 'equal))) |
| 250 | (dolist (resolver resolvers) |
| 251 | (cond |
| 252 | ((and (= 3 (length resolver)) (memq (nth 1 resolver) '(= < >))) |
| 253 | (smie-set-prec2tab |
| 254 | over (nth 0 resolver) (nth 2 resolver) (nth 1 resolver))) |
| 255 | ((memq (caar resolver) '(left right assoc nonassoc)) |
| 256 | (push resolver precs)) |
| 257 | (t (error "Unknown resolver %S" resolver)))) |
| 258 | (apply #'smie-merge-prec2s over |
| 259 | (mapcar 'smie-precs->prec2 precs)))) |
| 260 | again) |
| 261 | (dolist (rules bnf) |
| 262 | (let ((nt (car rules)) |
| 263 | (last-ops ()) |
| 264 | (first-ops ()) |
| 265 | (last-nts ()) |
| 266 | (first-nts ())) |
| 267 | (dolist (rhs (cdr rules)) |
| 268 | (unless (consp rhs) |
| 269 | (signal 'wrong-type-argument `(consp ,rhs))) |
| 270 | (if (not (member (car rhs) nts)) |
| 271 | (cl-pushnew (car rhs) first-ops) |
| 272 | (cl-pushnew (car rhs) first-nts) |
| 273 | (when (consp (cdr rhs)) |
| 274 | ;; If the first is not an OP we add the second (which |
| 275 | ;; should be an OP if BNF is an "operator grammar"). |
| 276 | ;; Strictly speaking, this should only be done if the |
| 277 | ;; first is a non-terminal which can expand to a phrase |
| 278 | ;; without any OP in it, but checking doesn't seem worth |
| 279 | ;; the trouble, and it lets the writer of the BNF |
| 280 | ;; be a bit more sloppy by skipping uninteresting base |
| 281 | ;; cases which are terminals but not OPs. |
| 282 | (when (member (cadr rhs) nts) |
| 283 | (error "Adjacent non-terminals: %s %s" |
| 284 | (car rhs) (cadr rhs))) |
| 285 | (cl-pushnew (cadr rhs) first-ops))) |
| 286 | (let ((shr (reverse rhs))) |
| 287 | (if (not (member (car shr) nts)) |
| 288 | (cl-pushnew (car shr) last-ops) |
| 289 | (cl-pushnew (car shr) last-nts) |
| 290 | (when (consp (cdr shr)) |
| 291 | (when (member (cadr shr) nts) |
| 292 | (error "Adjacent non-terminals: %s %s" |
| 293 | (cadr shr) (car shr))) |
| 294 | (cl-pushnew (cadr shr) last-ops))))) |
| 295 | (push (cons nt first-ops) first-ops-table) |
| 296 | (push (cons nt last-ops) last-ops-table) |
| 297 | (push (cons nt first-nts) first-nts-table) |
| 298 | (push (cons nt last-nts) last-nts-table))) |
| 299 | ;; Compute all first-ops by propagating the initial ones we have |
| 300 | ;; now, according to first-nts. |
| 301 | (setq again t) |
| 302 | (while (prog1 again (setq again nil)) |
| 303 | (dolist (first-nts first-nts-table) |
| 304 | (let* ((nt (pop first-nts)) |
| 305 | (first-ops (assoc nt first-ops-table))) |
| 306 | (dolist (first-nt first-nts) |
| 307 | (dolist (op (cdr (assoc first-nt first-ops-table))) |
| 308 | (unless (member op first-ops) |
| 309 | (setq again t) |
| 310 | (push op (cdr first-ops)))))))) |
| 311 | ;; Same thing for last-ops. |
| 312 | (setq again t) |
| 313 | (while (prog1 again (setq again nil)) |
| 314 | (dolist (last-nts last-nts-table) |
| 315 | (let* ((nt (pop last-nts)) |
| 316 | (last-ops (assoc nt last-ops-table))) |
| 317 | (dolist (last-nt last-nts) |
| 318 | (dolist (op (cdr (assoc last-nt last-ops-table))) |
| 319 | (unless (member op last-ops) |
| 320 | (setq again t) |
| 321 | (push op (cdr last-ops)))))))) |
| 322 | ;; Now generate the 2D precedence table. |
| 323 | (dolist (rules bnf) |
| 324 | (dolist (rhs (cdr rules)) |
| 325 | (while (cdr rhs) |
| 326 | (cond |
| 327 | ((member (car rhs) nts) |
| 328 | (dolist (last (cdr (assoc (car rhs) last-ops-table))) |
| 329 | (smie-set-prec2tab prec2 last (cadr rhs) '> override))) |
| 330 | ((member (cadr rhs) nts) |
| 331 | (dolist (first (cdr (assoc (cadr rhs) first-ops-table))) |
| 332 | (smie-set-prec2tab prec2 (car rhs) first '< override)) |
| 333 | (if (and (cddr rhs) (not (member (car (cddr rhs)) nts))) |
| 334 | (smie-set-prec2tab prec2 (car rhs) (car (cddr rhs)) |
| 335 | '= override))) |
| 336 | (t (smie-set-prec2tab prec2 (car rhs) (cadr rhs) '= override))) |
| 337 | (setq rhs (cdr rhs))))) |
| 338 | ;; Keep track of which tokens are openers/closer, so they can get a nil |
| 339 | ;; precedence in smie-prec2->grammar. |
| 340 | (puthash :smie-open/close-alist (smie-bnf--classify bnf) prec2) |
| 341 | (puthash :smie-closer-alist (smie-bnf--closer-alist bnf) prec2) |
| 342 | (if (> smie-warning-count 0) |
| 343 | (display-warning |
| 344 | 'smie (format "Total: %d warnings" smie-warning-count))) |
| 345 | prec2)) |
| 346 | |
| 347 | ;; (defun smie-prec2-closer-alist (prec2 include-inners) |
| 348 | ;; "Build a closer-alist from a PREC2 table. |
| 349 | ;; The return value is in the same form as `smie-closer-alist'. |
| 350 | ;; INCLUDE-INNERS if non-nil means that inner keywords will be included |
| 351 | ;; in the table, e.g. the table will include things like (\"if\" . \"else\")." |
| 352 | ;; (let* ((non-openers '()) |
| 353 | ;; (non-closers '()) |
| 354 | ;; ;; For each keyword, this gives the matching openers, if any. |
| 355 | ;; (openers (make-hash-table :test 'equal)) |
| 356 | ;; (closers '()) |
| 357 | ;; (done nil)) |
| 358 | ;; ;; First, find the non-openers and non-closers. |
| 359 | ;; (maphash (lambda (k v) |
| 360 | ;; (unless (or (eq v '<) (member (cdr k) non-openers)) |
| 361 | ;; (push (cdr k) non-openers)) |
| 362 | ;; (unless (or (eq v '>) (member (car k) non-closers)) |
| 363 | ;; (push (car k) non-closers))) |
| 364 | ;; prec2) |
| 365 | ;; ;; Then find the openers and closers. |
| 366 | ;; (maphash (lambda (k _) |
| 367 | ;; (unless (member (car k) non-openers) |
| 368 | ;; (puthash (car k) (list (car k)) openers)) |
| 369 | ;; (unless (or (member (cdr k) non-closers) |
| 370 | ;; (member (cdr k) closers)) |
| 371 | ;; (push (cdr k) closers))) |
| 372 | ;; prec2) |
| 373 | ;; ;; Then collect the matching elements. |
| 374 | ;; (while (not done) |
| 375 | ;; (setq done t) |
| 376 | ;; (maphash (lambda (k v) |
| 377 | ;; (when (eq v '=) |
| 378 | ;; (let ((aopeners (gethash (car k) openers)) |
| 379 | ;; (dopeners (gethash (cdr k) openers)) |
| 380 | ;; (new nil)) |
| 381 | ;; (dolist (o aopeners) |
| 382 | ;; (unless (member o dopeners) |
| 383 | ;; (setq new t) |
| 384 | ;; (push o dopeners))) |
| 385 | ;; (when new |
| 386 | ;; (setq done nil) |
| 387 | ;; (puthash (cdr k) dopeners openers))))) |
| 388 | ;; prec2)) |
| 389 | ;; ;; Finally, dump the resulting table. |
| 390 | ;; (let ((alist '())) |
| 391 | ;; (maphash (lambda (k v) |
| 392 | ;; (when (or include-inners (member k closers)) |
| 393 | ;; (dolist (opener v) |
| 394 | ;; (unless (equal opener k) |
| 395 | ;; (push (cons opener k) alist))))) |
| 396 | ;; openers) |
| 397 | ;; alist))) |
| 398 | |
| 399 | (defun smie-bnf--closer-alist (bnf &optional no-inners) |
| 400 | ;; We can also build this closer-alist table from a prec2 table, |
| 401 | ;; but it takes more work, and the order is unpredictable, which |
| 402 | ;; is a problem for smie-close-block. |
| 403 | ;; More convenient would be to build it from a levels table since we |
| 404 | ;; always have this table (contrary to the BNF), but it has all the |
| 405 | ;; disadvantages of the prec2 case plus the disadvantage that the levels |
| 406 | ;; table has lost some info which would result in extra invalid pairs. |
| 407 | "Build a closer-alist from a BNF table. |
| 408 | The return value is in the same form as `smie-closer-alist'. |
| 409 | NO-INNERS if non-nil means that inner keywords will be excluded |
| 410 | from the table, e.g. the table will not include things like (\"if\" . \"else\")." |
| 411 | (let ((nts (mapcar #'car bnf)) ;non terminals. |
| 412 | (alist '())) |
| 413 | (dolist (nt bnf) |
| 414 | (dolist (rhs (cdr nt)) |
| 415 | (unless (or (< (length rhs) 2) (member (car rhs) nts)) |
| 416 | (if no-inners |
| 417 | (let ((last (car (last rhs)))) |
| 418 | (unless (member last nts) |
| 419 | (cl-pushnew (cons (car rhs) last) alist :test #'equal))) |
| 420 | ;; Reverse so that the "real" closer gets there first, |
| 421 | ;; which is important for smie-close-block. |
| 422 | (dolist (term (reverse (cdr rhs))) |
| 423 | (unless (member term nts) |
| 424 | (cl-pushnew (cons (car rhs) term) alist :test #'equal))))))) |
| 425 | (nreverse alist))) |
| 426 | |
| 427 | (defun smie-bnf--set-class (table token class) |
| 428 | (let ((prev (gethash token table class))) |
| 429 | (puthash token |
| 430 | (cond |
| 431 | ((eq prev class) class) |
| 432 | ((eq prev t) t) ;Non-terminal. |
| 433 | (t (display-warning |
| 434 | 'smie |
| 435 | (format "token %s is both %s and %s" token class prev)) |
| 436 | 'neither)) |
| 437 | table))) |
| 438 | |
| 439 | (defun smie-bnf--classify (bnf) |
| 440 | "Return a table classifying terminals. |
| 441 | Each terminal can either be an `opener', a `closer', or `neither'." |
| 442 | (let ((table (make-hash-table :test #'equal)) |
| 443 | (alist '())) |
| 444 | (dolist (category bnf) |
| 445 | (puthash (car category) t table)) ;Mark non-terminals. |
| 446 | (dolist (category bnf) |
| 447 | (dolist (rhs (cdr category)) |
| 448 | (if (null (cdr rhs)) |
| 449 | (smie-bnf--set-class table (pop rhs) 'neither) |
| 450 | (smie-bnf--set-class table (pop rhs) 'opener) |
| 451 | (while (cdr rhs) ;Remove internals. |
| 452 | (smie-bnf--set-class table (pop rhs) 'neither)) |
| 453 | (smie-bnf--set-class table (pop rhs) 'closer)))) |
| 454 | (maphash (lambda (tok v) |
| 455 | (when (memq v '(closer opener)) |
| 456 | (push (cons tok v) alist))) |
| 457 | table) |
| 458 | alist)) |
| 459 | |
| 460 | (defun smie-debug--prec2-cycle (csts) |
| 461 | "Return a cycle in CSTS, assuming there's one. |
| 462 | CSTS is a list of pairs representing arcs in a graph." |
| 463 | ;; A PATH is of the form (START . REST) where REST is a reverse |
| 464 | ;; list of nodes through which the path goes. |
| 465 | (let ((paths (mapcar (lambda (pair) (list (car pair) (cdr pair))) csts)) |
| 466 | (cycle nil)) |
| 467 | (while (null cycle) |
| 468 | (dolist (path (prog1 paths (setq paths nil))) |
| 469 | (dolist (cst csts) |
| 470 | (when (eq (car cst) (nth 1 path)) |
| 471 | (if (eq (cdr cst) (car path)) |
| 472 | (setq cycle path) |
| 473 | (push (cons (car path) (cons (cdr cst) (cdr path))) |
| 474 | paths)))))) |
| 475 | (cons (car cycle) (nreverse (cdr cycle))))) |
| 476 | |
| 477 | (defun smie-debug--describe-cycle (table cycle) |
| 478 | (let ((names |
| 479 | (mapcar (lambda (val) |
| 480 | (let ((res nil)) |
| 481 | (dolist (elem table) |
| 482 | (if (eq (cdr elem) val) |
| 483 | (push (concat "." (car elem)) res)) |
| 484 | (if (eq (cddr elem) val) |
| 485 | (push (concat (car elem) ".") res))) |
| 486 | (cl-assert res) |
| 487 | res)) |
| 488 | cycle))) |
| 489 | (mapconcat |
| 490 | (lambda (elems) (mapconcat 'identity elems "=")) |
| 491 | (append names (list (car names))) |
| 492 | " < "))) |
| 493 | |
| 494 | ;; (defun smie-check-grammar (grammar prec2 &optional dummy) |
| 495 | ;; (maphash (lambda (k v) |
| 496 | ;; (when (consp k) |
| 497 | ;; (let ((left (nth 2 (assoc (car k) grammar))) |
| 498 | ;; (right (nth 1 (assoc (cdr k) grammar)))) |
| 499 | ;; (when (and left right) |
| 500 | ;; (cond |
| 501 | ;; ((< left right) (cl-assert (eq v '<))) |
| 502 | ;; ((> left right) (cl-assert (eq v '>))) |
| 503 | ;; (t (cl-assert (eq v '=)))))))) |
| 504 | ;; prec2)) |
| 505 | |
| 506 | (put 'smie-prec2->grammar 'pure t) |
| 507 | (defun smie-prec2->grammar (prec2) |
| 508 | "Take a 2D precedence table and turn it into an alist of precedence levels. |
| 509 | PREC2 is a table as returned by `smie-precs->prec2' or |
| 510 | `smie-bnf->prec2'." |
| 511 | ;; For each operator, we create two "variables" (corresponding to |
| 512 | ;; the left and right precedence level), which are represented by |
| 513 | ;; cons cells. Those are the very cons cells that appear in the |
| 514 | ;; final `table'. The value of each "variable" is kept in the `car'. |
| 515 | (let ((table ()) |
| 516 | (csts ()) |
| 517 | (eqs ())) |
| 518 | ;; From `prec2' we construct a list of constraints between |
| 519 | ;; variables (aka "precedence levels"). These can be either |
| 520 | ;; equality constraints (in `eqs') or `<' constraints (in `csts'). |
| 521 | (maphash (lambda (k v) |
| 522 | (when (consp k) |
| 523 | (let ((tmp (assoc (car k) table)) |
| 524 | x y) |
| 525 | (if tmp |
| 526 | (setq x (cddr tmp)) |
| 527 | (setq x (cons nil nil)) |
| 528 | (push (cons (car k) (cons nil x)) table)) |
| 529 | (if (setq tmp (assoc (cdr k) table)) |
| 530 | (setq y (cdr tmp)) |
| 531 | (setq y (cons nil (cons nil nil))) |
| 532 | (push (cons (cdr k) y) table)) |
| 533 | (pcase v |
| 534 | (`= (push (cons x y) eqs)) |
| 535 | (`< (push (cons x y) csts)) |
| 536 | (`> (push (cons y x) csts)) |
| 537 | (_ (error "SMIE error: prec2 has %S↦%S which ∉ {<,+,>}" |
| 538 | k v)))))) |
| 539 | prec2) |
| 540 | ;; First process the equality constraints. |
| 541 | (let ((eqs eqs)) |
| 542 | (while eqs |
| 543 | (let ((from (caar eqs)) |
| 544 | (to (cdar eqs))) |
| 545 | (setq eqs (cdr eqs)) |
| 546 | (if (eq to from) |
| 547 | nil ;Nothing to do. |
| 548 | (dolist (other-eq eqs) |
| 549 | (if (eq from (cdr other-eq)) (setcdr other-eq to)) |
| 550 | (when (eq from (car other-eq)) |
| 551 | ;; This can happen because of `assoc' settings in precs |
| 552 | ;; or because of a rhs like ("op" foo "op"). |
| 553 | (setcar other-eq to))) |
| 554 | (dolist (cst csts) |
| 555 | (if (eq from (cdr cst)) (setcdr cst to)) |
| 556 | (if (eq from (car cst)) (setcar cst to))))))) |
| 557 | ;; Then eliminate trivial constraints iteratively. |
| 558 | (let ((i 0)) |
| 559 | (while csts |
| 560 | (let ((rhvs (mapcar 'cdr csts)) |
| 561 | (progress nil)) |
| 562 | (dolist (cst csts) |
| 563 | (unless (memq (car cst) rhvs) |
| 564 | (setq progress t) |
| 565 | ;; We could give each var in a given iteration the same value, |
| 566 | ;; but we can also give them arbitrarily different values. |
| 567 | ;; Basically, these are vars between which there is no |
| 568 | ;; constraint (neither equality nor inequality), so |
| 569 | ;; anything will do. |
| 570 | ;; We give them arbitrary values, which means that we |
| 571 | ;; replace the "no constraint" case with either > or < |
| 572 | ;; but not =. The reason we do that is so as to try and |
| 573 | ;; distinguish associative operators (which will have |
| 574 | ;; left = right). |
| 575 | (unless (caar cst) |
| 576 | (setcar (car cst) i) |
| 577 | ;; (smie-check-grammar table prec2 'step1) |
| 578 | (cl-incf i)) |
| 579 | (setq csts (delq cst csts)))) |
| 580 | (unless progress |
| 581 | (error "Can't resolve the precedence cycle: %s" |
| 582 | (smie-debug--describe-cycle |
| 583 | table (smie-debug--prec2-cycle csts))))) |
| 584 | (cl-incf i 10)) |
| 585 | ;; Propagate equality constraints back to their sources. |
| 586 | (dolist (eq (nreverse eqs)) |
| 587 | (when (null (cadr eq)) |
| 588 | ;; There's an equality constraint, but we still haven't given |
| 589 | ;; it a value: that means it binds tighter than anything else, |
| 590 | ;; and it can't be an opener/closer (those don't have equality |
| 591 | ;; constraints). |
| 592 | ;; So set it here rather than below since doing it below |
| 593 | ;; makes it more difficult to obey the equality constraints. |
| 594 | (setcar (cdr eq) i) |
| 595 | (cl-incf i)) |
| 596 | (cl-assert (or (null (caar eq)) (eq (caar eq) (cadr eq)))) |
| 597 | (setcar (car eq) (cadr eq)) |
| 598 | ;; (smie-check-grammar table prec2 'step2) |
| 599 | ) |
| 600 | ;; Finally, fill in the remaining vars (which did not appear on the |
| 601 | ;; left side of any < constraint). |
| 602 | (dolist (x table) |
| 603 | (unless (nth 1 x) |
| 604 | (setf (nth 1 x) i) |
| 605 | (cl-incf i)) ;See other (cl-incf i) above. |
| 606 | (unless (nth 2 x) |
| 607 | (setf (nth 2 x) i) |
| 608 | (cl-incf i)))) ;See other (cl-incf i) above. |
| 609 | ;; Mark closers and openers. |
| 610 | (dolist (x (gethash :smie-open/close-alist prec2)) |
| 611 | (let* ((token (car x)) |
| 612 | (cons (pcase (cdr x) |
| 613 | (`closer (cddr (assoc token table))) |
| 614 | (`opener (cdr (assoc token table)))))) |
| 615 | (cl-assert (numberp (car cons))) |
| 616 | (setf (car cons) (list (car cons))))) |
| 617 | (let ((ca (gethash :smie-closer-alist prec2))) |
| 618 | (when ca (push (cons :smie-closer-alist ca) table))) |
| 619 | ;; (smie-check-grammar table prec2 'step3) |
| 620 | table)) |
| 621 | |
| 622 | ;;; Parsing using a precedence level table. |
| 623 | |
| 624 | (defvar smie-grammar 'unset |
| 625 | "List of token parsing info. |
| 626 | This list is normally built by `smie-prec2->grammar'. |
| 627 | Each element is of the form (TOKEN LEFT-LEVEL RIGHT-LEVEL). |
| 628 | Parsing is done using an operator precedence parser. |
| 629 | LEFT-LEVEL and RIGHT-LEVEL can be either numbers or a list, where a list |
| 630 | means that this operator does not bind on the corresponding side, |
| 631 | e.g. a LEFT-LEVEL of nil means this is a token that behaves somewhat like |
| 632 | an open-paren, whereas a RIGHT-LEVEL of nil would correspond to something |
| 633 | like a close-paren.") |
| 634 | |
| 635 | (defvar smie-forward-token-function 'smie-default-forward-token |
| 636 | "Function to scan forward for the next token. |
| 637 | Called with no argument should return a token and move to its end. |
| 638 | If no token is found, return nil or the empty string. |
| 639 | It can return nil when bumping into a parenthesis, which lets SMIE |
| 640 | use syntax-tables to handle them in efficient C code.") |
| 641 | |
| 642 | (defvar smie-backward-token-function 'smie-default-backward-token |
| 643 | "Function to scan backward the previous token. |
| 644 | Same calling convention as `smie-forward-token-function' except |
| 645 | it should move backward to the beginning of the previous token.") |
| 646 | |
| 647 | (defalias 'smie-op-left 'car) |
| 648 | (defalias 'smie-op-right 'cadr) |
| 649 | |
| 650 | (defun smie-default-backward-token () |
| 651 | (forward-comment (- (point))) |
| 652 | (buffer-substring-no-properties |
| 653 | (point) |
| 654 | (progn (if (zerop (skip-syntax-backward ".")) |
| 655 | (skip-syntax-backward "w_'")) |
| 656 | (point)))) |
| 657 | |
| 658 | (defun smie-default-forward-token () |
| 659 | (forward-comment (point-max)) |
| 660 | (buffer-substring-no-properties |
| 661 | (point) |
| 662 | (progn (if (zerop (skip-syntax-forward ".")) |
| 663 | (skip-syntax-forward "w_'")) |
| 664 | (point)))) |
| 665 | |
| 666 | (defun smie--associative-p (toklevels) |
| 667 | ;; in "a + b + c" we want to stop at each +, but in |
| 668 | ;; "if a then b elsif c then d else c" we don't want to stop at each keyword. |
| 669 | ;; To distinguish the two cases, we made smie-prec2->grammar choose |
| 670 | ;; different levels for each part of "if a then b else c", so that |
| 671 | ;; by checking if the left-level is equal to the right level, we can |
| 672 | ;; figure out that it's an associative operator. |
| 673 | ;; This is not 100% foolproof, tho, since the "elsif" will have to have |
| 674 | ;; equal left and right levels (since it's optional), so smie-next-sexp |
| 675 | ;; has to be careful to distinguish those different cases. |
| 676 | (eq (smie-op-left toklevels) (smie-op-right toklevels))) |
| 677 | |
| 678 | (defun smie-next-sexp (next-token next-sexp op-forw op-back halfsexp) |
| 679 | "Skip over one sexp. |
| 680 | NEXT-TOKEN is a function of no argument that moves forward by one |
| 681 | token (after skipping comments if needed) and returns it. |
| 682 | NEXT-SEXP is a lower-level function to skip one sexp. |
| 683 | OP-FORW is the accessor to the forward level of the level data. |
| 684 | OP-BACK is the accessor to the backward level of the level data. |
| 685 | HALFSEXP if non-nil, means skip over a partial sexp if needed. I.e. if the |
| 686 | first token we see is an operator, skip over its left-hand-side argument. |
| 687 | HALFSEXP can also be a token, in which case it means to parse as if |
| 688 | we had just successfully passed this token. |
| 689 | Possible return values: |
| 690 | (FORW-LEVEL POS TOKEN): we couldn't skip TOKEN because its back-level |
| 691 | is too high. FORW-LEVEL is the forw-level of TOKEN, |
| 692 | POS is its start position in the buffer. |
| 693 | (t POS TOKEN): same thing when we bump on the wrong side of a paren. |
| 694 | Instead of t, the `car' can also be some other non-nil non-number value. |
| 695 | (nil POS TOKEN): we skipped over a paren-like pair. |
| 696 | nil: we skipped over an identifier, matched parentheses, ..." |
| 697 | (catch 'return |
| 698 | (let ((levels |
| 699 | (if (stringp halfsexp) |
| 700 | (prog1 (list (cdr (assoc halfsexp smie-grammar))) |
| 701 | (setq halfsexp nil))))) |
| 702 | (while |
| 703 | (let* ((pos (point)) |
| 704 | (token (funcall next-token)) |
| 705 | (toklevels (cdr (assoc token smie-grammar)))) |
| 706 | (cond |
| 707 | ((null toklevels) |
| 708 | (when (zerop (length token)) |
| 709 | (condition-case err |
| 710 | (progn (goto-char pos) (funcall next-sexp 1) nil) |
| 711 | (scan-error |
| 712 | (let ((pos (nth 2 err))) |
| 713 | (throw 'return |
| 714 | (list t pos |
| 715 | (buffer-substring-no-properties |
| 716 | pos (+ pos (if (< (point) pos) -1 1)))))))) |
| 717 | (if (eq pos (point)) |
| 718 | ;; We did not move, so let's abort the loop. |
| 719 | (throw 'return (list t (point)))))) |
| 720 | ((not (numberp (funcall op-back toklevels))) |
| 721 | ;; A token like a paren-close. |
| 722 | (cl-assert (numberp ; Otherwise, why mention it in smie-grammar. |
| 723 | (funcall op-forw toklevels))) |
| 724 | (push toklevels levels)) |
| 725 | (t |
| 726 | (while (and levels (< (funcall op-back toklevels) |
| 727 | (funcall op-forw (car levels)))) |
| 728 | (setq levels (cdr levels))) |
| 729 | (cond |
| 730 | ((null levels) |
| 731 | (if (and halfsexp (numberp (funcall op-forw toklevels))) |
| 732 | (push toklevels levels) |
| 733 | (throw 'return |
| 734 | (prog1 (list (or (funcall op-forw toklevels) t) |
| 735 | (point) token) |
| 736 | (goto-char pos))))) |
| 737 | (t |
| 738 | (let ((lastlevels levels)) |
| 739 | (if (and levels (= (funcall op-back toklevels) |
| 740 | (funcall op-forw (car levels)))) |
| 741 | (setq levels (cdr levels))) |
| 742 | ;; We may have found a match for the previously pending |
| 743 | ;; operator. Is this the end? |
| 744 | (cond |
| 745 | ;; Keep looking as long as we haven't matched the |
| 746 | ;; topmost operator. |
| 747 | (levels |
| 748 | (cond |
| 749 | ((numberp (funcall op-forw toklevels)) |
| 750 | (push toklevels levels)) |
| 751 | ;; FIXME: For some languages, we can express the grammar |
| 752 | ;; OK, but next-sexp doesn't stop where we'd want it to. |
| 753 | ;; E.g. in SML, we'd want to stop right in front of |
| 754 | ;; "local" if we're scanning (both forward and backward) |
| 755 | ;; from a "val/fun/..." at the same level. |
| 756 | ;; Same for Pascal/Modula2's "procedure" w.r.t |
| 757 | ;; "type/var/const". |
| 758 | ;; |
| 759 | ;; ((and (functionp (cadr (funcall op-forw toklevels))) |
| 760 | ;; (funcall (cadr (funcall op-forw toklevels)) |
| 761 | ;; levels)) |
| 762 | ;; (setq levels nil)) |
| 763 | )) |
| 764 | ;; We matched the topmost operator. If the new operator |
| 765 | ;; is the last in the corresponding BNF rule, we're done. |
| 766 | ((not (numberp (funcall op-forw toklevels))) |
| 767 | ;; It is the last element, let's stop here. |
| 768 | (throw 'return (list nil (point) token))) |
| 769 | ;; If the new operator is not the last in the BNF rule, |
| 770 | ;; and is not associative, it's one of the inner operators |
| 771 | ;; (like the "in" in "let .. in .. end"), so keep looking. |
| 772 | ((not (smie--associative-p toklevels)) |
| 773 | (push toklevels levels)) |
| 774 | ;; The new operator is associative. Two cases: |
| 775 | ;; - it's really just an associative operator (like + or ;) |
| 776 | ;; in which case we should have stopped right before. |
| 777 | ((and lastlevels |
| 778 | (smie--associative-p (car lastlevels))) |
| 779 | (throw 'return |
| 780 | (prog1 (list (or (funcall op-forw toklevels) t) |
| 781 | (point) token) |
| 782 | (goto-char pos)))) |
| 783 | ;; - it's an associative operator within a larger construct |
| 784 | ;; (e.g. an "elsif"), so we should just ignore it and keep |
| 785 | ;; looking for the closing element. |
| 786 | (t (setq levels lastlevels)))))))) |
| 787 | levels) |
| 788 | (setq halfsexp nil))))) |
| 789 | |
| 790 | (defun smie-backward-sexp (&optional halfsexp) |
| 791 | "Skip over one sexp. |
| 792 | HALFSEXP if non-nil, means skip over a partial sexp if needed. I.e. if the |
| 793 | first token we see is an operator, skip over its left-hand-side argument. |
| 794 | HALFSEXP can also be a token, in which case we should skip the text |
| 795 | assuming it is the left-hand-side argument of that token. |
| 796 | Possible return values: |
| 797 | (LEFT-LEVEL POS TOKEN): we couldn't skip TOKEN because its right-level |
| 798 | is too high. LEFT-LEVEL is the left-level of TOKEN, |
| 799 | POS is its start position in the buffer. |
| 800 | (t POS TOKEN): same thing but for an open-paren or the beginning of buffer. |
| 801 | Instead of t, the `car' can also be some other non-nil non-number value. |
| 802 | (nil POS TOKEN): we skipped over a paren-like pair. |
| 803 | nil: we skipped over an identifier, matched parentheses, ..." |
| 804 | (smie-next-sexp |
| 805 | (indirect-function smie-backward-token-function) |
| 806 | (indirect-function 'backward-sexp) |
| 807 | (indirect-function 'smie-op-left) |
| 808 | (indirect-function 'smie-op-right) |
| 809 | halfsexp)) |
| 810 | |
| 811 | (defun smie-forward-sexp (&optional halfsexp) |
| 812 | "Skip over one sexp. |
| 813 | HALFSEXP if non-nil, means skip over a partial sexp if needed. I.e. if the |
| 814 | first token we see is an operator, skip over its right-hand-side argument. |
| 815 | HALFSEXP can also be a token, in which case we should skip the text |
| 816 | assuming it is the right-hand-side argument of that token. |
| 817 | Possible return values: |
| 818 | (RIGHT-LEVEL POS TOKEN): we couldn't skip TOKEN because its left-level |
| 819 | is too high. RIGHT-LEVEL is the right-level of TOKEN, |
| 820 | POS is its end position in the buffer. |
| 821 | (t POS TOKEN): same thing but for a close-paren or the end of buffer. |
| 822 | Instead of t, the `car' can also be some other non-nil non-number value. |
| 823 | (nil POS TOKEN): we skipped over a paren-like pair. |
| 824 | nil: we skipped over an identifier, matched parentheses, ..." |
| 825 | (smie-next-sexp |
| 826 | (indirect-function smie-forward-token-function) |
| 827 | (indirect-function 'forward-sexp) |
| 828 | (indirect-function 'smie-op-right) |
| 829 | (indirect-function 'smie-op-left) |
| 830 | halfsexp)) |
| 831 | |
| 832 | ;;; Miscellaneous commands using the precedence parser. |
| 833 | |
| 834 | (defun smie-backward-sexp-command (&optional n) |
| 835 | "Move backward through N logical elements." |
| 836 | (interactive "^p") |
| 837 | (smie-forward-sexp-command (- n))) |
| 838 | |
| 839 | (defun smie-forward-sexp-command (&optional n) |
| 840 | "Move forward through N logical elements." |
| 841 | (interactive "^p") |
| 842 | (let ((forw (> n 0)) |
| 843 | (forward-sexp-function nil)) |
| 844 | (while (/= n 0) |
| 845 | (setq n (- n (if forw 1 -1))) |
| 846 | (let ((pos (point)) |
| 847 | (res (if forw |
| 848 | (smie-forward-sexp 'halfsexp) |
| 849 | (smie-backward-sexp 'halfsexp)))) |
| 850 | (if (and (car res) (= pos (point)) (not (if forw (eobp) (bobp)))) |
| 851 | (signal 'scan-error |
| 852 | (list "Containing expression ends prematurely" |
| 853 | (cadr res) (cadr res))) |
| 854 | nil))))) |
| 855 | |
| 856 | (defvar smie-closer-alist nil |
| 857 | "Alist giving the closer corresponding to an opener.") |
| 858 | |
| 859 | (defun smie-close-block () |
| 860 | "Close the closest surrounding block." |
| 861 | (interactive) |
| 862 | (let ((closer |
| 863 | (save-excursion |
| 864 | (backward-up-list 1) |
| 865 | (if (looking-at "\\s(") |
| 866 | (string (cdr (syntax-after (point)))) |
| 867 | (let* ((open (funcall smie-forward-token-function)) |
| 868 | (closer (cdr (assoc open smie-closer-alist))) |
| 869 | (levels (list (assoc open smie-grammar))) |
| 870 | (seen '()) |
| 871 | (found '())) |
| 872 | (cond |
| 873 | ;; Even if we improve the auto-computation of closers, |
| 874 | ;; there are still cases where we need manual |
| 875 | ;; intervention, e.g. for Octave's use of `until' |
| 876 | ;; as a pseudo-closer of `do'. |
| 877 | (closer) |
| 878 | ((or (equal levels '(nil)) (numberp (nth 1 (car levels)))) |
| 879 | (error "Doesn't look like a block")) |
| 880 | (t |
| 881 | ;; Now that smie-setup automatically sets smie-closer-alist |
| 882 | ;; from the BNF, this is not really needed any more. |
| 883 | (while levels |
| 884 | (let ((level (pop levels))) |
| 885 | (dolist (other smie-grammar) |
| 886 | (when (and (eq (nth 2 level) (nth 1 other)) |
| 887 | (not (memq other seen))) |
| 888 | (push other seen) |
| 889 | (if (numberp (nth 2 other)) |
| 890 | (push other levels) |
| 891 | (push (car other) found)))))) |
| 892 | (cond |
| 893 | ((null found) (error "No known closer for opener %s" open)) |
| 894 | ;; What should we do if there are various closers? |
| 895 | (t (car found)))))))))) |
| 896 | (unless (save-excursion (skip-chars-backward " \t") (bolp)) |
| 897 | (newline)) |
| 898 | (insert closer) |
| 899 | (if (save-excursion (skip-chars-forward " \t") (eolp)) |
| 900 | (indent-according-to-mode) |
| 901 | (reindent-then-newline-and-indent)))) |
| 902 | |
| 903 | (defun smie-down-list (&optional arg) |
| 904 | "Move forward down one level paren-like blocks. Like `down-list'. |
| 905 | With argument ARG, do this that many times. |
| 906 | A negative argument means move backward but still go down a level. |
| 907 | This command assumes point is not in a string or comment." |
| 908 | (interactive "p") |
| 909 | (let ((start (point)) |
| 910 | (inc (if (< arg 0) -1 1)) |
| 911 | (offset (if (< arg 0) 1 0)) |
| 912 | (next-token (if (< arg 0) |
| 913 | smie-backward-token-function |
| 914 | smie-forward-token-function))) |
| 915 | (while (/= arg 0) |
| 916 | (setq arg (- arg inc)) |
| 917 | (while |
| 918 | (let* ((pos (point)) |
| 919 | (token (funcall next-token)) |
| 920 | (levels (assoc token smie-grammar))) |
| 921 | (cond |
| 922 | ((zerop (length token)) |
| 923 | (if (if (< inc 0) (looking-back "\\s(\\|\\s)" (1- (point))) |
| 924 | (looking-at "\\s(\\|\\s)")) |
| 925 | ;; Go back to `start' in case of an error. This presumes |
| 926 | ;; none of the token we've found until now include a ( or ). |
| 927 | (progn (goto-char start) (down-list inc) nil) |
| 928 | (forward-sexp inc) |
| 929 | (/= (point) pos))) |
| 930 | ((and levels (not (numberp (nth (+ 1 offset) levels)))) nil) |
| 931 | ((and levels (not (numberp (nth (- 2 offset) levels)))) |
| 932 | (let ((end (point))) |
| 933 | (goto-char start) |
| 934 | (signal 'scan-error |
| 935 | (list "Containing expression ends prematurely" |
| 936 | pos end)))) |
| 937 | (t))))))) |
| 938 | |
| 939 | (defvar smie-blink-matching-triggers '(?\s ?\n) |
| 940 | "Chars which might trigger `blink-matching-open'. |
| 941 | These can include the final chars of end-tokens, or chars that are |
| 942 | typically inserted right after an end token. |
| 943 | I.e. a good choice can be: |
| 944 | (delete-dups |
| 945 | (mapcar (lambda (kw) (aref (cdr kw) (1- (length (cdr kw))))) |
| 946 | smie-closer-alist))") |
| 947 | |
| 948 | (defcustom smie-blink-matching-inners t |
| 949 | "Whether SMIE should blink to matching opener for inner keywords. |
| 950 | If non-nil, it will blink not only for \"begin..end\" but also for \"if...else\"." |
| 951 | :type 'boolean |
| 952 | :group 'smie) |
| 953 | |
| 954 | (defun smie-blink-matching-check (start end) |
| 955 | (save-excursion |
| 956 | (goto-char end) |
| 957 | (let ((ender (funcall smie-backward-token-function))) |
| 958 | (cond |
| 959 | ((not (and ender (rassoc ender smie-closer-alist))) |
| 960 | ;; This not is one of the begin..end we know how to check. |
| 961 | (blink-matching-check-mismatch start end)) |
| 962 | ((not start) t) |
| 963 | ((eq t (car (rassoc ender smie-closer-alist))) nil) |
| 964 | (t |
| 965 | (goto-char start) |
| 966 | (let ((starter (funcall smie-forward-token-function))) |
| 967 | (not (member (cons starter ender) smie-closer-alist)))))))) |
| 968 | |
| 969 | (defun smie-blink-matching-open () |
| 970 | "Blink the matching opener when applicable. |
| 971 | This uses SMIE's tables and is expected to be placed on `post-self-insert-hook'." |
| 972 | (let ((pos (point)) ;Position after the close token. |
| 973 | token) |
| 974 | (when (and blink-matching-paren |
| 975 | smie-closer-alist ; Optimization. |
| 976 | (or (eq (char-before) last-command-event) ;; Sanity check. |
| 977 | (save-excursion |
| 978 | (or (progn (skip-chars-backward " \t") |
| 979 | (setq pos (point)) |
| 980 | (eq (char-before) last-command-event)) |
| 981 | (progn (skip-chars-backward " \n\t") |
| 982 | (setq pos (point)) |
| 983 | (eq (char-before) last-command-event))))) |
| 984 | (memq last-command-event smie-blink-matching-triggers) |
| 985 | (not (nth 8 (syntax-ppss)))) |
| 986 | (save-excursion |
| 987 | (setq token (funcall smie-backward-token-function)) |
| 988 | (when (and (eq (point) (1- pos)) |
| 989 | (= 1 (length token)) |
| 990 | (not (rassoc token smie-closer-alist))) |
| 991 | ;; The trigger char is itself a token but is not one of the |
| 992 | ;; closers (e.g. ?\; in Octave mode), so go back to the |
| 993 | ;; previous token. |
| 994 | (setq pos (point)) |
| 995 | (setq token (funcall smie-backward-token-function))) |
| 996 | (when (rassoc token smie-closer-alist) |
| 997 | ;; We're after a close token. Let's still make sure we |
| 998 | ;; didn't skip a comment to find that token. |
| 999 | (funcall smie-forward-token-function) |
| 1000 | (when (and (save-excursion |
| 1001 | ;; Skip the trigger char, if applicable. |
| 1002 | (if (eq (char-after) last-command-event) |
| 1003 | (forward-char 1)) |
| 1004 | (if (eq ?\n last-command-event) |
| 1005 | ;; Skip any auto-indentation, if applicable. |
| 1006 | (skip-chars-forward " \t")) |
| 1007 | (>= (point) pos)) |
| 1008 | ;; If token ends with a trigger char, don't blink for |
| 1009 | ;; anything else than this trigger char, lest we'd blink |
| 1010 | ;; both when inserting the trigger char and when |
| 1011 | ;; inserting a subsequent trigger char like SPC. |
| 1012 | (or (eq (char-before) last-command-event) |
| 1013 | (not (memq (char-before) |
| 1014 | smie-blink-matching-triggers))) |
| 1015 | (or smie-blink-matching-inners |
| 1016 | (not (numberp (nth 2 (assoc token smie-grammar)))))) |
| 1017 | ;; The major mode might set blink-matching-check-function |
| 1018 | ;; buffer-locally so that interactive calls to |
| 1019 | ;; blink-matching-open work right, but let's not presume |
| 1020 | ;; that's the case. |
| 1021 | (let ((blink-matching-check-function #'smie-blink-matching-check)) |
| 1022 | (blink-matching-open)))))))) |
| 1023 | |
| 1024 | ;;; The indentation engine. |
| 1025 | |
| 1026 | (defcustom smie-indent-basic 4 |
| 1027 | "Basic amount of indentation." |
| 1028 | :type 'integer |
| 1029 | :group 'smie) |
| 1030 | |
| 1031 | (defvar smie-rules-function 'ignore |
| 1032 | "Function providing the indentation rules. |
| 1033 | It takes two arguments METHOD and ARG where the meaning of ARG |
| 1034 | and the expected return value depends on METHOD. |
| 1035 | METHOD can be: |
| 1036 | - :after, in which case ARG is a token and the function should return the |
| 1037 | OFFSET to use for indentation after ARG. |
| 1038 | - :before, in which case ARG is a token and the function should return the |
| 1039 | OFFSET to use to indent ARG itself. |
| 1040 | - :elem, in which case the function should return either: |
| 1041 | - the offset to use to indent function arguments (ARG = `arg') |
| 1042 | - the basic indentation step (ARG = `basic'). |
| 1043 | - :list-intro, in which case ARG is a token and the function should return |
| 1044 | non-nil if TOKEN is followed by a list of expressions (not separated by any |
| 1045 | token) rather than an expression. |
| 1046 | |
| 1047 | When ARG is a token, the function is called with point just before that token. |
| 1048 | A return value of nil always means to fallback on the default behavior, so the |
| 1049 | function should return nil for arguments it does not expect. |
| 1050 | |
| 1051 | OFFSET can be: |
| 1052 | nil use the default indentation rule. |
| 1053 | \(column . COLUMN) indent to column COLUMN. |
| 1054 | NUMBER offset by NUMBER, relative to a base token |
| 1055 | which is the current token for :after and |
| 1056 | its parent for :before. |
| 1057 | |
| 1058 | The functions whose name starts with \"smie-rule-\" are helper functions |
| 1059 | designed specifically for use in this function.") |
| 1060 | |
| 1061 | (defalias 'smie-rule-hanging-p 'smie-indent--hanging-p) |
| 1062 | (defun smie-indent--hanging-p () |
| 1063 | "Return non-nil if the current token is \"hanging\". |
| 1064 | A hanging keyword is one that's at the end of a line except it's not at |
| 1065 | the beginning of a line." |
| 1066 | (and (not (smie-indent--bolp)) |
| 1067 | (save-excursion |
| 1068 | (<= (line-end-position) |
| 1069 | (progn |
| 1070 | (when (zerop (length (funcall smie-forward-token-function))) |
| 1071 | ;; Could be an open-paren. |
| 1072 | (forward-char 1)) |
| 1073 | (skip-chars-forward " \t") |
| 1074 | (or (eolp) |
| 1075 | (and (looking-at comment-start-skip) |
| 1076 | (forward-comment (point-max)))) |
| 1077 | (point)))))) |
| 1078 | |
| 1079 | (defalias 'smie-rule-bolp 'smie-indent--bolp) |
| 1080 | (defun smie-indent--bolp () |
| 1081 | "Return non-nil if the current token is the first on the line." |
| 1082 | (save-excursion (skip-chars-backward " \t") (bolp))) |
| 1083 | |
| 1084 | (defun smie-indent--bolp-1 () |
| 1085 | ;; Like smie-indent--bolp but also returns non-nil if it's the first |
| 1086 | ;; non-comment token. Maybe we should simply always use this? |
| 1087 | "Return non-nil if the current token is the first on the line. |
| 1088 | Comments are treated as spaces." |
| 1089 | (let ((bol (line-beginning-position))) |
| 1090 | (save-excursion |
| 1091 | (forward-comment (- (point))) |
| 1092 | (<= (point) bol)))) |
| 1093 | |
| 1094 | ;; Dynamically scoped. |
| 1095 | (defvar smie--parent) (defvar smie--after) (defvar smie--token) |
| 1096 | |
| 1097 | (defun smie-indent--parent () |
| 1098 | (or smie--parent |
| 1099 | (save-excursion |
| 1100 | (let* ((pos (point)) |
| 1101 | (tok (funcall smie-forward-token-function))) |
| 1102 | (unless (numberp (cadr (assoc tok smie-grammar))) |
| 1103 | (goto-char pos)) |
| 1104 | (setq smie--parent |
| 1105 | (or (smie-backward-sexp 'halfsexp) |
| 1106 | (let (res) |
| 1107 | (while (null (setq res (smie-backward-sexp)))) |
| 1108 | (list nil (point) (nth 2 res))))))))) |
| 1109 | |
| 1110 | (defun smie-rule-parent-p (&rest parents) |
| 1111 | "Return non-nil if the current token's parent is among PARENTS. |
| 1112 | Only meaningful when called from within `smie-rules-function'." |
| 1113 | (member (nth 2 (smie-indent--parent)) parents)) |
| 1114 | |
| 1115 | (defun smie-rule-next-p (&rest tokens) |
| 1116 | "Return non-nil if the next token is among TOKENS. |
| 1117 | Only meaningful when called from within `smie-rules-function'." |
| 1118 | (let ((next |
| 1119 | (save-excursion |
| 1120 | (unless smie--after |
| 1121 | (smie-indent-forward-token) (setq smie--after (point))) |
| 1122 | (goto-char smie--after) |
| 1123 | (smie-indent-forward-token)))) |
| 1124 | (member (car next) tokens))) |
| 1125 | |
| 1126 | (defun smie-rule-prev-p (&rest tokens) |
| 1127 | "Return non-nil if the previous token is among TOKENS." |
| 1128 | (let ((prev (save-excursion |
| 1129 | (smie-indent-backward-token)))) |
| 1130 | (member (car prev) tokens))) |
| 1131 | |
| 1132 | (defun smie-rule-sibling-p () |
| 1133 | "Return non-nil if the parent is actually a sibling. |
| 1134 | Only meaningful when called from within `smie-rules-function'." |
| 1135 | (eq (car (smie-indent--parent)) |
| 1136 | (cadr (assoc smie--token smie-grammar)))) |
| 1137 | |
| 1138 | (defun smie-rule-parent (&optional offset) |
| 1139 | "Align with parent. |
| 1140 | If non-nil, OFFSET should be an integer giving an additional offset to apply. |
| 1141 | Only meaningful when called from within `smie-rules-function'." |
| 1142 | (save-excursion |
| 1143 | (goto-char (cadr (smie-indent--parent))) |
| 1144 | (cons 'column |
| 1145 | (+ (or offset 0) |
| 1146 | ;; Use smie-indent-virtual when indenting relative to an opener: |
| 1147 | ;; this will also by default use current-column unless |
| 1148 | ;; that opener is hanging, but will additionally consult |
| 1149 | ;; rules-function, so it gives it a chance to tweak |
| 1150 | ;; indentation (e.g. by forcing indentation relative to |
| 1151 | ;; its own parent, as in fn a => fn b => fn c =>). |
| 1152 | (if (or (listp (car smie--parent)) (smie-indent--hanging-p)) |
| 1153 | (smie-indent-virtual) (current-column)))))) |
| 1154 | |
| 1155 | (defvar smie-rule-separator-outdent 2) |
| 1156 | |
| 1157 | (defun smie-indent--separator-outdent () |
| 1158 | ;; FIXME: Here we actually have several reasonable behaviors. |
| 1159 | ;; E.g. for a parent token of "FOO" and a separator ";" we may want to: |
| 1160 | ;; 1- left-align ; with FOO. |
| 1161 | ;; 2- right-align ; with FOO. |
| 1162 | ;; 3- align content after ; with content after FOO. |
| 1163 | ;; 4- align content plus add/remove spaces so as to align ; with FOO. |
| 1164 | ;; Currently, we try to align the contents (option 3) which actually behaves |
| 1165 | ;; just like option 2 (if the number of spaces after FOO and ; is equal). |
| 1166 | (let ((afterpos (save-excursion |
| 1167 | (let ((tok (funcall smie-forward-token-function))) |
| 1168 | (unless tok |
| 1169 | (with-demoted-errors |
| 1170 | (error "smie-rule-separator: can't skip token %s" |
| 1171 | smie--token)))) |
| 1172 | (skip-chars-forward " ") |
| 1173 | (unless (eolp) (point))))) |
| 1174 | (or (and afterpos |
| 1175 | ;; This should always be true, unless |
| 1176 | ;; smie-forward-token-function skipped a \n. |
| 1177 | (< afterpos (line-end-position)) |
| 1178 | (- afterpos (point))) |
| 1179 | smie-rule-separator-outdent))) |
| 1180 | |
| 1181 | (defun smie-rule-separator (method) |
| 1182 | "Indent current token as a \"separator\". |
| 1183 | By \"separator\", we mean here a token whose sole purpose is to separate |
| 1184 | various elements within some enclosing syntactic construct, and which does |
| 1185 | not have any semantic significance in itself (i.e. it would typically no exist |
| 1186 | as a node in an abstract syntax tree). |
| 1187 | Such a token is expected to have an associative syntax and be closely tied |
| 1188 | to its syntactic parent. Typical examples are \",\" in lists of arguments |
| 1189 | \(enclosed inside parentheses), or \";\" in sequences of instructions (enclosed |
| 1190 | in a {..} or begin..end block). |
| 1191 | METHOD should be the method name that was passed to `smie-rules-function'. |
| 1192 | Only meaningful when called from within `smie-rules-function'." |
| 1193 | ;; FIXME: The code below works OK for cases where the separators |
| 1194 | ;; are placed consistently always at beginning or always at the end, |
| 1195 | ;; but not if some are at the beginning and others are at the end. |
| 1196 | ;; I.e. it gets confused in cases such as: |
| 1197 | ;; ( a |
| 1198 | ;; , a, |
| 1199 | ;; b |
| 1200 | ;; , c, |
| 1201 | ;; d |
| 1202 | ;; ) |
| 1203 | ;; |
| 1204 | ;; Assuming token is associative, the default rule for associative |
| 1205 | ;; tokens (which assumes an infix operator) works fine for many cases. |
| 1206 | ;; We mostly need to take care of the case where token is at beginning of |
| 1207 | ;; line, in which case we want to align it with its enclosing parent. |
| 1208 | (cond |
| 1209 | ((and (eq method :before) (smie-rule-bolp) (not (smie-rule-sibling-p))) |
| 1210 | (let ((parent-col (cdr (smie-rule-parent))) |
| 1211 | (parent-pos-col ;FIXME: we knew this when computing smie--parent. |
| 1212 | (save-excursion |
| 1213 | (goto-char (cadr smie--parent)) |
| 1214 | (smie-indent-forward-token) |
| 1215 | (forward-comment (point-max)) |
| 1216 | (current-column)))) |
| 1217 | (cons 'column |
| 1218 | (max parent-col |
| 1219 | (min parent-pos-col |
| 1220 | (- parent-pos-col (smie-indent--separator-outdent))))))) |
| 1221 | ((and (eq method :after) (smie-indent--bolp)) |
| 1222 | (smie-indent--separator-outdent)))) |
| 1223 | |
| 1224 | (defun smie-indent--offset (elem) |
| 1225 | (or (funcall smie-rules-function :elem elem) |
| 1226 | (if (not (eq elem 'basic)) |
| 1227 | (funcall smie-rules-function :elem 'basic)) |
| 1228 | smie-indent-basic)) |
| 1229 | |
| 1230 | (defun smie-indent--rule (method token |
| 1231 | ;; FIXME: Too many parameters. |
| 1232 | &optional after parent base-pos) |
| 1233 | "Compute indentation column according to `indent-rule-functions'. |
| 1234 | METHOD and TOKEN are passed to `indent-rule-functions'. |
| 1235 | AFTER is the position after TOKEN, if known. |
| 1236 | PARENT is the parent info returned by `smie-backward-sexp', if known. |
| 1237 | BASE-POS is the position relative to which offsets should be applied." |
| 1238 | ;; This is currently called in 3 cases: |
| 1239 | ;; - :before opener, where rest=nil but base-pos could as well be parent. |
| 1240 | ;; - :before other, where |
| 1241 | ;; ; after=nil |
| 1242 | ;; ; parent is set |
| 1243 | ;; ; base-pos=parent |
| 1244 | ;; - :after tok, where |
| 1245 | ;; ; after is set; parent=nil; base-pos=point; |
| 1246 | (save-excursion |
| 1247 | (let ((offset |
| 1248 | (let ((smie--parent parent) |
| 1249 | (smie--token token) |
| 1250 | (smie--after after)) |
| 1251 | (funcall smie-rules-function method token)))) |
| 1252 | (cond |
| 1253 | ((not offset) nil) |
| 1254 | ((eq (car-safe offset) 'column) (cdr offset)) |
| 1255 | ((integerp offset) |
| 1256 | (+ offset |
| 1257 | (if (null base-pos) 0 |
| 1258 | (goto-char base-pos) |
| 1259 | ;; Use smie-indent-virtual when indenting relative to an opener: |
| 1260 | ;; this will also by default use current-column unless |
| 1261 | ;; that opener is hanging, but will additionally consult |
| 1262 | ;; rules-function, so it gives it a chance to tweak indentation |
| 1263 | ;; (e.g. by forcing indentation relative to its own parent, as in |
| 1264 | ;; fn a => fn b => fn c =>). |
| 1265 | ;; When parent==nil it doesn't matter because the only case |
| 1266 | ;; where it's really used is when the base-pos is hanging anyway. |
| 1267 | (if (or (and parent (null (car parent))) |
| 1268 | (smie-indent--hanging-p)) |
| 1269 | (smie-indent-virtual) (current-column))))) |
| 1270 | (t (error "Unknown indentation offset %s" offset)))))) |
| 1271 | |
| 1272 | (defun smie-indent-forward-token () |
| 1273 | "Skip token forward and return it, along with its levels." |
| 1274 | (let ((tok (funcall smie-forward-token-function))) |
| 1275 | (cond |
| 1276 | ((< 0 (length tok)) (assoc tok smie-grammar)) |
| 1277 | ((looking-at "\\s(\\|\\s)\\(\\)") |
| 1278 | (forward-char 1) |
| 1279 | (cons (buffer-substring (1- (point)) (point)) |
| 1280 | (if (match-end 1) '(0 nil) '(nil 0))))))) |
| 1281 | |
| 1282 | (defun smie-indent-backward-token () |
| 1283 | "Skip token backward and return it, along with its levels." |
| 1284 | (let ((tok (funcall smie-backward-token-function)) |
| 1285 | class) |
| 1286 | (cond |
| 1287 | ((< 0 (length tok)) (assoc tok smie-grammar)) |
| 1288 | ;; 4 == open paren syntax, 5 == close. |
| 1289 | ((memq (setq class (syntax-class (syntax-after (1- (point))))) '(4 5)) |
| 1290 | (forward-char -1) |
| 1291 | (cons (buffer-substring (point) (1+ (point))) |
| 1292 | (if (eq class 4) '(nil 0) '(0 nil))))))) |
| 1293 | |
| 1294 | (defun smie-indent-virtual () |
| 1295 | ;; We used to take an optional arg (with value :not-hanging) to specify that |
| 1296 | ;; we should only use (smie-indent-calculate) if we're looking at a hanging |
| 1297 | ;; keyword. This was a bad idea, because the virtual indent of a position |
| 1298 | ;; should not depend on the caller, since it leads to situations where two |
| 1299 | ;; dependent indentations get indented differently. |
| 1300 | "Compute the virtual indentation to use for point. |
| 1301 | This is used when we're not trying to indent point but just |
| 1302 | need to compute the column at which point should be indented |
| 1303 | in order to figure out the indentation of some other (further down) point." |
| 1304 | ;; Trust pre-existing indentation on other lines. |
| 1305 | (if (smie-indent--bolp) (current-column) (smie-indent-calculate))) |
| 1306 | |
| 1307 | (defun smie-indent-fixindent () |
| 1308 | ;; Obey the `fixindent' special comment. |
| 1309 | (and (smie-indent--bolp) |
| 1310 | (save-excursion |
| 1311 | (comment-normalize-vars) |
| 1312 | (re-search-forward (concat comment-start-skip |
| 1313 | "fixindent" |
| 1314 | comment-end-skip) |
| 1315 | ;; 1+ to account for the \n comment termination. |
| 1316 | (1+ (line-end-position)) t)) |
| 1317 | (current-column))) |
| 1318 | |
| 1319 | (defun smie-indent-bob () |
| 1320 | ;; Start the file at column 0. |
| 1321 | (save-excursion |
| 1322 | (forward-comment (- (point))) |
| 1323 | (if (bobp) 0))) |
| 1324 | |
| 1325 | (defun smie-indent-close () |
| 1326 | ;; Align close paren with opening paren. |
| 1327 | (save-excursion |
| 1328 | ;; (forward-comment (point-max)) |
| 1329 | (when (looking-at "\\s)") |
| 1330 | (while (not (zerop (skip-syntax-forward ")"))) |
| 1331 | (skip-chars-forward " \t")) |
| 1332 | (condition-case nil |
| 1333 | (progn |
| 1334 | (backward-sexp 1) |
| 1335 | (smie-indent-virtual)) ;:not-hanging |
| 1336 | (scan-error nil))))) |
| 1337 | |
| 1338 | (defun smie-indent-keyword (&optional token) |
| 1339 | "Indent point based on the token that follows it immediately. |
| 1340 | If TOKEN is non-nil, assume that that is the token that follows point. |
| 1341 | Returns either a column number or nil if it considers that indentation |
| 1342 | should not be computed on the basis of the following token." |
| 1343 | (save-excursion |
| 1344 | (let* ((pos (point)) |
| 1345 | (toklevels |
| 1346 | (if token |
| 1347 | (assoc token smie-grammar) |
| 1348 | (let* ((res (smie-indent-forward-token))) |
| 1349 | ;; Ignore tokens on subsequent lines. |
| 1350 | (if (and (< pos (line-beginning-position)) |
| 1351 | ;; Make sure `token' also *starts* on another line. |
| 1352 | (save-excursion |
| 1353 | (smie-indent-backward-token) |
| 1354 | (< pos (line-beginning-position)))) |
| 1355 | nil |
| 1356 | (goto-char pos) |
| 1357 | res))))) |
| 1358 | (setq token (pop toklevels)) |
| 1359 | (cond |
| 1360 | ((null (cdr toklevels)) nil) ;Not a keyword. |
| 1361 | ((not (numberp (car toklevels))) |
| 1362 | ;; Different cases: |
| 1363 | ;; - smie-indent--bolp: "indent according to others". |
| 1364 | ;; - common hanging: "indent according to others". |
| 1365 | ;; - SML-let hanging: "indent like parent". |
| 1366 | ;; - if-after-else: "indent-like parent". |
| 1367 | ;; - middle-of-line: "trust current position". |
| 1368 | (cond |
| 1369 | ((smie-indent--rule :before token)) |
| 1370 | ((smie-indent--bolp-1) ;I.e. non-virtual indent. |
| 1371 | ;; For an open-paren-like thingy at BOL, always indent only |
| 1372 | ;; based on other rules (typically smie-indent-after-keyword). |
| 1373 | ;; FIXME: we do the same if after a comment, since we may be trying |
| 1374 | ;; to compute the indentation of this comment and we shouldn't indent |
| 1375 | ;; based on the indentation of subsequent code. |
| 1376 | nil) |
| 1377 | (t |
| 1378 | ;; By default use point unless we're hanging. |
| 1379 | (unless (smie-indent--hanging-p) (current-column))))) |
| 1380 | (t |
| 1381 | ;; FIXME: This still looks too much like black magic!! |
| 1382 | (let* ((parent (smie-backward-sexp token))) |
| 1383 | ;; Different behaviors: |
| 1384 | ;; - align with parent. |
| 1385 | ;; - parent + offset. |
| 1386 | ;; - after parent's column + offset (actually, after or before |
| 1387 | ;; depending on where backward-sexp stopped). |
| 1388 | ;; ? let it drop to some other indentation function (almost never). |
| 1389 | ;; ? parent + offset + parent's own offset. |
| 1390 | ;; Different cases: |
| 1391 | ;; - bump into a same-level operator. |
| 1392 | ;; - bump into a specific known parent. |
| 1393 | ;; - find a matching open-paren thingy. |
| 1394 | ;; - bump into some random parent. |
| 1395 | ;; ? borderline case (almost never). |
| 1396 | ;; ? bump immediately into a parent. |
| 1397 | (cond |
| 1398 | ((not (or (< (point) pos) |
| 1399 | (and (cadr parent) (< (cadr parent) pos)))) |
| 1400 | ;; If we didn't move at all, that means we didn't really skip |
| 1401 | ;; what we wanted. Should almost never happen, other than |
| 1402 | ;; maybe when an infix or close-paren is at the beginning |
| 1403 | ;; of a buffer. |
| 1404 | nil) |
| 1405 | ((save-excursion |
| 1406 | (goto-char pos) |
| 1407 | (smie-indent--rule :before token nil parent (cadr parent)))) |
| 1408 | ((eq (car parent) (car toklevels)) |
| 1409 | ;; We bumped into a same-level operator; align with it. |
| 1410 | (if (and (smie-indent--bolp) (/= (point) pos) |
| 1411 | (save-excursion |
| 1412 | (goto-char (goto-char (cadr parent))) |
| 1413 | (not (smie-indent--bolp)))) |
| 1414 | ;; If the parent is at EOL and its children are indented like |
| 1415 | ;; itself, then we can just obey the indentation chosen for the |
| 1416 | ;; child. |
| 1417 | ;; This is important for operators like ";" which |
| 1418 | ;; are usually at EOL (and have an offset of 0): otherwise we'd |
| 1419 | ;; always go back over all the statements, which is |
| 1420 | ;; a performance problem and would also mean that fixindents |
| 1421 | ;; in the middle of such a sequence would be ignored. |
| 1422 | ;; |
| 1423 | ;; This is a delicate point! |
| 1424 | ;; Even if the offset is not 0, we could follow the same logic |
| 1425 | ;; and subtract the offset from the child's indentation. |
| 1426 | ;; But that would more often be a bad idea: OT1H we generally |
| 1427 | ;; want to reuse the closest similar indentation point, so that |
| 1428 | ;; the user's choice (or the fixindents) are obeyed. But OTOH |
| 1429 | ;; we don't want this to affect "unrelated" parts of the code. |
| 1430 | ;; E.g. a fixindent in the body of a "begin..end" should not |
| 1431 | ;; affect the indentation of the "end". |
| 1432 | (current-column) |
| 1433 | (goto-char (cadr parent)) |
| 1434 | ;; Don't use (smie-indent-virtual :not-hanging) here, because we |
| 1435 | ;; want to jump back over a sequence of same-level ops such as |
| 1436 | ;; a -> b -> c |
| 1437 | ;; -> d |
| 1438 | ;; So as to align with the earliest appropriate place. |
| 1439 | (smie-indent-virtual))) |
| 1440 | (t |
| 1441 | (if (and (= (point) pos) (smie-indent--bolp)) |
| 1442 | ;; Since we started at BOL, we're not computing a virtual |
| 1443 | ;; indentation, and we're still at the starting point, so |
| 1444 | ;; we can't use `current-column' which would cause |
| 1445 | ;; indentation to depend on itself and we can't use |
| 1446 | ;; smie-indent-virtual since that would be an inf-loop. |
| 1447 | nil |
| 1448 | ;; In indent-keyword, if we're indenting `then' wrt `if', we |
| 1449 | ;; want to use indent-virtual rather than use just |
| 1450 | ;; current-column, so that we can apply the (:before . "if") |
| 1451 | ;; rule which does the "else if" dance in SML. But in other |
| 1452 | ;; cases, we do not want to use indent-virtual (e.g. indentation |
| 1453 | ;; of "*" w.r.t "+", or ";" wrt "("). We could just always use |
| 1454 | ;; indent-virtual and then have indent-rules say explicitly to |
| 1455 | ;; use `point' after things like "(" or "+" when they're not at |
| 1456 | ;; EOL, but you'd end up with lots of those rules. |
| 1457 | ;; So we use a heuristic here, which is that we only use virtual |
| 1458 | ;; if the parent is tightly linked to the child token (they're |
| 1459 | ;; part of the same BNF rule). |
| 1460 | (if (car parent) (current-column) (smie-indent-virtual))))))))))) |
| 1461 | |
| 1462 | (defun smie-indent-comment () |
| 1463 | "Compute indentation of a comment." |
| 1464 | ;; Don't do it for virtual indentations. We should normally never be "in |
| 1465 | ;; front of a comment" when doing virtual-indentation anyway. And if we are |
| 1466 | ;; (as can happen in octave-mode), moving forward can lead to inf-loops. |
| 1467 | (and (smie-indent--bolp) |
| 1468 | (let ((pos (point))) |
| 1469 | (save-excursion |
| 1470 | (beginning-of-line) |
| 1471 | (and (re-search-forward comment-start-skip (line-end-position) t) |
| 1472 | (eq pos (or (match-end 1) (match-beginning 0)))))) |
| 1473 | (save-excursion |
| 1474 | (forward-comment (point-max)) |
| 1475 | (skip-chars-forward " \t\r\n") |
| 1476 | ;; FIXME: We assume here that smie-indent-calculate will compute the |
| 1477 | ;; indentation of the next token based on text before the comment, but |
| 1478 | ;; this is not guaranteed, so maybe we should let |
| 1479 | ;; smie-indent-calculate return some info about which buffer position |
| 1480 | ;; was used as the "indentation base" and check that this base is |
| 1481 | ;; before `pos'. |
| 1482 | (smie-indent-calculate)))) |
| 1483 | |
| 1484 | (defun smie-indent-comment-continue () |
| 1485 | ;; indentation of comment-continue lines. |
| 1486 | (let ((continue (and comment-continue |
| 1487 | (comment-string-strip comment-continue t t)))) |
| 1488 | (and (< 0 (length continue)) |
| 1489 | (looking-at (regexp-quote continue)) (nth 4 (syntax-ppss)) |
| 1490 | (let ((ppss (syntax-ppss))) |
| 1491 | (save-excursion |
| 1492 | (forward-line -1) |
| 1493 | (if (<= (point) (nth 8 ppss)) |
| 1494 | (progn (goto-char (1+ (nth 8 ppss))) (current-column)) |
| 1495 | (skip-chars-forward " \t") |
| 1496 | (if (looking-at (regexp-quote continue)) |
| 1497 | (current-column)))))))) |
| 1498 | |
| 1499 | (defun smie-indent-comment-close () |
| 1500 | (and (boundp 'comment-end-skip) |
| 1501 | comment-end-skip |
| 1502 | (not (looking-at " \t*$")) ;Not just a \n comment-closer. |
| 1503 | (looking-at comment-end-skip) |
| 1504 | (let ((end (match-string 0))) |
| 1505 | (and (nth 4 (syntax-ppss)) |
| 1506 | (save-excursion |
| 1507 | (goto-char (nth 8 (syntax-ppss))) |
| 1508 | (and (looking-at comment-start-skip) |
| 1509 | (let ((start (match-string 0))) |
| 1510 | ;; Align the common substring between starter |
| 1511 | ;; and ender, if possible. |
| 1512 | (if (string-match "\\(.+\\).*\n\\(.*?\\)\\1" |
| 1513 | (concat start "\n" end)) |
| 1514 | (+ (current-column) (match-beginning 0) |
| 1515 | (- (match-beginning 2) (match-end 2))) |
| 1516 | (current-column))))))))) |
| 1517 | |
| 1518 | (defun smie-indent-comment-inside () |
| 1519 | (and (nth 4 (syntax-ppss)) |
| 1520 | 'noindent)) |
| 1521 | |
| 1522 | (defun smie-indent-inside-string () |
| 1523 | (and (nth 3 (syntax-ppss)) |
| 1524 | 'noindent)) |
| 1525 | |
| 1526 | (defun smie-indent-after-keyword () |
| 1527 | ;; Indentation right after a special keyword. |
| 1528 | (save-excursion |
| 1529 | (let* ((pos (point)) |
| 1530 | (toklevel (smie-indent-backward-token)) |
| 1531 | (tok (car toklevel))) |
| 1532 | (cond |
| 1533 | ((null toklevel) nil) |
| 1534 | ((smie-indent--rule :after tok pos nil (point))) |
| 1535 | ;; The default indentation after a keyword/operator is |
| 1536 | ;; 0 for infix, t for prefix, and use another rule |
| 1537 | ;; for postfix. |
| 1538 | ((not (numberp (nth 2 toklevel))) nil) ;A closer. |
| 1539 | ((or (not (numberp (nth 1 toklevel))) ;An opener. |
| 1540 | (rassoc tok smie-closer-alist)) ;An inner. |
| 1541 | (+ (smie-indent-virtual) (smie-indent--offset 'basic))) ; |
| 1542 | (t (smie-indent-virtual)))))) ;An infix. |
| 1543 | |
| 1544 | (defun smie-indent-exps () |
| 1545 | ;; Indentation of sequences of simple expressions without |
| 1546 | ;; intervening keywords or operators. E.g. "a b c" or "g (balbla) f". |
| 1547 | ;; Can be a list of expressions or a function call. |
| 1548 | ;; If it's a function call, the first element is special (it's the |
| 1549 | ;; function). We distinguish function calls from mere lists of |
| 1550 | ;; expressions based on whether the preceding token is listed in |
| 1551 | ;; the `list-intro' entry of smie-indent-rules. |
| 1552 | ;; |
| 1553 | ;; TODO: to indent Lisp code, we should add a way to specify |
| 1554 | ;; particular indentation for particular args depending on the |
| 1555 | ;; function (which would require always skipping back until the |
| 1556 | ;; function). |
| 1557 | ;; TODO: to indent C code, such as "if (...) {...}" we might need |
| 1558 | ;; to add similar indentation hooks for particular positions, but |
| 1559 | ;; based on the preceding token rather than based on the first exp. |
| 1560 | (save-excursion |
| 1561 | (let ((positions nil) |
| 1562 | arg) |
| 1563 | (while (and (null (car (smie-backward-sexp))) |
| 1564 | (push (point) positions) |
| 1565 | (not (smie-indent--bolp)))) |
| 1566 | (save-excursion |
| 1567 | ;; Figure out if the atom we just skipped is an argument rather |
| 1568 | ;; than a function. |
| 1569 | (setq arg |
| 1570 | (or (null (car (smie-backward-sexp))) |
| 1571 | (funcall smie-rules-function :list-intro |
| 1572 | (funcall smie-backward-token-function))))) |
| 1573 | (cond |
| 1574 | ((null positions) |
| 1575 | ;; We're the first expression of the list. In that case, the |
| 1576 | ;; indentation should be (have been) determined by its context. |
| 1577 | nil) |
| 1578 | (arg |
| 1579 | ;; There's a previous element, and it's not special (it's not |
| 1580 | ;; the function), so let's just align with that one. |
| 1581 | (goto-char (car positions)) |
| 1582 | (current-column)) |
| 1583 | ((cdr positions) |
| 1584 | ;; We skipped some args plus the function and bumped into something. |
| 1585 | ;; Align with the first arg. |
| 1586 | (goto-char (cadr positions)) |
| 1587 | (current-column)) |
| 1588 | (positions |
| 1589 | ;; We're the first arg. |
| 1590 | (goto-char (car positions)) |
| 1591 | (+ (smie-indent--offset 'args) |
| 1592 | ;; We used to use (smie-indent-virtual), but that |
| 1593 | ;; doesn't seem right since it might then indent args less than |
| 1594 | ;; the function itself. |
| 1595 | (current-column))))))) |
| 1596 | |
| 1597 | (defvar smie-indent-functions |
| 1598 | '(smie-indent-fixindent smie-indent-bob smie-indent-close |
| 1599 | smie-indent-comment smie-indent-comment-continue smie-indent-comment-close |
| 1600 | smie-indent-comment-inside smie-indent-inside-string |
| 1601 | smie-indent-keyword smie-indent-after-keyword |
| 1602 | smie-indent-exps) |
| 1603 | "Functions to compute the indentation. |
| 1604 | Each function is called with no argument, shouldn't move point, and should |
| 1605 | return either nil if it has no opinion, or an integer representing the column |
| 1606 | to which that point should be aligned, if we were to reindent it.") |
| 1607 | |
| 1608 | (defun smie-indent-calculate () |
| 1609 | "Compute the indentation to use for point." |
| 1610 | (run-hook-with-args-until-success 'smie-indent-functions)) |
| 1611 | |
| 1612 | (defun smie-indent-line () |
| 1613 | "Indent current line using the SMIE indentation engine." |
| 1614 | (interactive) |
| 1615 | (let* ((savep (point)) |
| 1616 | (indent (or (with-demoted-errors |
| 1617 | (save-excursion |
| 1618 | (forward-line 0) |
| 1619 | (skip-chars-forward " \t") |
| 1620 | (if (>= (point) savep) (setq savep nil)) |
| 1621 | (or (smie-indent-calculate) 0))) |
| 1622 | 0))) |
| 1623 | (if (not (numberp indent)) |
| 1624 | ;; If something funny is used (e.g. `noindent'), return it. |
| 1625 | indent |
| 1626 | (if (< indent 0) (setq indent 0)) ;Just in case. |
| 1627 | (if savep |
| 1628 | (save-excursion (indent-line-to indent)) |
| 1629 | (indent-line-to indent))))) |
| 1630 | |
| 1631 | (defun smie-auto-fill () |
| 1632 | (let ((fc (current-fill-column))) |
| 1633 | (while (and fc (> (current-column) fc)) |
| 1634 | (cond |
| 1635 | ((not (or (nth 8 (save-excursion |
| 1636 | (syntax-ppss (line-beginning-position)))) |
| 1637 | (nth 8 (syntax-ppss)))) |
| 1638 | (save-excursion |
| 1639 | (beginning-of-line) |
| 1640 | (smie-indent-forward-token) |
| 1641 | (let ((bsf (point)) |
| 1642 | (gain 0) |
| 1643 | curcol) |
| 1644 | (while (<= (setq curcol (current-column)) fc) |
| 1645 | ;; FIXME? `smie-indent-calculate' can (and often will) |
| 1646 | ;; return a result that actually depends on the presence/absence |
| 1647 | ;; of a newline, so the gain computed here may not be accurate, |
| 1648 | ;; but in practice it seems to works well enough. |
| 1649 | (let* ((newcol (smie-indent-calculate)) |
| 1650 | (newgain (- curcol newcol))) |
| 1651 | (when (> newgain gain) |
| 1652 | (setq gain newgain) |
| 1653 | (setq bsf (point)))) |
| 1654 | (smie-indent-forward-token)) |
| 1655 | (when (> gain 0) |
| 1656 | (goto-char bsf) |
| 1657 | (newline-and-indent))))) |
| 1658 | (t (do-auto-fill)))))) |
| 1659 | |
| 1660 | |
| 1661 | (defun smie-setup (grammar rules-function &rest keywords) |
| 1662 | "Setup SMIE navigation and indentation. |
| 1663 | GRAMMAR is a grammar table generated by `smie-prec2->grammar'. |
| 1664 | RULES-FUNCTION is a set of indentation rules for use on `smie-rules-function'. |
| 1665 | KEYWORDS are additional arguments, which can use the following keywords: |
| 1666 | - :forward-token FUN |
| 1667 | - :backward-token FUN" |
| 1668 | (set (make-local-variable 'smie-rules-function) rules-function) |
| 1669 | (set (make-local-variable 'smie-grammar) grammar) |
| 1670 | (set (make-local-variable 'indent-line-function) 'smie-indent-line) |
| 1671 | (set (make-local-variable 'normal-auto-fill-function) 'smie-auto-fill) |
| 1672 | (set (make-local-variable 'forward-sexp-function) |
| 1673 | 'smie-forward-sexp-command) |
| 1674 | (while keywords |
| 1675 | (let ((k (pop keywords)) |
| 1676 | (v (pop keywords))) |
| 1677 | (pcase k |
| 1678 | (`:forward-token |
| 1679 | (set (make-local-variable 'smie-forward-token-function) v)) |
| 1680 | (`:backward-token |
| 1681 | (set (make-local-variable 'smie-backward-token-function) v)) |
| 1682 | (_ (message "smie-setup: ignoring unknown keyword %s" k))))) |
| 1683 | (let ((ca (cdr (assq :smie-closer-alist grammar)))) |
| 1684 | (when ca |
| 1685 | (set (make-local-variable 'smie-closer-alist) ca) |
| 1686 | ;; Only needed for interactive calls to blink-matching-open. |
| 1687 | (set (make-local-variable 'blink-matching-check-function) |
| 1688 | #'smie-blink-matching-check) |
| 1689 | (add-hook 'post-self-insert-hook |
| 1690 | #'smie-blink-matching-open 'append 'local) |
| 1691 | (set (make-local-variable 'smie-blink-matching-triggers) |
| 1692 | (append smie-blink-matching-triggers |
| 1693 | ;; Rather than wait for SPC to blink, try to blink as |
| 1694 | ;; soon as we type the last char of a block ender. |
| 1695 | (let ((closers (sort (mapcar #'cdr smie-closer-alist) |
| 1696 | #'string-lessp)) |
| 1697 | (triggers ()) |
| 1698 | closer) |
| 1699 | (while (setq closer (pop closers)) |
| 1700 | (unless (and closers |
| 1701 | ;; FIXME: this eliminates prefixes of other |
| 1702 | ;; closers, but we should probably |
| 1703 | ;; eliminate prefixes of other keywords |
| 1704 | ;; as well. |
| 1705 | (string-prefix-p closer (car closers))) |
| 1706 | (push (aref closer (1- (length closer))) triggers))) |
| 1707 | (delete-dups triggers))))))) |
| 1708 | |
| 1709 | |
| 1710 | (provide 'smie) |
| 1711 | ;;; smie.el ends here |