| 1 | ;;; cpp.el --- highlight or hide text according to cpp conditionals |
| 2 | |
| 3 | ;; Copyright (C) 1994, 1995, 2003 Free Software Foundation |
| 4 | |
| 5 | ;; Author: Per Abrahamsen <abraham@dina.kvl.dk> |
| 6 | ;; Keywords: c, faces, tools |
| 7 | |
| 8 | ;; This file is part of GNU Emacs. |
| 9 | |
| 10 | ;; GNU Emacs is free software; you can redistribute it and/or modify |
| 11 | ;; it under the terms of the GNU General Public License as published by |
| 12 | ;; the Free Software Foundation; either version 2, or (at your option) |
| 13 | ;; any later version. |
| 14 | |
| 15 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 16 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 17 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 18 | ;; GNU General Public License for more details. |
| 19 | |
| 20 | ;; You should have received a copy of the GNU General Public License |
| 21 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
| 22 | ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor, |
| 23 | ;; Boston, MA 02110-1301, USA. |
| 24 | |
| 25 | ;;; Commentary: |
| 26 | |
| 27 | ;; Parse a text for C preprocessor conditionals, and highlight or hide |
| 28 | ;; the text inside the conditionals as you wish. |
| 29 | |
| 30 | ;; This package is inspired by Jim Coplien's delta editor for SCCS. |
| 31 | |
| 32 | ;;; Todo: |
| 33 | |
| 34 | ;; Should parse "#if" and "#elif" expressions and merge the faces |
| 35 | ;; somehow. |
| 36 | |
| 37 | ;; Somehow it is sometimes possible to make changes near a read only |
| 38 | ;; area which you can't undo. Their are other strange effects in that |
| 39 | ;; area. |
| 40 | |
| 41 | ;; The Edit buffer should -- optionally -- appear in its own frame. |
| 42 | |
| 43 | ;; Conditionals seem to be rear-sticky. They shouldn't be. |
| 44 | |
| 45 | ;; Restore window configurations when exiting CPP Edit buffer. |
| 46 | |
| 47 | ;;; Code: |
| 48 | |
| 49 | ;;; Customization: |
| 50 | (defgroup cpp nil |
| 51 | "Highlight or hide text according to cpp conditionals." |
| 52 | :group 'c |
| 53 | :prefix "cpp-") |
| 54 | |
| 55 | (defcustom cpp-config-file (convert-standard-filename ".cpp.el") |
| 56 | "*File name to save cpp configuration." |
| 57 | :type 'file |
| 58 | :group 'cpp) |
| 59 | |
| 60 | (defcustom cpp-known-face 'invisible |
| 61 | "*Face used for known cpp symbols." |
| 62 | :type 'face |
| 63 | :group 'cpp) |
| 64 | |
| 65 | (defcustom cpp-unknown-face 'highlight |
| 66 | "*Face used for unknown cpp symbols." |
| 67 | :type 'face |
| 68 | :group 'cpp) |
| 69 | |
| 70 | (defcustom cpp-face-type 'light |
| 71 | "*Indicate what background face type you prefer. |
| 72 | Can be either light or dark for color screens, mono for monochrome |
| 73 | screens, and none if you don't use a window system and don't have |
| 74 | a color-capable display." |
| 75 | :options '(light dark mono nil) |
| 76 | :type 'symbol |
| 77 | :group 'cpp) |
| 78 | |
| 79 | (defcustom cpp-known-writable t |
| 80 | "*Non-nil means you are allowed to modify the known conditionals." |
| 81 | :type 'boolean |
| 82 | :group 'cpp) |
| 83 | |
| 84 | (defcustom cpp-unknown-writable t |
| 85 | "*Non-nil means you are allowed to modify the unknown conditionals." |
| 86 | :type 'boolean |
| 87 | :group 'cpp) |
| 88 | |
| 89 | (defcustom cpp-edit-list nil |
| 90 | "Alist of cpp macros and information about how they should be displayed. |
| 91 | Each entry is a list with the following elements: |
| 92 | 0. The name of the macro (a string). |
| 93 | 1. Face used for text that is `ifdef' the macro. |
| 94 | 2. Face used for text that is `ifndef' the macro. |
| 95 | 3. t, nil, or `both' depending on what text may be edited." |
| 96 | :type '(repeat (list string face face |
| 97 | (choice (const t) |
| 98 | (const nil) |
| 99 | (const both)))) |
| 100 | :group 'cpp) |
| 101 | |
| 102 | (defvar cpp-overlay-list nil) |
| 103 | ;; List of cpp overlays active in the current buffer. |
| 104 | (make-variable-buffer-local 'cpp-overlay-list) |
| 105 | |
| 106 | (defvar cpp-callback-data) |
| 107 | (defvar cpp-state-stack) |
| 108 | |
| 109 | (defconst cpp-face-type-list |
| 110 | '(("light color background" . light) |
| 111 | ("dark color background" . dark) |
| 112 | ("monochrome" . mono) |
| 113 | ("tty" . none)) |
| 114 | "Alist of strings and names of the defined face collections.") |
| 115 | |
| 116 | (defconst cpp-writable-list |
| 117 | ;; Names used for the writable property. |
| 118 | '(("writable" . t) |
| 119 | ("read-only" . nil))) |
| 120 | |
| 121 | (defvar cpp-button-event nil) |
| 122 | ;; This will be t in the callback for `cpp-make-button'. |
| 123 | |
| 124 | (defvar cpp-edit-buffer nil) |
| 125 | ;; Real buffer whose cpp display information we are editing. |
| 126 | (make-variable-buffer-local 'cpp-edit-buffer) |
| 127 | |
| 128 | (defconst cpp-branch-list |
| 129 | ;; Alist of branches. |
| 130 | '(("false" . nil) |
| 131 | ("true" . t) |
| 132 | ("both" . both))) |
| 133 | |
| 134 | (defcustom cpp-face-default-list nil |
| 135 | "Alist of faces you can choose from for cpp conditionals. |
| 136 | Each element has the form (STRING . FACE), where STRING |
| 137 | serves as a name (for `cpp-highlight-buffer' only) |
| 138 | and FACE is either a face (a symbol) |
| 139 | or a cons cell (background-color . COLOR)." |
| 140 | :type '(repeat (cons string (choice face (cons (const background-color) string)))) |
| 141 | :group 'cpp) |
| 142 | |
| 143 | (defcustom cpp-face-light-name-list |
| 144 | '("light gray" "light blue" "light cyan" "light yellow" "light pink" |
| 145 | "pale green" "beige" "orange" "magenta" "violet" "medium purple" |
| 146 | "turquoise") |
| 147 | "Background colors useful with dark foreground colors." |
| 148 | :type '(repeat string) |
| 149 | :group 'cpp) |
| 150 | |
| 151 | (defcustom cpp-face-dark-name-list |
| 152 | '("dim gray" "blue" "cyan" "yellow" "red" |
| 153 | "dark green" "brown" "dark orange" "dark khaki" "dark violet" "purple" |
| 154 | "dark turquoise") |
| 155 | "Background colors useful with light foreground colors." |
| 156 | :type '(repeat string) |
| 157 | :group 'cpp) |
| 158 | |
| 159 | (defcustom cpp-face-light-list nil |
| 160 | "Alist of names and faces to be used for light backgrounds." |
| 161 | :type '(repeat (cons string (choice face |
| 162 | (cons (const background-color) string)))) |
| 163 | :group 'cpp) |
| 164 | |
| 165 | (defcustom cpp-face-dark-list nil |
| 166 | "Alist of names and faces to be used for dark backgrounds." |
| 167 | :type '(repeat (cons string (choice face |
| 168 | (cons (const background-color) string)))) |
| 169 | :group 'cpp) |
| 170 | |
| 171 | (defcustom cpp-face-mono-list |
| 172 | '(("bold" . bold) |
| 173 | ("bold-italic" . bold-italic) |
| 174 | ("italic" . italic) |
| 175 | ("underline" . underline)) |
| 176 | "Alist of names and faces to be used for monochrome screens." |
| 177 | :type '(repeat (cons string face)) |
| 178 | :group 'cpp) |
| 179 | |
| 180 | (defcustom cpp-face-none-list |
| 181 | '(("default" . default) |
| 182 | ("invisible" . invisible)) |
| 183 | "Alist of names and faces available even if you don't use a window system." |
| 184 | :type '(repeat (cons string face)) |
| 185 | :group 'cpp) |
| 186 | |
| 187 | (defvar cpp-face-all-list |
| 188 | (append cpp-face-light-list |
| 189 | cpp-face-dark-list |
| 190 | cpp-face-mono-list |
| 191 | cpp-face-none-list) |
| 192 | "All faces used for highlighting text inside cpp conditionals.") |
| 193 | |
| 194 | ;;; Parse Buffer: |
| 195 | |
| 196 | (defvar cpp-parse-symbols nil |
| 197 | "List of cpp macros used in the local buffer.") |
| 198 | (make-variable-buffer-local 'cpp-parse-symbols) |
| 199 | |
| 200 | (defconst cpp-parse-regexp |
| 201 | ;; Regexp matching all tokens needed to find conditionals. |
| 202 | (concat |
| 203 | "'\\|\"\\|/\\*\\|//\\|" |
| 204 | "\\(^[ \t]*#[ \t]*\\(ifdef\\|ifndef\\|if\\|" |
| 205 | "elif\\|else\\|endif\\)\\b\\)")) |
| 206 | |
| 207 | ;;;###autoload |
| 208 | (defun cpp-highlight-buffer (arg) |
| 209 | "Highlight C code according to preprocessor conditionals. |
| 210 | This command pops up a buffer which you should edit to specify |
| 211 | what kind of highlighting to use, and the criteria for highlighting. |
| 212 | A prefix arg suppresses display of that buffer." |
| 213 | (interactive "P") |
| 214 | (unless (or (eq t buffer-invisibility-spec) |
| 215 | (memq 'cpp buffer-invisibility-spec)) |
| 216 | (add-to-invisibility-spec 'cpp)) |
| 217 | (setq cpp-parse-symbols nil) |
| 218 | (cpp-parse-reset) |
| 219 | (if (null cpp-edit-list) |
| 220 | (cpp-edit-load)) |
| 221 | (let (cpp-state-stack) |
| 222 | (save-excursion |
| 223 | (goto-char (point-min)) |
| 224 | (cpp-progress-message "Parsing...") |
| 225 | (while (re-search-forward cpp-parse-regexp nil t) |
| 226 | (cpp-progress-message "Parsing...%d%%" |
| 227 | (/ (* 100 (- (point) (point-min))) (buffer-size))) |
| 228 | (let ((match (buffer-substring (match-beginning 0) (match-end 0)))) |
| 229 | (cond ((or (string-equal match "'") |
| 230 | (string-equal match "\"")) |
| 231 | (goto-char (match-beginning 0)) |
| 232 | (condition-case nil |
| 233 | (forward-sexp) |
| 234 | (error (cpp-parse-error |
| 235 | "Unterminated string or character")))) |
| 236 | ((string-equal match "/*") |
| 237 | (or (search-forward "*/" nil t) |
| 238 | (error "Unterminated comment"))) |
| 239 | ((string-equal match "//") |
| 240 | (skip-chars-forward "^\n\r")) |
| 241 | (t |
| 242 | (end-of-line 1) |
| 243 | (let ((from (match-beginning 1)) |
| 244 | (to (1+ (point))) |
| 245 | (type (buffer-substring (match-beginning 2) |
| 246 | (match-end 2))) |
| 247 | (expr (buffer-substring (match-end 1) (point)))) |
| 248 | (cond ((string-equal type "ifdef") |
| 249 | (cpp-parse-open t expr from to)) |
| 250 | ((string-equal type "ifndef") |
| 251 | (cpp-parse-open nil expr from to)) |
| 252 | ((string-equal type "if") |
| 253 | (cpp-parse-open t expr from to)) |
| 254 | ((string-equal type "elif") |
| 255 | (let (cpp-known-face cpp-unknown-face) |
| 256 | (cpp-parse-close from to)) |
| 257 | (cpp-parse-open t expr from to)) |
| 258 | ((string-equal type "else") |
| 259 | (or cpp-state-stack |
| 260 | (cpp-parse-error "Top level #else")) |
| 261 | (let ((entry (list (not (nth 0 (car cpp-state-stack))) |
| 262 | (nth 1 (car cpp-state-stack)) |
| 263 | from to))) |
| 264 | (cpp-parse-close from to) |
| 265 | (setq cpp-state-stack (cons entry cpp-state-stack)))) |
| 266 | ((string-equal type "endif") |
| 267 | (cpp-parse-close from to)) |
| 268 | (t |
| 269 | (cpp-parse-error "Parser error")))))))) |
| 270 | (message "Parsing...done")) |
| 271 | (if cpp-state-stack |
| 272 | (save-excursion |
| 273 | (goto-char (nth 3 (car cpp-state-stack))) |
| 274 | (cpp-parse-error "Unclosed conditional")))) |
| 275 | (or arg |
| 276 | (null cpp-parse-symbols) |
| 277 | (cpp-parse-edit))) |
| 278 | |
| 279 | (defun cpp-parse-open (branch expr begin end) |
| 280 | "Push information about conditional-beginning onto `cpp-state-stack'." |
| 281 | ;; Discard comments within this line. |
| 282 | (while (string-match "\\b[ \t]*/\\*.*\\*/[ \t]*\\b" expr) |
| 283 | (setq expr (concat (substring expr 0 (match-beginning 0)) |
| 284 | (substring expr (match-end 0))))) |
| 285 | ;; If a comment starts on this line and continues past, discard it. |
| 286 | (if (string-match "\\b[ \t]*/\\*" expr) |
| 287 | (setq expr (substring expr 0 (match-beginning 0)))) |
| 288 | ;; Delete any C++ comment from the line. |
| 289 | (if (string-match "\\b[ \t]*\\(//.*\\)?$" expr) |
| 290 | (setq expr (substring expr 0 (match-beginning 0)))) |
| 291 | (while (string-match "[ \t]+" expr) |
| 292 | (setq expr (concat (substring expr 0 (match-beginning 0)) |
| 293 | (substring expr (match-end 0))))) |
| 294 | (setq cpp-state-stack (cons (list branch expr begin end) cpp-state-stack)) |
| 295 | (or (member expr cpp-parse-symbols) |
| 296 | (setq cpp-parse-symbols |
| 297 | (cons expr cpp-parse-symbols))) |
| 298 | (if (assoc expr cpp-edit-list) |
| 299 | (cpp-make-known-overlay begin end) |
| 300 | (cpp-make-unknown-overlay begin end))) |
| 301 | |
| 302 | (defun cpp-parse-close (from to) |
| 303 | ;; Pop top of cpp-state-stack and create overlay. |
| 304 | (let ((entry (assoc (nth 1 (car cpp-state-stack)) cpp-edit-list)) |
| 305 | (branch (nth 0 (car cpp-state-stack))) |
| 306 | (begin (nth 2 (car cpp-state-stack))) |
| 307 | (end (nth 3 (car cpp-state-stack)))) |
| 308 | (setq cpp-state-stack (cdr cpp-state-stack)) |
| 309 | (if entry |
| 310 | (let ((face (nth (if branch 1 2) entry)) |
| 311 | (read-only (eq (not branch) (nth 3 entry))) |
| 312 | (priority (length cpp-state-stack)) |
| 313 | (overlay (make-overlay end from))) |
| 314 | (cpp-make-known-overlay from to) |
| 315 | (setq cpp-overlay-list (cons overlay cpp-overlay-list)) |
| 316 | (if priority (overlay-put overlay 'priority priority)) |
| 317 | (cond ((eq face 'invisible) |
| 318 | (cpp-make-overlay-hidden overlay)) |
| 319 | ((eq face 'default)) |
| 320 | (t |
| 321 | (overlay-put overlay 'face face))) |
| 322 | (if read-only |
| 323 | (cpp-make-overlay-read-only overlay) |
| 324 | (cpp-make-overlay-sticky overlay))) |
| 325 | (cpp-make-unknown-overlay from to)))) |
| 326 | |
| 327 | (defun cpp-parse-error (error) |
| 328 | ;; Error message issued by the cpp parser. |
| 329 | (error "%s at line %d" error (count-lines (point-min) (point)))) |
| 330 | |
| 331 | (defun cpp-parse-reset () |
| 332 | "Reset display of cpp conditionals to normal." |
| 333 | (interactive) |
| 334 | (while cpp-overlay-list |
| 335 | (delete-overlay (car cpp-overlay-list)) |
| 336 | (setq cpp-overlay-list (cdr cpp-overlay-list)))) |
| 337 | |
| 338 | ;;;###autoload |
| 339 | (defun cpp-parse-edit () |
| 340 | "Edit display information for cpp conditionals." |
| 341 | (interactive) |
| 342 | (or cpp-parse-symbols |
| 343 | (cpp-highlight-buffer t)) |
| 344 | (let ((buffer (current-buffer))) |
| 345 | (pop-to-buffer "*CPP Edit*") |
| 346 | (cpp-edit-mode) |
| 347 | (setq cpp-edit-buffer buffer) |
| 348 | (cpp-edit-reset))) |
| 349 | |
| 350 | ;;; Overlays: |
| 351 | |
| 352 | (defun cpp-make-known-overlay (start end) |
| 353 | ;; Create an overlay for a known cpp command from START to END. |
| 354 | (let ((overlay (make-overlay start end))) |
| 355 | (if (eq cpp-known-face 'invisible) |
| 356 | (cpp-make-overlay-hidden overlay) |
| 357 | (or (eq cpp-known-face 'default) |
| 358 | (overlay-put overlay 'face cpp-known-face)) |
| 359 | (if cpp-known-writable |
| 360 | () |
| 361 | (overlay-put overlay 'modification-hooks '(cpp-signal-read-only)) |
| 362 | (overlay-put overlay 'insert-in-front-hooks '(cpp-signal-read-only)))) |
| 363 | (setq cpp-overlay-list (cons overlay cpp-overlay-list)))) |
| 364 | |
| 365 | (defun cpp-make-unknown-overlay (start end) |
| 366 | ;; Create an overlay for an unknown cpp command from START to END. |
| 367 | (let ((overlay (make-overlay start end))) |
| 368 | (cond ((eq cpp-unknown-face 'invisible) |
| 369 | (cpp-make-overlay-hidden overlay)) |
| 370 | ((eq cpp-unknown-face 'default)) |
| 371 | (t |
| 372 | (overlay-put overlay 'face cpp-unknown-face))) |
| 373 | (if cpp-unknown-writable |
| 374 | () |
| 375 | (overlay-put overlay 'modification-hooks '(cpp-signal-read-only)) |
| 376 | (overlay-put overlay 'insert-in-front-hooks '(cpp-signal-read-only))) |
| 377 | (setq cpp-overlay-list (cons overlay cpp-overlay-list)))) |
| 378 | |
| 379 | (defun cpp-make-overlay-hidden (overlay) |
| 380 | ;; Make overlay hidden and intangible. |
| 381 | (overlay-put overlay 'invisible 'cpp) |
| 382 | (overlay-put overlay 'modification-hooks '(cpp-signal-read-only)) |
| 383 | (overlay-put overlay 'insert-in-front-hooks '(cpp-signal-read-only))) |
| 384 | |
| 385 | (defun cpp-make-overlay-read-only (overlay) |
| 386 | ;; Make overlay read only. |
| 387 | (overlay-put overlay 'modification-hooks '(cpp-signal-read-only)) |
| 388 | (overlay-put overlay 'insert-in-front-hooks '(cpp-signal-read-only)) |
| 389 | (overlay-put overlay 'insert-behind-hooks '(cpp-signal-read-only))) |
| 390 | |
| 391 | (defun cpp-make-overlay-sticky (overlay) |
| 392 | ;; Make OVERLAY grow when you insert text at either end. |
| 393 | (overlay-put overlay 'insert-in-front-hooks '(cpp-grow-overlay)) |
| 394 | (overlay-put overlay 'insert-behind-hooks '(cpp-grow-overlay))) |
| 395 | |
| 396 | (defun cpp-signal-read-only (overlay after start end &optional len) |
| 397 | ;; Only allow deleting the whole overlay. |
| 398 | ;; Trying to change a read-only overlay. |
| 399 | (if (and (not after) |
| 400 | (or (< (overlay-start overlay) start) |
| 401 | (> (overlay-end overlay) end))) |
| 402 | (error "This text is read only"))) |
| 403 | |
| 404 | (defun cpp-grow-overlay (overlay after start end &optional len) |
| 405 | ;; Make OVERLAY grow to contain range START to END. |
| 406 | (if after |
| 407 | (move-overlay overlay |
| 408 | (min start (overlay-start overlay)) |
| 409 | (max end (overlay-end overlay))))) |
| 410 | |
| 411 | ;;; Edit Buffer: |
| 412 | |
| 413 | (defvar cpp-edit-map nil) |
| 414 | ;; Keymap for `cpp-edit-mode'. |
| 415 | |
| 416 | (if cpp-edit-map |
| 417 | () |
| 418 | (setq cpp-edit-map (make-keymap)) |
| 419 | (suppress-keymap cpp-edit-map) |
| 420 | (define-key cpp-edit-map [ down-mouse-2 ] 'cpp-push-button) |
| 421 | (define-key cpp-edit-map [ mouse-2 ] 'ignore) |
| 422 | (define-key cpp-edit-map " " 'scroll-up) |
| 423 | (define-key cpp-edit-map "\C-?" 'scroll-down) |
| 424 | (define-key cpp-edit-map [ delete ] 'scroll-down) |
| 425 | (define-key cpp-edit-map "\C-c\C-c" 'cpp-edit-apply) |
| 426 | (define-key cpp-edit-map "a" 'cpp-edit-apply) |
| 427 | (define-key cpp-edit-map "A" 'cpp-edit-apply) |
| 428 | (define-key cpp-edit-map "r" 'cpp-edit-reset) |
| 429 | (define-key cpp-edit-map "R" 'cpp-edit-reset) |
| 430 | (define-key cpp-edit-map "s" 'cpp-edit-save) |
| 431 | (define-key cpp-edit-map "S" 'cpp-edit-save) |
| 432 | (define-key cpp-edit-map "l" 'cpp-edit-load) |
| 433 | (define-key cpp-edit-map "L" 'cpp-edit-load) |
| 434 | (define-key cpp-edit-map "h" 'cpp-edit-home) |
| 435 | (define-key cpp-edit-map "H" 'cpp-edit-home) |
| 436 | (define-key cpp-edit-map "b" 'cpp-edit-background) |
| 437 | (define-key cpp-edit-map "B" 'cpp-edit-background) |
| 438 | (define-key cpp-edit-map "k" 'cpp-edit-known) |
| 439 | (define-key cpp-edit-map "K" 'cpp-edit-known) |
| 440 | (define-key cpp-edit-map "u" 'cpp-edit-unknown) |
| 441 | (define-key cpp-edit-map "u" 'cpp-edit-unknown) |
| 442 | (define-key cpp-edit-map "t" 'cpp-edit-true) |
| 443 | (define-key cpp-edit-map "T" 'cpp-edit-true) |
| 444 | (define-key cpp-edit-map "f" 'cpp-edit-false) |
| 445 | (define-key cpp-edit-map "F" 'cpp-edit-false) |
| 446 | (define-key cpp-edit-map "w" 'cpp-edit-write) |
| 447 | (define-key cpp-edit-map "W" 'cpp-edit-write) |
| 448 | (define-key cpp-edit-map "X" 'cpp-edit-toggle-known) |
| 449 | (define-key cpp-edit-map "x" 'cpp-edit-toggle-known) |
| 450 | (define-key cpp-edit-map "Y" 'cpp-edit-toggle-unknown) |
| 451 | (define-key cpp-edit-map "y" 'cpp-edit-toggle-unknown) |
| 452 | (define-key cpp-edit-map "q" 'bury-buffer) |
| 453 | (define-key cpp-edit-map "Q" 'bury-buffer)) |
| 454 | |
| 455 | (defvar cpp-edit-symbols nil) |
| 456 | ;; Symbols defined in the edit buffer. |
| 457 | (make-variable-buffer-local 'cpp-edit-symbols) |
| 458 | |
| 459 | (defun cpp-edit-mode () |
| 460 | "Major mode for editing the criteria for highlighting cpp conditionals. |
| 461 | Click on objects to change them. |
| 462 | You can also use the keyboard accelerators indicated like this: [K]ey." |
| 463 | (kill-all-local-variables) |
| 464 | (buffer-disable-undo) |
| 465 | (auto-save-mode -1) |
| 466 | (setq buffer-read-only t) |
| 467 | (setq major-mode 'cpp-edit-mode) |
| 468 | (setq mode-name "CPP Edit") |
| 469 | (use-local-map cpp-edit-map)) |
| 470 | |
| 471 | (defun cpp-edit-apply () |
| 472 | "Apply edited display information to original buffer." |
| 473 | (interactive) |
| 474 | (cpp-edit-home) |
| 475 | (cpp-highlight-buffer t)) |
| 476 | |
| 477 | (defun cpp-edit-reset () |
| 478 | "Reset display information from original buffer." |
| 479 | (interactive) |
| 480 | (let ((buffer (current-buffer)) |
| 481 | (buffer-read-only nil) |
| 482 | (start (window-start)) |
| 483 | (pos (point)) |
| 484 | symbols) |
| 485 | (set-buffer cpp-edit-buffer) |
| 486 | (setq symbols cpp-parse-symbols) |
| 487 | (set-buffer buffer) |
| 488 | (setq cpp-edit-symbols symbols) |
| 489 | (erase-buffer) |
| 490 | (insert "CPP Display Information for `") |
| 491 | (cpp-make-button (buffer-name cpp-edit-buffer) 'cpp-edit-home) |
| 492 | (insert "'\n\nClick mouse-2 on item you want to change or use\n" |
| 493 | "or switch to this buffer and type the keyboard equivalents.\n" |
| 494 | "Keyboard equivalents are indicated with brackets like [T]his.\n\n") |
| 495 | (cpp-make-button "[H]ome (display the C file)" 'cpp-edit-home) |
| 496 | (insert " ") |
| 497 | (cpp-make-button "[A]pply new settings" 'cpp-edit-apply) |
| 498 | (insert "\n") |
| 499 | (cpp-make-button "[S]ave settings" 'cpp-edit-save) |
| 500 | (insert " ") |
| 501 | (cpp-make-button "[L]oad settings" 'cpp-edit-load) |
| 502 | (insert "\n\n") |
| 503 | |
| 504 | (insert "[B]ackground: ") |
| 505 | (cpp-make-button (car (rassq cpp-face-type cpp-face-type-list)) |
| 506 | 'cpp-edit-background) |
| 507 | (insert "\n[K]nown conditionals: ") |
| 508 | (cpp-make-button (cpp-face-name cpp-known-face) |
| 509 | 'cpp-edit-known nil t) |
| 510 | (insert " [X] ") |
| 511 | (cpp-make-button (car (rassq cpp-known-writable cpp-writable-list)) |
| 512 | 'cpp-edit-toggle-known) |
| 513 | (insert "\n[U]nknown conditionals: ") |
| 514 | (cpp-make-button (cpp-face-name cpp-unknown-face) |
| 515 | 'cpp-edit-unknown nil t) |
| 516 | (insert " [Y] ") |
| 517 | (cpp-make-button (car (rassq cpp-unknown-writable cpp-writable-list)) |
| 518 | 'cpp-edit-toggle-unknown) |
| 519 | (insert (format "\n\n\n%39s: %14s %14s %7s\n\n" "Expression" |
| 520 | "[T]rue Face" "[F]alse Face" "[W]rite")) |
| 521 | (while symbols |
| 522 | (let* ((symbol (car symbols)) |
| 523 | (entry (assoc symbol cpp-edit-list)) |
| 524 | (true (nth 1 entry)) |
| 525 | (false (nth 2 entry)) |
| 526 | (write (if entry (nth 3 entry) 'both))) |
| 527 | (setq symbols (cdr symbols)) |
| 528 | |
| 529 | (if (and entry ; Make default entries unknown. |
| 530 | (or (null true) (eq true 'default)) |
| 531 | (or (null false) (eq false 'default)) |
| 532 | (eq write 'both)) |
| 533 | (setq cpp-edit-list (delq entry cpp-edit-list) |
| 534 | entry nil)) |
| 535 | |
| 536 | (if (> (length symbol) 39) |
| 537 | (insert (substring symbol 0 39) ": ") |
| 538 | (insert (format "%39s: " symbol))) |
| 539 | |
| 540 | (cpp-make-button (cpp-face-name true) |
| 541 | 'cpp-edit-true symbol t 14) |
| 542 | (insert " ") |
| 543 | (cpp-make-button (cpp-face-name false) |
| 544 | 'cpp-edit-false symbol t 14) |
| 545 | (insert " ") |
| 546 | (cpp-make-button (car (rassq write cpp-branch-list)) |
| 547 | 'cpp-edit-write symbol nil 6) |
| 548 | (insert "\n"))) |
| 549 | (insert "\n\n") |
| 550 | (set-window-start nil start) |
| 551 | (goto-char pos))) |
| 552 | |
| 553 | (defun cpp-edit-load () |
| 554 | "Load cpp configuration." |
| 555 | (interactive) |
| 556 | (cond ((null init-file-user) |
| 557 | ;; If -q was specified, don't load any init files. |
| 558 | nil) |
| 559 | ((file-readable-p cpp-config-file) |
| 560 | (load-file cpp-config-file)) |
| 561 | ((file-readable-p (concat "~/" cpp-config-file)) |
| 562 | (load-file cpp-config-file))) |
| 563 | (if (eq major-mode 'cpp-edit-mode) |
| 564 | (cpp-edit-reset))) |
| 565 | |
| 566 | (defun cpp-edit-save () |
| 567 | "Save the current cpp configuration in a file." |
| 568 | (interactive) |
| 569 | (require 'pp) |
| 570 | (save-excursion |
| 571 | (set-buffer cpp-edit-buffer) |
| 572 | (let ((buffer (find-file-noselect cpp-config-file))) |
| 573 | (set-buffer buffer) |
| 574 | (erase-buffer) |
| 575 | (pp (list 'setq 'cpp-known-face |
| 576 | (list 'quote cpp-known-face)) buffer) |
| 577 | (pp (list 'setq 'cpp-unknown-face |
| 578 | (list 'quote cpp-unknown-face)) buffer) |
| 579 | (pp (list 'setq 'cpp-face-type |
| 580 | (list 'quote cpp-face-type)) buffer) |
| 581 | (pp (list 'setq 'cpp-known-writable |
| 582 | (list 'quote cpp-known-writable)) buffer) |
| 583 | (pp (list 'setq 'cpp-unknown-writable |
| 584 | (list 'quote cpp-unknown-writable)) buffer) |
| 585 | (pp (list 'setq 'cpp-edit-list |
| 586 | (list 'quote cpp-edit-list)) buffer) |
| 587 | (write-file cpp-config-file)))) |
| 588 | |
| 589 | (defun cpp-edit-home () |
| 590 | "Switch back to original buffer." |
| 591 | (interactive) |
| 592 | (if cpp-button-event |
| 593 | (read-event)) |
| 594 | (pop-to-buffer cpp-edit-buffer)) |
| 595 | |
| 596 | (defun cpp-edit-background () |
| 597 | "Change default face collection." |
| 598 | (interactive) |
| 599 | (call-interactively 'cpp-choose-default-face) |
| 600 | (cpp-edit-reset)) |
| 601 | |
| 602 | (defun cpp-edit-known () |
| 603 | "Select default for known conditionals." |
| 604 | (interactive) |
| 605 | (setq cpp-known-face (cpp-choose-face "Known face" cpp-known-face)) |
| 606 | (cpp-edit-reset)) |
| 607 | |
| 608 | (defun cpp-edit-unknown () |
| 609 | "Select default for unknown conditionals." |
| 610 | (interactive) |
| 611 | (setq cpp-unknown-face (cpp-choose-face "Unknown face" cpp-unknown-face)) |
| 612 | (cpp-edit-reset)) |
| 613 | |
| 614 | (defun cpp-edit-toggle-known (arg) |
| 615 | "Toggle writable status for known conditionals. |
| 616 | With optional argument ARG, make them writable iff ARG is positive." |
| 617 | (interactive "@P") |
| 618 | (if (or (and (null arg) cpp-known-writable) |
| 619 | (<= (prefix-numeric-value arg) 0)) |
| 620 | (setq cpp-known-writable nil) |
| 621 | (setq cpp-known-writable t)) |
| 622 | (cpp-edit-reset)) |
| 623 | |
| 624 | (defun cpp-edit-toggle-unknown (arg) |
| 625 | "Toggle writable status for unknown conditionals. |
| 626 | With optional argument ARG, make them writable iff ARG is positive." |
| 627 | (interactive "@P") |
| 628 | (if (or (and (null arg) cpp-unknown-writable) |
| 629 | (<= (prefix-numeric-value arg) 0)) |
| 630 | (setq cpp-unknown-writable nil) |
| 631 | (setq cpp-unknown-writable t)) |
| 632 | (cpp-edit-reset)) |
| 633 | |
| 634 | (defun cpp-edit-true (symbol face) |
| 635 | "Select SYMBOL's true FACE used for highlighting taken conditionals." |
| 636 | (interactive |
| 637 | (let ((symbol (cpp-choose-symbol))) |
| 638 | (list symbol |
| 639 | (cpp-choose-face "True face" |
| 640 | (nth 1 (assoc symbol cpp-edit-list)))))) |
| 641 | (setcar (nthcdr 1 (cpp-edit-list-entry-get-or-create symbol)) face) |
| 642 | (cpp-edit-reset)) |
| 643 | |
| 644 | (defun cpp-edit-false (symbol face) |
| 645 | "Select SYMBOL's false FACE used for highlighting untaken conditionals." |
| 646 | (interactive |
| 647 | (let ((symbol (cpp-choose-symbol))) |
| 648 | (list symbol |
| 649 | (cpp-choose-face "False face" |
| 650 | (nth 2 (assoc symbol cpp-edit-list)))))) |
| 651 | (setcar (nthcdr 2 (cpp-edit-list-entry-get-or-create symbol)) face) |
| 652 | (cpp-edit-reset)) |
| 653 | |
| 654 | (defun cpp-edit-write (symbol branch) |
| 655 | "Set which branches of SYMBOL should be writable to BRANCH. |
| 656 | BRANCH should be either nil (false branch), t (true branch) or 'both." |
| 657 | (interactive (list (cpp-choose-symbol) (cpp-choose-branch))) |
| 658 | (setcar (nthcdr 3 (cpp-edit-list-entry-get-or-create symbol)) branch) |
| 659 | (cpp-edit-reset)) |
| 660 | |
| 661 | (defun cpp-edit-list-entry-get-or-create (symbol) |
| 662 | ;; Return the entry for SYMBOL in `cpp-edit-list'. |
| 663 | ;; If it does not exist, create it. |
| 664 | (let ((entry (assoc symbol cpp-edit-list))) |
| 665 | (or entry |
| 666 | (setq entry (list symbol nil nil 'both nil) |
| 667 | cpp-edit-list (cons entry cpp-edit-list))) |
| 668 | entry)) |
| 669 | |
| 670 | ;;; Prompts: |
| 671 | |
| 672 | (defun cpp-choose-symbol () |
| 673 | ;; Choose a symbol if called from keyboard, otherwise use the one clicked on. |
| 674 | (if cpp-button-event |
| 675 | cpp-callback-data |
| 676 | (completing-read "Symbol: " cpp-edit-symbols nil t))) |
| 677 | |
| 678 | (defun cpp-choose-branch () |
| 679 | ;; Choose a branch, either nil, t, or both. |
| 680 | (if cpp-button-event |
| 681 | (x-popup-menu cpp-button-event |
| 682 | (list "Branch" (cons "Branch" cpp-branch-list))) |
| 683 | (cdr (assoc (completing-read "Branch: " cpp-branch-list nil t) |
| 684 | cpp-branch-list)))) |
| 685 | |
| 686 | (defun cpp-choose-face (prompt default) |
| 687 | ;; Choose a face from cpp-face-default-list. |
| 688 | ;; PROMPT is what to say to the user. |
| 689 | ;; DEFAULT is the default face. |
| 690 | (or (if cpp-button-event |
| 691 | (x-popup-menu cpp-button-event |
| 692 | (list prompt (cons prompt cpp-face-default-list))) |
| 693 | (let ((name (car (rassq default cpp-face-default-list)))) |
| 694 | (cdr (assoc (completing-read (if name |
| 695 | (concat prompt |
| 696 | " (default " name "): ") |
| 697 | (concat prompt ": ")) |
| 698 | cpp-face-default-list nil t) |
| 699 | cpp-face-all-list)))) |
| 700 | default)) |
| 701 | |
| 702 | (defun cpp-choose-default-face (type) |
| 703 | ;; Choose default face list for screen of TYPE. |
| 704 | ;; Type must be one of the types defined in `cpp-face-type-list'. |
| 705 | (interactive (list (if cpp-button-event |
| 706 | (x-popup-menu cpp-button-event |
| 707 | (list "Screen type" |
| 708 | (cons "Screen type" |
| 709 | cpp-face-type-list))) |
| 710 | (cdr (assoc (completing-read "Screen type: " |
| 711 | cpp-face-type-list |
| 712 | nil t) |
| 713 | cpp-face-type-list))))) |
| 714 | (cond ((null type)) |
| 715 | ((eq type 'light) |
| 716 | (if cpp-face-light-list |
| 717 | () |
| 718 | (setq cpp-face-light-list |
| 719 | (mapcar 'cpp-create-bg-face cpp-face-light-name-list)) |
| 720 | (setq cpp-face-all-list |
| 721 | (append cpp-face-all-list cpp-face-light-list))) |
| 722 | (setq cpp-face-type 'light) |
| 723 | (setq cpp-face-default-list |
| 724 | (append cpp-face-light-list cpp-face-none-list))) |
| 725 | ((eq type 'dark) |
| 726 | (if cpp-face-dark-list |
| 727 | () |
| 728 | (setq cpp-face-dark-list |
| 729 | (mapcar 'cpp-create-bg-face cpp-face-dark-name-list)) |
| 730 | (setq cpp-face-all-list |
| 731 | (append cpp-face-all-list cpp-face-dark-list))) |
| 732 | (setq cpp-face-type 'dark) |
| 733 | (setq cpp-face-default-list |
| 734 | (append cpp-face-dark-list cpp-face-none-list))) |
| 735 | ((eq type 'mono) |
| 736 | (setq cpp-face-type 'mono) |
| 737 | (setq cpp-face-default-list |
| 738 | (append cpp-face-mono-list cpp-face-none-list))) |
| 739 | (t |
| 740 | (setq cpp-face-type 'none) |
| 741 | (setq cpp-face-default-list cpp-face-none-list)))) |
| 742 | |
| 743 | ;;; Buttons: |
| 744 | |
| 745 | (defun cpp-make-button (name callback &optional data face padding) |
| 746 | ;; Create a button at point. |
| 747 | ;; NAME is the name of the button. |
| 748 | ;; CALLBACK is the function to call when the button is pushed. |
| 749 | ;; DATA will be made available to CALLBACK |
| 750 | ;;in the free variable cpp-callback-data. |
| 751 | ;; FACE means that NAME is the name of a face in `cpp-face-all-list'. |
| 752 | ;; PADDING means NAME will be right justified at that length. |
| 753 | (let ((name (format "%s" name)) |
| 754 | from to) |
| 755 | (cond ((null padding) |
| 756 | (setq from (point)) |
| 757 | (insert name)) |
| 758 | ((> (length name) padding) |
| 759 | (setq from (point)) |
| 760 | (insert (substring name 0 padding))) |
| 761 | (t |
| 762 | (insert (make-string (- padding (length name)) ? )) |
| 763 | (setq from (point)) |
| 764 | (insert name))) |
| 765 | (setq to (point)) |
| 766 | (setq face |
| 767 | (if face |
| 768 | (let ((check (cdr (assoc name cpp-face-all-list)))) |
| 769 | (if (memq check '(default invisible)) |
| 770 | 'bold |
| 771 | check)) |
| 772 | 'bold)) |
| 773 | (add-text-properties from to |
| 774 | (append (list 'face face) |
| 775 | '(mouse-face highlight) |
| 776 | '(help-echo "mouse-2: change/use this item") |
| 777 | (list 'cpp-callback callback) |
| 778 | (if data (list 'cpp-data data)))))) |
| 779 | |
| 780 | (defun cpp-push-button (event) |
| 781 | ;; Pushed a CPP button. |
| 782 | (interactive "@e") |
| 783 | (set-buffer (window-buffer (posn-window (event-start event)))) |
| 784 | (let ((pos (posn-point (event-start event)))) |
| 785 | (let ((cpp-callback-data (get-text-property pos 'cpp-data)) |
| 786 | (fun (get-text-property pos 'cpp-callback)) |
| 787 | (cpp-button-event event)) |
| 788 | (cond (fun |
| 789 | (call-interactively (get-text-property pos 'cpp-callback))) |
| 790 | ((lookup-key global-map [ down-mouse-2]) |
| 791 | (call-interactively (lookup-key global-map [ down-mouse-2]))))))) |
| 792 | |
| 793 | ;;; Faces: |
| 794 | |
| 795 | (defun cpp-create-bg-face (color) |
| 796 | ;; Create entry for face with background COLOR. |
| 797 | (cons color (cons 'background-color color))) |
| 798 | |
| 799 | (cpp-choose-default-face |
| 800 | (if (or window-system (display-color-p)) cpp-face-type 'none)) |
| 801 | |
| 802 | (defun cpp-face-name (face) |
| 803 | ;; Return the name of FACE from `cpp-face-all-list'. |
| 804 | (let ((entry (rassq (if face face 'default) cpp-face-all-list))) |
| 805 | (if entry |
| 806 | (car entry) |
| 807 | (format "<%s>" face)))) |
| 808 | |
| 809 | ;;; Utilities: |
| 810 | |
| 811 | (defvar cpp-progress-time 0) |
| 812 | ;; Last time we issued a progress message. |
| 813 | |
| 814 | (defun cpp-progress-message (&rest args) |
| 815 | ;; Report progress at most once a second. Take same ARGS as `message'. |
| 816 | (let ((time (nth 1 (current-time)))) |
| 817 | (if (= time cpp-progress-time) |
| 818 | () |
| 819 | (setq cpp-progress-time time) |
| 820 | (apply 'message args)))) |
| 821 | |
| 822 | (provide 'cpp) |
| 823 | |
| 824 | ;;; arch-tag: fb7d433d-745d-495a-96f0-86908ab63f74 |
| 825 | ;;; cpp.el ends here |