| 1 | ;;; double.el --- support for keyboard remapping with double clicking |
| 2 | |
| 3 | ;; Copyright (C) 1994, 1997, 1998, 2001, 2002, 2003, 2004, |
| 4 | ;; 2005, 2006, 2007, 2008 Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Author: Per Abrahamsen <abraham@dina.kvl.dk> |
| 7 | ;; Keywords: i18n |
| 8 | |
| 9 | ;; This file is part of GNU Emacs. |
| 10 | |
| 11 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 12 | ;; it under the terms of the GNU General Public License as published by |
| 13 | ;; the Free Software Foundation; either version 3, or (at your option) |
| 14 | ;; any later version. |
| 15 | |
| 16 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | ;; GNU General Public License for more details. |
| 20 | |
| 21 | ;; You should have received a copy of the GNU General Public License |
| 22 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 23 | ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, |
| 24 | ;; Boston, MA 02110-1301, USA. |
| 25 | |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; This mode is intended for use with languages that adds a small |
| 29 | ;; number of extra letters not available on the keyboard. |
| 30 | ;; |
| 31 | ;; Examples includes Scandinavian and German with an US keyboard. |
| 32 | ;; |
| 33 | ;; The idea is that certain keys are overloaded. When you press it |
| 34 | ;; once it will insert one string, and when you press it twice the |
| 35 | ;; string will be replaced by another. This can be used for mapping |
| 36 | ;; keys on a US keyboard to generate characters according to the local |
| 37 | ;; keyboard convention when pressed once, and according to US keyboard |
| 38 | ;; convention when pressed twice. |
| 39 | ;; |
| 40 | ;; To use this mode, you must define the variable `double-map' and |
| 41 | ;; then enable double mode with `M-x double-mode'. Read the |
| 42 | ;; documentation for both of them. |
| 43 | ;; |
| 44 | ;; The default mapping is for getting Danish/Norwegian keyboard layout |
| 45 | ;; using ISO Latin 1 on a US keyboard. |
| 46 | ;; |
| 47 | ;; Important node: While I would like to hear comments, bug reports, |
| 48 | ;; suggestions, please do @strong{not} expect me to put other mappings |
| 49 | ;; than the default into this file. There are billions and billions |
| 50 | ;; of such mappings, and just supporting the most common would |
| 51 | ;; increase the size of this nice small file manyfold. |
| 52 | |
| 53 | ;;; Code: |
| 54 | |
| 55 | (defgroup double nil |
| 56 | "Remap keyboard, but get original by typing the same key twice." |
| 57 | :group 'i18n) |
| 58 | |
| 59 | (defcustom double-map |
| 60 | '((?\; "\346" ";") |
| 61 | (?\' "\370" "'") |
| 62 | (?\[ "\345" "[") |
| 63 | (?\: "\306" ":") |
| 64 | (?\" "\330" "\"") |
| 65 | (?\{ "\305" "{")) |
| 66 | "Alist of key translations activated by double mode. |
| 67 | |
| 68 | Each entry is a list with three elements: |
| 69 | 1. The key activating the translation. |
| 70 | 2. The string to be inserted when the key is pressed once. |
| 71 | 3. The string to be inserted when the key is pressed twice." |
| 72 | :group 'double |
| 73 | :type '(repeat (list (character :tag "Key") |
| 74 | (string :tag "Once") |
| 75 | (string :tag "Twice")))) |
| 76 | |
| 77 | (defcustom double-prefix-only t |
| 78 | "Non-nil means that Double mode mapping only works for prefix keys. |
| 79 | That is, for any key `X' in `double-map', `X' alone will be mapped |
| 80 | but not `C-u X' or `ESC X' since the X is not the prefix key." |
| 81 | :group 'double |
| 82 | :type 'boolean) |
| 83 | |
| 84 | ;;; Read Event |
| 85 | |
| 86 | (defvar double-last-event nil) |
| 87 | ;; The last key that generated a double key event. |
| 88 | |
| 89 | (defun double-read-event (prompt) |
| 90 | ;; Read an event |
| 91 | (if isearch-mode (isearch-update)) |
| 92 | (if prompt |
| 93 | (prog2 (message "%s%c" prompt double-last-event) |
| 94 | (read-event) |
| 95 | (message "")) |
| 96 | (read-event))) |
| 97 | |
| 98 | (global-set-key [ignore] 'ignore) |
| 99 | |
| 100 | (or (boundp 'isearch-mode-map) |
| 101 | (load-library "isearch")) |
| 102 | |
| 103 | (define-key isearch-mode-map [ignore] |
| 104 | (function (lambda () (interactive) (isearch-update)))) |
| 105 | |
| 106 | (defun double-translate-key (prompt) |
| 107 | ;; Translate input events using double map. |
| 108 | (let ((key last-input-char)) |
| 109 | (cond (unread-command-events |
| 110 | ;; Artificial event, ignore it. |
| 111 | (vector key)) |
| 112 | ((and double-prefix-only |
| 113 | (> (length (this-command-keys)) 1)) |
| 114 | ;; This is not a prefix key, ignore it. |
| 115 | (vector key)) |
| 116 | ((eq key 'magic-start) |
| 117 | ;; End of generated event. See if he will repeat it... |
| 118 | (let ((new (double-read-event prompt)) |
| 119 | (entry (assoc double-last-event double-map))) |
| 120 | (force-window-update (selected-window)) |
| 121 | (if (eq new double-last-event) |
| 122 | (progn |
| 123 | (setq unread-command-events |
| 124 | (append (make-list (1- (length (nth 1 entry))) |
| 125 | 127) |
| 126 | (nth 2 entry) |
| 127 | '(magic-end))) |
| 128 | (vector 127)) |
| 129 | (setq unread-command-events (list new)) |
| 130 | [ignore]))) |
| 131 | ((eq key 'magic-end) |
| 132 | ;; End of double event. Ignore. |
| 133 | [ignore]) |
| 134 | (t |
| 135 | ;; New key. |
| 136 | (let ((exp (nth 1 (assoc key double-map)))) |
| 137 | (setq double-last-event key) |
| 138 | (setq unread-command-events |
| 139 | (append (substring exp 1) '(magic-start))) |
| 140 | (vector (aref exp 0))))))) |
| 141 | |
| 142 | ;;; Mode |
| 143 | |
| 144 | ;; This feature seemed useless and it confused describe-mode, |
| 145 | ;; so I deleted it. |
| 146 | ;; (defvar double-mode-name "Double") |
| 147 | ;; ;; Name of current double mode. |
| 148 | ;; (make-variable-buffer-local 'double-mode-name) |
| 149 | |
| 150 | ;;;###autoload |
| 151 | (define-minor-mode double-mode |
| 152 | "Toggle Double mode. |
| 153 | With prefix argument ARG, turn Double mode on if ARG is positive, otherwise |
| 154 | turn it off. |
| 155 | |
| 156 | When Double mode is on, some keys will insert different strings |
| 157 | when pressed twice. See variable `double-map' for details." |
| 158 | :lighter " Double" |
| 159 | :link '(emacs-commentary-link "double") |
| 160 | (kill-local-variable 'key-translation-map) |
| 161 | (when double-mode |
| 162 | ;; Set up key-translation-map as indicated by `double-map'. |
| 163 | ;; XXX I don't think key-translation-map should be made local here. -- Lorentey |
| 164 | (make-local-variable 'key-translation-map) |
| 165 | (let ((map (make-sparse-keymap))) |
| 166 | (set-keymap-parent map key-translation-map) |
| 167 | (setq key-translation-map map) |
| 168 | (dolist (entry (append double-map '((magic-start) (magic-end)))) |
| 169 | (define-key map |
| 170 | (vector (nth 0 entry)) 'double-translate-key))))) |
| 171 | |
| 172 | (provide 'double) |
| 173 | |
| 174 | ;; arch-tag: 2e170036-44cb-4493-bc32-ada0a4395221 |
| 175 | ;;; double.el ends here |