| 1 | ;;; uniquify.el --- unique buffer names dependent on file name -*- lexical-binding: t -*- |
| 2 | |
| 3 | ;; Copyright (C) 1989, 1995-1997, 2001-2013 Free Software Foundation, |
| 4 | ;; Inc. |
| 5 | |
| 6 | ;; Author: Dick King <king@reasoning.com> |
| 7 | ;; Maintainer: FSF |
| 8 | ;; Keywords: files |
| 9 | ;; Created: 15 May 86 |
| 10 | ;; Package: emacs |
| 11 | |
| 12 | ;; This file is part of GNU Emacs. |
| 13 | |
| 14 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 15 | ;; it under the terms of the GNU General Public License as published by |
| 16 | ;; the Free Software Foundation, either version 3 of the License, or |
| 17 | ;; (at your option) any later version. |
| 18 | |
| 19 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 20 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ;; GNU General Public License for more details. |
| 23 | |
| 24 | ;; You should have received a copy of the GNU General Public License |
| 25 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 26 | |
| 27 | ;;; Commentary: |
| 28 | |
| 29 | ;; Emacs's standard method for making buffer names unique adds <2>, <3>, |
| 30 | ;; etc. to the end of (all but one of) the buffers. This file replaces |
| 31 | ;; that behavior, for buffers visiting files and dired buffers, with a |
| 32 | ;; uniquification that adds parts of the file name until the buffer names |
| 33 | ;; are unique. For instance, buffers visiting /u/mernst/tmp/Makefile and |
| 34 | ;; /usr/projects/zaphod/Makefile would be named Makefile|tmp and |
| 35 | ;; Makefile|zaphod, respectively (instead of Makefile and Makefile<2>). |
| 36 | ;; Other buffer name styles are also available. |
| 37 | |
| 38 | ;; To use this file, do (require 'uniquify) |
| 39 | ;; and set uniquify-buffer-name-style to one of its non-nil alternative values. |
| 40 | |
| 41 | ;; For other options, see "User-visible variables", below. |
| 42 | |
| 43 | ;; A version of uniquify.el that works under Emacs 18, Emacs 19, XEmacs, |
| 44 | ;; and InfoDock is available from the maintainer. |
| 45 | |
| 46 | ;;; Change Log: |
| 47 | |
| 48 | ;; Originally by Dick King <king@reasoning.com> 15 May 86 |
| 49 | ;; Converted for Emacs 18 by Stephen Gildea <gildea@stop.mail-abuse.org> |
| 50 | ;; Make uniquify-min-dir-content 0 truly non-invasive. gildea 23 May 89 |
| 51 | ;; Some cleanup. uniquify-min-dir-content default 0. gildea 01 Jun 89 |
| 52 | ;; Don't rename to "". Michael Ernst <mernst@theory.lcs.mit.edu> 15 Jun 94 |
| 53 | ;; Add kill-buffer-hook. Kenneth Manheimer <ken.manheimer@nist.gov> 09 May 95 |
| 54 | ;; Add advice for rename-buffer and create-file-buffer, handle dired buffers, |
| 55 | ;; kill-buffer-rationalize-buffer-names-p, documentation. mernst 24 May 95 |
| 56 | ;; Remove free variables, fix typos. mernst 5 Jun 95 |
| 57 | ;; Efficiently support Emacs 19.27 & earlier. ken.manheimer, mernst 10 Jun 95 |
| 58 | ;; Rename user options to "uniquify-...", add uniquify-reverse-dir-content-p, |
| 59 | ;; add uniquify-ask-about-buffer-names-p. king, mernst 13 Jun 95 |
| 60 | ;; Prefix functions by "uniquify-..."; rename mnemonic-buffer-names to |
| 61 | ;; uniquify-buffer-name-style; add 'forward and 'post-forward-angle-brackets |
| 62 | ;; styles; remove uniquify-reverse-dir-content-p; add |
| 63 | ;; uniquify-trailing-separator-p. mernst 4 Aug 95 |
| 64 | ;; Don't call expand-file-name on nil. mernst 7 Jan 96 |
| 65 | ;; Check whether list-buffers-directory is bound. mernst 11 Oct 96 |
| 66 | ;; Ignore non-file non-dired buffers. Colin Rafferty <craffert@ml.com> 3 Mar 97 |
| 67 | ;; Use last component, not "", for file name of directories. mernst 27 Jun 97 |
| 68 | ;; Use directory-file-name; code cleanup. mernst 6 Sep 97 |
| 69 | ;; Add uniquify-ignore-buffers-re. |
| 70 | ;; Andre Srinivasan <andre@visigenic.com> 9 Sep 97 |
| 71 | ;; Add uniquify-list-buffers-directory-modes |
| 72 | ;; Stefan Monnier <monnier@cs.yale.edu> 17 Nov 2000 |
| 73 | ;; Algorithm and data structure changed to reduce consing with lots of buffers |
| 74 | ;; Francesco Potortì <pot@gnu.org> (ideas by rms and monnier) 2001-07-18 |
| 75 | |
| 76 | ;; Valuable feedback was provided by |
| 77 | ;; Paul Smith <psmith@baynetworks.com>, |
| 78 | ;; Alastair Burt <burt@dfki.uni-kl.de>, |
| 79 | ;; Bob Weiner <weiner@footloose.sps.mot.com>, |
| 80 | ;; Albert L. Ting <alt@vlibs.com>, |
| 81 | ;; gyro@reasoning.com, |
| 82 | ;; Bryan O'Sullivan <bos@eng.sun.com>. |
| 83 | |
| 84 | |
| 85 | ;;; Code: |
| 86 | |
| 87 | (eval-when-compile (require 'cl-lib)) |
| 88 | |
| 89 | ;;; User-visible variables |
| 90 | |
| 91 | (defgroup uniquify nil |
| 92 | "Unique buffer names dependent on file name." |
| 93 | :group 'files) |
| 94 | |
| 95 | |
| 96 | (defcustom uniquify-buffer-name-style nil |
| 97 | "If non-nil, buffer names are uniquified with parts of directory name. |
| 98 | The value determines the buffer name style and is one of `forward', |
| 99 | `reverse', `post-forward', or `post-forward-angle-brackets'. |
| 100 | For example, files `/foo/bar/mumble/name' and `/baz/quux/mumble/name' |
| 101 | would have the following buffer names in the various styles: |
| 102 | forward bar/mumble/name quux/mumble/name |
| 103 | reverse name\\mumble\\bar name\\mumble\\quux |
| 104 | post-forward name|bar/mumble name|quux/mumble |
| 105 | post-forward-angle-brackets name<bar/mumble> name<quux/mumble> |
| 106 | nil name name<2> |
| 107 | Of course, the \"mumble\" part may be stripped as well, depending on the setting |
| 108 | of `uniquify-strip-common-suffix'." |
| 109 | :type '(radio (const forward) |
| 110 | (const reverse) |
| 111 | (const post-forward) |
| 112 | (const post-forward-angle-brackets) |
| 113 | (const :tag "standard Emacs behavior (nil)" nil)) |
| 114 | :require 'uniquify |
| 115 | :group 'uniquify) |
| 116 | |
| 117 | (defcustom uniquify-after-kill-buffer-p t |
| 118 | "If non-nil, rerationalize buffer names after a buffer has been killed." |
| 119 | :type 'boolean |
| 120 | :group 'uniquify) |
| 121 | |
| 122 | (defcustom uniquify-ask-about-buffer-names-p nil |
| 123 | "If non-nil, permit user to choose names for buffers with same base file. |
| 124 | If the user chooses to name a buffer, uniquification is preempted and no |
| 125 | other buffer names are changed." |
| 126 | :type 'boolean |
| 127 | :group 'uniquify) |
| 128 | |
| 129 | ;; The default value matches certain Gnus buffers. |
| 130 | (defcustom uniquify-ignore-buffers-re nil |
| 131 | "Regular expression matching buffer names that should not be uniquified. |
| 132 | For instance, set this to \"^draft-[0-9]+$\" to avoid having uniquify rename |
| 133 | draft buffers even if `uniquify-after-kill-buffer-p' is non-nil and the |
| 134 | visited file name isn't the same as that of the buffer." |
| 135 | :type '(choice (const :tag "Uniquify all buffers" nil) regexp) |
| 136 | :group 'uniquify) |
| 137 | |
| 138 | (defcustom uniquify-min-dir-content 0 |
| 139 | "Minimum number of directory name components included in buffer name." |
| 140 | :type 'integer |
| 141 | :group 'uniquify) |
| 142 | |
| 143 | (defcustom uniquify-separator nil |
| 144 | "String separator for buffer name components. |
| 145 | When `uniquify-buffer-name-style' is `post-forward', separates |
| 146 | base file name from directory part in buffer names (default \"|\"). |
| 147 | When `uniquify-buffer-name-style' is `reverse', separates all |
| 148 | file name components (default \"\\\")." |
| 149 | :type '(choice (const nil) string) |
| 150 | :group 'uniquify) |
| 151 | |
| 152 | (defcustom uniquify-trailing-separator-p nil |
| 153 | "If non-nil, add a file name separator to dired buffer names. |
| 154 | If `uniquify-buffer-name-style' is `forward', add the separator at the end; |
| 155 | if it is `reverse', add the separator at the beginning; otherwise, this |
| 156 | variable is ignored." |
| 157 | :type 'boolean |
| 158 | :group 'uniquify) |
| 159 | |
| 160 | (defcustom uniquify-strip-common-suffix |
| 161 | ;; Using it when uniquify-min-dir-content>0 doesn't make much sense. |
| 162 | (eq 0 uniquify-min-dir-content) |
| 163 | "If non-nil, strip common directory suffixes of conflicting files. |
| 164 | E.g. if you open /a1/b/c/d and /a2/b/c/d, the buffer names will say |
| 165 | \"d|a1\" and \"d|a2\" instead of \"d|a1/b/c\" and \"d|a2/b/c\". |
| 166 | This can be handy when you have deep parallel hierarchies." |
| 167 | :type 'boolean |
| 168 | :group 'uniquify) |
| 169 | |
| 170 | (defvar uniquify-list-buffers-directory-modes '(dired-mode cvs-mode vc-dir-mode) |
| 171 | "List of modes for which uniquify should obey `list-buffers-directory'. |
| 172 | That means that when `buffer-file-name' is set to nil, `list-buffers-directory' |
| 173 | contains the name of the directory which the buffer is visiting.") |
| 174 | |
| 175 | ;;; Utilities |
| 176 | |
| 177 | ;; uniquify-fix-list data structure |
| 178 | (cl-defstruct (uniquify-item |
| 179 | (:constructor nil) (:copier nil) |
| 180 | (:constructor uniquify-make-item |
| 181 | (base dirname buffer &optional proposed))) |
| 182 | base dirname buffer proposed) |
| 183 | |
| 184 | ;; Internal variables used free |
| 185 | (defvar uniquify-possibly-resolvable nil) |
| 186 | |
| 187 | (defvar-local uniquify-managed nil |
| 188 | "Non-nil if the name of this buffer is managed by uniquify. |
| 189 | It actually holds the list of `uniquify-item's corresponding to the conflict.") |
| 190 | (put 'uniquify-managed 'permanent-local t) |
| 191 | |
| 192 | ;; Used in desktop.el to save the non-uniquified buffer name |
| 193 | (defun uniquify-buffer-base-name () |
| 194 | "Return the base name of the current buffer. |
| 195 | Return nil if the buffer is not managed by uniquify." |
| 196 | (and uniquify-managed |
| 197 | (uniquify-item-base (car uniquify-managed)))) |
| 198 | |
| 199 | ;;; Main entry point. |
| 200 | |
| 201 | (defun uniquify-rationalize-file-buffer-names (base dirname newbuf) |
| 202 | "Make file buffer names unique by adding segments from file name. |
| 203 | If `uniquify-min-dir-content' > 0, always pulls that many |
| 204 | file name elements. |
| 205 | Arguments BASE, DIRNAME, and NEWBUF specify the new buffer that causes |
| 206 | this rationalization." |
| 207 | (interactive |
| 208 | (list (if uniquify-managed |
| 209 | (uniquify-item-base (car uniquify-managed)) (buffer-name)) |
| 210 | (uniquify-buffer-file-name (current-buffer)) |
| 211 | (current-buffer))) |
| 212 | ;; Make sure we don't get confused by outdated uniquify-managed info in |
| 213 | ;; this buffer. |
| 214 | (with-current-buffer newbuf (setq uniquify-managed nil)) |
| 215 | (when dirname |
| 216 | (setq dirname (expand-file-name (directory-file-name dirname))) |
| 217 | (let ((fix-list (list (uniquify-make-item base dirname newbuf))) |
| 218 | items) |
| 219 | (dolist (buffer (buffer-list)) |
| 220 | (when (and (not (and uniquify-ignore-buffers-re |
| 221 | (string-match uniquify-ignore-buffers-re |
| 222 | (buffer-name buffer)))) |
| 223 | ;; Only try to rename buffers we actually manage. |
| 224 | (setq items (buffer-local-value 'uniquify-managed buffer)) |
| 225 | (equal base (uniquify-item-base (car items))) |
| 226 | ;; Don't re-add stuff we already have. Actually this |
| 227 | ;; whole `and' test should only match at most once. |
| 228 | (not (memq (car items) fix-list))) |
| 229 | (unless (cdr items) |
| 230 | ;; If there was no conflict, the buffer-name is equal to the |
| 231 | ;; base-name and we may have missed a rename-buffer because |
| 232 | ;; of code like in set-visited-file-name: |
| 233 | ;; (or (string= new-name (buffer-name)) (rename-buffer new-name t)) |
| 234 | ;; So we need to refresh the dirname of the uniquify-item. |
| 235 | (setf (uniquify-item-dirname (car items)) |
| 236 | (uniquify-buffer-file-name |
| 237 | (uniquify-item-buffer (car items)))) |
| 238 | ;; This shouldn't happen, but maybe there's no dirname any more. |
| 239 | (unless (uniquify-item-dirname (car items)) |
| 240 | (with-current-buffer (uniquify-item-buffer (car items)) |
| 241 | (setq uniquify-managed nil)) |
| 242 | (setq items nil))) |
| 243 | ;; In case we missed some calls to kill-buffer, there may be dead |
| 244 | ;; buffers in uniquify-managed, so filter them out. |
| 245 | (setq items |
| 246 | (delq nil (mapcar |
| 247 | (lambda (item) |
| 248 | (if (buffer-live-p (uniquify-item-buffer item)) |
| 249 | item)) |
| 250 | items))) |
| 251 | (setq fix-list (append fix-list items)))) |
| 252 | ;; selects buffers whose names may need changing, and others that |
| 253 | ;; may conflict, then bring conflicting names together |
| 254 | (uniquify-rationalize fix-list)))) |
| 255 | |
| 256 | ;; uniquify's version of buffer-file-name; result never contains trailing slash |
| 257 | (defun uniquify-buffer-file-name (buffer) |
| 258 | "Return name of directory, file BUFFER is visiting, or nil if none. |
| 259 | Works on ordinary file-visiting buffers and buffers whose mode is mentioned |
| 260 | in `uniquify-list-buffers-directory-modes', otherwise returns nil." |
| 261 | (with-current-buffer buffer |
| 262 | (let ((filename |
| 263 | (or buffer-file-name |
| 264 | (if (memq major-mode uniquify-list-buffers-directory-modes) |
| 265 | list-buffers-directory)))) |
| 266 | (when filename |
| 267 | (directory-file-name |
| 268 | (file-name-directory |
| 269 | (expand-file-name |
| 270 | (directory-file-name filename)))))))) |
| 271 | |
| 272 | (defun uniquify-rerationalize-w/o-cb (fix-list) |
| 273 | "Re-rationalize the buffers in FIX-LIST, but ignoring `current-buffer'." |
| 274 | (let ((new-fix-list nil)) |
| 275 | (dolist (item fix-list) |
| 276 | (let ((buf (uniquify-item-buffer item))) |
| 277 | (unless (or (eq buf (current-buffer)) (not (buffer-live-p buf))) |
| 278 | (push item new-fix-list)))) |
| 279 | (when new-fix-list |
| 280 | (uniquify-rationalize new-fix-list)))) |
| 281 | |
| 282 | (defun uniquify-rationalize (fix-list) |
| 283 | ;; Set up uniquify to re-rationalize after killing/renaming |
| 284 | ;; if there is a conflict. |
| 285 | (dolist (item fix-list) |
| 286 | (with-current-buffer (uniquify-item-buffer item) |
| 287 | ;; Refresh the dirnames and proposed names. |
| 288 | (setf (uniquify-item-proposed item) |
| 289 | (uniquify-get-proposed-name (uniquify-item-base item) |
| 290 | (uniquify-item-dirname item))) |
| 291 | (setq uniquify-managed fix-list))) |
| 292 | ;; Strip any shared last directory names of the dirname. |
| 293 | (when (and (cdr fix-list) uniquify-strip-common-suffix) |
| 294 | (let ((strip t)) |
| 295 | (while (let* ((base (file-name-nondirectory |
| 296 | (uniquify-item-dirname (car fix-list)))) |
| 297 | (items fix-list)) |
| 298 | (when (> (length base) 0) |
| 299 | (while (and strip items) |
| 300 | (unless (equal base (file-name-nondirectory |
| 301 | (uniquify-item-dirname (pop items)))) |
| 302 | (setq strip nil))) |
| 303 | strip)) |
| 304 | ;; It's all the same => strip. |
| 305 | (dolist (item (prog1 fix-list (setq fix-list nil))) |
| 306 | ;; Create new items because the old ones are kept (with the true |
| 307 | ;; `dirname') for later rerationalizing. |
| 308 | (push (uniquify-make-item (uniquify-item-base item) |
| 309 | (let ((f (file-name-directory |
| 310 | (uniquify-item-dirname item)))) |
| 311 | (and f (directory-file-name f))) |
| 312 | (uniquify-item-buffer item) |
| 313 | (uniquify-item-proposed item)) |
| 314 | fix-list))))) |
| 315 | ;; If uniquify-min-dir-content is 0, this will end up just |
| 316 | ;; passing fix-list to uniquify-rationalize-conflicting-sublist. |
| 317 | (uniquify-rationalize-a-list fix-list)) |
| 318 | |
| 319 | (defun uniquify-item-greaterp (item1 item2) |
| 320 | (string-lessp (uniquify-item-proposed item2) |
| 321 | (uniquify-item-proposed item1))) |
| 322 | |
| 323 | (defun uniquify-rationalize-a-list (fix-list &optional depth) |
| 324 | (unless depth (setq depth uniquify-min-dir-content)) |
| 325 | (let (conflicting-sublist ; all elements have the same proposed name |
| 326 | (old-proposed "") |
| 327 | proposed) |
| 328 | ;; Divide fix-list into items with same proposed names and pass them |
| 329 | ;; to uniquify-rationalize-conflicting-sublist. |
| 330 | (dolist (item (sort (copy-sequence fix-list) 'uniquify-item-greaterp)) |
| 331 | (setq proposed (uniquify-item-proposed item)) |
| 332 | (unless (equal proposed old-proposed) |
| 333 | (uniquify-rationalize-conflicting-sublist conflicting-sublist |
| 334 | old-proposed depth) |
| 335 | (setq conflicting-sublist nil)) |
| 336 | (push item conflicting-sublist) |
| 337 | (setq old-proposed proposed)) |
| 338 | (uniquify-rationalize-conflicting-sublist conflicting-sublist |
| 339 | old-proposed depth))) |
| 340 | |
| 341 | (defun uniquify-get-proposed-name (base dirname &optional depth) |
| 342 | (unless depth (setq depth uniquify-min-dir-content)) |
| 343 | (cl-assert (equal (directory-file-name dirname) dirname)) ;No trailing slash. |
| 344 | |
| 345 | ;; Distinguish directories by adding extra separator. |
| 346 | (if (and uniquify-trailing-separator-p |
| 347 | (file-directory-p (expand-file-name base dirname)) |
| 348 | (not (string-equal base ""))) |
| 349 | (cond ((eq uniquify-buffer-name-style 'forward) |
| 350 | (setq base (file-name-as-directory base))) |
| 351 | ;; (setq base (concat base "/"))) |
| 352 | ((eq uniquify-buffer-name-style 'reverse) |
| 353 | (setq base (concat (or uniquify-separator "\\") base))))) |
| 354 | |
| 355 | (let ((extra-string nil) |
| 356 | (n depth)) |
| 357 | (while (and (> n 0) dirname) |
| 358 | (let ((file (file-name-nondirectory dirname))) |
| 359 | (when (setq dirname (file-name-directory dirname)) |
| 360 | (setq dirname (directory-file-name dirname))) |
| 361 | (setq n (1- n)) |
| 362 | (push (if (zerop (length file)) ;nil or "". |
| 363 | (prog1 (or (file-remote-p dirname) "") |
| 364 | (setq dirname nil)) ;Could be `dirname' iso "". |
| 365 | file) |
| 366 | extra-string))) |
| 367 | (when (zerop n) |
| 368 | (if (and dirname extra-string |
| 369 | (equal dirname (file-name-directory dirname))) |
| 370 | ;; We're just before the root. Let's add the leading / already. |
| 371 | ;; With "/a/b"+"/c/d/b" this leads to "/a/b" and "d/b" but with |
| 372 | ;; "/a/b"+"/c/a/b" this leads to "/a/b" and "a/b". |
| 373 | (push "" extra-string)) |
| 374 | (setq uniquify-possibly-resolvable t)) |
| 375 | |
| 376 | (cond |
| 377 | ((null extra-string) base) |
| 378 | ((string-equal base "") ;Happens for dired buffers on the root directory. |
| 379 | (mapconcat 'identity extra-string "/")) |
| 380 | ((eq uniquify-buffer-name-style 'reverse) |
| 381 | (mapconcat 'identity |
| 382 | (cons base (nreverse extra-string)) |
| 383 | (or uniquify-separator "\\"))) |
| 384 | ((eq uniquify-buffer-name-style 'forward) |
| 385 | (mapconcat 'identity (nconc extra-string (list base)) |
| 386 | "/")) |
| 387 | ((eq uniquify-buffer-name-style 'post-forward) |
| 388 | (concat base (or uniquify-separator "|") |
| 389 | (mapconcat 'identity extra-string "/"))) |
| 390 | ((eq uniquify-buffer-name-style 'post-forward-angle-brackets) |
| 391 | (concat base "<" (mapconcat 'identity extra-string "/") |
| 392 | ">")) |
| 393 | (t (error "Bad value for uniquify-buffer-name-style: %s" |
| 394 | uniquify-buffer-name-style))))) |
| 395 | |
| 396 | |
| 397 | ;; Deal with conflicting-sublist, all of whose elements have identical |
| 398 | ;; "base" components. |
| 399 | (defun uniquify-rationalize-conflicting-sublist (conf-list old-name depth) |
| 400 | (when conf-list |
| 401 | (if (or (cdr conf-list) |
| 402 | ;; Check that the proposed name doesn't conflict with some |
| 403 | ;; existing buffer. |
| 404 | (let ((buf (get-buffer old-name))) |
| 405 | (and buf (not (eq buf (uniquify-item-buffer (car conf-list))))))) |
| 406 | (when uniquify-possibly-resolvable |
| 407 | (setq uniquify-possibly-resolvable nil |
| 408 | depth (1+ depth)) |
| 409 | (dolist (item conf-list) |
| 410 | (setf (uniquify-item-proposed item) |
| 411 | (uniquify-get-proposed-name |
| 412 | (uniquify-item-base item) |
| 413 | (uniquify-item-dirname item) |
| 414 | depth))) |
| 415 | (uniquify-rationalize-a-list conf-list depth)) |
| 416 | (unless (string= old-name "") |
| 417 | (uniquify-rename-buffer (car conf-list) old-name))))) |
| 418 | |
| 419 | |
| 420 | (defun uniquify-rename-buffer (item newname) |
| 421 | (let ((buffer (uniquify-item-buffer item))) |
| 422 | (unless (equal newname (buffer-name buffer)) |
| 423 | (with-current-buffer buffer |
| 424 | (let ((uniquify-buffer-name-style nil)) ;Avoid hooks on rename-buffer. |
| 425 | ;; Pass the `unique' arg, so the advice doesn't mark it as unmanaged. |
| 426 | (rename-buffer newname t)))))) |
| 427 | |
| 428 | ;;; Hooks from the rest of Emacs |
| 429 | |
| 430 | (defun uniquify-maybe-rerationalize-w/o-cb () |
| 431 | "Re-rationalize buffer names, ignoring current buffer." |
| 432 | (and (cdr uniquify-managed) |
| 433 | uniquify-buffer-name-style |
| 434 | (uniquify-rerationalize-w/o-cb uniquify-managed))) |
| 435 | |
| 436 | ;; Buffer deletion |
| 437 | ;; Rerationalize after a buffer is killed, to reduce coinciding buffer names. |
| 438 | ;; This mechanism uses `kill-buffer-hook', which runs *before* deletion, so |
| 439 | ;; it calls `uniquify-rerationalize-w/o-cb' to rerationalize the buffer list |
| 440 | ;; ignoring the current buffer (which is going to be deleted anyway). |
| 441 | (defun uniquify-kill-buffer-function () |
| 442 | "Re-rationalize buffer names, ignoring current buffer. |
| 443 | For use on `kill-buffer-hook'." |
| 444 | (and uniquify-after-kill-buffer-p |
| 445 | (uniquify-maybe-rerationalize-w/o-cb))) |
| 446 | |
| 447 | ;; Ideally we'd like to add it buffer-locally, but that doesn't work |
| 448 | ;; because kill-buffer-hook is not permanent-local :-( |
| 449 | ;; FIXME kill-buffer-hook _is_ permanent-local in 22+. |
| 450 | (add-hook 'kill-buffer-hook 'uniquify-kill-buffer-function) |
| 451 | |
| 452 | ;; The logical place to put all this code is in generate-new-buffer-name. |
| 453 | ;; It's written in C, so we would add a generate-new-buffer-name-function |
| 454 | ;; which, if non-nil, would be called instead of the C. One problem with |
| 455 | ;; that is that generate-new-buffer-name takes a potential buffer name as |
| 456 | ;; its argument -- not other information, such as what file the buffer will |
| 457 | ;; visit. |
| 458 | |
| 459 | ;; The below solution works because generate-new-buffer-name is called |
| 460 | ;; only by rename-buffer (which, as of 19.29, is never called from C) and |
| 461 | ;; generate-new-buffer, which is called only by Lisp functions |
| 462 | ;; create-file-buffer and rename-uniquely. Rename-uniquely generally |
| 463 | ;; isn't used for buffers visiting files, so it's sufficient to hook |
| 464 | ;; rename-buffer and create-file-buffer. (Setting find-file-hook isn't |
| 465 | ;; sufficient.) |
| 466 | |
| 467 | (advice-add 'rename-buffer :around #'uniquify--rename-buffer-advice) |
| 468 | (defun uniquify--rename-buffer-advice (rb-fun newname &optional unique &rest args) |
| 469 | "Uniquify buffer names with parts of directory name." |
| 470 | (let ((retval (apply rb-fun newname unique args))) |
| 471 | (uniquify-maybe-rerationalize-w/o-cb) |
| 472 | (if (null unique) |
| 473 | ;; Mark this buffer so it won't be renamed by uniquify. |
| 474 | (setq uniquify-managed nil) |
| 475 | (when uniquify-buffer-name-style |
| 476 | ;; Rerationalize w.r.t the new name. |
| 477 | (uniquify-rationalize-file-buffer-names |
| 478 | newname |
| 479 | (uniquify-buffer-file-name (current-buffer)) |
| 480 | (current-buffer)) |
| 481 | (setq retval (buffer-name (current-buffer))))) |
| 482 | retval)) |
| 483 | |
| 484 | |
| 485 | (advice-add 'create-file-buffer :around #'uniquify--create-file-buffer-advice) |
| 486 | (defun uniquify--create-file-buffer-advice (cfb-fun filename &rest args) |
| 487 | "Uniquify buffer names with parts of directory name." |
| 488 | (let ((retval (apply cfb-fun filename args))) |
| 489 | (if uniquify-buffer-name-style |
| 490 | (let ((filename (expand-file-name (directory-file-name filename)))) |
| 491 | (uniquify-rationalize-file-buffer-names |
| 492 | (file-name-nondirectory filename) |
| 493 | (file-name-directory filename) retval))) |
| 494 | retval)) |
| 495 | |
| 496 | ;;; The End |
| 497 | |
| 498 | (defun uniquify-unload-function () |
| 499 | "Unload the uniquify library." |
| 500 | (save-current-buffer |
| 501 | (let ((buffers nil)) |
| 502 | (dolist (buf (buffer-list)) |
| 503 | (set-buffer buf) |
| 504 | (when uniquify-managed |
| 505 | (push (cons buf (uniquify-item-base (car uniquify-managed))) buffers))) |
| 506 | (advice-remove 'rename-buffer #'uniquify--rename-buffer-advice) |
| 507 | (advice-remove 'create-file-buffer #'uniquify--create-file-buffer-advice) |
| 508 | (dolist (buf buffers) |
| 509 | (set-buffer (car buf)) |
| 510 | (rename-buffer (cdr buf) t)))) |
| 511 | ;; continue standard unloading |
| 512 | nil) |
| 513 | |
| 514 | (provide 'uniquify) |
| 515 | |
| 516 | ;;; uniquify.el ends here |