| 1 | ;;; dirtrack.el --- Directory Tracking by watching the prompt |
| 2 | |
| 3 | ;; Copyright (C) 1996 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Peter Breton <pbreton@cs.umb.edu> |
| 6 | ;; Created: Sun Nov 17 1996 |
| 7 | ;; Keywords: processes |
| 8 | |
| 9 | ;; This file is part of GNU Emacs. |
| 10 | |
| 11 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 12 | ;; it under the terms of the GNU General Public License as published by |
| 13 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 14 | ;; any later version. |
| 15 | |
| 16 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | ;; GNU General Public License for more details. |
| 20 | |
| 21 | ;; You should have received a copy of the GNU General Public License |
| 22 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 23 | ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, |
| 24 | ;; Boston, MA 02110-1301, USA. |
| 25 | |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; Shell directory tracking by watching the prompt. |
| 29 | ;; |
| 30 | ;; This is yet another attempt at a directory-tracking package for |
| 31 | ;; Emacs shell-mode. However, this package makes one strong assumption: |
| 32 | ;; that you can customize your shell's prompt to contain the |
| 33 | ;; current working directory. Most shells do support this, including |
| 34 | ;; almost every type of Bourne and C shell on Unix, the native shells on |
| 35 | ;; Windows95 (COMMAND.COM) and Windows NT (CMD.EXE), and most 3rd party |
| 36 | ;; Windows shells. If you cannot do this, or do not wish to, this package |
| 37 | ;; will be useless to you. |
| 38 | ;; |
| 39 | ;; Installation: |
| 40 | ;; |
| 41 | ;; 1) Set your shell's prompt to contain the current working directory. |
| 42 | ;; You may need to consult your shell's documentation to find out how to |
| 43 | ;; do this. |
| 44 | ;; |
| 45 | ;; Note that directory tracking is done by matching regular expressions, |
| 46 | ;; therefore it is *VERY IMPORTANT* for your prompt to be easily |
| 47 | ;; distinguishable from other output. If your prompt regexp is too general, |
| 48 | ;; you will see error messages from the dirtrack filter as it attempts to cd |
| 49 | ;; to non-existent directories. |
| 50 | ;; |
| 51 | ;; 2) Set the variable `dirtrack-list' to an appropriate value. This |
| 52 | ;; should be a list of two elements: the first is a regular expression |
| 53 | ;; which matches your prompt up to and including the pathname part. |
| 54 | ;; The second is a number which tells which regular expression group to |
| 55 | ;; match to extract only the pathname. If you use a multi-line prompt, |
| 56 | ;; add 't' as a third element. Note that some of the functions in |
| 57 | ;; 'comint.el' assume a single-line prompt (eg, comint-bol). |
| 58 | ;; |
| 59 | ;; Determining this information may take some experimentation. Setting |
| 60 | ;; the variable `dirtrack-debug' may help; it causes the directory-tracking |
| 61 | ;; filter to log messages to the buffer `dirtrack-debug-buffer'. You can easily |
| 62 | ;; toggle this setting with the `dirtrack-debug-toggle' function. |
| 63 | ;; |
| 64 | ;; 3) Add a hook to shell-mode to enable the directory tracking: |
| 65 | ;; |
| 66 | ;; (add-hook 'shell-mode-hook |
| 67 | ;; (function (lambda () |
| 68 | ;; (setq comint-preoutput-filter-functions |
| 69 | ;; (append (list 'dirtrack) |
| 70 | ;; comint-preoutput-filter-functions))))) |
| 71 | ;; |
| 72 | ;; You may wish to turn ordinary shell tracking off by calling |
| 73 | ;; `shell-dirtrack-toggle' or setting `shell-dirtrackp'. |
| 74 | ;; |
| 75 | ;; Examples: |
| 76 | ;; |
| 77 | ;; 1) On Windows NT, my prompt is set to emacs$S$P$G. |
| 78 | ;; 'dirtrack-list' is set to (list "^emacs \\([a-zA-Z]:.*\\)>" 1) |
| 79 | ;; |
| 80 | ;; 2) On Solaris running bash, my prompt is set like this: |
| 81 | ;; PS1="\w\012emacs@\h(\!) [\t]% " |
| 82 | ;; 'dirtrack-list' is set to (list "^\\([/~].*\\)\nemacs@[^%]+% *" 1 t) |
| 83 | ;; |
| 84 | ;; I'd appreciate other examples from people who use this package. |
| 85 | ;; |
| 86 | ;; Here's one from Stephen Eglen: |
| 87 | ;; |
| 88 | ;; Running under tcsh: |
| 89 | ;; (setq-default dirtrack-list '("^%E \\([^ ]+\\)" 1)) |
| 90 | ;; |
| 91 | ;; It might be worth mentioning in your file that emacs sources start up |
| 92 | ;; files of the form: ~/.emacs_<SHELL> where <SHELL> is the name of the |
| 93 | ;; shell. So for example, I have the following in ~/.emacs_tcsh: |
| 94 | ;; |
| 95 | ;; set prompt = "%%E %~ %h% " |
| 96 | ;; |
| 97 | ;; This produces a prompt of the form: |
| 98 | ;; %E /var/spool 10% |
| 99 | ;; |
| 100 | ;; This saves me from having to use the %E prefix in other non-emacs |
| 101 | ;; shells. |
| 102 | ;; |
| 103 | ;; A final note: |
| 104 | ;; |
| 105 | ;; I run LOTS of shell buffers through Emacs, sometimes as different users |
| 106 | ;; (eg, when logged in as myself, I'll run a root shell in the same Emacs). |
| 107 | ;; If you do this, and the shell prompt contains a ~, Emacs will interpret |
| 108 | ;; this relative to the user which owns the Emacs process, not the user |
| 109 | ;; who owns the shell buffer. This may cause dirtrack to behave strangely |
| 110 | ;; (typically it reports that it is unable to cd to a directory |
| 111 | ;; with a ~ in it). |
| 112 | ;; |
| 113 | ;; The same behavior can occur if you use dirtrack with remote filesystems |
| 114 | ;; (using telnet, rlogin, etc) as Emacs will be checking the local |
| 115 | ;; filesystem, not the remote one. This problem is not specific to dirtrack, |
| 116 | ;; but also affects file completion, etc. |
| 117 | |
| 118 | ;;; Code: |
| 119 | |
| 120 | (eval-when-compile |
| 121 | (require 'comint) |
| 122 | (require 'shell)) |
| 123 | |
| 124 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 125 | ;; Customization Variables |
| 126 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 127 | |
| 128 | (defgroup dirtrack nil |
| 129 | "Directory tracking by watching the prompt." |
| 130 | :prefix "dirtrack-" |
| 131 | :group 'shell) |
| 132 | |
| 133 | (defcustom dirtrack-list (list "^emacs \\([a-zA-Z]:.*\\)>" 1) |
| 134 | "*List for directory tracking. |
| 135 | First item is a regexp that describes where to find the path in a prompt. |
| 136 | Second is a number, the regexp group to match. Optional third item is |
| 137 | whether the prompt is multi-line. If nil or omitted, prompt is assumed to |
| 138 | be on a single line." |
| 139 | :group 'dirtrack |
| 140 | :type '(sexp (regexp :tag "Prompt Expression") |
| 141 | (integer :tag "Regexp Group") |
| 142 | (boolean :tag "Multiline Prompt") |
| 143 | ) |
| 144 | ) |
| 145 | |
| 146 | (make-variable-buffer-local 'dirtrack-list) |
| 147 | |
| 148 | (defcustom dirtrack-debug nil |
| 149 | "*If non-nil, the function `dirtrack' will report debugging info." |
| 150 | :group 'dirtrack |
| 151 | :type 'boolean |
| 152 | ) |
| 153 | |
| 154 | (defcustom dirtrack-debug-buffer "*Directory Tracking Log*" |
| 155 | "Buffer to write directory tracking debug information." |
| 156 | :group 'dirtrack |
| 157 | :type 'string |
| 158 | ) |
| 159 | |
| 160 | (defcustom dirtrackp t |
| 161 | "*If non-nil, directory tracking via `dirtrack' is enabled." |
| 162 | :group 'dirtrack |
| 163 | :type 'boolean |
| 164 | ) |
| 165 | |
| 166 | (make-variable-buffer-local 'dirtrackp) |
| 167 | |
| 168 | (defcustom dirtrack-directory-function |
| 169 | (if (memq system-type (list 'ms-dos 'windows-nt 'cygwin)) |
| 170 | 'dirtrack-windows-directory-function |
| 171 | 'dirtrack-default-directory-function) |
| 172 | "*Function to apply to the prompt directory for comparison purposes." |
| 173 | :group 'dirtrack |
| 174 | :type 'function |
| 175 | ) |
| 176 | |
| 177 | (defcustom dirtrack-canonicalize-function |
| 178 | (if (memq system-type (list 'ms-dos 'windows-nt 'cygwin)) |
| 179 | 'downcase 'identity) |
| 180 | "*Function to apply to the default directory for comparison purposes." |
| 181 | :group 'dirtrack |
| 182 | :type 'function |
| 183 | ) |
| 184 | |
| 185 | (defcustom dirtrack-directory-change-hook nil |
| 186 | "Hook that is called when a directory change is made." |
| 187 | :group 'dirtrack |
| 188 | :type 'hook |
| 189 | ) |
| 190 | |
| 191 | |
| 192 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 193 | ;; Functions |
| 194 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 195 | |
| 196 | (defun dirtrack-default-directory-function (dir) |
| 197 | "Return a canonical directory for comparison purposes. |
| 198 | Such a directory ends with a forward slash." |
| 199 | (let ((directory dir)) |
| 200 | (if (not (char-equal ?/ (string-to-char (substring directory -1)))) |
| 201 | (concat directory "/") |
| 202 | directory))) |
| 203 | |
| 204 | (defun dirtrack-windows-directory-function (dir) |
| 205 | "Return a canonical directory for comparison purposes. |
| 206 | Such a directory is all lowercase, has forward-slashes as delimiters, |
| 207 | and ends with a forward slash." |
| 208 | (let ((directory dir)) |
| 209 | (setq directory (downcase (dirtrack-replace-slash directory t))) |
| 210 | (if (not (char-equal ?/ (string-to-char (substring directory -1)))) |
| 211 | (concat directory "/") |
| 212 | directory))) |
| 213 | |
| 214 | (defun dirtrack-cygwin-directory-function (dir) |
| 215 | "Return a canonical directory taken from a Cygwin path for comparison purposes." |
| 216 | (if (string-match "/cygdrive/\\([A-Z]\\)\\(.*\\)" dir) |
| 217 | (concat (match-string 1 dir) ":" (match-string 2 dir)) |
| 218 | dir)) |
| 219 | |
| 220 | (defconst dirtrack-forward-slash (regexp-quote "/")) |
| 221 | (defconst dirtrack-backward-slash (regexp-quote "\\")) |
| 222 | |
| 223 | (defun dirtrack-replace-slash (string &optional opposite) |
| 224 | "Replace forward slashes with backwards ones. |
| 225 | If additional argument is non-nil, replace backwards slashes with |
| 226 | forward ones." |
| 227 | (let ((orig (if opposite |
| 228 | dirtrack-backward-slash |
| 229 | dirtrack-forward-slash)) |
| 230 | (replace (if opposite |
| 231 | dirtrack-forward-slash |
| 232 | dirtrack-backward-slash)) |
| 233 | (newstring string) |
| 234 | ) |
| 235 | (while (string-match orig newstring) |
| 236 | (setq newstring (replace-match replace nil t newstring))) |
| 237 | newstring)) |
| 238 | |
| 239 | ;; Copied from shell.el |
| 240 | (defun dirtrack-toggle () |
| 241 | "Enable or disable Dirtrack directory tracking in a shell buffer." |
| 242 | (interactive) |
| 243 | (setq dirtrackp (not dirtrackp)) |
| 244 | (message "Directory tracking %s" (if dirtrackp "ON" "OFF"))) |
| 245 | |
| 246 | (defun dirtrack-debug-toggle () |
| 247 | "Enable or disable Dirtrack debugging." |
| 248 | (interactive) |
| 249 | (setq dirtrack-debug (not dirtrack-debug)) |
| 250 | (message "Directory debugging %s" (if dirtrack-debug "ON" "OFF")) |
| 251 | (and dirtrack-debug |
| 252 | (display-buffer (get-buffer-create dirtrack-debug-buffer)))) |
| 253 | |
| 254 | (defun dirtrack-debug-message (string) |
| 255 | (let ((buf (current-buffer)) |
| 256 | (debug-buf (get-buffer-create dirtrack-debug-buffer)) |
| 257 | ) |
| 258 | (set-buffer debug-buf) |
| 259 | (goto-char (point-max)) |
| 260 | (insert (concat string "\n")) |
| 261 | (set-buffer buf) |
| 262 | )) |
| 263 | |
| 264 | ;;;###autoload |
| 265 | (defun dirtrack (input) |
| 266 | "Determine the current directory by scanning the process output for a prompt. |
| 267 | The prompt to look for is the first item in `dirtrack-list'. |
| 268 | |
| 269 | You can toggle directory tracking by using the function `dirtrack-toggle'. |
| 270 | |
| 271 | If directory tracking does not seem to be working, you can use the |
| 272 | function `dirtrack-debug-toggle' to turn on debugging output. |
| 273 | |
| 274 | You can enable directory tracking by adding this function to |
| 275 | `comint-output-filter-functions'. |
| 276 | " |
| 277 | (if (null dirtrackp) |
| 278 | nil |
| 279 | (let (prompt-path |
| 280 | matched |
| 281 | (current-dir default-directory) |
| 282 | (dirtrack-regexp (nth 0 dirtrack-list)) |
| 283 | (match-num (nth 1 dirtrack-list)) |
| 284 | (multi-line (nth 2 dirtrack-list)) |
| 285 | ) |
| 286 | ;; No output? |
| 287 | (if (eq (point) (point-min)) |
| 288 | nil |
| 289 | (save-excursion |
| 290 | (setq matched (string-match dirtrack-regexp input))) |
| 291 | ;; No match |
| 292 | (if (null matched) |
| 293 | (and dirtrack-debug |
| 294 | (dirtrack-debug-message |
| 295 | (format |
| 296 | "Input `%s' failed to match regexp: %s" |
| 297 | input dirtrack-regexp))) |
| 298 | (setq prompt-path |
| 299 | (substring input |
| 300 | (match-beginning match-num) (match-end match-num))) |
| 301 | ;; Empty string |
| 302 | (if (not (> (length prompt-path) 0)) |
| 303 | (and dirtrack-debug |
| 304 | (dirtrack-debug-message "Match is empty string")) |
| 305 | ;; Transform prompts into canonical forms |
| 306 | (setq prompt-path (funcall dirtrack-directory-function |
| 307 | prompt-path)) |
| 308 | (setq current-dir (funcall dirtrack-canonicalize-function |
| 309 | current-dir)) |
| 310 | (and dirtrack-debug |
| 311 | (dirtrack-debug-message |
| 312 | (format |
| 313 | "Prompt is %s\nCurrent directory is %s" |
| 314 | prompt-path current-dir))) |
| 315 | ;; Compare them |
| 316 | (if (or (string= current-dir prompt-path) |
| 317 | (string= current-dir |
| 318 | (abbreviate-file-name prompt-path))) |
| 319 | (and dirtrack-debug |
| 320 | (dirtrack-debug-message |
| 321 | (format "Not changing directory"))) |
| 322 | ;; It's possible that Emacs will think the directory |
| 323 | ;; won't exist (eg, rlogin buffers) |
| 324 | (if (file-accessible-directory-p prompt-path) |
| 325 | ;; Change directory |
| 326 | (and (shell-process-cd prompt-path) |
| 327 | (run-hooks 'dirtrack-directory-change-hook) |
| 328 | dirtrack-debug |
| 329 | (dirtrack-debug-message |
| 330 | (format "Changing directory to %s" prompt-path))) |
| 331 | (error "Directory %s does not exist" prompt-path))) |
| 332 | ))))) |
| 333 | input) |
| 334 | |
| 335 | (provide 'dirtrack) |
| 336 | |
| 337 | ;;; arch-tag: 168de071-be88-4937-aff6-2aba9f328d5a |
| 338 | ;;; dirtrack.el ends here |