| 1 | ;;; cc-align.el --- custom indentation functions for CC Mode |
| 2 | |
| 3 | ;; Copyright (C) 1985,1987,1992-2003 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Authors: 1998- Martin Stjernholm |
| 6 | ;; 1992-1999 Barry A. Warsaw |
| 7 | ;; 1987 Dave Detlefs and Stewart Clamen |
| 8 | ;; 1985 Richard M. Stallman |
| 9 | ;; Maintainer: bug-cc-mode@gnu.org |
| 10 | ;; Created: 22-Apr-1997 (split from cc-mode.el) |
| 11 | ;; Version: See cc-mode.el |
| 12 | ;; Keywords: c languages oop |
| 13 | |
| 14 | ;; This file is part of GNU Emacs. |
| 15 | |
| 16 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 17 | ;; it under the terms of the GNU General Public License as published by |
| 18 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 19 | ;; any later version. |
| 20 | |
| 21 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 22 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 23 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 24 | ;; GNU General Public License for more details. |
| 25 | |
| 26 | ;; You should have received a copy of the GNU General Public License |
| 27 | ;; along with GNU Emacs; see the file COPYING. If not, write to |
| 28 | ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330, |
| 29 | ;; Boston, MA 02111-1307, USA. |
| 30 | |
| 31 | ;;; Commentary: |
| 32 | |
| 33 | ;;; Code: |
| 34 | |
| 35 | (eval-when-compile |
| 36 | (let ((load-path |
| 37 | (if (and (boundp 'byte-compile-dest-file) |
| 38 | (stringp byte-compile-dest-file)) |
| 39 | (cons (file-name-directory byte-compile-dest-file) load-path) |
| 40 | load-path))) |
| 41 | (load "cc-bytecomp" nil t))) |
| 42 | |
| 43 | (cc-require 'cc-defs) |
| 44 | (cc-require 'cc-vars) |
| 45 | (cc-require 'cc-engine) |
| 46 | |
| 47 | \f |
| 48 | ;; Standard indentation line-ups |
| 49 | |
| 50 | ;; Calling convention: |
| 51 | ;; |
| 52 | ;; The single argument is a cons cell containing the syntactic symbol |
| 53 | ;; in the car, and the relpos (a.k.a. anchor position) in the cdr. |
| 54 | ;; The cdr may be nil for syntactic symbols which doesn't have an |
| 55 | ;; associated relpos. |
| 56 | ;; |
| 57 | ;; Some syntactic symbols provide more information, usually more |
| 58 | ;; interesting positions. The complete list for the syntactic element |
| 59 | ;; (beginning with the symbol itself) is available in |
| 60 | ;; `c-syntactic-element'. |
| 61 | |
| 62 | (defun c-lineup-topmost-intro-cont (langelem) |
| 63 | "Line up declaration continuation lines zero or one indentation step. |
| 64 | For lines in the \"header\" of a definition, zero is used. For other |
| 65 | lines, `c-basic-offset' is added to the indentation. E.g: |
| 66 | |
| 67 | int |
| 68 | neg (int i) <- c-lineup-topmost-intro-cont |
| 69 | { |
| 70 | return -i; |
| 71 | } |
| 72 | |
| 73 | struct |
| 74 | larch <- c-lineup-topmost-intro-cont |
| 75 | { |
| 76 | double height; |
| 77 | } |
| 78 | the_larch, <- c-lineup-topmost-intro-cont |
| 79 | another_larch; <- c-lineup-topmost-intro-cont |
| 80 | <--> c-basic-offset |
| 81 | |
| 82 | struct larch |
| 83 | the_larch, <- c-lineup-topmost-intro-cont |
| 84 | another_larch; <- c-lineup-topmost-intro-cont |
| 85 | |
| 86 | \(This function is mainly provided to mimic the behavior of CC Mode |
| 87 | 5.28 and earlier where this case wasn't handled consistently so that |
| 88 | these lines could be analyzed as either topmost-intro-cont or |
| 89 | statement-cont.) |
| 90 | |
| 91 | Works with: topmost-intro-cont." |
| 92 | (save-excursion |
| 93 | (beginning-of-line) |
| 94 | (c-backward-syntactic-ws (cdr langelem)) |
| 95 | (if (memq (char-before) '(?} ?,)) |
| 96 | c-basic-offset))) |
| 97 | |
| 98 | (defun c-lineup-arglist (langelem) |
| 99 | "Line up the current argument line under the first argument. |
| 100 | |
| 101 | As a special case, if an argument on the same line as the open |
| 102 | parenthesis starts with a brace block opener, the indentation is |
| 103 | `c-basic-offset' only. This is intended as a \"DWIM\" measure in |
| 104 | cases like macros that contains statement blocks, e.g: |
| 105 | |
| 106 | A_VERY_LONG_MACRO_NAME ({ |
| 107 | some (code, with + long, lines * in[it]); |
| 108 | }); |
| 109 | <--> c-basic-offset |
| 110 | |
| 111 | This is motivated partly because it's more in line with how code |
| 112 | blocks are handled, and partly since it approximates the behavior of |
| 113 | earlier CC Mode versions, which due to inaccurate analysis tended to |
| 114 | indent such cases this way. |
| 115 | |
| 116 | Works with: arglist-cont-nonempty, arglist-close." |
| 117 | (save-excursion |
| 118 | (goto-char (1+ (elt c-syntactic-element 2))) |
| 119 | |
| 120 | ;; Don't stop in the middle of a special brace list opener |
| 121 | ;; like "({". |
| 122 | (when c-special-brace-lists |
| 123 | (let ((special-list (c-looking-at-special-brace-list))) |
| 124 | (when special-list |
| 125 | (goto-char (+ (car (car special-list)) 2))))) |
| 126 | |
| 127 | (let ((savepos (point)) |
| 128 | (eol (c-point 'eol))) |
| 129 | |
| 130 | ;; Find out if an argument on the same line starts with an |
| 131 | ;; unclosed open brace paren. Note similar code in |
| 132 | ;; `c-lineup-close-paren' and |
| 133 | ;; `c-lineup-arglist-close-under-paren'. |
| 134 | (if (and (c-syntactic-re-search-forward "{" eol t t) |
| 135 | (looking-at c-syntactic-eol) |
| 136 | (progn (backward-char) |
| 137 | (not (c-looking-at-special-brace-list))) |
| 138 | (progn (c-backward-syntactic-ws) |
| 139 | (or (= (point) savepos) |
| 140 | (eq (char-before) ?,)))) |
| 141 | c-basic-offset |
| 142 | |
| 143 | ;; Normal case. Indent to the token after the arglist open paren. |
| 144 | (goto-char savepos) |
| 145 | (c-forward-syntactic-ws) |
| 146 | (when (< (point) eol) |
| 147 | (goto-char savepos) |
| 148 | (skip-chars-forward " \t")) |
| 149 | (vector (current-column)))))) |
| 150 | |
| 151 | ;; Contributed by Kevin Ryde <user42@zip.com.au>. |
| 152 | (defun c-lineup-argcont (elem) |
| 153 | "Line up a continued argument. |
| 154 | |
| 155 | foo (xyz, aaa + bbb + ccc |
| 156 | + ddd + eee + fff); <- c-lineup-argcont |
| 157 | |
| 158 | Only continuation lines like this are touched, nil is returned on lines |
| 159 | which are the start of an argument. |
| 160 | |
| 161 | Within a gcc asm block, \":\" is recognised as an argument separator, |
| 162 | but of course only between operand specifications, not in the expressions |
| 163 | for the operands. |
| 164 | |
| 165 | Works with: arglist-cont, arglist-cont-nonempty." |
| 166 | |
| 167 | (save-excursion |
| 168 | (beginning-of-line) |
| 169 | |
| 170 | (when (eq (car elem) 'arglist-cont-nonempty) |
| 171 | ;; Our argument list might not be the innermost one. If it |
| 172 | ;; isn't, go back to the last position in it. We do this by |
| 173 | ;; stepping back over open parens until we get to the open paren |
| 174 | ;; of our argument list. |
| 175 | (let ((open-paren (elt c-syntactic-element 2)) |
| 176 | (paren-state (c-parse-state))) |
| 177 | (while (not (eq (car paren-state) open-paren)) |
| 178 | (goto-char (car paren-state)) |
| 179 | (setq paren-state (cdr paren-state))))) |
| 180 | |
| 181 | (let ((start (point)) c) |
| 182 | |
| 183 | (when (bolp) |
| 184 | ;; Previous line ending in a comma means we're the start of an |
| 185 | ;; argument. This should quickly catch most cases not for us. |
| 186 | ;; This case is only applicable if we're the innermost arglist. |
| 187 | (c-backward-syntactic-ws) |
| 188 | (setq c (char-before))) |
| 189 | |
| 190 | (unless (eq c ?,) |
| 191 | ;; In a gcc asm, ":" on the previous line means the start of an |
| 192 | ;; argument. And lines starting with ":" are not for us, don't |
| 193 | ;; want them to indent to the preceding operand. |
| 194 | (let ((gcc-asm (save-excursion |
| 195 | (goto-char start) |
| 196 | (c-in-gcc-asm-p)))) |
| 197 | (unless (and gcc-asm |
| 198 | (or (eq c ?:) |
| 199 | (save-excursion |
| 200 | (goto-char start) |
| 201 | (looking-at "[ \t]*:")))) |
| 202 | |
| 203 | (c-lineup-argcont-scan (if gcc-asm ?:)) |
| 204 | (vector (current-column)))))))) |
| 205 | |
| 206 | (defun c-lineup-argcont-scan (&optional other-match) |
| 207 | ;; Find the start of an argument, for `c-lineup-argcont'. |
| 208 | (when (zerop (c-backward-token-2 1 t)) |
| 209 | (let ((c (char-after))) |
| 210 | (if (or (eq c ?,) (eq c other-match)) |
| 211 | (progn |
| 212 | (forward-char) |
| 213 | (c-forward-syntactic-ws)) |
| 214 | (c-lineup-argcont-scan other-match))))) |
| 215 | |
| 216 | (defun c-lineup-arglist-intro-after-paren (langelem) |
| 217 | "Line up a line to just after the open paren of the surrounding paren |
| 218 | or brace block. |
| 219 | |
| 220 | Works with: defun-block-intro, brace-list-intro, |
| 221 | statement-block-intro, statement-case-intro, arglist-intro." |
| 222 | (save-excursion |
| 223 | (beginning-of-line) |
| 224 | (backward-up-list 1) |
| 225 | (skip-chars-forward " \t" (c-point 'eol)) |
| 226 | (vector (1+ (current-column))))) |
| 227 | |
| 228 | (defun c-lineup-arglist-close-under-paren (langelem) |
| 229 | "Line up a line under the enclosing open paren. |
| 230 | Normally used to line up a closing paren in the same column as its |
| 231 | corresponding open paren, but can also be used with arglist-cont and |
| 232 | arglist-cont-nonempty to line up all lines inside a parenthesis under |
| 233 | the open paren. |
| 234 | |
| 235 | As a special case, if a brace block is opened at the same line as the |
| 236 | open parenthesis of the argument list, the indentation is |
| 237 | `c-basic-offset' only. See `c-lineup-arglist' for further discussion |
| 238 | of this \"DWIM\" measure. |
| 239 | |
| 240 | Works with: Almost all symbols, but are typically most useful on |
| 241 | arglist-close, brace-list-close, arglist-cont and arglist-cont-nonempty." |
| 242 | (save-excursion |
| 243 | (let (special-list paren-start savepos) |
| 244 | (if (memq (car langelem) '(arglist-cont-nonempty arglist-close)) |
| 245 | (goto-char (elt c-syntactic-element 2)) |
| 246 | (beginning-of-line) |
| 247 | (c-go-up-list-backward)) |
| 248 | |
| 249 | (if (and c-special-brace-lists |
| 250 | (setq special-list (c-looking-at-special-brace-list))) |
| 251 | ;; Don't stop in the middle of a special brace list opener |
| 252 | ;; like "({". |
| 253 | (progn |
| 254 | (setq paren-start (car (car special-list))) |
| 255 | (goto-char (+ paren-start 2))) |
| 256 | (setq paren-start (point)) |
| 257 | (forward-char 1)) |
| 258 | |
| 259 | (setq savepos (point)) |
| 260 | ;; Find out if an argument on the same line starts with an |
| 261 | ;; unclosed open brace paren. Note similar code in |
| 262 | ;; `c-lineup-arglist' and `c-lineup-close-paren'. |
| 263 | (if (and (c-syntactic-re-search-forward "{" (c-point 'eol) t t) |
| 264 | (looking-at c-syntactic-eol) |
| 265 | (progn (backward-char) |
| 266 | (not (c-looking-at-special-brace-list))) |
| 267 | (progn (c-backward-syntactic-ws) |
| 268 | (or (= (point) savepos) |
| 269 | (eq (char-before) ?,)))) |
| 270 | c-basic-offset |
| 271 | |
| 272 | ;; Normal case. Indent to the arglist open paren. |
| 273 | (goto-char paren-start) |
| 274 | (vector (current-column)))))) |
| 275 | |
| 276 | (defun c-lineup-arglist-operators (langelem) |
| 277 | "Line up lines starting with an infix operator under the open paren. |
| 278 | Return nil on lines that don't start with an operator, to leave those |
| 279 | cases to other lineup functions. Example: |
| 280 | |
| 281 | if ( x < 10 |
| 282 | || at_limit (x, <- c-lineup-arglist-operators |
| 283 | list) <- c-lineup-arglist-operators returns nil |
| 284 | ) |
| 285 | |
| 286 | Since this function doesn't do anything for lines without an infix |
| 287 | operator you typically want to use it together with some other lineup |
| 288 | settings, e.g. as follows \(the arglist-close setting is just a |
| 289 | suggestion to get a consistent style): |
| 290 | |
| 291 | \(c-set-offset 'arglist-cont '(c-lineup-arglist-operators 0)) |
| 292 | \(c-set-offset 'arglist-cont-nonempty '(c-lineup-arglist-operators |
| 293 | c-lineup-arglist)) |
| 294 | \(c-set-offset 'arglist-close '(c-lineup-arglist-close-under-paren)) |
| 295 | |
| 296 | Works with: arglist-cont, arglist-cont-nonempty." |
| 297 | (save-excursion |
| 298 | (back-to-indentation) |
| 299 | (when (looking-at "[-+|&*%<>=]\\|\\(/[^/*]\\)") |
| 300 | ;; '-' can be both an infix and a prefix operator, but I'm lazy now.. |
| 301 | (c-lineup-arglist-close-under-paren langelem)))) |
| 302 | |
| 303 | (defun c-lineup-close-paren (langelem) |
| 304 | "Line up the closing paren under its corresponding open paren if the |
| 305 | open paren is followed by code. If the open paren ends its line, no |
| 306 | indentation is added. E.g: |
| 307 | |
| 308 | main (int, main ( |
| 309 | char ** int, char ** |
| 310 | ) <-> ) <- c-lineup-close-paren |
| 311 | |
| 312 | As a special case, if a brace block is opened at the same line as the |
| 313 | open parenthesis of the argument list, the indentation is |
| 314 | `c-basic-offset' instead of the open paren column. See |
| 315 | `c-lineup-arglist' for further discussion of this \"DWIM\" measure. |
| 316 | |
| 317 | Works with: All *-close symbols." |
| 318 | (save-excursion |
| 319 | (beginning-of-line) |
| 320 | (c-go-up-list-backward) |
| 321 | |
| 322 | (let ((spec (c-looking-at-special-brace-list)) savepos argstart) |
| 323 | (if spec (goto-char (car (car spec)))) |
| 324 | (setq savepos (point)) |
| 325 | (forward-char 1) |
| 326 | (when spec |
| 327 | (c-forward-syntactic-ws) |
| 328 | (forward-char 1)) |
| 329 | |
| 330 | (if (looking-at c-syntactic-eol) |
| 331 | ;; The arglist is "empty". |
| 332 | 0 |
| 333 | |
| 334 | ;; Find out if an argument on the same line starts with an |
| 335 | ;; unclosed open brace paren. Note similar code in |
| 336 | ;; `c-lineup-arglist' and |
| 337 | ;; `c-lineup-arglist-close-under-paren'. |
| 338 | (setq argstart (point)) |
| 339 | (if (and (c-syntactic-re-search-forward "{" (c-point 'eol) t t) |
| 340 | (looking-at c-syntactic-eol) |
| 341 | (progn (backward-char) |
| 342 | (not (c-looking-at-special-brace-list))) |
| 343 | (progn (c-backward-syntactic-ws) |
| 344 | (or (= (point) argstart) |
| 345 | (eq (char-before) ?,)))) |
| 346 | c-basic-offset |
| 347 | |
| 348 | ;; Normal case. Indent to the arglist open paren. |
| 349 | (goto-char savepos) |
| 350 | (vector (current-column))))))) |
| 351 | |
| 352 | (defun c-lineup-streamop (langelem) |
| 353 | "Line up C++ stream operators under each other. |
| 354 | |
| 355 | Works with: stream-op." |
| 356 | (save-excursion |
| 357 | (goto-char (cdr langelem)) |
| 358 | (re-search-forward "<<\\|>>" (c-point 'eol) 'move) |
| 359 | (goto-char (match-beginning 0)) |
| 360 | (vector (current-column)))) |
| 361 | |
| 362 | (defun c-lineup-multi-inher (langelem) |
| 363 | "Line up the classes in C++ multiple inheritance clauses and member |
| 364 | initializers under each other. E.g: |
| 365 | |
| 366 | class Foo: Foo::Foo (int a, int b): |
| 367 | public Cyphr, Cyphr (a), |
| 368 | public Bar <-> Bar (b) <- c-lineup-multi-inher |
| 369 | |
| 370 | class Foo Foo::Foo (int a, int b) |
| 371 | : public Cyphr, : Cyphr (a), |
| 372 | public Bar <-> Bar (b) <- c-lineup-multi-inher |
| 373 | |
| 374 | class Foo Foo::Foo (int a, int b) |
| 375 | : public Cyphr : Cyphr (a) |
| 376 | , public Bar <-> , Bar (b) <- c-lineup-multi-inher |
| 377 | |
| 378 | Works with: inher-cont, member-init-cont." |
| 379 | (save-excursion |
| 380 | (back-to-indentation) |
| 381 | (let* ((eol (c-point 'eol)) |
| 382 | (here (point)) |
| 383 | (char-after-ip (progn |
| 384 | (skip-chars-forward " \t") |
| 385 | (char-after)))) |
| 386 | (if (cdr langelem) (goto-char (cdr langelem))) |
| 387 | |
| 388 | ;; This kludge is necessary to support both inher-cont and |
| 389 | ;; member-init-cont, since they have different anchor positions. |
| 390 | (c-backward-syntactic-ws) |
| 391 | (when (eq (char-before) ?:) |
| 392 | (backward-char) |
| 393 | (c-backward-syntactic-ws)) |
| 394 | |
| 395 | (skip-chars-forward "^:" eol) |
| 396 | (if (eq char-after-ip ?,) |
| 397 | (skip-chars-forward " \t" eol) |
| 398 | (skip-chars-forward " \t:" eol)) |
| 399 | (if (or (eolp) |
| 400 | (looking-at c-comment-start-regexp)) |
| 401 | (c-forward-syntactic-ws here)) |
| 402 | (if (< (point) here) |
| 403 | (vector (current-column))) |
| 404 | ))) |
| 405 | |
| 406 | (defun c-lineup-java-inher (langelem) |
| 407 | "Line up Java implements and extends declarations. |
| 408 | If class names follow on the same line as the implements/extends |
| 409 | keyword, they are lined up under each other. Otherwise, they are |
| 410 | indented by adding `c-basic-offset' to the column of the keyword. |
| 411 | E.g: |
| 412 | |
| 413 | class Foo class Foo |
| 414 | extends extends Cyphr, |
| 415 | Bar <-> Bar <- c-lineup-java-inher |
| 416 | <--> c-basic-offset |
| 417 | |
| 418 | Works with: inher-cont." |
| 419 | (save-excursion |
| 420 | (goto-char (cdr langelem)) |
| 421 | (forward-word 1) |
| 422 | (if (looking-at "[ \t]*$") |
| 423 | c-basic-offset |
| 424 | (c-forward-syntactic-ws) |
| 425 | (vector (current-column))))) |
| 426 | |
| 427 | (defun c-lineup-java-throws (langelem) |
| 428 | "Line up Java throws declarations. |
| 429 | If exception names follow on the same line as the throws keyword, |
| 430 | they are lined up under each other. Otherwise, they are indented by |
| 431 | adding `c-basic-offset' to the column of the throws keyword. The |
| 432 | throws keyword itself is also indented by `c-basic-offset' from the |
| 433 | function declaration start if it doesn't hang. E.g: |
| 434 | |
| 435 | int foo() int foo() throws Cyphr, |
| 436 | throws <-> Bar, <- c-lineup-java-throws |
| 437 | Bar <-> Vlod <- c-lineup-java-throws |
| 438 | <--><--> c-basic-offset |
| 439 | |
| 440 | Works with: func-decl-cont." |
| 441 | (save-excursion |
| 442 | (let* ((lim (1- (c-point 'bol))) |
| 443 | (throws (catch 'done |
| 444 | (goto-char (cdr langelem)) |
| 445 | (while (zerop (c-forward-token-2 1 t lim)) |
| 446 | (if (looking-at "throws\\>[^_]") |
| 447 | (throw 'done t)))))) |
| 448 | (if throws |
| 449 | (if (zerop (c-forward-token-2 1 nil (c-point 'eol))) |
| 450 | (vector (current-column)) |
| 451 | (back-to-indentation) |
| 452 | (vector (+ (current-column) c-basic-offset))) |
| 453 | c-basic-offset)))) |
| 454 | |
| 455 | (defun c-indent-one-line-block (langelem) |
| 456 | "Indent a one line block `c-basic-offset' extra. |
| 457 | E.g: |
| 458 | |
| 459 | if (n > 0) if (n > 0) |
| 460 | {m+=n; n=0;} <-> { <- c-indent-one-line-block |
| 461 | <--> c-basic-offset m+=n; n=0; |
| 462 | } |
| 463 | |
| 464 | The block may use any kind of parenthesis character. nil is returned |
| 465 | if the line doesn't start with a one line block, which makes the |
| 466 | function usable in list expressions. |
| 467 | |
| 468 | Work with: Almost all syntactic symbols, but most useful on *-open." |
| 469 | (save-excursion |
| 470 | (let ((eol (c-point 'eol))) |
| 471 | (back-to-indentation) |
| 472 | (if (and (eq (char-syntax (char-after)) ?\() |
| 473 | (c-safe (progn (c-forward-sexp) t)) |
| 474 | (<= (point) eol)) |
| 475 | c-basic-offset |
| 476 | nil)))) |
| 477 | |
| 478 | (defun c-indent-multi-line-block (langelem) |
| 479 | "Indent a multi line block `c-basic-offset' extra. |
| 480 | E.g: |
| 481 | |
| 482 | int *foo[] = { int *foo[] = { |
| 483 | NULL, NULL, |
| 484 | {17}, <-> { <- c-indent-multi-line-block |
| 485 | 17 |
| 486 | } |
| 487 | <--> c-basic-offset |
| 488 | |
| 489 | The block may use any kind of parenthesis character. nil is returned |
| 490 | if the line doesn't start with a multi line block, which makes the |
| 491 | function usable in list expressions. |
| 492 | |
| 493 | Work with: Almost all syntactic symbols, but most useful on *-open." |
| 494 | (save-excursion |
| 495 | (let ((eol (c-point 'eol))) |
| 496 | (back-to-indentation) |
| 497 | (if (and (eq (char-syntax (char-after)) ?\() |
| 498 | (or (not (c-safe (progn (c-forward-sexp) t))) |
| 499 | (> (point) eol))) |
| 500 | c-basic-offset |
| 501 | nil)))) |
| 502 | |
| 503 | (defun c-lineup-C-comments (langelem) |
| 504 | "Line up C block comment continuation lines. |
| 505 | Various heuristics are used to handle many of the common comment |
| 506 | styles. Some examples: |
| 507 | |
| 508 | /* /** /* /* text /* /** |
| 509 | * text * text text text ** text ** text |
| 510 | */ */ */ */ */ */ |
| 511 | |
| 512 | /********************************************************************* |
| 513 | * text |
| 514 | ********************************************************************/ |
| 515 | |
| 516 | /********************************************************************* |
| 517 | Free form text comments: |
| 518 | In comments with a long delimiter line at the start, the indentation |
| 519 | is kept unchanged for lines that start with an empty comment line |
| 520 | prefix. The delimiter line is whatever matches the |
| 521 | `comment-start-skip' regexp. |
| 522 | *********************************************************************/ |
| 523 | |
| 524 | The variable `c-comment-prefix-regexp' is used to recognize the |
| 525 | comment line prefix, e.g. the `*' that usually starts every line |
| 526 | inside a comment. |
| 527 | |
| 528 | Works with: The `c' syntactic symbol." |
| 529 | (save-excursion |
| 530 | (let* ((here (point)) |
| 531 | (prefixlen (progn (back-to-indentation) |
| 532 | (if (looking-at c-current-comment-prefix) |
| 533 | (- (match-end 0) (point)) |
| 534 | 0))) |
| 535 | (starterlen |
| 536 | ;; Get the length of the comment starter, not including |
| 537 | ;; the first '/'. We check if the comment prefix matched |
| 538 | ;; on the current line matches the starter or if it |
| 539 | ;; matches comment-start-skip, and choose whichever is |
| 540 | ;; longest. |
| 541 | (max (save-excursion |
| 542 | (goto-char (1+ (cdr langelem))) |
| 543 | (if (and (match-string 0) |
| 544 | (looking-at (regexp-quote (match-string 0)))) |
| 545 | (- (match-end 0) (match-beginning 0)) |
| 546 | 0)) |
| 547 | (save-excursion |
| 548 | (goto-char (cdr langelem)) |
| 549 | (looking-at comment-start-skip) |
| 550 | (- (or (match-end 1) |
| 551 | (save-excursion |
| 552 | (goto-char (match-end 0)) |
| 553 | (skip-chars-backward " \t") |
| 554 | (point))) |
| 555 | (point) |
| 556 | 1))))) |
| 557 | (if (and (> starterlen 10) (zerop prefixlen)) |
| 558 | ;; The comment has a long starter and the line doesn't have |
| 559 | ;; a nonempty comment prefix. Treat it as free form text |
| 560 | ;; and don't change the indentation. |
| 561 | (vector (current-column)) |
| 562 | (forward-line -1) |
| 563 | (back-to-indentation) |
| 564 | (if (>= (cdr langelem) (point)) |
| 565 | ;; On the second line in the comment. |
| 566 | (if (zerop prefixlen) |
| 567 | ;; No nonempty comment prefix. Align after comment |
| 568 | ;; starter. |
| 569 | (progn |
| 570 | (goto-char (match-end 0)) |
| 571 | ;; The following should not be necessary, since |
| 572 | ;; comment-start-skip should match everything (i.e. |
| 573 | ;; typically whitespace) that leads up to the text. |
| 574 | ;;(if (looking-at "\\([ \t]+\\).+$") |
| 575 | ;; ;; Align with the text that hangs after the |
| 576 | ;; ;; comment starter. |
| 577 | ;; (goto-char (match-end 1))) |
| 578 | (vector (current-column))) |
| 579 | ;; How long is the comment starter? if greater than the |
| 580 | ;; length of the comment prefix, align left. if less |
| 581 | ;; than or equal, align right. this should also pick up |
| 582 | ;; Javadoc style comments. |
| 583 | (if (> starterlen prefixlen) |
| 584 | (progn |
| 585 | (goto-char (cdr langelem)) |
| 586 | (vector (1+ (current-column)))) |
| 587 | (goto-char (+ (cdr langelem) starterlen 1)) |
| 588 | (vector (- (current-column) prefixlen)))) |
| 589 | ;; Not on the second line in the comment. If the previous |
| 590 | ;; line has a nonempty comment prefix, align with it. |
| 591 | ;; Otherwise, align with the previous nonempty line, but |
| 592 | ;; align the comment ender with the starter. |
| 593 | (when (or (not (looking-at c-current-comment-prefix)) |
| 594 | (eq (match-beginning 0) (match-end 0))) |
| 595 | (goto-char here) |
| 596 | (back-to-indentation) |
| 597 | (if (looking-at (concat "\\(" c-current-comment-prefix "\\)\\*/")) |
| 598 | (goto-char (cdr langelem)) |
| 599 | (while (and (zerop (forward-line -1)) |
| 600 | (looking-at "^[ \t]*$"))) |
| 601 | (back-to-indentation) |
| 602 | (if (< (point) (cdr langelem)) |
| 603 | ;; Align with the comment starter rather than |
| 604 | ;; with the code before it. |
| 605 | (goto-char (cdr langelem))))) |
| 606 | (vector (current-column))))))) |
| 607 | |
| 608 | (defun c-lineup-comment (langelem) |
| 609 | "Line up a comment start according to `c-comment-only-line-offset'. |
| 610 | If the comment is lined up with a comment starter on the previous |
| 611 | line, that alignment is preserved. |
| 612 | |
| 613 | Works with: comment-intro." |
| 614 | (save-excursion |
| 615 | (back-to-indentation) |
| 616 | (let ((col (current-column))) |
| 617 | (cond |
| 618 | ;; CASE 1: preserve aligned comments |
| 619 | ((save-excursion |
| 620 | (and (c-backward-single-comment) |
| 621 | (= col (current-column)))) |
| 622 | (vector col)) ; Return an absolute column. |
| 623 | ;; indent as specified by c-comment-only-line-offset |
| 624 | ((not (bolp)) |
| 625 | (or (car-safe c-comment-only-line-offset) |
| 626 | c-comment-only-line-offset)) |
| 627 | (t |
| 628 | (or (cdr-safe c-comment-only-line-offset) |
| 629 | (car-safe c-comment-only-line-offset) |
| 630 | -1000)) ;jam it against the left side |
| 631 | )))) |
| 632 | |
| 633 | (defun c-lineup-knr-region-comment (langelem) |
| 634 | "Line up a comment in the \"K&R region\" with the declaration. |
| 635 | That is the region between the function or class header and the |
| 636 | beginning of the block. E.g: |
| 637 | |
| 638 | int main() |
| 639 | /* This is the main function. */ <- c-lineup-knr-region-comment |
| 640 | { |
| 641 | return 0; |
| 642 | } |
| 643 | |
| 644 | Return nil if called in any other situation, to be useful in list |
| 645 | expressions. |
| 646 | |
| 647 | Works with: comment-intro." |
| 648 | (when (or (assq 'topmost-intro-cont c-syntactic-context) |
| 649 | (assq 'func-decl-cont c-syntactic-context) |
| 650 | (assq 'knr-argdecl-intro c-syntactic-context) |
| 651 | (assq 'lambda-intro-cont c-syntactic-context)) |
| 652 | (save-excursion |
| 653 | (beginning-of-line) |
| 654 | (c-beginning-of-statement-1) |
| 655 | (vector (current-column))))) |
| 656 | |
| 657 | (defun c-lineup-runin-statements (langelem) |
| 658 | "Line up statements when the first statement is on the same line as |
| 659 | the block opening brace. E.g: |
| 660 | |
| 661 | int main() |
| 662 | { puts (\"Hello world!\"); |
| 663 | return 0; <- c-lineup-runin-statements |
| 664 | } |
| 665 | |
| 666 | If there is no statement after the opening brace to align with, nil is |
| 667 | returned. This makes the function usable in list expressions. |
| 668 | |
| 669 | Works with: The `statement' syntactic symbol." |
| 670 | (if (eq (char-after (cdr langelem)) ?{) |
| 671 | (save-excursion |
| 672 | (if (cdr langelem) (goto-char (cdr langelem))) |
| 673 | (forward-char 1) |
| 674 | (skip-chars-forward " \t") |
| 675 | (unless (eolp) |
| 676 | (vector (current-column)))))) |
| 677 | |
| 678 | (defun c-lineup-math (langelem) |
| 679 | "Line up the current line after the equal sign on the first line in |
| 680 | the statement. If there isn't any, indent with `c-basic-offset'. If |
| 681 | the current line contains an equal sign too, try to align it with the |
| 682 | first one. |
| 683 | |
| 684 | Works with: topmost-intro-cont, statement-cont, arglist-cont, |
| 685 | arglist-cont-nonempty." |
| 686 | (let (startpos endpos equalp) |
| 687 | |
| 688 | (if (eq (car langelem) 'arglist-cont-nonempty) |
| 689 | ;; If it's an arglist-cont-nonempty then we're only interested |
| 690 | ;; in equal signs outside it. We don't search for a "=" on |
| 691 | ;; the current line since that'd have a different nesting |
| 692 | ;; compared to the one we should align with. |
| 693 | (save-excursion |
| 694 | (save-restriction |
| 695 | (setq endpos (nth 2 c-syntactic-element)) |
| 696 | (narrow-to-region (cdr langelem) endpos) |
| 697 | (if (setq startpos (c-up-list-backward endpos)) |
| 698 | (setq startpos (1+ startpos)) |
| 699 | (setq startpos (cdr langelem))))) |
| 700 | |
| 701 | (setq startpos (cdr langelem) |
| 702 | endpos (point)) |
| 703 | |
| 704 | ;; Find a syntactically relevant and unnested "=" token on the |
| 705 | ;; current line. equalp is in that case set to the number of |
| 706 | ;; columns to left shift the current line to align it with the |
| 707 | ;; goal column. |
| 708 | (save-excursion |
| 709 | (beginning-of-line) |
| 710 | (when (c-syntactic-re-search-forward |
| 711 | c-assignment-op-regexp |
| 712 | (c-point 'eol) t t t) |
| 713 | (setq equalp (- (or (match-beginning 1) |
| 714 | (match-end 0)) |
| 715 | (c-point 'boi)))))) |
| 716 | |
| 717 | (save-excursion |
| 718 | (goto-char startpos) |
| 719 | (if (or (if (c-syntactic-re-search-forward |
| 720 | c-assignment-op-regexp |
| 721 | (min endpos (c-point 'eol)) t t t) |
| 722 | (progn |
| 723 | (goto-char (or (match-beginning 1) |
| 724 | (match-end 0))) |
| 725 | nil) |
| 726 | t) |
| 727 | (save-excursion |
| 728 | (c-forward-syntactic-ws (c-point 'eol)) |
| 729 | (eolp))) |
| 730 | ;; There's no equal sign on the line, or there is one but |
| 731 | ;; nothing follows it. |
| 732 | c-basic-offset |
| 733 | |
| 734 | ;; calculate indentation column after equals and ws, unless |
| 735 | ;; our line contains an equals sign |
| 736 | (if (not equalp) |
| 737 | (progn |
| 738 | (skip-chars-forward " \t") |
| 739 | (setq equalp 0))) |
| 740 | |
| 741 | (vector (- (current-column) equalp))) |
| 742 | ))) |
| 743 | |
| 744 | (defun c-lineup-cascaded-calls (langelem) |
| 745 | "Line up \"cascaded calls\" under each other. |
| 746 | If the line begins with \"->\" or \".\" and the preceding line ends |
| 747 | with one or more function calls preceded by the same token, then the |
| 748 | arrow is lined up with the first of those tokens. E.g: |
| 749 | |
| 750 | result = proc->add(17)->add(18) |
| 751 | ->add(19) + <- c-lineup-cascaded-calls |
| 752 | offset; <- c-lineup-cascaded-calls (inactive) |
| 753 | |
| 754 | In any other situation nil is returned to allow use in list |
| 755 | expressions. |
| 756 | |
| 757 | Works with: topmost-intro-cont, statement-cont, arglist-cont, |
| 758 | arglist-cont-nonempty." |
| 759 | |
| 760 | (if (and (eq (car langelem) 'arglist-cont-nonempty) |
| 761 | (not (eq (nth 2 c-syntactic-element) |
| 762 | (c-most-enclosing-brace (c-parse-state))))) |
| 763 | ;; The innermost open paren is not our one, so don't do |
| 764 | ;; anything. This can occur for arglist-cont-nonempty with |
| 765 | ;; nested arglist starts on the same line. |
| 766 | nil |
| 767 | |
| 768 | (save-excursion |
| 769 | (back-to-indentation) |
| 770 | (let ((operator (and (looking-at "->\\|\\.") |
| 771 | (regexp-quote (match-string 0)))) |
| 772 | (stmt-start (cdr langelem)) col) |
| 773 | |
| 774 | (when (and operator |
| 775 | (looking-at operator) |
| 776 | (zerop (c-backward-token-2 1 t stmt-start)) |
| 777 | (eq (char-after) ?\() |
| 778 | (zerop (c-backward-token-2 2 t stmt-start)) |
| 779 | (looking-at operator)) |
| 780 | (setq col (current-column)) |
| 781 | |
| 782 | (while (and (zerop (c-backward-token-2 1 t stmt-start)) |
| 783 | (eq (char-after) ?\() |
| 784 | (zerop (c-backward-token-2 2 t stmt-start)) |
| 785 | (looking-at operator)) |
| 786 | (setq col (current-column))) |
| 787 | |
| 788 | (vector col)))))) |
| 789 | |
| 790 | (defun c-lineup-string-cont (langelem) |
| 791 | "Line up a continued string under the one it continues. |
| 792 | A continued string in this sense is where a string literal follows |
| 793 | directly after another one. E.g: |
| 794 | |
| 795 | result = prefix + \"A message \" |
| 796 | \"string.\"; <- c-lineup-string-cont |
| 797 | |
| 798 | Nil is returned in other situations, to allow stacking with other |
| 799 | lineup functions. |
| 800 | |
| 801 | Works with: topmost-intro-cont, statement-cont, arglist-cont, |
| 802 | arglist-cont-nonempty." |
| 803 | (save-excursion |
| 804 | (back-to-indentation) |
| 805 | (and (looking-at "\\s\"") |
| 806 | (let ((quote (char-after)) pos) |
| 807 | (while (and (progn (c-backward-syntactic-ws) |
| 808 | (eq (char-before) quote)) |
| 809 | (c-safe (c-backward-sexp) t) |
| 810 | (/= (setq pos (point)) (c-point 'boi)))) |
| 811 | (when pos |
| 812 | (goto-char pos) |
| 813 | (vector (current-column))))))) |
| 814 | |
| 815 | (defun c-lineup-template-args (langelem) |
| 816 | "Line up template argument lines under the first argument. |
| 817 | To allow this function to be used in a list expression, nil is |
| 818 | returned if there's no template argument on the first line. |
| 819 | |
| 820 | Works with: template-args-cont." |
| 821 | (save-excursion |
| 822 | (c-with-syntax-table c++-template-syntax-table |
| 823 | (beginning-of-line) |
| 824 | (backward-up-list 1) |
| 825 | (if (and (eq (char-after) ?<) |
| 826 | (zerop (c-forward-token-2 1 nil (c-point 'eol)))) |
| 827 | (vector (current-column)))))) |
| 828 | |
| 829 | (defun c-lineup-ObjC-method-call (langelem) |
| 830 | "Line up selector args as Emacs Lisp mode does with function args: |
| 831 | Go to the position right after the message receiver, and if you are at |
| 832 | the end of the line, indent the current line c-basic-offset columns |
| 833 | from the opening bracket; otherwise you are looking at the first |
| 834 | character of the first method call argument, so lineup the current |
| 835 | line with it. |
| 836 | |
| 837 | Works with: objc-method-call-cont." |
| 838 | (save-excursion |
| 839 | (let* ((extra (save-excursion |
| 840 | (back-to-indentation) |
| 841 | (c-backward-syntactic-ws (cdr langelem)) |
| 842 | (if (eq (char-before) ?:) |
| 843 | (- c-basic-offset) |
| 844 | 0))) |
| 845 | (open-bracket-pos (cdr langelem)) |
| 846 | (open-bracket-col (progn |
| 847 | (goto-char open-bracket-pos) |
| 848 | (current-column))) |
| 849 | (target-col (progn |
| 850 | (forward-char) |
| 851 | (c-forward-sexp) |
| 852 | (skip-chars-forward " \t") |
| 853 | (if (eolp) |
| 854 | (+ open-bracket-col c-basic-offset) |
| 855 | (current-column)))) |
| 856 | ) |
| 857 | (- target-col open-bracket-col extra)))) |
| 858 | |
| 859 | (defun c-lineup-ObjC-method-args (langelem) |
| 860 | "Line up the colons that separate args. |
| 861 | The colon on the current line is aligned with the one on the first |
| 862 | line. |
| 863 | |
| 864 | Works with: objc-method-args-cont." |
| 865 | (save-excursion |
| 866 | (let* ((here (c-point 'boi)) |
| 867 | (curcol (progn (goto-char here) (current-column))) |
| 868 | (eol (c-point 'eol)) |
| 869 | (relpos (cdr langelem)) |
| 870 | (first-col-column (progn |
| 871 | (goto-char relpos) |
| 872 | (skip-chars-forward "^:" eol) |
| 873 | (and (eq (char-after) ?:) |
| 874 | (current-column))))) |
| 875 | (if (not first-col-column) |
| 876 | c-basic-offset |
| 877 | (goto-char here) |
| 878 | (skip-chars-forward "^:" eol) |
| 879 | (if (eq (char-after) ?:) |
| 880 | (+ curcol (- first-col-column (current-column))) |
| 881 | c-basic-offset))))) |
| 882 | |
| 883 | (defun c-lineup-ObjC-method-args-2 (langelem) |
| 884 | "Line up the colons that separate args. |
| 885 | The colon on the current line is aligned with the one on the previous |
| 886 | line. |
| 887 | |
| 888 | Works with: objc-method-args-cont." |
| 889 | (save-excursion |
| 890 | (let* ((here (c-point 'boi)) |
| 891 | (curcol (progn (goto-char here) (current-column))) |
| 892 | (eol (c-point 'eol)) |
| 893 | (relpos (cdr langelem)) |
| 894 | (prev-col-column (progn |
| 895 | (skip-chars-backward "^:" relpos) |
| 896 | (and (eq (char-before) ?:) |
| 897 | (- (current-column) 1))))) |
| 898 | (if (not prev-col-column) |
| 899 | c-basic-offset |
| 900 | (goto-char here) |
| 901 | (skip-chars-forward "^:" eol) |
| 902 | (if (eq (char-after) ?:) |
| 903 | (+ curcol (- prev-col-column (current-column))) |
| 904 | c-basic-offset))))) |
| 905 | |
| 906 | (defun c-lineup-inexpr-block (langelem) |
| 907 | "Line up the block for constructs that use a block inside an expression, |
| 908 | e.g. anonymous classes in Java and lambda functions in Pike. The body |
| 909 | is aligned with the start of the header, e.g. with the \"new\" or |
| 910 | \"lambda\" keyword. Returns nil if the block isn't part of such a |
| 911 | construct. |
| 912 | |
| 913 | Works with: inlambda, inexpr-statement, inexpr-class." |
| 914 | (save-excursion |
| 915 | (back-to-indentation) |
| 916 | (let* ((paren-state (c-parse-state)) |
| 917 | (containing-sexp (c-most-enclosing-brace paren-state)) |
| 918 | (res (or (c-looking-at-inexpr-block |
| 919 | (c-safe-position containing-sexp paren-state) |
| 920 | containing-sexp) |
| 921 | (and containing-sexp |
| 922 | (progn (goto-char containing-sexp) |
| 923 | (eq (char-after) ?{)) |
| 924 | (progn (setq containing-sexp |
| 925 | (c-most-enclosing-brace paren-state |
| 926 | (point))) |
| 927 | (c-looking-at-inexpr-block |
| 928 | (c-safe-position containing-sexp paren-state) |
| 929 | containing-sexp)))))) |
| 930 | (when res |
| 931 | (goto-char (cdr res)) |
| 932 | (- (current-column) |
| 933 | (progn |
| 934 | (back-to-indentation) |
| 935 | (current-column))))))) |
| 936 | |
| 937 | (defun c-lineup-whitesmith-in-block (langelem) |
| 938 | "Line up lines inside a block in whitesmith style. |
| 939 | It's done in a way that works both when the opening brace hangs and |
| 940 | when it doesn't. E.g: |
| 941 | |
| 942 | something |
| 943 | { something { |
| 944 | foo; <-> foo; <- c-lineup-whitesmith-in-block |
| 945 | } } |
| 946 | <--> c-basic-offset |
| 947 | |
| 948 | In the first case the indentation is kept unchanged, in the |
| 949 | second `c-basic-offset' is added. |
| 950 | |
| 951 | Works with: defun-close, defun-block-intro, block-close, |
| 952 | brace-list-close, brace-list-intro, statement-block-intro and all in* |
| 953 | symbols, e.g. inclass and inextern-lang." |
| 954 | (save-excursion |
| 955 | (goto-char (cdr langelem)) |
| 956 | (back-to-indentation) |
| 957 | (if (eq (char-syntax (char-after)) ?\() |
| 958 | 0 |
| 959 | c-basic-offset))) |
| 960 | |
| 961 | (defun c-lineup-cpp-define (langelem) |
| 962 | "Line up macro continuation lines according to the indentation of |
| 963 | the construct preceding the macro. E.g: |
| 964 | |
| 965 | v beg of preceding constr v beg of preceding constr |
| 966 | int dribble() { |
| 967 | const char msg[] = if (!running) |
| 968 | \"Some text.\"; error(\"Not running!\"); |
| 969 | |
| 970 | #define X(A, B) \ #define X(A, B) \ |
| 971 | do { \ <-> do { \ <- c-lineup-cpp-define |
| 972 | printf (A, B); \ printf (A, B); \ |
| 973 | } while (0) } while (0) |
| 974 | |
| 975 | If `c-syntactic-indentation-in-macros' is non-nil, the function |
| 976 | returns the relative indentation to the macro start line to allow |
| 977 | accumulation with other offsets. E.g. in the following cases, |
| 978 | cpp-define-intro is combined with the statement-block-intro that comes |
| 979 | from the \"do {\" that hangs on the \"#define\" line: |
| 980 | |
| 981 | int dribble() { |
| 982 | const char msg[] = if (!running) |
| 983 | \"Some text.\"; error(\"Not running!\"); |
| 984 | |
| 985 | #define X(A, B) do { \ #define X(A, B) do { \ |
| 986 | printf (A, B); \ <-> printf (A, B); \ <- c-lineup-cpp-define |
| 987 | this->refs++; \ this->refs++; \ |
| 988 | } while (0) <-> } while (0) <- c-lineup-cpp-define |
| 989 | |
| 990 | The relative indentation returned by `c-lineup-cpp-define' is zero and |
| 991 | two, respectively, in these two examples. They are then added to the |
| 992 | two column indentation that statement-block-intro gives in both cases |
| 993 | here. |
| 994 | |
| 995 | If the relative indentation is zero, then nil is returned instead. |
| 996 | That is useful in a list expression to specify the default indentation |
| 997 | on the top level. |
| 998 | |
| 999 | If `c-syntactic-indentation-in-macros' is nil then this function keeps |
| 1000 | the current indentation, except for empty lines \(ignoring the ending |
| 1001 | backslash) where it takes the indentation from the closest preceding |
| 1002 | nonempty line in the macro. If there's no such line in the macro then |
| 1003 | the indentation is taken from the construct preceding it, as described |
| 1004 | above. |
| 1005 | |
| 1006 | Works with: cpp-define-intro." |
| 1007 | (let (offset) |
| 1008 | (if c-syntactic-indentation-in-macros |
| 1009 | ;; Go to the macro start and do a syntactic analysis of it. |
| 1010 | ;; Then remove the cpp-macro element it should contain and |
| 1011 | ;; calculate the indentation it then would get. |
| 1012 | (save-excursion |
| 1013 | (c-beginning-of-macro) |
| 1014 | (setq offset (- (c-get-syntactic-indentation |
| 1015 | (delete '(cpp-macro) (c-guess-basic-syntax))) |
| 1016 | (save-excursion |
| 1017 | (back-to-indentation) |
| 1018 | (current-column)))) |
| 1019 | (if (zerop offset) |
| 1020 | nil |
| 1021 | offset)) |
| 1022 | ;; Do not indent syntactically inside the macro. |
| 1023 | (save-excursion |
| 1024 | (let ((macro-start-line (save-excursion |
| 1025 | (goto-char (c-query-macro-start)) |
| 1026 | (beginning-of-line) |
| 1027 | (point)))) |
| 1028 | (beginning-of-line) |
| 1029 | ;; Check every line while inside the macro. |
| 1030 | (while (and (> (point) macro-start-line) |
| 1031 | (looking-at "[ \t]*\\\\?$") |
| 1032 | (= (forward-line -1) 0))) |
| 1033 | (if (<= (point) macro-start-line) |
| 1034 | ;; If we've stepped out of the macro we take the |
| 1035 | ;; syntactic offset. |
| 1036 | (setq offset (c-get-syntactic-indentation |
| 1037 | (delete '(cpp-macro) (c-guess-basic-syntax)))) |
| 1038 | (setq offset (current-indentation))) |
| 1039 | (if (zerop offset) |
| 1040 | nil |
| 1041 | (vector offset))))))) |
| 1042 | |
| 1043 | ;; Contributed by Kevin Ryde <user42@zip.com.au>. |
| 1044 | (defun c-lineup-gcc-asm-reg (elem) |
| 1045 | "Line up a gcc asm register under one on a previous line. |
| 1046 | |
| 1047 | asm (\"foo %1, %0\\n\" |
| 1048 | \"bar %0, %1\" |
| 1049 | : \"=r\" (w), |
| 1050 | \"=r\" (x) |
| 1051 | : \"0\" (y), |
| 1052 | \"1\" (z)); |
| 1053 | |
| 1054 | The \"x\" line is aligned to the text after the \":\" on the \"w\" line, and |
| 1055 | similarly \"z\" under \"y\". |
| 1056 | |
| 1057 | This is done only in an \"asm\" or \"__asm__\" block, and only to those |
| 1058 | lines mentioned. Anywhere else nil is returned. The usual arrangement is |
| 1059 | to have this routine as an extra feature at the start of arglist lineups, e.g. |
| 1060 | |
| 1061 | (c-lineup-gcc-asm-reg c-lineup-arglist) |
| 1062 | |
| 1063 | Works with: arglist-cont, arglist-cont-nonempty." |
| 1064 | |
| 1065 | (let ((orig-pos (point)) |
| 1066 | alignto) |
| 1067 | (save-excursion |
| 1068 | (and |
| 1069 | c-opt-asm-stmt-key |
| 1070 | |
| 1071 | ;; Don't do anything if the innermost open paren isn't our one. |
| 1072 | ;; This can occur for arglist-cont-nonempty with nested arglist |
| 1073 | ;; starts on the same line. |
| 1074 | (or (not (eq (car elem) 'arglist-cont-nonempty)) |
| 1075 | (eq (elt c-syntactic-element 2) |
| 1076 | (c-most-enclosing-brace (c-parse-state)))) |
| 1077 | |
| 1078 | ;; Find the ":" to align to. Look for this first so as to quickly |
| 1079 | ;; eliminate pretty much all cases which are not for us. |
| 1080 | (re-search-backward "^[ \t]*:[ \t]*\\(.\\)?" (cdr elem) t) |
| 1081 | |
| 1082 | ;; Must have something after the ":". |
| 1083 | (setq alignto (match-beginning 1)) |
| 1084 | |
| 1085 | ;; Don't touch ":" lines themselves. |
| 1086 | (progn (goto-char orig-pos) |
| 1087 | (beginning-of-line) |
| 1088 | (not (looking-at "^[ \t]*:"))) |
| 1089 | |
| 1090 | ;; Only operate in an asm statement. |
| 1091 | (progn (goto-char orig-pos) |
| 1092 | (c-in-gcc-asm-p)) |
| 1093 | |
| 1094 | (vector (progn (goto-char alignto) (current-column))))))) |
| 1095 | |
| 1096 | (defun c-lineup-dont-change (langelem) |
| 1097 | "Do not change the indentation of the current line. |
| 1098 | |
| 1099 | Works with: Any syntactic symbol." |
| 1100 | (save-excursion |
| 1101 | (back-to-indentation) |
| 1102 | (vector (current-column)))) |
| 1103 | |
| 1104 | \f |
| 1105 | (defun c-snug-do-while (syntax pos) |
| 1106 | "Dynamically calculate brace hanginess for do-while statements. |
| 1107 | Using this function, `while' clauses that end a `do-while' block will |
| 1108 | remain on the same line as the brace that closes that block. |
| 1109 | |
| 1110 | See `c-hanging-braces-alist' for how to utilize this function as an |
| 1111 | ACTION associated with `block-close' syntax." |
| 1112 | (save-excursion |
| 1113 | (let (langelem) |
| 1114 | (if (and (eq syntax 'block-close) |
| 1115 | (setq langelem (assq 'block-close c-syntactic-context)) |
| 1116 | (progn (goto-char (elt langelem 1)) |
| 1117 | (if (eq (char-after) ?{) |
| 1118 | (c-safe (c-forward-sexp -1))) |
| 1119 | (looking-at "\\<do\\>[^_]"))) |
| 1120 | '(before) |
| 1121 | '(before after))))) |
| 1122 | |
| 1123 | (defun c-gnu-impose-minimum () |
| 1124 | "Imposes a minimum indentation for lines inside a top-level construct. |
| 1125 | The variable `c-label-minimum-indentation' specifies the minimum |
| 1126 | indentation amount." |
| 1127 | |
| 1128 | ;; Don't adjust macro or comment-only lines. |
| 1129 | (unless (or (assq 'cpp-macro c-syntactic-context) |
| 1130 | (assq 'comment-intro c-syntactic-context)) |
| 1131 | |
| 1132 | (let ((paren-state (save-excursion |
| 1133 | ;; Get the parenthesis state, but skip past |
| 1134 | ;; an initial closing paren on the line since |
| 1135 | ;; the close brace of a block shouldn't be |
| 1136 | ;; considered to be inside the block. |
| 1137 | (back-to-indentation) |
| 1138 | (when (looking-at "\\s\)") |
| 1139 | (forward-char)) |
| 1140 | (c-parse-state)))) |
| 1141 | |
| 1142 | ;; Search for an enclosing brace on paren-state. |
| 1143 | (while (and paren-state |
| 1144 | (not (and (integer-or-marker-p (car paren-state)) |
| 1145 | (eq (char-after (car paren-state)) ?{)))) |
| 1146 | (setq paren-state (cdr paren-state))) |
| 1147 | |
| 1148 | (when paren-state |
| 1149 | (save-excursion |
| 1150 | (back-to-indentation) |
| 1151 | (if (zerop (current-column)) |
| 1152 | (insert-char ?\ c-label-minimum-indentation t))))))) |
| 1153 | |
| 1154 | \f |
| 1155 | ;; Useful for c-hanging-semi&comma-criteria |
| 1156 | |
| 1157 | (defun c-semi&comma-inside-parenlist () |
| 1158 | "Controls newline insertion after semicolons in parenthesis lists. |
| 1159 | If a comma was inserted, no determination is made. If a semicolon was |
| 1160 | inserted inside a parenthesis list, no newline is added otherwise a |
| 1161 | newline is added. In either case, checking is stopped. This supports |
| 1162 | exactly the old newline insertion behavior." |
| 1163 | ;; newline only after semicolon, but only if that semicolon is not |
| 1164 | ;; inside a parenthesis list (e.g. a for loop statement) |
| 1165 | (if (not (eq last-command-char ?\;)) |
| 1166 | nil ; continue checking |
| 1167 | (if (condition-case nil |
| 1168 | (save-excursion |
| 1169 | (up-list -1) |
| 1170 | (not (eq (char-after) ?\())) |
| 1171 | (error t)) |
| 1172 | t |
| 1173 | 'stop))) |
| 1174 | |
| 1175 | ;; Suppresses newlines before non-blank lines |
| 1176 | (defun c-semi&comma-no-newlines-before-nonblanks () |
| 1177 | "Controls newline insertion after semicolons. |
| 1178 | If a comma was inserted, no determination is made. If a semicolon was |
| 1179 | inserted, and the following line is not blank, no newline is inserted. |
| 1180 | Otherwise, no determination is made." |
| 1181 | (save-excursion |
| 1182 | (if (and (= last-command-char ?\;) |
| 1183 | ;;(/= (point-max) |
| 1184 | ;; (save-excursion (skip-syntax-forward " ") (point)) |
| 1185 | (zerop (forward-line 1)) |
| 1186 | (not (looking-at "^[ \t]*$"))) |
| 1187 | 'stop |
| 1188 | nil))) |
| 1189 | |
| 1190 | ;; Suppresses new lines after semicolons in one-liners methods |
| 1191 | (defun c-semi&comma-no-newlines-for-oneline-inliners () |
| 1192 | "Controls newline insertion after semicolons for some one-line methods. |
| 1193 | If a comma was inserted, no determination is made. Newlines are |
| 1194 | suppressed in one-liners, if the line is an in-class inline function. |
| 1195 | For other semicolon contexts, no determination is made." |
| 1196 | (let ((syntax (c-guess-basic-syntax)) |
| 1197 | (bol (save-excursion |
| 1198 | (if (c-safe (up-list -1) t) |
| 1199 | (c-point 'bol) |
| 1200 | -1)))) |
| 1201 | (if (and (eq last-command-char ?\;) |
| 1202 | (eq (car (car syntax)) 'inclass) |
| 1203 | (eq (car (car (cdr syntax))) 'topmost-intro) |
| 1204 | (= (c-point 'bol) bol)) |
| 1205 | 'stop |
| 1206 | nil))) |
| 1207 | |
| 1208 | \f |
| 1209 | (cc-provide 'cc-align) |
| 1210 | |
| 1211 | ;;; arch-tag: 4d71ed28-bf51-4509-a148-f39669669a2e |
| 1212 | ;;; cc-align.el ends here |