| 1 | ;;; cc-compat.el --- cc-mode compatibility with c-mode.el confusion |
| 2 | |
| 3 | ;; Copyright (C) 1985, 1987, 1992-2014 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Authors: 1998- Martin Stjernholm |
| 6 | ;; 1994-1999 Barry A. Warsaw |
| 7 | ;; Maintainer: bug-cc-mode@gnu.org |
| 8 | ;; Created: August 1994, split from cc-mode.el |
| 9 | ;; Keywords: c languages |
| 10 | ;; Package: cc-mode |
| 11 | |
| 12 | ;; This file is part of GNU Emacs. |
| 13 | |
| 14 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 15 | ;; it under the terms of the GNU General Public License as published by |
| 16 | ;; the Free Software Foundation, either version 3 of the License, or |
| 17 | ;; (at your option) any later version. |
| 18 | |
| 19 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 20 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ;; GNU General Public License for more details. |
| 23 | |
| 24 | ;; You should have received a copy of the GNU General Public License |
| 25 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 26 | |
| 27 | ;;; Commentary: |
| 28 | ;; |
| 29 | ;; Boring old c-mode.el (BOCM) is confusion and brain melt. cc-mode.el |
| 30 | ;; is clarity of thought and purity of chi. If you are still unwilling |
| 31 | ;; to accept enlightenment, this might help, or it may prolong your |
| 32 | ;; agony. |
| 33 | ;; |
| 34 | ;; To use, add the following to your c-mode-hook: |
| 35 | ;; |
| 36 | ;; (require 'cc-compat) |
| 37 | ;; (c-set-style "BOCM") |
| 38 | ;; |
| 39 | ;; This file is completely unsupported! Although it has been patched |
| 40 | ;; superficially to keep pace with the rest of CC Mode, it hasn't been |
| 41 | ;; tested for a long time. |
| 42 | |
| 43 | ;;; Code: |
| 44 | |
| 45 | (eval-when-compile |
| 46 | (let ((load-path |
| 47 | (if (and (boundp 'byte-compile-dest-file) |
| 48 | (stringp byte-compile-dest-file)) |
| 49 | (cons (file-name-directory byte-compile-dest-file) load-path) |
| 50 | load-path))) |
| 51 | (load "cc-bytecomp" nil t))) |
| 52 | |
| 53 | (cc-require 'cc-defs) |
| 54 | (cc-require 'cc-vars) |
| 55 | (cc-require 'cc-styles) |
| 56 | (cc-require 'cc-engine) |
| 57 | |
| 58 | \f |
| 59 | ;; In case c-mode.el isn't loaded |
| 60 | (defvar c-indent-level 2 |
| 61 | "*Indentation of C statements with respect to containing block.") |
| 62 | ;;;###autoload(put 'c-indent-level 'safe-local-variable 'integerp) |
| 63 | |
| 64 | (defvar c-brace-imaginary-offset 0 |
| 65 | "*Imagined indentation of a C open brace that actually follows a statement.") |
| 66 | (defvar c-brace-offset 0 |
| 67 | "*Extra indentation for braces, compared with other text in same context.") |
| 68 | (defvar c-argdecl-indent 5 |
| 69 | "*Indentation level of declarations of C function arguments.") |
| 70 | (defvar c-label-offset -2 |
| 71 | "*Offset of C label lines and case statements relative to usual indentation.") |
| 72 | (defvar c-continued-statement-offset 2 |
| 73 | "*Extra indent for lines not starting new statements.") |
| 74 | (defvar c-continued-brace-offset 0 |
| 75 | "*Extra indent for substatements that start with open-braces. |
| 76 | This is in addition to c-continued-statement-offset.") |
| 77 | |
| 78 | |
| 79 | \f |
| 80 | ;; these offsets are taken by brute force testing c-mode.el, since |
| 81 | ;; there's no logic to what it does. |
| 82 | (let* ((offsets '(c-offsets-alist . |
| 83 | ((defun-block-intro . cc-block-intro-offset) |
| 84 | (statement-block-intro . cc-block-intro-offset) |
| 85 | (defun-open . 0) |
| 86 | (class-open . 0) |
| 87 | (inline-open . c-brace-offset) |
| 88 | (block-open . c-brace-offset) |
| 89 | (block-close . cc-block-close-offset) |
| 90 | (brace-list-open . c-brace-offset) |
| 91 | (substatement-open . cc-substatement-open-offset) |
| 92 | (substatement . c-continued-statement-offset) |
| 93 | (knr-argdecl-intro . c-argdecl-indent) |
| 94 | (case-label . c-label-offset) |
| 95 | (access-label . c-label-offset) |
| 96 | (label . c-label-offset) |
| 97 | )))) |
| 98 | (c-add-style "BOCM" offsets)) |
| 99 | |
| 100 | |
| 101 | (defun cc-block-intro-offset (langelem) |
| 102 | ;; taken directly from calculate-c-indent confusion |
| 103 | (save-excursion |
| 104 | (c-backward-syntactic-ws) |
| 105 | (if (eq (char-before) ?{) |
| 106 | (forward-char -1) |
| 107 | (goto-char (cdr langelem))) |
| 108 | (let* ((curcol (save-excursion |
| 109 | (goto-char (cdr langelem)) |
| 110 | (current-column))) |
| 111 | (bocm-lossage |
| 112 | ;; If no previous statement, indent it relative to line |
| 113 | ;; brace is on. For open brace in column zero, don't let |
| 114 | ;; statement start there too. If c-indent-level is zero, |
| 115 | ;; use c-brace-offset + c-continued-statement-offset |
| 116 | ;; instead. For open-braces not the first thing in a line, |
| 117 | ;; add in c-brace-imaginary-offset. |
| 118 | (+ (if (and (bolp) (zerop c-indent-level)) |
| 119 | (+ c-brace-offset c-continued-statement-offset) |
| 120 | c-indent-level) |
| 121 | ;; Move back over whitespace before the openbrace. If |
| 122 | ;; openbrace is not first nonwhite thing on the line, |
| 123 | ;; add the c-brace-imaginary-offset. |
| 124 | (progn (skip-chars-backward " \t") |
| 125 | (if (bolp) 0 c-brace-imaginary-offset)) |
| 126 | ;; If the openbrace is preceded by a parenthesized exp, |
| 127 | ;; move to the beginning of that; possibly a different |
| 128 | ;; line |
| 129 | (progn |
| 130 | (if (eq (char-before) ?\)) |
| 131 | (c-forward-sexp -1)) |
| 132 | ;; Get initial indentation of the line we are on. |
| 133 | (current-indentation))))) |
| 134 | (- bocm-lossage curcol)))) |
| 135 | |
| 136 | |
| 137 | (defun cc-block-close-offset (langelem) |
| 138 | (save-excursion |
| 139 | (let* ((here (point)) |
| 140 | bracep |
| 141 | (curcol (progn |
| 142 | (goto-char (cdr langelem)) |
| 143 | (current-column))) |
| 144 | (bocm-lossage (progn |
| 145 | (goto-char (cdr langelem)) |
| 146 | (if (eq (char-after) ?{) |
| 147 | (setq bracep t) |
| 148 | (goto-char here) |
| 149 | (beginning-of-line) |
| 150 | (backward-up-list 1) |
| 151 | (forward-char 1) |
| 152 | (c-forward-syntactic-ws)) |
| 153 | (current-column)))) |
| 154 | (- bocm-lossage curcol |
| 155 | (if bracep 0 c-indent-level))))) |
| 156 | |
| 157 | |
| 158 | (defun cc-substatement-open-offset (langelem) |
| 159 | (+ c-continued-statement-offset c-continued-brace-offset)) |
| 160 | |
| 161 | \f |
| 162 | (cc-provide 'cc-compat) |
| 163 | |
| 164 | ;;; cc-compat.el ends here |