| 1 | ;;; ibuf-macs.el --- macros for ibuffer |
| 2 | |
| 3 | ;; Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Colin Walters <walters@verbum.org> |
| 6 | ;; Maintainer: John Paul Wallington <jpw@shootybangbang.com> |
| 7 | ;; Created: 6 Dec 2001 |
| 8 | ;; Keywords: buffer, convenience |
| 9 | |
| 10 | ;; This file is part of GNU Emacs. |
| 11 | |
| 12 | ;; This program is free software; you can redistribute it and/or |
| 13 | ;; modify it under the terms of the GNU General Public License as |
| 14 | ;; published by the Free Software Foundation; either version 2, or (at |
| 15 | ;; your option) any later version. |
| 16 | |
| 17 | ;; This program is distributed in the hope that it will be useful, but |
| 18 | ;; WITHOUT ANY WARRANTY; without even the implied warranty of |
| 19 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
| 20 | ;; General Public License for more details. |
| 21 | |
| 22 | ;; You should have received a copy of the GNU General Public License |
| 23 | ;; along with this program ; see the file COPYING. If not, write to |
| 24 | ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 25 | ;; Boston, MA 02111-1307, USA. |
| 26 | |
| 27 | ;;; Commentary: |
| 28 | |
| 29 | ;;; Code: |
| 30 | |
| 31 | (eval-when-compile |
| 32 | (require 'cl)) |
| 33 | |
| 34 | ;; From Paul Graham's "ANSI Common Lisp", adapted for Emacs Lisp here. |
| 35 | (defmacro ibuffer-aif (test true-body &rest false-body) |
| 36 | "Evaluate TRUE-BODY or FALSE-BODY depending on value of TEST. |
| 37 | If TEST returns non-nil, bind `it' to the value, and evaluate |
| 38 | TRUE-BODY. Otherwise, evaluate forms in FALSE-BODY as if in `progn'. |
| 39 | Compare with `if'." |
| 40 | (let ((sym (gensym "--ibuffer-aif-"))) |
| 41 | `(let ((,sym ,test)) |
| 42 | (if ,sym |
| 43 | (let ((it ,sym)) |
| 44 | ,true-body) |
| 45 | (progn |
| 46 | ,@false-body))))) |
| 47 | ;; (put 'ibuffer-aif 'lisp-indent-function 2) |
| 48 | |
| 49 | (defmacro ibuffer-awhen (test &rest body) |
| 50 | "Evaluate BODY if TEST returns non-nil. |
| 51 | During evaluation of body, bind `it' to the value returned by TEST." |
| 52 | `(ibuffer-aif ,test |
| 53 | (progn ,@body) |
| 54 | nil)) |
| 55 | ;; (put 'ibuffer-awhen 'lisp-indent-function 1) |
| 56 | |
| 57 | (defmacro ibuffer-save-marks (&rest body) |
| 58 | "Save the marked status of the buffers and execute BODY; restore marks." |
| 59 | (let ((bufsym (gensym))) |
| 60 | `(let ((,bufsym (current-buffer)) |
| 61 | (ibuffer-save-marks-tmp-mark-list (ibuffer-current-state-list))) |
| 62 | (unwind-protect |
| 63 | (progn |
| 64 | (save-excursion |
| 65 | ,@body)) |
| 66 | (with-current-buffer ,bufsym |
| 67 | (ibuffer-redisplay-engine |
| 68 | ;; Get rid of dead buffers |
| 69 | (delq nil |
| 70 | (mapcar #'(lambda (e) (when (buffer-live-p (car e)) |
| 71 | e)) |
| 72 | ibuffer-save-marks-tmp-mark-list))) |
| 73 | (ibuffer-redisplay t)))))) |
| 74 | ;; (put 'ibuffer-save-marks 'lisp-indent-function 0) |
| 75 | |
| 76 | ;;;###autoload |
| 77 | (defmacro* define-ibuffer-column (symbol (&key name inline props |
| 78 | summarizer) &rest body) |
| 79 | "Define a column SYMBOL for use with `ibuffer-formats'. |
| 80 | |
| 81 | BODY will be called with `buffer' bound to the buffer object, and |
| 82 | `mark' bound to the current mark on the buffer. The original ibuffer |
| 83 | buffer will be bound to `ibuffer-buf'. |
| 84 | |
| 85 | If NAME is given, it will be used as a title for the column. |
| 86 | Otherwise, the title will default to a capitalized version of the |
| 87 | SYMBOL's name. PROPS is a plist of additional properties to add to |
| 88 | the text, such as `mouse-face'. And SUMMARIZER, if given, is a |
| 89 | function which will be passed a list of all the strings in its column; |
| 90 | it should return a string to display at the bottom. |
| 91 | |
| 92 | Note that this macro expands into a `defun' for a function named |
| 93 | ibuffer-make-column-NAME. If INLINE is non-nil, then the form will be |
| 94 | inlined into the compiled format versions. This means that if you |
| 95 | change its definition, you should explicitly call |
| 96 | `ibuffer-recompile-formats'." |
| 97 | (let* ((sym (intern (concat "ibuffer-make-column-" |
| 98 | (symbol-name symbol)))) |
| 99 | (bod-1 `(with-current-buffer buffer |
| 100 | ,@body)) |
| 101 | (bod (if props |
| 102 | `(propertize |
| 103 | ,bod-1 |
| 104 | ,@props) |
| 105 | bod-1))) |
| 106 | `(progn |
| 107 | ,(if inline |
| 108 | `(push '(,sym ,bod) ibuffer-inline-columns) |
| 109 | `(defun ,sym (buffer mark) |
| 110 | ,bod)) |
| 111 | (put (quote ,sym) 'ibuffer-column-name |
| 112 | ,(if (stringp name) |
| 113 | name |
| 114 | (capitalize (symbol-name symbol)))) |
| 115 | ,(if summarizer |
| 116 | ;; Store the name of the summarizing function. |
| 117 | `(put (quote ,sym) 'ibuffer-column-summarizer |
| 118 | (quote ,summarizer))) |
| 119 | ,(if summarizer |
| 120 | ;; This will store the actual values of the column |
| 121 | ;; summary. |
| 122 | `(put (quote ,sym) 'ibuffer-column-summary nil)) |
| 123 | :autoload-end))) |
| 124 | ;; (put 'define-ibuffer-column 'lisp-indent-function 'defun) |
| 125 | |
| 126 | ;;;###autoload |
| 127 | (defmacro* define-ibuffer-sorter (name documentation |
| 128 | (&key |
| 129 | description) |
| 130 | &rest body) |
| 131 | "Define a method of sorting named NAME. |
| 132 | DOCUMENTATION is the documentation of the function, which will be called |
| 133 | `ibuffer-do-sort-by-NAME'. |
| 134 | DESCRIPTION is a short string describing the sorting method. |
| 135 | |
| 136 | For sorting, the forms in BODY will be evaluated with `a' bound to one |
| 137 | buffer object, and `b' bound to another. BODY should return a non-nil |
| 138 | value if and only if `a' is \"less than\" `b'." |
| 139 | `(progn |
| 140 | (defun ,(intern (concat "ibuffer-do-sort-by-" (symbol-name name))) () |
| 141 | ,(or documentation "No :documentation specified for this sorting method.") |
| 142 | (interactive) |
| 143 | (setq ibuffer-sorting-mode ',name) |
| 144 | (ibuffer-redisplay t)) |
| 145 | (push (list ',name ,description |
| 146 | #'(lambda (a b) |
| 147 | ,@body)) |
| 148 | ibuffer-sorting-functions-alist) |
| 149 | :autoload-end)) |
| 150 | ;; (put 'define-ibuffer-sorter 'lisp-indent-function 1) |
| 151 | |
| 152 | ;;;###autoload |
| 153 | (defmacro* define-ibuffer-op (op args |
| 154 | documentation |
| 155 | (&key |
| 156 | interactive |
| 157 | mark |
| 158 | modifier-p |
| 159 | dangerous |
| 160 | (opstring "operated on") |
| 161 | (active-opstring "Operate on") |
| 162 | complex) |
| 163 | &rest body) |
| 164 | "Generate a function which operates on a buffer. |
| 165 | OP becomes the name of the function; if it doesn't begin with |
| 166 | `ibuffer-do-', then that is prepended to it. |
| 167 | When an operation is performed, this function will be called once for |
| 168 | each marked buffer, with that buffer current. |
| 169 | |
| 170 | ARGS becomes the formal parameters of the function. |
| 171 | DOCUMENTATION becomes the docstring of the function. |
| 172 | INTERACTIVE becomes the interactive specification of the function. |
| 173 | MARK describes which type of mark (:deletion, or nil) this operation |
| 174 | uses. :deletion means the function operates on buffers marked for |
| 175 | deletion, otherwise it acts on normally marked buffers. |
| 176 | MODIFIER-P describes how the function modifies buffers. This is used |
| 177 | to set the modification flag of the Ibuffer buffer itself. Valid |
| 178 | values are: |
| 179 | nil - the function never modifiers buffers |
| 180 | t - the function it always modifies buffers |
| 181 | :maybe - attempt to discover this information by comparing the |
| 182 | buffer's modification flag. |
| 183 | DANGEROUS is a boolean which should be set if the user should be |
| 184 | prompted before performing this operation. |
| 185 | OPSTRING is a string which will be displayed to the user after the |
| 186 | operation is complete, in the form: |
| 187 | \"Operation complete; OPSTRING x buffers\" |
| 188 | ACTIVE-OPSTRING is a string which will be displayed to the user in a |
| 189 | confirmation message, in the form: |
| 190 | \"Really ACTIVE-OPSTRING x buffers?\" |
| 191 | COMPLEX means this function is special; see the source code of this |
| 192 | macro for exactly what it does." |
| 193 | `(progn |
| 194 | (defun ,(intern (concat (if (string-match "^ibuffer-do" (symbol-name op)) |
| 195 | "" "ibuffer-do-") (symbol-name op))) |
| 196 | ,args |
| 197 | ,(if (stringp documentation) |
| 198 | documentation |
| 199 | (format "%s marked buffers." active-opstring)) |
| 200 | ,(if (not (null interactive)) |
| 201 | `(interactive ,interactive) |
| 202 | '(interactive)) |
| 203 | (assert (eq major-mode 'ibuffer-mode)) |
| 204 | (setq ibuffer-did-modification nil) |
| 205 | (let ((marked-names (,(case mark |
| 206 | (:deletion |
| 207 | 'ibuffer-deletion-marked-buffer-names) |
| 208 | (t |
| 209 | 'ibuffer-marked-buffer-names))))) |
| 210 | (when (null marked-names) |
| 211 | (setq marked-names (list (buffer-name (ibuffer-current-buffer)))) |
| 212 | (ibuffer-set-mark ,(case mark |
| 213 | (:deletion |
| 214 | 'ibuffer-deletion-char) |
| 215 | (t |
| 216 | 'ibuffer-marked-char)))) |
| 217 | ,(let* ((finish (append |
| 218 | '(progn) |
| 219 | (if (eq modifier-p t) |
| 220 | '((setq ibuffer-did-modification t)) |
| 221 | ()) |
| 222 | `((ibuffer-redisplay t) |
| 223 | (message ,(concat "Operation finished; " opstring " %s buffers") count)))) |
| 224 | (inner-body (if complex |
| 225 | `(progn ,@body) |
| 226 | `(progn |
| 227 | (with-current-buffer buf |
| 228 | (save-excursion |
| 229 | ,@body)) |
| 230 | t))) |
| 231 | (body `(let ((count |
| 232 | (,(case mark |
| 233 | (:deletion |
| 234 | 'ibuffer-map-deletion-lines) |
| 235 | (t |
| 236 | 'ibuffer-map-marked-lines)) |
| 237 | #'(lambda (buf mark) |
| 238 | ,(if (eq modifier-p :maybe) |
| 239 | `(let ((ibuffer-tmp-previous-buffer-modification |
| 240 | (buffer-modified-p buf))) |
| 241 | (prog1 ,inner-body |
| 242 | (when (not (eq ibuffer-tmp-previous-buffer-modification |
| 243 | (buffer-modified-p buf))) |
| 244 | (setq ibuffer-did-modification t)))) |
| 245 | inner-body))))) |
| 246 | ,finish))) |
| 247 | (if dangerous |
| 248 | `(when (ibuffer-confirm-operation-on ,active-opstring marked-names) |
| 249 | ,body) |
| 250 | body)))) |
| 251 | :autoload-end)) |
| 252 | ;; (put 'define-ibuffer-op 'lisp-indent-function 2) |
| 253 | |
| 254 | ;;;###autoload |
| 255 | (defmacro* define-ibuffer-filter (name documentation |
| 256 | (&key |
| 257 | reader |
| 258 | description) |
| 259 | &rest body) |
| 260 | "Define a filter named NAME. |
| 261 | DOCUMENTATION is the documentation of the function. |
| 262 | READER is a form which should read a qualifier from the user. |
| 263 | DESCRIPTION is a short string describing the filter. |
| 264 | |
| 265 | BODY should contain forms which will be evaluated to test whether or |
| 266 | not a particular buffer should be displayed or not. The forms in BODY |
| 267 | will be evaluated with BUF bound to the buffer object, and QUALIFIER |
| 268 | bound to the current value of the filter." |
| 269 | (let ((fn-name (intern (concat "ibuffer-filter-by-" (symbol-name name))))) |
| 270 | `(progn |
| 271 | (defun ,fn-name (qualifier) |
| 272 | ,(concat (or documentation "This filter is not documented.")) |
| 273 | (interactive (list ,reader)) |
| 274 | (ibuffer-push-filter (cons ',name qualifier)) |
| 275 | (message |
| 276 | (format ,(concat (format "Filter by %s added: " description) |
| 277 | " %s") |
| 278 | qualifier)) |
| 279 | (ibuffer-update nil t)) |
| 280 | (push (list ',name ,description |
| 281 | #'(lambda (buf qualifier) |
| 282 | ,@body)) |
| 283 | ibuffer-filtering-alist) |
| 284 | :autoload-end))) |
| 285 | ;; (put 'define-ibuffer-filter 'lisp-indent-function 2) |
| 286 | |
| 287 | (provide 'ibuf-macs) |
| 288 | |
| 289 | ;;; ibuf-macs.el ends here |