| 1 | ;;; mailheader.el --- mail header parsing, merging, formatting |
| 2 | |
| 3 | ;; Copyright (C) 1996, 2001-2012 Free Software Foundation, Inc. |
| 4 | |
| 5 | ;; Author: Erik Naggum <erik@naggum.no> |
| 6 | ;; Keywords: tools, mail, news |
| 7 | ;; Package: mail-utils |
| 8 | |
| 9 | ;; This file is part of GNU Emacs. |
| 10 | |
| 11 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 12 | ;; it under the terms of the GNU General Public License as published by |
| 13 | ;; the Free Software Foundation, either version 3 of the License, or |
| 14 | ;; (at your option) any later version. |
| 15 | |
| 16 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 19 | ;; GNU General Public License for more details. |
| 20 | |
| 21 | ;; You should have received a copy of the GNU General Public License |
| 22 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 23 | |
| 24 | ;;; Commentary: |
| 25 | |
| 26 | ;; This package provides an abstraction to RFC822-style messages, used in |
| 27 | ;; mail, news, and some other systems. The simple syntactic rules for such |
| 28 | ;; headers, such as quoting and line folding, are routinely reimplemented |
| 29 | ;; in many individual packages. This package removes the need for this |
| 30 | ;; redundancy by representing message headers as association lists, |
| 31 | ;; offering functions to extract the set of headers from a message, to |
| 32 | ;; parse individual headers, to merge sets of headers, and to format a set |
| 33 | ;; of headers. |
| 34 | |
| 35 | ;; The car of each element in the message-header alist is a symbol whose |
| 36 | ;; print name is the name of the header, in all lower-case. The cdr of an |
| 37 | ;; element depends on the operation. After extracting headers from a |
| 38 | ;; message, it is a string, the value of the header. An extracted set of |
| 39 | ;; headers may be parsed further, which may turn it into a list, whose car |
| 40 | ;; is the original value and whose subsequent elements depend on the |
| 41 | ;; header. For formatting, it is evaluated to obtain the strings to be |
| 42 | ;; inserted. For merging, one set of headers consists of strings, while |
| 43 | ;; the other set will be evaluated with the symbols in the first set of |
| 44 | ;; headers bound to their respective values. |
| 45 | |
| 46 | ;;; Code: |
| 47 | |
| 48 | (eval-when-compile |
| 49 | (require 'cl)) |
| 50 | |
| 51 | (defun mail-header-extract () |
| 52 | "Extract headers from current buffer after point. |
| 53 | Returns a header alist, where each element is a cons cell (name . value), |
| 54 | where NAME is a symbol, and VALUE is the string value of the header having |
| 55 | that name." |
| 56 | (let ((message-headers ()) (top (point)) |
| 57 | start end) |
| 58 | (while (and (setq start (point)) |
| 59 | (> (skip-chars-forward "^\0- :") 0) |
| 60 | (= (following-char) ?:) |
| 61 | (setq end (point)) |
| 62 | (progn (forward-char) |
| 63 | (> (skip-chars-forward " \t") 0))) |
| 64 | (let ((header (intern (downcase (buffer-substring start end)))) |
| 65 | (value (list (buffer-substring |
| 66 | (point) (progn (end-of-line) (point)))))) |
| 67 | (while (progn (forward-char) (> (skip-chars-forward " \t") 0)) |
| 68 | (push (buffer-substring (point) (progn (end-of-line) (point))) |
| 69 | value)) |
| 70 | (push (if (cdr value) |
| 71 | (cons header (mapconcat #'identity (nreverse value) " ")) |
| 72 | (cons header (car value))) |
| 73 | message-headers))) |
| 74 | (goto-char top) |
| 75 | (nreverse message-headers))) |
| 76 | |
| 77 | (defun mail-header-extract-no-properties () |
| 78 | "Extract headers from current buffer after point, without properties. |
| 79 | Returns a header alist, where each element is a cons cell (name . value), |
| 80 | where NAME is a symbol, and VALUE is the string value of the header having |
| 81 | that name." |
| 82 | (mapcar |
| 83 | (lambda (elt) |
| 84 | (set-text-properties 0 (length (cdr elt)) nil (cdr elt)) |
| 85 | elt) |
| 86 | (mail-header-extract))) |
| 87 | |
| 88 | (defun mail-header-parse (parsing-rules headers) |
| 89 | "Apply PARSING-RULES to HEADERS. |
| 90 | PARSING-RULES is an alist whose keys are header names (symbols) and whose |
| 91 | value is a parsing function. The function takes one argument, a string, |
| 92 | and return a list of values, which will destructively replace the value |
| 93 | associated with the key in HEADERS, after being prepended with the original |
| 94 | value." |
| 95 | (dolist (rule parsing-rules) |
| 96 | (let ((header (assq (car rule) headers))) |
| 97 | (when header |
| 98 | (if (consp (cdr header)) |
| 99 | (setf (cddr header) (funcall (cdr rule) (cadr header))) |
| 100 | (setf (cdr header) |
| 101 | (cons (cdr header) (funcall (cdr rule) (cdr header)))))))) |
| 102 | headers) |
| 103 | |
| 104 | ;; Advertised part of the interface; see mail-header, mail-header-set. |
| 105 | (defvar headers) |
| 106 | |
| 107 | (defsubst mail-header (header &optional header-alist) |
| 108 | "Return the value associated with header HEADER in HEADER-ALIST. |
| 109 | If the value is a string, it is the original value of the header. If the |
| 110 | value is a list, its first element is the original value of the header, |
| 111 | with any subsequent elements being the result of parsing the value. |
| 112 | If HEADER-ALIST is nil, the dynamically bound variable `headers' is used." |
| 113 | (cdr (assq header (or header-alist headers)))) |
| 114 | |
| 115 | (defun mail-header-set (header value &optional header-alist) |
| 116 | "Set the value associated with header HEADER to VALUE in HEADER-ALIST. |
| 117 | HEADER-ALIST defaults to the dynamically bound variable `headers' if nil. |
| 118 | See `mail-header' for the semantics of VALUE." |
| 119 | (let* ((alist (or header-alist headers)) |
| 120 | (entry (assq header alist))) |
| 121 | (if entry |
| 122 | (setf (cdr entry) value) |
| 123 | (nconc alist (list (cons header value))))) |
| 124 | value) |
| 125 | |
| 126 | (defsetf mail-header (header &optional header-alist) (value) |
| 127 | `(mail-header-set ,header ,value ,header-alist)) |
| 128 | |
| 129 | (defun mail-header-merge (merge-rules headers) |
| 130 | "Return a new header alist with MERGE-RULES applied to HEADERS. |
| 131 | MERGE-RULES is an alist whose keys are header names (symbols) and whose |
| 132 | values are forms to evaluate, the results of which are the new headers. It |
| 133 | should be a string or a list of string. The first element may be nil to |
| 134 | denote that the formatting functions must use the remaining elements, or |
| 135 | skip the header altogether if there are no other elements. |
| 136 | The macro `mail-header' can be used to access headers in HEADERS." |
| 137 | (mapcar |
| 138 | (lambda (rule) |
| 139 | (cons (car rule) (eval (cdr rule)))) |
| 140 | merge-rules)) |
| 141 | |
| 142 | (defvar mail-header-format-function |
| 143 | (lambda (header value) |
| 144 | "Function to format headers without a specified formatting function." |
| 145 | (insert (capitalize (symbol-name header)) |
| 146 | ": " |
| 147 | (if (consp value) (car value) value) |
| 148 | "\n"))) |
| 149 | |
| 150 | (defun mail-header-format (format-rules headers) |
| 151 | "Use FORMAT-RULES to format HEADERS and insert into current buffer. |
| 152 | HEADERS should be an alist of the form (HEADER . VALUE), |
| 153 | where HEADER is a header field name (a symbol or a string), |
| 154 | and VALUE is the contents for that header field. |
| 155 | |
| 156 | FORMAT-RULES is an alist of elements (HEADER . FUNCTION) Here HEADER |
| 157 | is a header field name (a symbol), and FUNCTION is how to format that |
| 158 | header field, if it appears in HEADERS. Each FUNCTION should take two |
| 159 | arguments: the header symbol, and the value of that header. The value |
| 160 | returned by FUNCTION is inserted in the buffer unless it is nil. |
| 161 | |
| 162 | If the function for a header field is nil, or if no function is |
| 163 | specified for a particular header field, the default action is to |
| 164 | insert the value of the header, unless it is nil. |
| 165 | |
| 166 | The headers are inserted in the order of the FORMAT-RULES. |
| 167 | A key of t in FORMAT-RULES represents any otherwise unmentioned headers. |
| 168 | A key of nil has as its value a list of defaulted headers to ignore." |
| 169 | (let ((ignore (append (cdr (assq nil format-rules)) |
| 170 | (mapcar #'car format-rules)))) |
| 171 | (dolist (rule format-rules) |
| 172 | (let* ((header (car rule)) |
| 173 | (value (mail-header header))) |
| 174 | (if (stringp header) |
| 175 | (setq header (intern header))) |
| 176 | (cond ((null header) 'ignore) |
| 177 | ((eq header t) |
| 178 | (dolist (defaulted headers) |
| 179 | (unless (memq (car defaulted) ignore) |
| 180 | (let* ((header (car defaulted)) |
| 181 | (value (cdr defaulted))) |
| 182 | (if (cdr rule) |
| 183 | (funcall (cdr rule) header value) |
| 184 | (funcall mail-header-format-function header value)))))) |
| 185 | (value |
| 186 | (if (cdr rule) |
| 187 | (funcall (cdr rule) header value) |
| 188 | (funcall mail-header-format-function header value)))))) |
| 189 | (insert "\n"))) |
| 190 | |
| 191 | (provide 'mailheader) |
| 192 | |
| 193 | ;;; mailheader.el ends here |