| 1 | ;;; face-remap.el --- Functions for managing `face-remapping-alist' |
| 2 | ;; |
| 3 | ;; Copyright (C) 2008 Free Software Foundation, Inc. |
| 4 | ;; |
| 5 | ;; Author: Miles Bader <miles@gnu.org> |
| 6 | ;; Keywords: faces face remapping display user commands |
| 7 | ;; |
| 8 | ;; This file is part of GNU Emacs. |
| 9 | ;; |
| 10 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 11 | ;; it under the terms of the GNU General Public License as published by |
| 12 | ;; the Free Software Foundation, either version 3 of the License, or |
| 13 | ;; (at your option) any later version. |
| 14 | ;; |
| 15 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 16 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 17 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 18 | ;; GNU General Public License for more details. |
| 19 | ;; |
| 20 | ;; You should have received a copy of the GNU General Public License |
| 21 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 22 | ;; |
| 23 | |
| 24 | ;;; Commentary: |
| 25 | |
| 26 | ;; |
| 27 | ;; This file defines some simple operations that can be used for |
| 28 | ;; maintaining the `face-remapping-alist' in a cooperative way. This is |
| 29 | ;; especially important for the `default' face. |
| 30 | ;; |
| 31 | ;; Each face-remapping definition in `face-remapping-alist' added by |
| 32 | ;; this code uses the form: |
| 33 | ;; |
| 34 | ;; (face RELATIVE_SPECS_1 RELATIVE_SPECS_2 ... BASE_SPECS) |
| 35 | ;; |
| 36 | ;; The "specs" values are a lists of face names or face attribute-value |
| 37 | ;; pairs, and are merged together, with earlier values taking precedence. |
| 38 | ;; |
| 39 | ;; The RELATIVE_SPECS_* values are added by `face-remap-add-relative' |
| 40 | ;; (and removed by `face-remap-remove-relative', and are intended for |
| 41 | ;; face "modifications" (such as increasing the size). Typical users of |
| 42 | ;; relative specs would be minor modes. |
| 43 | ;; |
| 44 | ;; BASE_SPECS is the lowest-priority value, and by default is just the |
| 45 | ;; face name, which causes the global definition of that face to be used. |
| 46 | ;; |
| 47 | ;; A non-default value of BASE_SPECS may also be set using |
| 48 | ;; `face-remap-set-base'. Because this _overwrites_ the default |
| 49 | ;; value inheriting from the global face definition, it is up to the |
| 50 | ;; caller of face-remap-set-base to add such inheritance if it is |
| 51 | ;; desired. A typical use of face-remap-set-base would be a major |
| 52 | ;; mode setting face remappings, e.g., of the default face. |
| 53 | ;; |
| 54 | ;; All modifications cause face-remapping-alist to be made buffer-local. |
| 55 | ;; |
| 56 | |
| 57 | |
| 58 | ;;; Code: |
| 59 | |
| 60 | \f |
| 61 | ;; ---------------------------------------------------------------- |
| 62 | ;; Utility functions |
| 63 | |
| 64 | ;; Names of face attributes corresponding to lisp face-vector positions. |
| 65 | ;; This variable should probably be defined in C code where the actual |
| 66 | ;; definitions are available. |
| 67 | ;; |
| 68 | (defvar internal-lisp-face-attributes |
| 69 | [nil |
| 70 | :family :foundry :swidth :height :weight :slant :underline :inverse |
| 71 | :foreground :background :stipple :overline :strike :box |
| 72 | :font :inherit :fontset :vector]) |
| 73 | |
| 74 | (defun face-attrs-more-relative-p (attrs1 attrs2) |
| 75 | "Return true if ATTRS1 contains a greater number of relative |
| 76 | face-attributes than ATTRS2. A face attribute is considered |
| 77 | relative if `face-attribute-relative-p' returns non-nil. |
| 78 | |
| 79 | ATTRS1 and ATTRS2 may be any value suitable for a `face' text |
| 80 | property, including face names, lists of face names, |
| 81 | face-attribute plists, etc. |
| 82 | |
| 83 | This function can be used as a predicate with `sort', to sort |
| 84 | face lists so that more specific faces are located near the end." |
| 85 | (unless (vectorp attrs1) |
| 86 | (setq attrs1 (face-attributes-as-vector attrs1))) |
| 87 | (unless (vectorp attrs2) |
| 88 | (setq attrs2 (face-attributes-as-vector attrs2))) |
| 89 | (let ((rel1-count 0) (rel2-count 0)) |
| 90 | (dotimes (i (length attrs1)) |
| 91 | (let ((attr (aref internal-lisp-face-attributes i))) |
| 92 | (when attr |
| 93 | (when (face-attribute-relative-p attr (aref attrs1 i)) |
| 94 | (setq rel1-count (+ rel1-count 1))) |
| 95 | (when (face-attribute-relative-p attr (aref attrs2 i)) |
| 96 | (setq rel2-count (+ rel2-count 1)))))) |
| 97 | (< rel1-count rel2-count))) |
| 98 | |
| 99 | (defun face-remap-order (entry) |
| 100 | "Order ENTRY so that more relative face specs are near the beginning. |
| 101 | The list structure of ENTRY may be destructively modified." |
| 102 | (setq entry (nreverse entry)) |
| 103 | (setcdr entry (sort (cdr entry) 'face-attrs-more-relative-p)) |
| 104 | (nreverse entry)) |
| 105 | |
| 106 | ;;;###autoload |
| 107 | (defun face-remap-add-relative (face &rest specs) |
| 108 | "Add a face remapping entry of FACE to SPECS in the current buffer. |
| 109 | |
| 110 | Return a cookie which can be used to delete the remapping with |
| 111 | `face-remap-remove-relative'. |
| 112 | |
| 113 | SPECS can be any value suitable for the `face' text property, |
| 114 | including a face name, a list of face names, or a face-attribute |
| 115 | property list. The attributes given by SPECS will be merged with |
| 116 | any other currently active face remappings of FACE, and with the |
| 117 | global definition of FACE. An attempt is made to sort multiple |
| 118 | entries so that entries with relative face-attributes are applied |
| 119 | after entries with absolute face-attributes. |
| 120 | |
| 121 | The base (lowest priority) remapping may be set to a specific |
| 122 | value, instead of the default of the global face definition, |
| 123 | using `face-remap-set-base'." |
| 124 | (while (and (consp specs) (null (cdr specs))) |
| 125 | (setq specs (car specs))) |
| 126 | (make-local-variable 'face-remapping-alist) |
| 127 | (let ((entry (assq face face-remapping-alist))) |
| 128 | (when (null entry) |
| 129 | (setq entry (list face face)) ; explicitly merge with global def |
| 130 | (push entry face-remapping-alist)) |
| 131 | (setcdr entry (face-remap-order (cons specs (cdr entry)))) |
| 132 | (cons face specs))) |
| 133 | |
| 134 | (defun face-remap-remove-relative (cookie) |
| 135 | "Remove a face remapping previously added by `face-remap-add-relative'. |
| 136 | COOKIE should be the return value from that function." |
| 137 | (let ((remapping (assq (car cookie) face-remapping-alist))) |
| 138 | (when remapping |
| 139 | (let ((updated-entries (remq (cdr cookie) (cdr remapping)))) |
| 140 | (unless (eq updated-entries (cdr remapping)) |
| 141 | (setcdr remapping updated-entries) |
| 142 | (when (or (null updated-entries) |
| 143 | (and (eq (car-safe updated-entries) (car cookie)) |
| 144 | (null (cdr updated-entries)))) |
| 145 | (setq face-remapping-alist |
| 146 | (remq remapping face-remapping-alist))) |
| 147 | (cdr cookie)))))) |
| 148 | |
| 149 | ;;;###autoload |
| 150 | (defun face-remap-reset-base (face) |
| 151 | "Set the base remapping of FACE to inherit from FACE's global definition." |
| 152 | (let ((entry (assq face face-remapping-alist))) |
| 153 | (when entry |
| 154 | ;; If there's nothing except a base remapping, we simply remove |
| 155 | ;; the entire remapping entry, as setting the base to the default |
| 156 | ;; would be the same as the global definition. Otherwise, we |
| 157 | ;; modify the base remapping. |
| 158 | (if (null (cddr entry)) ; nothing except base remapping |
| 159 | (setq face-remapping-alist ; so remove entire entry |
| 160 | (remq entry face-remapping-alist)) |
| 161 | (setcar (last entry) face))))) ; otherwise, just inherit global def |
| 162 | |
| 163 | ;;;###autoload |
| 164 | (defun face-remap-set-base (face &rest specs) |
| 165 | "Set the base remapping of FACE in the current buffer to SPECS. |
| 166 | If SPECS is empty, the default base remapping is restored, which |
| 167 | inherits from the global definition of FACE; note that this is |
| 168 | different from SPECS containing a single value `nil', which does |
| 169 | not inherit from the global definition of FACE." |
| 170 | (while (and (consp specs) (not (null (car specs))) (null (cdr specs))) |
| 171 | (setq specs (car specs))) |
| 172 | (if (or (null specs) |
| 173 | (and (eq (car specs) face) (null (cdr specs)))) ; default |
| 174 | ;; Set entry back to default |
| 175 | (face-remap-reset-base face) |
| 176 | ;; Set the base remapping |
| 177 | (make-local-variable 'face-remapping-alist) |
| 178 | (let ((entry (assq face face-remapping-alist))) |
| 179 | (if entry |
| 180 | (setcar (last entry) specs) ; overwrite existing base entry |
| 181 | (push (list face specs) face-remapping-alist))))) |
| 182 | |
| 183 | \f |
| 184 | ;; ---------------------------------------------------------------- |
| 185 | ;; text-scale-mode |
| 186 | |
| 187 | (defcustom text-scale-mode-step 1.2 |
| 188 | "Scale factor used by `text-scale-mode'. |
| 189 | Each positive or negative step scales the default face height by this amount." |
| 190 | :group 'display |
| 191 | :type 'number) |
| 192 | |
| 193 | ;; current remapping cookie for text-scale-mode |
| 194 | (defvar text-scale-mode-remapping nil) |
| 195 | (make-variable-buffer-local 'text-scale-mode-remapping) |
| 196 | |
| 197 | ;; Lighter displayed for text-scale-mode in mode-line minor-mode list |
| 198 | (defvar text-scale-mode-lighter "+0") |
| 199 | (make-variable-buffer-local 'text-scale-mode-lighter) |
| 200 | |
| 201 | ;; Number of steps that text-scale-mode will increase/decrease text height |
| 202 | (defvar text-scale-mode-amount 0) |
| 203 | (make-variable-buffer-local 'text-scale-mode-amount) |
| 204 | |
| 205 | (define-minor-mode text-scale-mode |
| 206 | "Minor mode for displaying buffer text in a larger/smaller font than usual. |
| 207 | |
| 208 | The amount of scaling is determined by the variable |
| 209 | `text-scale-mode-amount': one step scales the global default |
| 210 | face size by the value of the variable `text-scale-mode-step' |
| 211 | \(a negative amount shrinks the text). |
| 212 | |
| 213 | The `text-scale-increase' and `text-scale-decrease' functions may |
| 214 | be used to interactively modify the variable |
| 215 | `text-scale-mode-amount' (they also enable or disable |
| 216 | `text-scale-mode' as necessary)." |
| 217 | :lighter (" " text-scale-mode-lighter) |
| 218 | (when text-scale-mode-remapping |
| 219 | (face-remap-remove-relative text-scale-mode-remapping)) |
| 220 | (setq text-scale-mode-lighter |
| 221 | (format (if (>= text-scale-mode-amount 0) "+%d" "%d") |
| 222 | text-scale-mode-amount)) |
| 223 | (setq text-scale-mode-remapping |
| 224 | (and text-scale-mode |
| 225 | (face-remap-add-relative 'default |
| 226 | :height |
| 227 | (expt text-scale-mode-step |
| 228 | text-scale-mode-amount)))) |
| 229 | (force-window-update (current-buffer))) |
| 230 | |
| 231 | ;;;###autoload |
| 232 | (defun text-scale-increase (inc) |
| 233 | "Increase the height of the default face in the current buffer by INC steps. |
| 234 | If the new height is other than the default, `text-scale-mode' is enabled. |
| 235 | |
| 236 | Each step scales the height of the default face by the variable |
| 237 | `text-scale-mode-step' (a negative number of steps decreases the |
| 238 | height by the same amount). As a special case, an argument of 0 |
| 239 | will remove any scaling currently active." |
| 240 | (interactive "p") |
| 241 | (setq text-scale-mode-amount |
| 242 | (if (= inc 0) 0 (+ (if text-scale-mode text-scale-mode-amount 0) inc))) |
| 243 | (text-scale-mode (if (zerop text-scale-mode-amount) -1 1))) |
| 244 | |
| 245 | ;;;###autoload |
| 246 | (defun text-scale-decrease (dec) |
| 247 | "Decrease the height of the default face in the current buffer by DEC steps. |
| 248 | See `text-scale-increase' for more details." |
| 249 | (interactive "p") |
| 250 | (text-scale-increase (- dec))) |
| 251 | |
| 252 | ;;;###autoload (define-key ctl-x-map [(control ?+)] 'text-scale-adjust) |
| 253 | ;;;###autoload (define-key ctl-x-map [(control ?-)] 'text-scale-adjust) |
| 254 | ;;;###autoload (define-key ctl-x-map [(control ?=)] 'text-scale-adjust) |
| 255 | ;;;###autoload (define-key ctl-x-map [(control ?0)] 'text-scale-adjust) |
| 256 | ;;;###autoload |
| 257 | (defun text-scale-adjust (inc) |
| 258 | "Increase or decrease the height of the default face in the current buffer. |
| 259 | |
| 260 | The actual adjustment made depends on the final component of the |
| 261 | key-binding used to invoke the command, with all modifiers removed: |
| 262 | |
| 263 | +, = Increase the default face height by one step |
| 264 | - Decrease the default face height by one step |
| 265 | 0 Reset the default face height to the global default |
| 266 | |
| 267 | Then, continue to read input events and further adjust the face |
| 268 | height as long as the input event read (with all modifiers removed) |
| 269 | is one of the above. |
| 270 | |
| 271 | Each step scales the height of the default face by the variable |
| 272 | `text-scale-mode-step' (a negative number of steps decreases the |
| 273 | height by the same amount). As a special case, an argument of 0 |
| 274 | will remove any scaling currently active. |
| 275 | |
| 276 | This command is a special-purpose wrapper around the |
| 277 | `text-scale-increase' command which makes repetition convenient |
| 278 | even when it is bound in a non-top-level keymap. For binding in |
| 279 | a top-level keymap, `text-scale-increase' or |
| 280 | `text-scale-decrease' may be more appropriate." |
| 281 | (interactive "p") |
| 282 | (let ((first t) |
| 283 | (step t) |
| 284 | (ev last-command-event) |
| 285 | (echo-keystrokes nil)) |
| 286 | (while step |
| 287 | (let ((base (event-basic-type ev))) |
| 288 | (cond ((or (eq base ?+) (eq base ?=)) |
| 289 | (setq step inc)) |
| 290 | ((eq base ?-) |
| 291 | (setq step (- inc))) |
| 292 | ((eq base ?0) |
| 293 | (setq step 0)) |
| 294 | (first |
| 295 | (setq step inc)) |
| 296 | (t |
| 297 | (setq step nil)))) |
| 298 | (when step |
| 299 | (text-scale-increase step) |
| 300 | (setq inc 1 first nil) |
| 301 | (setq ev (read-event)))) |
| 302 | (push ev unread-command-events))) |
| 303 | |
| 304 | \f |
| 305 | ;; ---------------------------------------------------------------- |
| 306 | ;; buffer-face-mode |
| 307 | |
| 308 | (defcustom buffer-face-mode-face 'variable-pitch |
| 309 | "The face specification used by `buffer-face-mode'. |
| 310 | It may contain any value suitable for a `face' text property, |
| 311 | including a face name, a list of face names, a face-attribute |
| 312 | plist, etc." |
| 313 | :group 'display) |
| 314 | |
| 315 | ;; current remapping cookie for buffer-face-mode |
| 316 | (defvar buffer-face-mode-remapping nil) |
| 317 | (make-variable-buffer-local 'buffer-face-mode-remapping) |
| 318 | |
| 319 | ;;;###autoload |
| 320 | (define-minor-mode buffer-face-mode |
| 321 | "Minor mode for a buffer-specific default face. |
| 322 | When enabled, the face specified by the variable |
| 323 | `buffer-face-mode-face' is used to display the buffer text." |
| 324 | :lighter " BufFace" |
| 325 | (when buffer-face-mode-remapping |
| 326 | (face-remap-remove-relative buffer-face-mode-remapping)) |
| 327 | (setq buffer-face-mode-remapping |
| 328 | (and buffer-face-mode |
| 329 | (face-remap-add-relative 'default buffer-face-mode-face))) |
| 330 | (force-window-update (current-buffer))) |
| 331 | |
| 332 | ;;;###autoload |
| 333 | (defun buffer-face-set (&rest specs) |
| 334 | "Enable `buffer-face-mode', using face specs SPECS. |
| 335 | SPECS can be any value suitable for the `face' text property, |
| 336 | including a face name, a list of face names, or a face-attribute |
| 337 | If SPECS is nil, then `buffer-face-mode' is disabled. |
| 338 | |
| 339 | This function will make the variable `buffer-face-mode-face' |
| 340 | buffer local, and set it to FACE." |
| 341 | (interactive (list (read-face-name "Set buffer face"))) |
| 342 | (while (and (consp specs) (null (cdr specs))) |
| 343 | (setq specs (car specs))) |
| 344 | (if (null specs) |
| 345 | (buffer-face-mode 0) |
| 346 | (set (make-local-variable 'buffer-face-mode-face) specs) |
| 347 | (buffer-face-mode t))) |
| 348 | |
| 349 | ;;;###autoload |
| 350 | (defun buffer-face-toggle (&rest specs) |
| 351 | "Toggle `buffer-face-mode', using face specs SPECS. |
| 352 | SPECS can be any value suitable for the `face' text property, |
| 353 | including a face name, a list of face names, or a face-attribute |
| 354 | |
| 355 | If `buffer-face-mode' is already enabled, and is currently using |
| 356 | the face specs SPECS, then it is disabled; if buffer-face-mode is |
| 357 | disabled, or is enabled and currently displaying some other face, |
| 358 | then is left enabled, but the face changed to reflect SPECS. |
| 359 | |
| 360 | This function will make the variable `buffer-face-mode-face' |
| 361 | buffer local, and set it to SPECS." |
| 362 | (interactive (list buffer-face-mode-face)) |
| 363 | (while (and (consp specs) (null (cdr specs))) |
| 364 | (setq specs (car specs))) |
| 365 | (if (or (null specs) |
| 366 | (and buffer-face-mode (equal buffer-face-mode-face specs))) |
| 367 | (buffer-face-mode 0) |
| 368 | (set (make-local-variable 'buffer-face-mode-face) specs) |
| 369 | (buffer-face-mode t))) |
| 370 | |
| 371 | (defun buffer-face-mode-invoke (specs arg &optional interactive) |
| 372 | "Enable or disable `buffer-face-mode' using face specs SPECS, and argument ARG. |
| 373 | ARG controls whether the mode is enabled or disabled, and is |
| 374 | interpreted in the usual manner for minor-mode commands. |
| 375 | |
| 376 | SPECS can be any value suitable for the `face' text property, |
| 377 | including a face name, a list of face names, or a face-attribute |
| 378 | |
| 379 | If INTERACTIVE is non-nil, a message will be displayed describing the result. |
| 380 | |
| 381 | This is a wrapper function which calls `buffer-face-set' or |
| 382 | `buffer-face-toggle' (depending on ARG), and prints a status |
| 383 | message in the echo area. In many cases one of those functions |
| 384 | may be more appropriate." |
| 385 | (let ((last-message (current-message))) |
| 386 | (if (or (eq arg 'toggle) (not arg)) |
| 387 | (buffer-face-toggle specs) |
| 388 | (buffer-face-set (and (> (prefix-numeric-value arg) 0) specs))) |
| 389 | (when interactive |
| 390 | (unless (and (current-message) |
| 391 | (not (equal last-message (current-message)))) |
| 392 | (message "Buffer-Face mode %sabled" |
| 393 | (if buffer-face-mode "en" "dis")))))) |
| 394 | |
| 395 | \f |
| 396 | ;; ---------------------------------------------------------------- |
| 397 | ;; variable-pitch-mode |
| 398 | |
| 399 | ;;;###autoload |
| 400 | (defun variable-pitch-mode (&optional arg) |
| 401 | "Variable-pitch default-face mode. |
| 402 | An interface to `buffer-face-mode' which uses the `variable-pitch' face. |
| 403 | Besides the choice of face, it is the same as `buffer-face-mode'." |
| 404 | (interactive (list (or current-prefix-arg 'toggle))) |
| 405 | (buffer-face-mode-invoke 'variable-pitch arg (interactive-p))) |
| 406 | |
| 407 | |
| 408 | (provide 'face-remap) |
| 409 | |
| 410 | ;; arch-tag: 5c5f034b-8d58-4967-82bd-d61fd364e686 |
| 411 | ;;; face-remap.el ends here |