| 1 | ;;; avoid.el --- make mouse pointer stay out of the way of editing |
| 2 | |
| 3 | ;;; Copyright (C) 1993, 1994 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Boris Goldowsky <boris@gnu.org> |
| 6 | ;; Keywords: mouse |
| 7 | |
| 8 | ;; This file is part of GNU Emacs. |
| 9 | |
| 10 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 11 | ;; it under the terms of the GNU General Public License as published by |
| 12 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 13 | ;; any later version. |
| 14 | |
| 15 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 16 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 17 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 18 | ;; GNU General Public License for more details. |
| 19 | |
| 20 | ;; You should have received a copy of the GNU General Public License |
| 21 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 22 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 23 | ;; Boston, MA 02111-1307, USA. |
| 24 | |
| 25 | ;;; Commentary: |
| 26 | |
| 27 | ;; For those who are annoyed by the mouse pointer obscuring text, |
| 28 | ;; this mode moves the mouse pointer - either just a little out of |
| 29 | ;; the way, or all the way to the corner of the frame. |
| 30 | ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode . |
| 31 | ;; To set up permanently, put the following in your .emacs: |
| 32 | ;; |
| 33 | ;; (if (display-mouse-p) (mouse-avoidance-mode 'animate)) |
| 34 | ;; |
| 35 | ;; Other legitimate alternatives include |
| 36 | ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'. |
| 37 | ;; They do somewhat different things. |
| 38 | ;; See the documentation for function `mouse-avoidance-mode' for |
| 39 | ;; details of the different modes. |
| 40 | ;; |
| 41 | ;; For added silliness, make the animatee animate... |
| 42 | ;; put something similar to the following into your .emacs: |
| 43 | ;; |
| 44 | ;; (if (eq window-system 'x) |
| 45 | ;; (mouse-avoidance-set-pointer-shape |
| 46 | ;; (eval (nth (random 4) |
| 47 | ;; '(x-pointer-man x-pointer-spider |
| 48 | ;; x-pointer-gobbler x-pointer-gumby))))) |
| 49 | ;; |
| 50 | ;; For completely random pointer shape, replace the setq above with: |
| 51 | ;; (setq x-pointer-shape (mouse-avoidance-random-shape)) |
| 52 | ;; |
| 53 | ;; Bugs / Warnings / To-Do: |
| 54 | ;; |
| 55 | ;; - Using this code does slow emacs down. "banish" mode shouldn't |
| 56 | ;; be too bad, and on my workstation even "animate" is reasonable. |
| 57 | ;; |
| 58 | ;; - It ought to find out where any overlapping frames are and avoid them, |
| 59 | ;; rather than always raising the frame. |
| 60 | |
| 61 | ;; Credits: |
| 62 | ;; This code was helped by all those who contributed suggestions, |
| 63 | ;; fixes, and additions |
| 64 | ;; Joe Harrington (and his advisor), for the original inspiration. |
| 65 | ;; Ken Manheimer, for dreaming up the Protean mode. |
| 66 | ;; Richard Stallman, for the awful cat-and-mouse pun, among other things. |
| 67 | ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris, |
| 68 | ;; Simon Marshall, and M.S. Ashton, for their feedback. |
| 69 | |
| 70 | ;;; Code: |
| 71 | |
| 72 | (provide 'avoid) |
| 73 | |
| 74 | (defgroup avoid nil |
| 75 | "Make mouse pointer stay out of the way of editing." |
| 76 | :prefix "mouse-avoidance-" |
| 77 | :group 'mouse) |
| 78 | |
| 79 | ;;;###autoload |
| 80 | (defcustom mouse-avoidance-mode nil |
| 81 | "Activate mouse avoidance mode. |
| 82 | See function `mouse-avoidance-mode' for possible values. |
| 83 | Setting this variable directly does not take effect; |
| 84 | use either \\[customize] or the function `mouse-avoidance-mode'." |
| 85 | :set (lambda (symbol value) |
| 86 | ;; 'none below prevents toggling when value is nil. |
| 87 | (mouse-avoidance-mode (or value 'none))) |
| 88 | :initialize 'custom-initialize-default |
| 89 | :type '(choice (const :tag "none" nil) (const banish) (const jump) |
| 90 | (const animate) (const exile) (const proteus) |
| 91 | ) |
| 92 | :group 'avoid |
| 93 | :require 'avoid |
| 94 | :version "20.3") |
| 95 | |
| 96 | |
| 97 | (defcustom mouse-avoidance-nudge-dist 15 |
| 98 | "*Average distance that mouse will be moved when approached by cursor. |
| 99 | Only applies in mouse-avoidance-mode `jump' and its derivatives. |
| 100 | For best results make this larger than `mouse-avoidance-threshold'." |
| 101 | :type 'integer |
| 102 | :group 'avoid) |
| 103 | |
| 104 | (defcustom mouse-avoidance-nudge-var 10 |
| 105 | "*Variability of `mouse-avoidance-nudge-dist' (which see)." |
| 106 | :type 'integer |
| 107 | :group 'avoid) |
| 108 | |
| 109 | (defcustom mouse-avoidance-animation-delay .01 |
| 110 | "Delay between animation steps, in seconds." |
| 111 | :type 'number |
| 112 | :group 'avoid) |
| 113 | |
| 114 | (defcustom mouse-avoidance-threshold 5 |
| 115 | "*Mouse-pointer's flight distance. |
| 116 | If the cursor gets closer than this, the mouse pointer will move away. |
| 117 | Only applies in mouse-avoidance-modes `animate' and `jump'." |
| 118 | :type 'integer |
| 119 | :group 'avoid) |
| 120 | |
| 121 | ;; Internal variables |
| 122 | (defvar mouse-avoidance-state nil) |
| 123 | (defvar mouse-avoidance-pointer-shapes nil) |
| 124 | (defvar mouse-avoidance-n-pointer-shapes 0) |
| 125 | (defvar mouse-avoidance-old-pointer-shape nil) |
| 126 | |
| 127 | ;; This timer is used to run something when Emacs is idle. |
| 128 | (defvar mouse-avoidance-timer nil) |
| 129 | |
| 130 | ;;; Functions: |
| 131 | |
| 132 | (defsubst mouse-avoidance-set-pointer-shape (shape) |
| 133 | "Set the shape of the mouse pointer to SHAPE." |
| 134 | (setq x-pointer-shape shape) |
| 135 | (set-mouse-color nil)) |
| 136 | |
| 137 | (defun mouse-avoidance-point-position () |
| 138 | "Return the position of point as (FRAME X . Y). |
| 139 | Analogous to mouse-position." |
| 140 | (let* ((w (selected-window)) |
| 141 | (edges (window-edges w)) |
| 142 | (list |
| 143 | (compute-motion (max (window-start w) (point-min)) ; start pos |
| 144 | ;; window-start can be < point-min if the |
| 145 | ;; latter has changed since the last redisplay |
| 146 | '(0 . 0) ; start XY |
| 147 | (point) ; stop pos |
| 148 | (cons (window-width) (window-height)); stop XY: none |
| 149 | (1- (window-width)) ; width |
| 150 | (cons (window-hscroll w) 0) ; 0 may not be right? |
| 151 | (selected-window)))) |
| 152 | ;; compute-motion returns (pos HPOS VPOS prevhpos contin) |
| 153 | ;; we want: (frame hpos . vpos) |
| 154 | (cons (selected-frame) |
| 155 | (cons (+ (car edges) (car (cdr list))) |
| 156 | (+ (car (cdr edges)) (car (cdr (cdr list)))))))) |
| 157 | |
| 158 | ;(defun mouse-avoidance-point-position-test () |
| 159 | ; (interactive) |
| 160 | ; (message (format "point=%s mouse=%s" |
| 161 | ; (cdr (mouse-avoidance-point-position)) |
| 162 | ; (cdr (mouse-position))))) |
| 163 | |
| 164 | (defun mouse-avoidance-set-mouse-position (pos) |
| 165 | ;; Carefully set mouse position to given position (X . Y) |
| 166 | ;; Ideally, should check if X,Y is in the current frame, and if not, |
| 167 | ;; leave the mouse where it was. However, this is currently |
| 168 | ;; difficult to do, so we just raise the frame to avoid frame switches. |
| 169 | ;; Returns t if it moved the mouse. |
| 170 | (let ((f (selected-frame))) |
| 171 | (raise-frame f) |
| 172 | (set-mouse-position f (car pos) (cdr pos)) |
| 173 | t)) |
| 174 | |
| 175 | (defun mouse-avoidance-too-close-p (mouse) |
| 176 | ;; Return t if mouse pointer and point cursor are too close. |
| 177 | ;; Acceptable distance is defined by mouse-avoidance-threshold. |
| 178 | (let ((point (mouse-avoidance-point-position))) |
| 179 | (and (eq (car mouse) (car point)) |
| 180 | (car (cdr mouse)) |
| 181 | (< (abs (- (car (cdr mouse)) (car (cdr point)))) |
| 182 | mouse-avoidance-threshold) |
| 183 | (< (abs (- (cdr (cdr mouse)) (cdr (cdr point)))) |
| 184 | mouse-avoidance-threshold)))) |
| 185 | |
| 186 | (defun mouse-avoidance-banish-destination () |
| 187 | "The position to which mouse-avoidance-mode `banish' moves the mouse. |
| 188 | You can redefine this if you want the mouse banished to a different corner." |
| 189 | (cons (1- (frame-width)) |
| 190 | 0)) |
| 191 | |
| 192 | (defun mouse-avoidance-banish-mouse () |
| 193 | ;; Put the mouse pointer in the upper-right corner of the current frame. |
| 194 | (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination))) |
| 195 | |
| 196 | (defsubst mouse-avoidance-delta (cur delta dist var min max) |
| 197 | ;; Decide how far to move in either dimension. |
| 198 | ;; Args are the CURRENT location, the desired DELTA for |
| 199 | ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY |
| 200 | ;; in distance allowed, and the MIN and MAX possible window positions. |
| 201 | ;; Returns something as close to DELTA as possible within the constraints. |
| 202 | (let ((L1 (max (- min cur) (+ (- dist) (- var)))) |
| 203 | (R1 (+ (- dist) var )) |
| 204 | (L2 (+ dist (- var))) |
| 205 | (R2 (min (- max cur) (+ dist var)))) |
| 206 | (if (< R1 (- min cur)) (setq L1 nil R1 nil)) |
| 207 | (if (> L2 (- max cur)) (setq L2 nil R2 nil)) |
| 208 | (cond ((and L1 (< delta L1)) L1) |
| 209 | ((and R1 (< delta R1)) delta) |
| 210 | ((and R1 (< delta 0)) R1) |
| 211 | ((and L2 (< delta L2)) L2) |
| 212 | ((and R2 (< delta R2)) delta) |
| 213 | (R2) |
| 214 | ((or R1 L2)) |
| 215 | (t 0)))) |
| 216 | |
| 217 | (defun mouse-avoidance-nudge-mouse () |
| 218 | ;; Push the mouse a little way away, possibly animating the move |
| 219 | ;; For these modes, state keeps track of the total offset that we've |
| 220 | ;; accumulated, and tries to keep it close to zero. |
| 221 | (let* ((cur (mouse-position)) |
| 222 | (cur-frame (car cur)) |
| 223 | (cur-pos (cdr cur)) |
| 224 | (deltax (mouse-avoidance-delta |
| 225 | (car cur-pos) (- (random mouse-avoidance-nudge-var) |
| 226 | (car mouse-avoidance-state)) |
| 227 | mouse-avoidance-nudge-dist mouse-avoidance-nudge-var |
| 228 | 0 (frame-width))) |
| 229 | (deltay (mouse-avoidance-delta |
| 230 | (cdr cur-pos) (- (random mouse-avoidance-nudge-var) |
| 231 | (cdr mouse-avoidance-state)) |
| 232 | mouse-avoidance-nudge-dist mouse-avoidance-nudge-var |
| 233 | 0 (frame-height)))) |
| 234 | (setq mouse-avoidance-state |
| 235 | (cons (+ (car mouse-avoidance-state) deltax) |
| 236 | (+ (cdr mouse-avoidance-state) deltay))) |
| 237 | (if (or (eq mouse-avoidance-mode 'animate) |
| 238 | (eq mouse-avoidance-mode 'proteus)) |
| 239 | (let ((i 0.0)) |
| 240 | (while (<= i 1) |
| 241 | (mouse-avoidance-set-mouse-position |
| 242 | (cons (+ (car cur-pos) (round (* i deltax))) |
| 243 | (+ (cdr cur-pos) (round (* i deltay))))) |
| 244 | (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist)))) |
| 245 | (if (eq mouse-avoidance-mode 'proteus) |
| 246 | (mouse-avoidance-set-pointer-shape |
| 247 | (mouse-avoidance-random-shape))) |
| 248 | (sit-for mouse-avoidance-animation-delay))) |
| 249 | (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax) |
| 250 | (+ (cdr (cdr cur)) deltay)))))) |
| 251 | |
| 252 | (defun mouse-avoidance-random-shape () |
| 253 | "Return a random cursor shape. |
| 254 | This assumes that any variable whose name begins with x-pointer- and |
| 255 | has an integer value is a valid cursor shape. You might want to |
| 256 | redefine this function to suit your own tastes." |
| 257 | (if (null mouse-avoidance-pointer-shapes) |
| 258 | (progn |
| 259 | (setq mouse-avoidance-pointer-shapes |
| 260 | (mapcar (lambda (x) (symbol-value (intern x))) |
| 261 | (all-completions "x-pointer-" obarray |
| 262 | (lambda (x) |
| 263 | (and (boundp x) |
| 264 | (integerp (symbol-value x))))))) |
| 265 | (setq mouse-avoidance-n-pointer-shapes |
| 266 | (length mouse-avoidance-pointer-shapes)))) |
| 267 | (nth (random mouse-avoidance-n-pointer-shapes) |
| 268 | mouse-avoidance-pointer-shapes)) |
| 269 | |
| 270 | (defun mouse-avoidance-banish-hook () |
| 271 | (if (and (not executing-kbd-macro) ; don't check inside macro |
| 272 | (cadr (mouse-position)) ; don't move unless in an Emacs frame |
| 273 | ;; Don't do anything if last event was a mouse event. |
| 274 | (not (and (consp last-input-event) |
| 275 | (symbolp (car last-input-event)) |
| 276 | (let ((modifiers (event-modifiers (car last-input-event)))) |
| 277 | (or (memq (car last-input-event) |
| 278 | '(mouse-movement scroll-bar-movement)) |
| 279 | (memq 'click modifiers) |
| 280 | (memq 'drag modifiers) |
| 281 | (memq 'down modifiers)))))) |
| 282 | (mouse-avoidance-banish-mouse))) |
| 283 | |
| 284 | (defun mouse-avoidance-exile-hook () |
| 285 | ;; For exile mode, the state is nil when the mouse is in its normal |
| 286 | ;; position, and set to the old mouse-position when the mouse is in exile. |
| 287 | (if (and (not executing-kbd-macro) |
| 288 | ;; Don't do anything if last event was a mouse event. |
| 289 | (not (and (consp last-input-event) |
| 290 | (symbolp (car last-input-event)) |
| 291 | (let ((modifiers (event-modifiers (car last-input-event)))) |
| 292 | (or (memq (car last-input-event) |
| 293 | '(mouse-movement scroll-bar-movement)) |
| 294 | (memq 'click modifiers) |
| 295 | (memq 'drag modifiers) |
| 296 | (memq 'down modifiers)))))) |
| 297 | (let ((mp (mouse-position))) |
| 298 | (cond ((and (not mouse-avoidance-state) |
| 299 | (mouse-avoidance-too-close-p mp)) |
| 300 | (setq mouse-avoidance-state mp) |
| 301 | (mouse-avoidance-banish-mouse)) |
| 302 | ((and mouse-avoidance-state |
| 303 | (not (mouse-avoidance-too-close-p mouse-avoidance-state))) |
| 304 | (if (and (eq (car mp) (selected-frame)) |
| 305 | (equal (cdr mp) (mouse-avoidance-banish-destination))) |
| 306 | (mouse-avoidance-set-mouse-position |
| 307 | ;; move back only if user has not moved mouse |
| 308 | (cdr mouse-avoidance-state))) |
| 309 | ;; but clear state anyway, to be ready for another move |
| 310 | (setq mouse-avoidance-state nil)))))) |
| 311 | |
| 312 | (defun mouse-avoidance-fancy-hook () |
| 313 | ;; Used for the "fancy" modes, ie jump et al. |
| 314 | (if (and (not executing-kbd-macro) ; don't check inside macro |
| 315 | ;; Don't do anything if last event was a mouse event. |
| 316 | (not (and (consp last-input-event) |
| 317 | (symbolp (car last-input-event)) |
| 318 | (let ((modifiers (event-modifiers (car last-input-event)))) |
| 319 | (or (memq (car last-input-event) |
| 320 | '(mouse-movement scroll-bar-movement)) |
| 321 | (memq 'click modifiers) |
| 322 | (memq 'drag modifiers) |
| 323 | (memq 'down modifiers))))) |
| 324 | (mouse-avoidance-too-close-p (mouse-position))) |
| 325 | (let ((old-pos (mouse-position))) |
| 326 | (mouse-avoidance-nudge-mouse) |
| 327 | (if (not (eq (selected-frame) (car old-pos))) |
| 328 | ;; This should never happen. |
| 329 | (apply 'set-mouse-position old-pos))))) |
| 330 | |
| 331 | ;;;###autoload |
| 332 | (defun mouse-avoidance-mode (&optional mode) |
| 333 | "Set cursor avoidance mode to MODE. |
| 334 | MODE should be one of the symbols `banish', `exile', `jump', `animate', |
| 335 | `cat-and-mouse', `proteus', or `none'. |
| 336 | |
| 337 | If MODE is nil, toggle mouse avoidance between `none' and `banish' |
| 338 | modes. Positive numbers and symbols other than the above are treated |
| 339 | as equivalent to `banish'; negative numbers and `-' are equivalent to `none'. |
| 340 | |
| 341 | Effects of the different modes: |
| 342 | * banish: Move the mouse to the upper-right corner on any keypress. |
| 343 | * exile: Move the mouse to the corner only if the cursor gets too close, |
| 344 | and allow it to return once the cursor is out of the way. |
| 345 | * jump: If the cursor gets too close to the mouse, displace the mouse |
| 346 | a random distance & direction. |
| 347 | * animate: As `jump', but shows steps along the way for illusion of motion. |
| 348 | * cat-and-mouse: Same as `animate'. |
| 349 | * proteus: As `animate', but changes the shape of the mouse pointer too. |
| 350 | |
| 351 | Whenever the mouse is moved, the frame is also raised. |
| 352 | |
| 353 | \(see `mouse-avoidance-threshold' for definition of \"too close\", |
| 354 | and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for |
| 355 | definition of \"random distance\".)" |
| 356 | (interactive |
| 357 | (list (intern (completing-read |
| 358 | "Select cursor avoidance technique (SPACE for list): " |
| 359 | '(("banish") ("exile") ("jump") ("animate") |
| 360 | ("cat-and-mouse") ("proteus") ("none")) |
| 361 | nil t)))) |
| 362 | (if (eq mode 'cat-and-mouse) |
| 363 | (setq mode 'animate)) |
| 364 | (if mouse-avoidance-timer |
| 365 | (cancel-timer mouse-avoidance-timer)) |
| 366 | (setq mouse-avoidance-timer nil) |
| 367 | |
| 368 | ;; Restore pointer shape if necessary |
| 369 | (if (eq mouse-avoidance-mode 'proteus) |
| 370 | (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape)) |
| 371 | |
| 372 | ;; Do additional setup depending on version of mode requested |
| 373 | (cond ((eq mode 'none) |
| 374 | (setq mouse-avoidance-mode nil)) |
| 375 | ((or (eq mode 'jump) |
| 376 | (eq mode 'animate) |
| 377 | (eq mode 'proteus)) |
| 378 | (setq mouse-avoidance-timer |
| 379 | (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy-hook)) |
| 380 | (setq mouse-avoidance-mode mode |
| 381 | mouse-avoidance-state (cons 0 0) |
| 382 | mouse-avoidance-old-pointer-shape x-pointer-shape)) |
| 383 | ((eq mode 'exile) |
| 384 | (setq mouse-avoidance-timer |
| 385 | (run-with-idle-timer 0.1 t 'mouse-avoidance-exile-hook)) |
| 386 | (setq mouse-avoidance-mode mode |
| 387 | mouse-avoidance-state nil)) |
| 388 | ((or (eq mode 'banish) |
| 389 | (eq mode t) |
| 390 | (and (null mode) (null mouse-avoidance-mode)) |
| 391 | (and mode (> (prefix-numeric-value mode) 0))) |
| 392 | (setq mouse-avoidance-timer |
| 393 | (run-with-idle-timer 0.1 t 'mouse-avoidance-banish-hook)) |
| 394 | (setq mouse-avoidance-mode 'banish)) |
| 395 | (t (setq mouse-avoidance-mode nil))) |
| 396 | (force-mode-line-update)) |
| 397 | |
| 398 | ;; Most people who use avoid mode leave it on all the time, so it's not |
| 399 | ;; very informative to announce it in the mode line. |
| 400 | ;;(or (assq 'mouse-avoidance-mode minor-mode-alist) |
| 401 | ;; (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid") |
| 402 | ;; minor-mode-alist))) |
| 403 | |
| 404 | ;; Needed for custom. |
| 405 | (if mouse-avoidance-mode |
| 406 | (mouse-avoidance-mode mouse-avoidance-mode)) |
| 407 | |
| 408 | ;;; avoid.el ends here |