| 1 | ;;; window.el --- GNU Emacs window commands aside from those written in C |
| 2 | |
| 3 | ;; Copyright (C) 1985, 1989, 1992, 1993, 1994, 2000, 2001, 2002, |
| 4 | ;; 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc. |
| 5 | |
| 6 | ;; Maintainer: FSF |
| 7 | ;; Keywords: internal |
| 8 | |
| 9 | ;; This file is part of GNU Emacs. |
| 10 | |
| 11 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 12 | ;; it under the terms of the GNU General Public License as published by |
| 13 | ;; the Free Software Foundation; either version 3, or (at your option) |
| 14 | ;; any later version. |
| 15 | |
| 16 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | ;; GNU General Public License for more details. |
| 20 | |
| 21 | ;; You should have received a copy of the GNU General Public License |
| 22 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 23 | ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, |
| 24 | ;; Boston, MA 02110-1301, USA. |
| 25 | |
| 26 | ;;; Commentary: |
| 27 | |
| 28 | ;; Window tree functions. |
| 29 | |
| 30 | ;;; Code: |
| 31 | |
| 32 | (defvar window-size-fixed nil |
| 33 | "*Non-nil in a buffer means windows displaying the buffer are fixed-size. |
| 34 | If the value is `height', then only the window's height is fixed. |
| 35 | If the value is `width', then only the window's width is fixed. |
| 36 | Any other non-nil value fixes both the width and the height. |
| 37 | Emacs won't change the size of any window displaying that buffer, |
| 38 | unless you explicitly change the size, or Emacs has no other choice.") |
| 39 | (make-variable-buffer-local 'window-size-fixed) |
| 40 | |
| 41 | (defmacro save-selected-window (&rest body) |
| 42 | "Execute BODY, then select the window that was selected before BODY. |
| 43 | The value returned is the value of the last form in BODY. |
| 44 | |
| 45 | This macro saves and restores the current buffer, since otherwise |
| 46 | its normal operation could potentially make a different |
| 47 | buffer current. It does not alter the buffer list ordering. |
| 48 | |
| 49 | This macro saves and restores the selected window, as well as |
| 50 | the selected window in each frame. If the previously selected |
| 51 | window of some frame is no longer live at the end of BODY, that |
| 52 | frame's selected window is left alone. If the selected window is |
| 53 | no longer live, then whatever window is selected at the end of |
| 54 | BODY remains selected." |
| 55 | `(let ((save-selected-window-window (selected-window)) |
| 56 | ;; It is necessary to save all of these, because calling |
| 57 | ;; select-window changes frame-selected-window for whatever |
| 58 | ;; frame that window is in. |
| 59 | (save-selected-window-alist |
| 60 | (mapcar (lambda (frame) (cons frame (frame-selected-window frame))) |
| 61 | (frame-list)))) |
| 62 | (save-current-buffer |
| 63 | (unwind-protect |
| 64 | (progn ,@body) |
| 65 | (dolist (elt save-selected-window-alist) |
| 66 | (and (frame-live-p (car elt)) |
| 67 | (window-live-p (cdr elt)) |
| 68 | (set-frame-selected-window (car elt) (cdr elt)))) |
| 69 | (if (window-live-p save-selected-window-window) |
| 70 | (select-window save-selected-window-window)))))) |
| 71 | |
| 72 | (defun window-body-height (&optional window) |
| 73 | "Return number of lines in window WINDOW for actual buffer text. |
| 74 | This does not include the mode line (if any) or the header line (if any)." |
| 75 | (or window (setq window (selected-window))) |
| 76 | (if (window-minibuffer-p window) |
| 77 | (window-height window) |
| 78 | (with-current-buffer (window-buffer window) |
| 79 | (max 1 (- (window-height window) |
| 80 | (if mode-line-format 1 0) |
| 81 | (if header-line-format 1 0)))))) |
| 82 | |
| 83 | (defun one-window-p (&optional nomini all-frames) |
| 84 | "Return non-nil if the selected window is the only window. |
| 85 | Optional arg NOMINI non-nil means don't count the minibuffer |
| 86 | even if it is active. Otherwise, the minibuffer is counted |
| 87 | when it is active. |
| 88 | |
| 89 | The optional arg ALL-FRAMES t means count windows on all frames. |
| 90 | If it is `visible', count windows on all visible frames. |
| 91 | ALL-FRAMES nil or omitted means count only the selected frame, |
| 92 | plus the minibuffer it uses (which may be on another frame). |
| 93 | ALL-FRAMES 0 means count all windows in all visible or iconified frames. |
| 94 | If ALL-FRAMES is anything else, count only the selected frame." |
| 95 | (let ((base-window (selected-window))) |
| 96 | (if (and nomini (eq base-window (minibuffer-window))) |
| 97 | (setq base-window (next-window base-window))) |
| 98 | (eq base-window |
| 99 | (next-window base-window (if nomini 'arg) all-frames)))) |
| 100 | |
| 101 | (defun window-current-scroll-bars (&optional window) |
| 102 | "Return the current scroll-bar settings in window WINDOW. |
| 103 | Value is a cons (VERTICAL . HORIZONTAL) where VERTICAL specifies the |
| 104 | current location of the vertical scroll-bars (left, right, or nil), |
| 105 | and HORIZONTAL specifies the current location of the horizontal scroll |
| 106 | bars (top, bottom, or nil)." |
| 107 | (let ((vert (nth 2 (window-scroll-bars window))) |
| 108 | (hor nil)) |
| 109 | (when (or (eq vert t) (eq hor t)) |
| 110 | (let ((fcsb (frame-current-scroll-bars |
| 111 | (window-frame (or window (selected-window)))))) |
| 112 | (if (eq vert t) |
| 113 | (setq vert (car fcsb))) |
| 114 | (if (eq hor t) |
| 115 | (setq hor (cdr fcsb))))) |
| 116 | (cons vert hor))) |
| 117 | |
| 118 | (defun walk-windows (proc &optional minibuf all-frames) |
| 119 | "Cycle through all visible windows, calling PROC for each one. |
| 120 | PROC is called with a window as argument. |
| 121 | |
| 122 | Optional second arg MINIBUF t means count the minibuffer window even |
| 123 | if not active. MINIBUF nil or omitted means count the minibuffer only if |
| 124 | it is active. MINIBUF neither t nor nil means not to count the |
| 125 | minibuffer even if it is active. |
| 126 | |
| 127 | Several frames may share a single minibuffer; if the minibuffer |
| 128 | counts, all windows on all frames that share that minibuffer count |
| 129 | too. Therefore, if you are using a separate minibuffer frame |
| 130 | and the minibuffer is active and MINIBUF says it counts, |
| 131 | `walk-windows' includes the windows in the frame from which you |
| 132 | entered the minibuffer, as well as the minibuffer window. |
| 133 | |
| 134 | ALL-FRAMES is the optional third argument. |
| 135 | ALL-FRAMES nil or omitted means cycle within the frames as specified above. |
| 136 | ALL-FRAMES = `visible' means include windows on all visible frames. |
| 137 | ALL-FRAMES = 0 means include windows on all visible and iconified frames. |
| 138 | ALL-FRAMES = t means include windows on all frames including invisible frames. |
| 139 | If ALL-FRAMES is a frame, it means include windows on that frame. |
| 140 | Anything else means restrict to the selected frame." |
| 141 | ;; If we start from the minibuffer window, don't fail to come back to it. |
| 142 | (if (window-minibuffer-p (selected-window)) |
| 143 | (setq minibuf t)) |
| 144 | (save-selected-window |
| 145 | (if (framep all-frames) |
| 146 | (select-window (frame-first-window all-frames))) |
| 147 | (let* (walk-windows-already-seen |
| 148 | (walk-windows-current (selected-window))) |
| 149 | (while (progn |
| 150 | (setq walk-windows-current |
| 151 | (next-window walk-windows-current minibuf all-frames)) |
| 152 | (not (memq walk-windows-current walk-windows-already-seen))) |
| 153 | (setq walk-windows-already-seen |
| 154 | (cons walk-windows-current walk-windows-already-seen)) |
| 155 | (funcall proc walk-windows-current))))) |
| 156 | |
| 157 | (defun get-window-with-predicate (predicate &optional minibuf |
| 158 | all-frames default) |
| 159 | "Return a window satisfying PREDICATE. |
| 160 | |
| 161 | This function cycles through all visible windows using `walk-windows', |
| 162 | calling PREDICATE on each one. PREDICATE is called with a window as |
| 163 | argument. The first window for which PREDICATE returns a non-nil |
| 164 | value is returned. If no window satisfies PREDICATE, DEFAULT is |
| 165 | returned. |
| 166 | |
| 167 | Optional second arg MINIBUF t means count the minibuffer window even |
| 168 | if not active. MINIBUF nil or omitted means count the minibuffer only if |
| 169 | it is active. MINIBUF neither t nor nil means not to count the |
| 170 | minibuffer even if it is active. |
| 171 | |
| 172 | Several frames may share a single minibuffer; if the minibuffer |
| 173 | counts, all windows on all frames that share that minibuffer count |
| 174 | too. Therefore, if you are using a separate minibuffer frame |
| 175 | and the minibuffer is active and MINIBUF says it counts, |
| 176 | `walk-windows' includes the windows in the frame from which you |
| 177 | entered the minibuffer, as well as the minibuffer window. |
| 178 | |
| 179 | ALL-FRAMES is the optional third argument. |
| 180 | ALL-FRAMES nil or omitted means cycle within the frames as specified above. |
| 181 | ALL-FRAMES = `visible' means include windows on all visible frames. |
| 182 | ALL-FRAMES = 0 means include windows on all visible and iconified frames. |
| 183 | ALL-FRAMES = t means include windows on all frames including invisible frames. |
| 184 | If ALL-FRAMES is a frame, it means include windows on that frame. |
| 185 | Anything else means restrict to the selected frame." |
| 186 | (catch 'found |
| 187 | (walk-windows #'(lambda (window) |
| 188 | (when (funcall predicate window) |
| 189 | (throw 'found window))) |
| 190 | minibuf all-frames) |
| 191 | default)) |
| 192 | |
| 193 | (defalias 'some-window 'get-window-with-predicate) |
| 194 | |
| 195 | ;; This should probably be written in C (i.e., without using `walk-windows'). |
| 196 | (defun get-buffer-window-list (buffer &optional minibuf frame) |
| 197 | "Return list of all windows displaying BUFFER, or nil if none. |
| 198 | BUFFER can be a buffer or a buffer name. |
| 199 | See `walk-windows' for the meaning of MINIBUF and FRAME." |
| 200 | (let ((buffer (if (bufferp buffer) buffer (get-buffer buffer))) windows) |
| 201 | (walk-windows (function (lambda (window) |
| 202 | (if (eq (window-buffer window) buffer) |
| 203 | (setq windows (cons window windows))))) |
| 204 | minibuf frame) |
| 205 | windows)) |
| 206 | |
| 207 | (defun minibuffer-window-active-p (window) |
| 208 | "Return t if WINDOW (a minibuffer window) is now active." |
| 209 | (eq window (active-minibuffer-window))) |
| 210 | \f |
| 211 | (defun count-windows (&optional minibuf) |
| 212 | "Return the number of visible windows. |
| 213 | This counts the windows in the selected frame and (if the minibuffer is |
| 214 | to be counted) its minibuffer frame (if that's not the same frame). |
| 215 | The optional arg MINIBUF non-nil means count the minibuffer |
| 216 | even if it is inactive." |
| 217 | (let ((count 0)) |
| 218 | (walk-windows (lambda (w) (setq count (+ count 1))) |
| 219 | minibuf) |
| 220 | count)) |
| 221 | |
| 222 | (defun window-safely-shrinkable-p (&optional window) |
| 223 | "Non-nil if the WINDOW can be shrunk without shrinking other windows. |
| 224 | If WINDOW is nil or omitted, it defaults to the currently selected window." |
| 225 | (with-selected-window (or window (selected-window)) |
| 226 | (let ((edges (window-edges))) |
| 227 | (or (= (nth 2 edges) (nth 2 (window-edges (previous-window)))) |
| 228 | (= (nth 0 edges) (nth 0 (window-edges (next-window)))))))) |
| 229 | |
| 230 | \f |
| 231 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 232 | ;;; `balance-windows' subroutines using `window-tree' |
| 233 | |
| 234 | ;;; Translate from internal window tree format |
| 235 | |
| 236 | (defun bw-get-tree (&optional window-or-frame) |
| 237 | "Get a window split tree in our format. |
| 238 | |
| 239 | WINDOW-OR-FRAME must be nil, a frame, or a window. If it is nil, |
| 240 | then the whole window split tree for `selected-frame' is returned. |
| 241 | If it is a frame, then this is used instead. If it is a window, |
| 242 | then the smallest tree containing that window is returned." |
| 243 | (when window-or-frame |
| 244 | (unless (or (framep window-or-frame) |
| 245 | (windowp window-or-frame)) |
| 246 | (error "Not a frame or window: %s" window-or-frame))) |
| 247 | (let ((subtree (bw-find-tree-sub window-or-frame))) |
| 248 | (when subtree |
| 249 | (if (integerp subtree) |
| 250 | nil |
| 251 | (bw-get-tree-1 subtree))))) |
| 252 | |
| 253 | (defun bw-get-tree-1 (split) |
| 254 | (if (windowp split) |
| 255 | split |
| 256 | (let ((dir (car split)) |
| 257 | (edges (car (cdr split))) |
| 258 | (childs (cdr (cdr split)))) |
| 259 | (list |
| 260 | (cons 'dir (if dir 'ver 'hor)) |
| 261 | (cons 'b (nth 3 edges)) |
| 262 | (cons 'r (nth 2 edges)) |
| 263 | (cons 't (nth 1 edges)) |
| 264 | (cons 'l (nth 0 edges)) |
| 265 | (cons 'childs (mapcar #'bw-get-tree-1 childs)))))) |
| 266 | |
| 267 | (defun bw-find-tree-sub (window-or-frame &optional get-parent) |
| 268 | (let* ((window (when (windowp window-or-frame) window-or-frame)) |
| 269 | (frame (when (windowp window) (window-frame window))) |
| 270 | (wt (car (window-tree frame)))) |
| 271 | (when (< 1 (length (window-list frame 0))) |
| 272 | (if window |
| 273 | (bw-find-tree-sub-1 wt window get-parent) |
| 274 | wt)))) |
| 275 | |
| 276 | (defun bw-find-tree-sub-1 (tree win &optional get-parent) |
| 277 | (unless (windowp win) (error "Not a window: %s" win)) |
| 278 | (if (memq win tree) |
| 279 | (if get-parent |
| 280 | get-parent |
| 281 | tree) |
| 282 | (let ((childs (cdr (cdr tree))) |
| 283 | child |
| 284 | subtree) |
| 285 | (while (and childs (not subtree)) |
| 286 | (setq child (car childs)) |
| 287 | (setq childs (cdr childs)) |
| 288 | (when (and child (listp child)) |
| 289 | (setq subtree (bw-find-tree-sub-1 child win get-parent)))) |
| 290 | (if (integerp subtree) |
| 291 | (progn |
| 292 | (if (= 1 subtree) |
| 293 | tree |
| 294 | (1- subtree))) |
| 295 | subtree |
| 296 | )))) |
| 297 | |
| 298 | ;;; Window or object edges |
| 299 | |
| 300 | (defun bw-l (obj) |
| 301 | "Left edge of OBJ." |
| 302 | (if (windowp obj) (nth 0 (window-edges obj)) (cdr (assq 'l obj)))) |
| 303 | (defun bw-t (obj) |
| 304 | "Top edge of OBJ." |
| 305 | (if (windowp obj) (nth 1 (window-edges obj)) (cdr (assq 't obj)))) |
| 306 | (defun bw-r (obj) |
| 307 | "Right edge of OBJ." |
| 308 | (if (windowp obj) (nth 2 (window-edges obj)) (cdr (assq 'r obj)))) |
| 309 | (defun bw-b (obj) |
| 310 | "Bottom edge of OBJ." |
| 311 | (if (windowp obj) (nth 3 (window-edges obj)) (cdr (assq 'b obj)))) |
| 312 | |
| 313 | ;;; Split directions |
| 314 | |
| 315 | (defun bw-dir (obj) |
| 316 | "Return window split tree direction if OBJ. |
| 317 | If OBJ is a window return 'both. If it is a window split tree |
| 318 | then return its direction." |
| 319 | (if (symbolp obj) |
| 320 | obj |
| 321 | (if (windowp obj) |
| 322 | 'both |
| 323 | (let ((dir (cdr (assq 'dir obj)))) |
| 324 | (unless (memq dir '(hor ver both)) |
| 325 | (error "Can't find dir in %s" obj)) |
| 326 | dir)))) |
| 327 | |
| 328 | (defun bw-eqdir (obj1 obj2) |
| 329 | "Return t if window split tree directions are equal. |
| 330 | OBJ1 and OBJ2 should be either windows or window split trees in |
| 331 | our format. The directions returned by `bw-dir' are compared and |
| 332 | t is returned if they are `eq' or one of them is 'both." |
| 333 | (let ((dir1 (bw-dir obj1)) |
| 334 | (dir2 (bw-dir obj2))) |
| 335 | (or (eq dir1 dir2) |
| 336 | (eq dir1 'both) |
| 337 | (eq dir2 'both)))) |
| 338 | |
| 339 | ;;; Building split tree |
| 340 | |
| 341 | (defun bw-refresh-edges (obj) |
| 342 | "Refresh the edge information of OBJ and return OBJ." |
| 343 | (unless (windowp obj) |
| 344 | (let ((childs (cdr (assq 'childs obj))) |
| 345 | (ol 1000) |
| 346 | (ot 1000) |
| 347 | (or -1) |
| 348 | (ob -1)) |
| 349 | (dolist (o childs) |
| 350 | (when (> ol (bw-l o)) (setq ol (bw-l o))) |
| 351 | (when (> ot (bw-t o)) (setq ot (bw-t o))) |
| 352 | (when (< or (bw-r o)) (setq or (bw-r o))) |
| 353 | (when (< ob (bw-b o)) (setq ob (bw-b o)))) |
| 354 | (setq obj (delq 'l obj)) |
| 355 | (setq obj (delq 't obj)) |
| 356 | (setq obj (delq 'r obj)) |
| 357 | (setq obj (delq 'b obj)) |
| 358 | (add-to-list 'obj (cons 'l ol)) |
| 359 | (add-to-list 'obj (cons 't ot)) |
| 360 | (add-to-list 'obj (cons 'r or)) |
| 361 | (add-to-list 'obj (cons 'b ob)) |
| 362 | )) |
| 363 | obj) |
| 364 | |
| 365 | ;;; Balance windows |
| 366 | |
| 367 | (defun balance-windows (&optional window-or-frame) |
| 368 | "Make windows the same heights or widths in window split subtrees. |
| 369 | |
| 370 | When called non-interactively WINDOW-OR-FRAME may be either a |
| 371 | window or a frame. It then balances the windows on the implied |
| 372 | frame. If the parameter is a window only the corresponding window |
| 373 | subtree is balanced." |
| 374 | (interactive) |
| 375 | (let ( |
| 376 | (wt (bw-get-tree window-or-frame)) |
| 377 | (w) |
| 378 | (h) |
| 379 | (tried-sizes) |
| 380 | (last-sizes) |
| 381 | (windows (window-list nil 0))) |
| 382 | (when wt |
| 383 | (while (not (member last-sizes tried-sizes)) |
| 384 | (when last-sizes (setq tried-sizes (cons last-sizes tried-sizes))) |
| 385 | (setq last-sizes (mapcar (lambda (w) |
| 386 | (window-edges w)) |
| 387 | windows)) |
| 388 | (when (eq 'hor (bw-dir wt)) |
| 389 | (setq w (- (bw-r wt) (bw-l wt)))) |
| 390 | (when (eq 'ver (bw-dir wt)) |
| 391 | (setq h (- (bw-b wt) (bw-t wt)))) |
| 392 | (bw-balance-sub wt w h))))) |
| 393 | |
| 394 | (defun bw-adjust-window (window delta horizontal) |
| 395 | "Wrapper around `adjust-window-trailing-edge' with error checking. |
| 396 | Arguments WINDOW, DELTA and HORIZONTAL are passed on to that function." |
| 397 | ;; `adjust-window-trailing-edge' may fail if delta is too large. |
| 398 | (while (>= (abs delta) 1) |
| 399 | (condition-case err |
| 400 | (progn |
| 401 | (adjust-window-trailing-edge window delta horizontal) |
| 402 | (setq delta 0)) |
| 403 | (error |
| 404 | ;;(message "adjust: %s" (error-message-string err)) |
| 405 | (setq delta (/ delta 2)))))) |
| 406 | |
| 407 | (defun bw-balance-sub (wt w h) |
| 408 | (setq wt (bw-refresh-edges wt)) |
| 409 | (unless w (setq w (- (bw-r wt) (bw-l wt)))) |
| 410 | (unless h (setq h (- (bw-b wt) (bw-t wt)))) |
| 411 | (if (windowp wt) |
| 412 | (progn |
| 413 | (when w |
| 414 | (let ((dw (- w (- (bw-r wt) (bw-l wt))))) |
| 415 | (when (/= 0 dw) |
| 416 | (bw-adjust-window wt dw t)))) |
| 417 | (when h |
| 418 | (let ((dh (- h (- (bw-b wt) (bw-t wt))))) |
| 419 | (when (/= 0 dh) |
| 420 | (bw-adjust-window wt dh nil))))) |
| 421 | (let* ((childs (cdr (assq 'childs wt))) |
| 422 | (cw (when w (/ w (if (bw-eqdir 'hor wt) (length childs) 1)))) |
| 423 | (ch (when h (/ h (if (bw-eqdir 'ver wt) (length childs) 1))))) |
| 424 | (dolist (c childs) |
| 425 | (bw-balance-sub c cw ch))))) |
| 426 | |
| 427 | ;;; A different solution to balance-windows |
| 428 | |
| 429 | (defun window-fixed-size-p (&optional window direction) |
| 430 | "Non-nil if WINDOW cannot be resized in DIRECTION. |
| 431 | DIRECTION can be nil (i.e. any), `height' or `width'." |
| 432 | (with-current-buffer (window-buffer window) |
| 433 | (let ((fixed (and (boundp 'window-size-fixed) window-size-fixed))) |
| 434 | (when fixed |
| 435 | (not (and direction |
| 436 | (member (cons direction window-size-fixed) |
| 437 | '((height . width) (width . height))))))))) |
| 438 | |
| 439 | (defvar window-area-factor 1 |
| 440 | "Factor by which the window area should be over-estimated. |
| 441 | This is used by `balance-windows-area'. |
| 442 | Changing this globally has no effect.") |
| 443 | |
| 444 | (defun balance-windows-area () |
| 445 | "Make all visible windows the same area (approximately). |
| 446 | See also `window-area-factor' to change the relative size of specific buffers." |
| 447 | (interactive) |
| 448 | (let* ((unchanged 0) (carry 0) (round 0) |
| 449 | ;; Remove fixed-size windows. |
| 450 | (wins (delq nil (mapcar (lambda (win) |
| 451 | (if (not (window-fixed-size-p win)) win)) |
| 452 | (window-list nil 'nomini)))) |
| 453 | (changelog nil) |
| 454 | next) |
| 455 | ;; Resizing a window changes the size of surrounding windows in complex |
| 456 | ;; ways, so it's difficult to balance them all. The introduction of |
| 457 | ;; `adjust-window-trailing-edge' made it a bit easier, but it is still |
| 458 | ;; very difficult to do. `balance-window' above takes an off-line |
| 459 | ;; approach: get the whole window tree, then balance it, then try to |
| 460 | ;; adjust the windows so they fit the result. |
| 461 | ;; Here, instead, we take a "local optimization" approach, where we just |
| 462 | ;; go through all the windows several times until nothing needs to be |
| 463 | ;; changed. The main problem with this approach is that it's difficult |
| 464 | ;; to make sure it terminates, so we use some heuristic to try and break |
| 465 | ;; off infinite loops. |
| 466 | ;; After a round without any change, we allow a second, to give a chance |
| 467 | ;; to the carry to propagate a minor imbalance from the end back to |
| 468 | ;; the beginning. |
| 469 | (while (< unchanged 2) |
| 470 | ;; (message "New round") |
| 471 | (setq unchanged (1+ unchanged) round (1+ round)) |
| 472 | (dolist (win wins) |
| 473 | (setq next win) |
| 474 | (while (progn (setq next (next-window next)) |
| 475 | (window-fixed-size-p next))) |
| 476 | ;; (assert (eq next (or (cadr (member win wins)) (car wins)))) |
| 477 | (let* ((horiz |
| 478 | (< (car (window-edges win)) (car (window-edges next)))) |
| 479 | (areadiff (/ (- (* (window-height next) (window-width next) |
| 480 | (buffer-local-value 'window-area-factor |
| 481 | (window-buffer next))) |
| 482 | (* (window-height win) (window-width win) |
| 483 | (buffer-local-value 'window-area-factor |
| 484 | (window-buffer win)))) |
| 485 | (max (buffer-local-value 'window-area-factor |
| 486 | (window-buffer win)) |
| 487 | (buffer-local-value 'window-area-factor |
| 488 | (window-buffer next))))) |
| 489 | (edgesize (if horiz |
| 490 | (+ (window-height win) (window-height next)) |
| 491 | (+ (window-width win) (window-width next)))) |
| 492 | (diff (/ areadiff edgesize))) |
| 493 | (when (zerop diff) |
| 494 | ;; Maybe diff is actually closer to 1 than to 0. |
| 495 | (setq diff (/ (* 3 areadiff) (* 2 edgesize)))) |
| 496 | (when (and (zerop diff) (not (zerop areadiff))) |
| 497 | (setq diff (/ (+ areadiff carry) edgesize)) |
| 498 | ;; Change things smoothly. |
| 499 | (if (or (> diff 1) (< diff -1)) (setq diff (/ diff 2)))) |
| 500 | (if (zerop diff) |
| 501 | ;; Make sure negligible differences don't accumulate to |
| 502 | ;; become significant. |
| 503 | (setq carry (+ carry areadiff)) |
| 504 | (bw-adjust-window win diff horiz) |
| 505 | ;; (sit-for 0.5) |
| 506 | (let ((change (cons win (window-edges win)))) |
| 507 | ;; If the same change has been seen already for this window, |
| 508 | ;; we're most likely in an endless loop, so don't count it as |
| 509 | ;; a change. |
| 510 | (unless (member change changelog) |
| 511 | (push change changelog) |
| 512 | (setq unchanged 0 carry 0))))))) |
| 513 | ;; We've now basically balanced all the windows. |
| 514 | ;; But there may be some minor off-by-one imbalance left over, |
| 515 | ;; so let's do some fine tuning. |
| 516 | ;; (bw-finetune wins) |
| 517 | ;; (message "Done in %d rounds" round) |
| 518 | )) |
| 519 | |
| 520 | ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;; |
| 521 | \f |
| 522 | ;; I think this should be the default; I think people will prefer it--rms. |
| 523 | (defcustom split-window-keep-point t |
| 524 | "*If non-nil, \\[split-window-vertically] keeps the original point \ |
| 525 | in both children. |
| 526 | This is often more convenient for editing. |
| 527 | If nil, adjust point in each of the two windows to minimize redisplay. |
| 528 | This is convenient on slow terminals, but point can move strangely. |
| 529 | |
| 530 | This option applies only to `split-window-vertically' and |
| 531 | functions that call it. `split-window' always keeps the original |
| 532 | point in both children." |
| 533 | :type 'boolean |
| 534 | :group 'windows) |
| 535 | |
| 536 | (defun split-window-vertically (&optional arg) |
| 537 | "Split current window into two windows, one above the other. |
| 538 | The uppermost window gets ARG lines and the other gets the rest. |
| 539 | Negative ARG means select the size of the lowermost window instead. |
| 540 | With no argument, split equally or close to it. |
| 541 | Both windows display the same buffer now current. |
| 542 | |
| 543 | If the variable `split-window-keep-point' is non-nil, both new windows |
| 544 | will get the same value of point as the current window. This is often |
| 545 | more convenient for editing. The upper window is the selected window. |
| 546 | |
| 547 | Otherwise, we choose window starts so as to minimize the amount of |
| 548 | redisplay; this is convenient on slow terminals. The new selected |
| 549 | window is the one that the current value of point appears in. The |
| 550 | value of point can change if the text around point is hidden by the |
| 551 | new mode line. |
| 552 | |
| 553 | Regardless of the value of `split-window-keep-point', the upper |
| 554 | window is the original one and the return value is the new, lower |
| 555 | window." |
| 556 | (interactive "P") |
| 557 | (let ((old-w (selected-window)) |
| 558 | (old-point (point)) |
| 559 | (size (and arg (prefix-numeric-value arg))) |
| 560 | (window-full-p nil) |
| 561 | new-w bottom moved) |
| 562 | (and size (< size 0) (setq size (+ (window-height) size))) |
| 563 | (setq new-w (split-window nil size)) |
| 564 | (or split-window-keep-point |
| 565 | (progn |
| 566 | (save-excursion |
| 567 | (set-buffer (window-buffer)) |
| 568 | (goto-char (window-start)) |
| 569 | (setq moved (vertical-motion (window-height))) |
| 570 | (set-window-start new-w (point)) |
| 571 | (if (> (point) (window-point new-w)) |
| 572 | (set-window-point new-w (point))) |
| 573 | (and (= moved (window-height)) |
| 574 | (progn |
| 575 | (setq window-full-p t) |
| 576 | (vertical-motion -1))) |
| 577 | (setq bottom (point))) |
| 578 | (and window-full-p |
| 579 | (<= bottom (point)) |
| 580 | (set-window-point old-w (1- bottom))) |
| 581 | (and window-full-p |
| 582 | (<= (window-start new-w) old-point) |
| 583 | (progn |
| 584 | (set-window-point new-w old-point) |
| 585 | (select-window new-w))))) |
| 586 | (split-window-save-restore-data new-w old-w))) |
| 587 | |
| 588 | ;; This is to avoid compiler warnings. |
| 589 | (defvar view-return-to-alist) |
| 590 | |
| 591 | (defun split-window-save-restore-data (new-w old-w) |
| 592 | (with-current-buffer (window-buffer) |
| 593 | (if view-mode |
| 594 | (let ((old-info (assq old-w view-return-to-alist))) |
| 595 | (if old-info |
| 596 | (push (cons new-w (cons (car (cdr old-info)) t)) |
| 597 | view-return-to-alist)))) |
| 598 | new-w)) |
| 599 | |
| 600 | (defun split-window-horizontally (&optional arg) |
| 601 | "Split current window into two windows side by side. |
| 602 | This window becomes the leftmost of the two, and gets ARG columns. |
| 603 | Negative ARG means select the size of the rightmost window instead. |
| 604 | The argument includes the width of the window's scroll bar; if there |
| 605 | are no scroll bars, it includes the width of the divider column |
| 606 | to the window's right, if any. No ARG means split equally. |
| 607 | |
| 608 | The original, leftmost window remains selected. |
| 609 | The return value is the new, rightmost window." |
| 610 | (interactive "P") |
| 611 | (let ((old-w (selected-window)) |
| 612 | (size (and arg (prefix-numeric-value arg)))) |
| 613 | (and size (< size 0) |
| 614 | (setq size (+ (window-width) size))) |
| 615 | (split-window-save-restore-data (split-window nil size t) old-w))) |
| 616 | |
| 617 | \f |
| 618 | (defun set-window-text-height (window height) |
| 619 | "Sets the height in lines of the text display area of WINDOW to HEIGHT. |
| 620 | This doesn't include the mode-line (or header-line if any) or any |
| 621 | partial-height lines in the text display area. |
| 622 | |
| 623 | If WINDOW is nil, the selected window is used. |
| 624 | |
| 625 | Note that the current implementation of this function cannot always set |
| 626 | the height exactly, but attempts to be conservative, by allocating more |
| 627 | lines than are actually needed in the case where some error may be present." |
| 628 | (let ((delta (- height (window-text-height window)))) |
| 629 | (unless (zerop delta) |
| 630 | ;; Setting window-min-height to a value like 1 can lead to very |
| 631 | ;; bizarre displays because it also allows Emacs to make *other* |
| 632 | ;; windows 1-line tall, which means that there's no more space for |
| 633 | ;; the modeline. |
| 634 | (let ((window-min-height (min 2 height))) ;One text line plus a modeline. |
| 635 | (if (and window (not (eq window (selected-window)))) |
| 636 | (save-selected-window |
| 637 | (select-window window) |
| 638 | (enlarge-window delta)) |
| 639 | (enlarge-window delta)))))) |
| 640 | |
| 641 | \f |
| 642 | (defun enlarge-window-horizontally (arg) |
| 643 | "Make current window ARG columns wider." |
| 644 | (interactive "p") |
| 645 | (enlarge-window arg t)) |
| 646 | |
| 647 | (defun shrink-window-horizontally (arg) |
| 648 | "Make current window ARG columns narrower." |
| 649 | (interactive "p") |
| 650 | (shrink-window arg t)) |
| 651 | |
| 652 | (defun window-buffer-height (window) |
| 653 | "Return the height (in screen lines) of the buffer that WINDOW is displaying." |
| 654 | (with-current-buffer (window-buffer window) |
| 655 | (max 1 |
| 656 | (count-screen-lines (point-min) (point-max) |
| 657 | ;; If buffer ends with a newline, ignore it when |
| 658 | ;; counting height unless point is after it. |
| 659 | (eobp) |
| 660 | window)))) |
| 661 | |
| 662 | (defun count-screen-lines (&optional beg end count-final-newline window) |
| 663 | "Return the number of screen lines in the region. |
| 664 | The number of screen lines may be different from the number of actual lines, |
| 665 | due to line breaking, display table, etc. |
| 666 | |
| 667 | Optional arguments BEG and END default to `point-min' and `point-max' |
| 668 | respectively. |
| 669 | |
| 670 | If region ends with a newline, ignore it unless optional third argument |
| 671 | COUNT-FINAL-NEWLINE is non-nil. |
| 672 | |
| 673 | The optional fourth argument WINDOW specifies the window used for obtaining |
| 674 | parameters such as width, horizontal scrolling, and so on. The default is |
| 675 | to use the selected window's parameters. |
| 676 | |
| 677 | Like `vertical-motion', `count-screen-lines' always uses the current buffer, |
| 678 | regardless of which buffer is displayed in WINDOW. This makes possible to use |
| 679 | `count-screen-lines' in any buffer, whether or not it is currently displayed |
| 680 | in some window." |
| 681 | (unless beg |
| 682 | (setq beg (point-min))) |
| 683 | (unless end |
| 684 | (setq end (point-max))) |
| 685 | (if (= beg end) |
| 686 | 0 |
| 687 | (save-excursion |
| 688 | (save-restriction |
| 689 | (widen) |
| 690 | (narrow-to-region (min beg end) |
| 691 | (if (and (not count-final-newline) |
| 692 | (= ?\n (char-before (max beg end)))) |
| 693 | (1- (max beg end)) |
| 694 | (max beg end))) |
| 695 | (goto-char (point-min)) |
| 696 | (1+ (vertical-motion (buffer-size) window)))))) |
| 697 | |
| 698 | (defun fit-window-to-buffer (&optional window max-height min-height) |
| 699 | "Make WINDOW the right height to display its contents exactly. |
| 700 | If WINDOW is omitted or nil, it defaults to the selected window. |
| 701 | If the optional argument MAX-HEIGHT is supplied, it is the maximum height |
| 702 | the window is allowed to be, defaulting to the frame height. |
| 703 | If the optional argument MIN-HEIGHT is supplied, it is the minimum |
| 704 | height the window is allowed to be, defaulting to `window-min-height'. |
| 705 | |
| 706 | The heights in MAX-HEIGHT and MIN-HEIGHT include the mode-line and/or |
| 707 | header-line." |
| 708 | (interactive) |
| 709 | |
| 710 | (when (null window) |
| 711 | (setq window (selected-window))) |
| 712 | (when (null max-height) |
| 713 | (setq max-height (frame-height (window-frame window)))) |
| 714 | |
| 715 | (let* ((buf |
| 716 | ;; Buffer that is displayed in WINDOW |
| 717 | (window-buffer window)) |
| 718 | (window-height |
| 719 | ;; The current height of WINDOW |
| 720 | (window-height window)) |
| 721 | (desired-height |
| 722 | ;; The height necessary to show the buffer displayed by WINDOW |
| 723 | ;; (`count-screen-lines' always works on the current buffer). |
| 724 | (with-current-buffer buf |
| 725 | (+ (count-screen-lines) |
| 726 | ;; If the buffer is empty, (count-screen-lines) is |
| 727 | ;; zero. But, even in that case, we need one text line |
| 728 | ;; for cursor. |
| 729 | (if (= (point-min) (point-max)) |
| 730 | 1 0) |
| 731 | ;; For non-minibuffers, count the mode-line, if any |
| 732 | (if (and (not (window-minibuffer-p window)) |
| 733 | mode-line-format) |
| 734 | 1 0) |
| 735 | ;; Count the header-line, if any |
| 736 | (if header-line-format 1 0)))) |
| 737 | (delta |
| 738 | ;; Calculate how much the window height has to change to show |
| 739 | ;; desired-height lines, constrained by MIN-HEIGHT and MAX-HEIGHT. |
| 740 | (- (max (min desired-height max-height) |
| 741 | (or min-height window-min-height)) |
| 742 | window-height))) |
| 743 | |
| 744 | ;; Don't try to redisplay with the cursor at the end |
| 745 | ;; on its own line--that would force a scroll and spoil things. |
| 746 | (when (with-current-buffer buf |
| 747 | (and (eobp) (bolp) (not (bobp)))) |
| 748 | (set-window-point window (1- (window-point window)))) |
| 749 | |
| 750 | (save-selected-window |
| 751 | (select-window window) |
| 752 | |
| 753 | ;; Adjust WINDOW to the nominally correct size (which may actually |
| 754 | ;; be slightly off because of variable height text, etc). |
| 755 | (unless (zerop delta) |
| 756 | (enlarge-window delta)) |
| 757 | |
| 758 | ;; Check if the last line is surely fully visible. If not, |
| 759 | ;; enlarge the window. |
| 760 | (let ((end (with-current-buffer buf |
| 761 | (save-excursion |
| 762 | (goto-char (point-max)) |
| 763 | (when (and (bolp) (not (bobp))) |
| 764 | ;; Don't include final newline |
| 765 | (backward-char 1)) |
| 766 | (when truncate-lines |
| 767 | ;; If line-wrapping is turned off, test the |
| 768 | ;; beginning of the last line for visibility |
| 769 | ;; instead of the end, as the end of the line |
| 770 | ;; could be invisible by virtue of extending past |
| 771 | ;; the edge of the window. |
| 772 | (forward-line 0)) |
| 773 | (point))))) |
| 774 | (set-window-vscroll window 0) |
| 775 | (while (and (< desired-height max-height) |
| 776 | (= desired-height (window-height window)) |
| 777 | (not (pos-visible-in-window-p end window))) |
| 778 | (enlarge-window 1) |
| 779 | (setq desired-height (1+ desired-height))))))) |
| 780 | |
| 781 | (defun shrink-window-if-larger-than-buffer (&optional window) |
| 782 | "Shrink the WINDOW to be as small as possible to display its contents. |
| 783 | If WINDOW is omitted or nil, it defaults to the selected window. |
| 784 | Do not shrink to less than `window-min-height' lines. |
| 785 | Do nothing if the buffer contains more lines than the present window height, |
| 786 | or if some of the window's contents are scrolled out of view, |
| 787 | or if shrinking this window would also shrink another window, |
| 788 | or if the window is the only window of its frame." |
| 789 | (interactive) |
| 790 | (when (null window) |
| 791 | (setq window (selected-window))) |
| 792 | (let* ((frame (window-frame window)) |
| 793 | (mini (frame-parameter frame 'minibuffer)) |
| 794 | (edges (window-edges window))) |
| 795 | (if (and (not (eq window (frame-root-window frame))) |
| 796 | (window-safely-shrinkable-p) |
| 797 | (pos-visible-in-window-p (point-min) window) |
| 798 | (not (eq mini 'only)) |
| 799 | (or (not mini) |
| 800 | (let ((mini-window (minibuffer-window frame))) |
| 801 | (or (null mini-window) |
| 802 | (not (eq frame (window-frame mini-window))) |
| 803 | (< (nth 3 edges) |
| 804 | (nth 1 (window-edges mini-window))) |
| 805 | (> (nth 1 edges) |
| 806 | (frame-parameter frame 'menu-bar-lines)))))) |
| 807 | (fit-window-to-buffer window (window-height window))))) |
| 808 | |
| 809 | (defun kill-buffer-and-window () |
| 810 | "Kill the current buffer and delete the selected window." |
| 811 | (interactive) |
| 812 | (let ((window-to-delete (selected-window)) |
| 813 | (buffer-to-kill (current-buffer)) |
| 814 | (delete-window-hook (lambda () |
| 815 | (condition-case nil |
| 816 | (delete-window) |
| 817 | (error nil))))) |
| 818 | (unwind-protect |
| 819 | (progn |
| 820 | (add-hook 'kill-buffer-hook delete-window-hook t t) |
| 821 | (if (kill-buffer (current-buffer)) |
| 822 | ;; If `delete-window' failed before, we rerun it to regenerate |
| 823 | ;; the error so it can be seen in the echo area. |
| 824 | (when (eq (selected-window) window-to-delete) |
| 825 | (delete-window)))) |
| 826 | ;; If the buffer is not dead for some reason (probably because |
| 827 | ;; of a `quit' signal), remove the hook again. |
| 828 | (condition-case nil |
| 829 | (with-current-buffer buffer-to-kill |
| 830 | (remove-hook 'kill-buffer-hook delete-window-hook t)) |
| 831 | (error nil))))) |
| 832 | |
| 833 | (defun quit-window (&optional kill window) |
| 834 | "Quit the current buffer. Bury it, and maybe delete the selected frame. |
| 835 | \(The frame is deleted if it contains a dedicated window for the buffer.) |
| 836 | With a prefix argument, kill the buffer instead. |
| 837 | |
| 838 | Noninteractively, if KILL is non-nil, then kill the current buffer, |
| 839 | otherwise bury it. |
| 840 | |
| 841 | If WINDOW is non-nil, it specifies a window; we delete that window, |
| 842 | and the buffer that is killed or buried is the one in that window." |
| 843 | (interactive "P") |
| 844 | (let ((buffer (window-buffer window)) |
| 845 | (frame (window-frame (or window (selected-window)))) |
| 846 | (window-solitary |
| 847 | (save-selected-window |
| 848 | (if window |
| 849 | (select-window window)) |
| 850 | (one-window-p t))) |
| 851 | window-handled) |
| 852 | |
| 853 | (save-selected-window |
| 854 | (if window |
| 855 | (select-window window)) |
| 856 | (or (window-minibuffer-p) |
| 857 | (window-dedicated-p (selected-window)) |
| 858 | (switch-to-buffer (other-buffer)))) |
| 859 | |
| 860 | ;; Get rid of the frame, if it has just one dedicated window |
| 861 | ;; and other visible frames exist. |
| 862 | (and (or (window-minibuffer-p) (window-dedicated-p window)) |
| 863 | (delq frame (visible-frame-list)) |
| 864 | window-solitary |
| 865 | (if (and (eq default-minibuffer-frame frame) |
| 866 | (= 1 (length (minibuffer-frame-list)))) |
| 867 | (setq window nil) |
| 868 | (delete-frame frame) |
| 869 | (setq window-handled t))) |
| 870 | |
| 871 | ;; Deal with the buffer. |
| 872 | (if kill |
| 873 | (kill-buffer buffer) |
| 874 | (bury-buffer buffer)) |
| 875 | |
| 876 | ;; Maybe get rid of the window. |
| 877 | (and window (not window-handled) (not window-solitary) |
| 878 | (delete-window window)))) |
| 879 | |
| 880 | (defvar recenter-last-op nil |
| 881 | "Indicates the last recenter operation performed. |
| 882 | Possible values: `top', `middle', `bottom'.") |
| 883 | |
| 884 | (defun recenter-top-bottom (&optional arg) |
| 885 | "Move current line to window center, top, and bottom, successively. |
| 886 | With a prefix argument, this is the same as `recenter': |
| 887 | With numeric prefix ARG, move current line to window-line ARG. |
| 888 | With plain `C-u', move current line to window center. |
| 889 | |
| 890 | Otherwise move current line to window center on first call, and to |
| 891 | top, middle, or bottom on successive calls. |
| 892 | |
| 893 | The cycling order is: middle -> top -> bottom. |
| 894 | |
| 895 | Top and bottom destinations are actually `scroll-conservatively' lines |
| 896 | from true window top and bottom." |
| 897 | (interactive "P") |
| 898 | (cond |
| 899 | (arg (recenter arg)) ; Always respect ARG. |
| 900 | ((not (eq this-command last-command)) |
| 901 | ;; First time - save mode and recenter. |
| 902 | (setq recenter-last-op 'middle) |
| 903 | (recenter)) |
| 904 | (t ;; repeat: loop through various options. |
| 905 | (setq recenter-last-op |
| 906 | (cond ((eq recenter-last-op 'middle) |
| 907 | (recenter scroll-conservatively) |
| 908 | 'top) |
| 909 | ((eq recenter-last-op 'top) |
| 910 | (recenter (1- (- scroll-conservatively))) |
| 911 | 'bottom) |
| 912 | ((eq recenter-last-op 'bottom) |
| 913 | (recenter) |
| 914 | 'middle)))))) |
| 915 | |
| 916 | (define-key global-map [?\C-l] 'recenter-top-bottom) |
| 917 | \f |
| 918 | (defvar mouse-autoselect-window-timer nil |
| 919 | "Timer used by delayed window autoselection.") |
| 920 | |
| 921 | (defvar mouse-autoselect-window-position nil |
| 922 | "Last mouse position recorded by delayed window autoselection.") |
| 923 | |
| 924 | (defvar mouse-autoselect-window-window nil |
| 925 | "Last window recorded by delayed window autoselection.") |
| 926 | |
| 927 | (defvar mouse-autoselect-window-state nil |
| 928 | "When non-nil, special state of delayed window autoselection. |
| 929 | Possible values are `suspend' \(suspend autoselection after a menu or |
| 930 | scrollbar interaction\) and `select' \(the next invocation of |
| 931 | 'handle-select-window' shall select the window immediately\).") |
| 932 | |
| 933 | (defun mouse-autoselect-window-cancel (&optional force) |
| 934 | "Cancel delayed window autoselection. |
| 935 | Optional argument FORCE means cancel unconditionally." |
| 936 | (unless (and (not force) |
| 937 | ;; Don't cancel for select-window or select-frame events |
| 938 | ;; or when the user drags a scroll bar. |
| 939 | (or (memq this-command |
| 940 | '(handle-select-window handle-switch-frame)) |
| 941 | (and (eq this-command 'scroll-bar-toolkit-scroll) |
| 942 | (memq (nth 4 (event-end last-input-event)) |
| 943 | '(handle end-scroll))))) |
| 944 | (setq mouse-autoselect-window-state nil) |
| 945 | (when (timerp mouse-autoselect-window-timer) |
| 946 | (cancel-timer mouse-autoselect-window-timer)) |
| 947 | (remove-hook 'pre-command-hook 'mouse-autoselect-window-cancel))) |
| 948 | |
| 949 | (defun mouse-autoselect-window-start (mouse-position &optional window suspend) |
| 950 | "Start delayed window autoselection. |
| 951 | MOUSE-POSITION is the last position where the mouse was seen as returned |
| 952 | by `mouse-position'. Optional argument WINDOW non-nil denotes the |
| 953 | window where the mouse was seen. Optional argument SUSPEND non-nil |
| 954 | means suspend autoselection." |
| 955 | ;; Record values for MOUSE-POSITION, WINDOW, and SUSPEND. |
| 956 | (setq mouse-autoselect-window-position mouse-position) |
| 957 | (when window (setq mouse-autoselect-window-window window)) |
| 958 | (setq mouse-autoselect-window-state (when suspend 'suspend)) |
| 959 | ;; Install timer which runs `mouse-autoselect-window-select' after |
| 960 | ;; `mouse-autoselect-window' seconds. |
| 961 | (setq mouse-autoselect-window-timer |
| 962 | (run-at-time |
| 963 | (abs mouse-autoselect-window) nil 'mouse-autoselect-window-select))) |
| 964 | |
| 965 | (defun mouse-autoselect-window-select () |
| 966 | "Select window with delayed window autoselection. |
| 967 | If the mouse position has stabilized in a non-selected window, select |
| 968 | that window. The minibuffer window is selected only if the minibuffer is |
| 969 | active. This function is run by `mouse-autoselect-window-timer'." |
| 970 | (condition-case nil |
| 971 | (let* ((mouse-position (mouse-position)) |
| 972 | (window |
| 973 | (condition-case nil |
| 974 | (window-at (cadr mouse-position) (cddr mouse-position) |
| 975 | (car mouse-position)) |
| 976 | (error nil)))) |
| 977 | (cond |
| 978 | ((or (menu-or-popup-active-p) |
| 979 | (and window |
| 980 | (not (coordinates-in-window-p (cdr mouse-position) window)))) |
| 981 | ;; A menu / popup dialog is active or the mouse is on the scroll-bar |
| 982 | ;; of WINDOW, temporarily suspend delayed autoselection. |
| 983 | (mouse-autoselect-window-start mouse-position nil t)) |
| 984 | ((eq mouse-autoselect-window-state 'suspend) |
| 985 | ;; Delayed autoselection was temporarily suspended, reenable it. |
| 986 | (mouse-autoselect-window-start mouse-position)) |
| 987 | ((and window (not (eq window (selected-window))) |
| 988 | (or (not (numberp mouse-autoselect-window)) |
| 989 | (and (> mouse-autoselect-window 0) |
| 990 | ;; If `mouse-autoselect-window' is positive, select |
| 991 | ;; window if the window is the same as before. |
| 992 | (eq window mouse-autoselect-window-window)) |
| 993 | ;; Otherwise select window if the mouse is at the same |
| 994 | ;; position as before. Observe that the first test after |
| 995 | ;; starting autoselection usually fails since the value of |
| 996 | ;; `mouse-autoselect-window-position' recorded there is the |
| 997 | ;; position where the mouse has entered the new window and |
| 998 | ;; not necessarily where the mouse has stopped moving. |
| 999 | (equal mouse-position mouse-autoselect-window-position)) |
| 1000 | ;; The minibuffer is a candidate window if it's active. |
| 1001 | (or (not (window-minibuffer-p window)) |
| 1002 | (eq window (active-minibuffer-window)))) |
| 1003 | ;; Mouse position has stabilized in non-selected window: Cancel |
| 1004 | ;; delayed autoselection and try to select that window. |
| 1005 | (mouse-autoselect-window-cancel t) |
| 1006 | ;; Select window where mouse appears unless the selected window is the |
| 1007 | ;; minibuffer. Use `unread-command-events' in order to execute pre- |
| 1008 | ;; and post-command hooks and trigger idle timers. To avoid delaying |
| 1009 | ;; autoselection again, set `mouse-autoselect-window-state'." |
| 1010 | (unless (window-minibuffer-p (selected-window)) |
| 1011 | (setq mouse-autoselect-window-state 'select) |
| 1012 | (setq unread-command-events |
| 1013 | (cons (list 'select-window (list window)) |
| 1014 | unread-command-events)))) |
| 1015 | ((or (and window (eq window (selected-window))) |
| 1016 | (not (numberp mouse-autoselect-window)) |
| 1017 | (equal mouse-position mouse-autoselect-window-position)) |
| 1018 | ;; Mouse position has either stabilized in the selected window or at |
| 1019 | ;; `mouse-autoselect-window-position': Cancel delayed autoselection. |
| 1020 | (mouse-autoselect-window-cancel t)) |
| 1021 | (t |
| 1022 | ;; Mouse position has not stabilized yet, resume delayed |
| 1023 | ;; autoselection. |
| 1024 | (mouse-autoselect-window-start mouse-position window)))) |
| 1025 | (error nil))) |
| 1026 | |
| 1027 | (defun handle-select-window (event) |
| 1028 | "Handle select-window events." |
| 1029 | (interactive "e") |
| 1030 | (let ((window (posn-window (event-start event)))) |
| 1031 | (unless (or (not (window-live-p window)) |
| 1032 | ;; Don't switch if we're currently in the minibuffer. |
| 1033 | ;; This tries to work around problems where the |
| 1034 | ;; minibuffer gets unselected unexpectedly, and where |
| 1035 | ;; you then have to move your mouse all the way down to |
| 1036 | ;; the minibuffer to select it. |
| 1037 | (window-minibuffer-p (selected-window)) |
| 1038 | ;; Don't switch to minibuffer window unless it's active. |
| 1039 | (and (window-minibuffer-p window) |
| 1040 | (not (minibuffer-window-active-p window))) |
| 1041 | ;; Don't switch when autoselection shall be delayed. |
| 1042 | (and (numberp mouse-autoselect-window) |
| 1043 | (not (zerop mouse-autoselect-window)) |
| 1044 | (not (eq mouse-autoselect-window-state 'select)) |
| 1045 | (progn |
| 1046 | ;; Cancel any delayed autoselection. |
| 1047 | (mouse-autoselect-window-cancel t) |
| 1048 | ;; Start delayed autoselection from current mouse position |
| 1049 | ;; and window. |
| 1050 | (mouse-autoselect-window-start (mouse-position) window) |
| 1051 | ;; Executing a command cancels delayed autoselection. |
| 1052 | (add-hook |
| 1053 | 'pre-command-hook 'mouse-autoselect-window-cancel)))) |
| 1054 | (when mouse-autoselect-window |
| 1055 | ;; Reset state of delayed autoselection. |
| 1056 | (setq mouse-autoselect-window-state nil) |
| 1057 | ;; Run `mouse-leave-buffer-hook' when autoselecting window. |
| 1058 | (run-hooks 'mouse-leave-buffer-hook)) |
| 1059 | (select-window window)))) |
| 1060 | |
| 1061 | (define-key ctl-x-map "2" 'split-window-vertically) |
| 1062 | (define-key ctl-x-map "3" 'split-window-horizontally) |
| 1063 | (define-key ctl-x-map "}" 'enlarge-window-horizontally) |
| 1064 | (define-key ctl-x-map "{" 'shrink-window-horizontally) |
| 1065 | (define-key ctl-x-map "-" 'shrink-window-if-larger-than-buffer) |
| 1066 | (define-key ctl-x-map "+" 'balance-windows) |
| 1067 | (define-key ctl-x-4-map "0" 'kill-buffer-and-window) |
| 1068 | |
| 1069 | ;; arch-tag: b508dfcc-c353-4c37-89fa-e773fe10cea9 |
| 1070 | ;;; window.el ends here |