| 1 | ;;; japan-util.el --- utilities for Japanese -*- coding: iso-2022-7bit; -*- |
| 2 | |
| 3 | ;; Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010 |
| 4 | ;; Free Software Foundation, Inc. |
| 5 | ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, |
| 6 | ;; 2005, 2006, 2007, 2008, 2009, 2010 |
| 7 | ;; National Institute of Advanced Industrial Science and Technology (AIST) |
| 8 | ;; Registration Number H14PRO021 |
| 9 | |
| 10 | ;; Keywords: mule, multilingual, Japanese |
| 11 | |
| 12 | ;; This file is part of GNU Emacs. |
| 13 | |
| 14 | ;; GNU Emacs is free software: you can redistribute it and/or modify |
| 15 | ;; it under the terms of the GNU General Public License as published by |
| 16 | ;; the Free Software Foundation, either version 3 of the License, or |
| 17 | ;; (at your option) any later version. |
| 18 | |
| 19 | ;; GNU Emacs is distributed in the hope that it will be useful, |
| 20 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 21 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 22 | ;; GNU General Public License for more details. |
| 23 | |
| 24 | ;; You should have received a copy of the GNU General Public License |
| 25 | ;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>. |
| 26 | |
| 27 | ;;; Commentary: |
| 28 | |
| 29 | ;;; Code: |
| 30 | |
| 31 | ;;;###autoload |
| 32 | (defun setup-japanese-environment-internal () |
| 33 | ;; By default, we use 'japanese-iso-8bit for file names. But, the |
| 34 | ;; following prefer-coding-system will override it. |
| 35 | (if (memq system-type '(windows-nt ms-dos cygwin)) |
| 36 | (prefer-coding-system 'japanese-shift-jis) |
| 37 | (prefer-coding-system 'japanese-iso-8bit)) |
| 38 | (use-cjk-char-width-table 'ja_JP)) |
| 39 | |
| 40 | (defconst japanese-kana-table |
| 41 | '((?\e$B$"\e(B ?\e$B%"\e(B ?\e(I1\e(B) (?\e$B$$\e(B ?\e$B%$\e(B ?\e(I2\e(B) (?\e$B$&\e(B ?\e$B%&\e(B ?\e(I3\e(B) (?\e$B$(\e(B ?\e$B%(\e(B ?\e(I4\e(B) (?\e$B$*\e(B ?\e$B%*\e(B ?\e(I5\e(B) |
| 42 | (?\e$B$+\e(B ?\e$B%+\e(B ?\e(I6\e(B) (?\e$B$-\e(B ?\e$B%-\e(B ?\e(I7\e(B) (?\e$B$/\e(B ?\e$B%/\e(B ?\e(I8\e(B) (?\e$B$1\e(B ?\e$B%1\e(B ?\e(I9\e(B) (?\e$B$3\e(B ?\e$B%3\e(B ?\e(I:\e(B) |
| 43 | (?\e$B$5\e(B ?\e$B%5\e(B ?\e(I;\e(B) (?\e$B$7\e(B ?\e$B%7\e(B ?\e(I<\e(B) (?\e$B$9\e(B ?\e$B%9\e(B ?\e(I=\e(B) (?\e$B$;\e(B ?\e$B%;\e(B ?\e(I>\e(B) (?\e$B$=\e(B ?\e$B%=\e(B ?\e(I?\e(B) |
| 44 | (?\e$B$?\e(B ?\e$B%?\e(B ?\e(I@\e(B) (?\e$B$A\e(B ?\e$B%A\e(B ?\e(IA\e(B) (?\e$B$D\e(B ?\e$B%D\e(B ?\e(IB\e(B) (?\e$B$F\e(B ?\e$B%F\e(B ?\e(IC\e(B) (?\e$B$H\e(B ?\e$B%H\e(B ?\e(ID\e(B) |
| 45 | (?\e$B$J\e(B ?\e$B%J\e(B ?\e(IE\e(B) (?\e$B$K\e(B ?\e$B%K\e(B ?\e(IF\e(B) (?\e$B$L\e(B ?\e$B%L\e(B ?\e(IG\e(B) (?\e$B$M\e(B ?\e$B%M\e(B ?\e(IH\e(B) (?\e$B$N\e(B ?\e$B%N\e(B ?\e(II\e(B) |
| 46 | (?\e$B$O\e(B ?\e$B%O\e(B ?\e(IJ\e(B) (?\e$B$R\e(B ?\e$B%R\e(B ?\e(IK\e(B) (?\e$B$U\e(B ?\e$B%U\e(B ?\e(IL\e(B) (?\e$B$X\e(B ?\e$B%X\e(B ?\e(IM\e(B) (?\e$B$[\e(B ?\e$B%[\e(B ?\e(IN\e(B) |
| 47 | (?\e$B$^\e(B ?\e$B%^\e(B ?\e(IO\e(B) (?\e$B$_\e(B ?\e$B%_\e(B ?\e(IP\e(B) (?\e$B$`\e(B ?\e$B%`\e(B ?\e(IQ\e(B) (?\e$B$a\e(B ?\e$B%a\e(B ?\e(IR\e(B) (?\e$B$b\e(B ?\e$B%b\e(B ?\e(IS\e(B) |
| 48 | (?\e$B$d\e(B ?\e$B%d\e(B ?\e(IT\e(B) (?\e$B$f\e(B ?\e$B%f\e(B ?\e(IU\e(B) (?\e$B$h\e(B ?\e$B%h\e(B ?\e(IV\e(B) |
| 49 | (?\e$B$i\e(B ?\e$B%i\e(B ?\e(IW\e(B) (?\e$B$j\e(B ?\e$B%j\e(B ?\e(IX\e(B) (?\e$B$k\e(B ?\e$B%k\e(B ?\e(IY\e(B) (?\e$B$l\e(B ?\e$B%l\e(B ?\e(IZ\e(B) (?\e$B$m\e(B ?\e$B%m\e(B ?\e(I[\e(B) |
| 50 | (?\e$B$o\e(B ?\e$B%o\e(B ?\e(I\\e(B) (?\e$B$p\e(B ?\e$B%p\e(B "\e(I2\e(B") (?\e$B$q\e(B ?\e$B%q\e(B "\e(I4\e(B") (?\e$B$r\e(B ?\e$B%r\e(B ?\e(I&\e(B) |
| 51 | (?\e$B$s\e(B ?\e$B%s\e(B ?\e(I]\e(B) |
| 52 | (?\e$B$,\e(B ?\e$B%,\e(B "\e(I6^\e(B") (?\e$B$.\e(B ?\e$B%.\e(B "\e(I7^\e(B") (?\e$B$0\e(B ?\e$B%0\e(B "\e(I8^\e(B") (?\e$B$2\e(B ?\e$B%2\e(B "\e(I9^\e(B") (?\e$B$4\e(B ?\e$B%4\e(B "\e(I:^\e(B") |
| 53 | (?\e$B$6\e(B ?\e$B%6\e(B "\e(I;^\e(B") (?\e$B$8\e(B ?\e$B%8\e(B "\e(I<^\e(B") (?\e$B$:\e(B ?\e$B%:\e(B "\e(I=^\e(B") (?\e$B$<\e(B ?\e$B%<\e(B "\e(I>^\e(B") (?\e$B$>\e(B ?\e$B%>\e(B "\e(I?^\e(B") |
| 54 | (?\e$B$@\e(B ?\e$B%@\e(B "\e(I@^\e(B") (?\e$B$B\e(B ?\e$B%B\e(B "\e(IA^\e(B") (?\e$B$E\e(B ?\e$B%E\e(B "\e(IB^\e(B") (?\e$B$G\e(B ?\e$B%G\e(B "\e(IC^\e(B") (?\e$B$I\e(B ?\e$B%I\e(B "\e(ID^\e(B") |
| 55 | (?\e$B$P\e(B ?\e$B%P\e(B "\e(IJ^\e(B") (?\e$B$S\e(B ?\e$B%S\e(B "\e(IK^\e(B") (?\e$B$V\e(B ?\e$B%V\e(B "\e(IL^\e(B") (?\e$B$Y\e(B ?\e$B%Y\e(B "\e(IM^\e(B") (?\e$B$\\e(B ?\e$B%\\e(B "\e(IN^\e(B") |
| 56 | (?\e$B$Q\e(B ?\e$B%Q\e(B "\e(IJ_\e(B") (?\e$B$T\e(B ?\e$B%T\e(B "\e(IK_\e(B") (?\e$B$W\e(B ?\e$B%W\e(B "\e(IL_\e(B") (?\e$B$Z\e(B ?\e$B%Z\e(B "\e(IM_\e(B") (?\e$B$]\e(B ?\e$B%]\e(B "\e(IN_\e(B") |
| 57 | (?\e$B$!\e(B ?\e$B%!\e(B ?\e(I'\e(B) (?\e$B$#\e(B ?\e$B%#\e(B ?\e(I(\e(B) (?\e$B$%\e(B ?\e$B%%\e(B ?\e(I)\e(B) (?\e$B$'\e(B ?\e$B%'\e(B ?\e(I*\e(B) (?\e$B$)\e(B ?\e$B%)\e(B ?\e(I+\e(B) |
| 58 | (?\e$B$C\e(B ?\e$B%C\e(B ?\e(I/\e(B) |
| 59 | (?\e$B$c\e(B ?\e$B%c\e(B ?\e(I,\e(B) (?\e$B$e\e(B ?\e$B%e\e(B ?\e(I-\e(B) (?\e$B$g\e(B ?\e$B%g\e(B ?\e(I.\e(B) |
| 60 | (?\e$B$n\e(B ?\e$B%n\e(B "\e(I\\e(B") |
| 61 | ("\e$B$&!+\e(B" ?\e$B%t\e(B "\e(I3^\e(B") (nil ?\e$B%u\e(B "\e(I6\e(B") (nil ?\e$B%v\e(B "\e(I9\e(B")) |
| 62 | "Japanese JISX0208 Kana character table. |
| 63 | Each element is of the form (HIRAGANA KATAKANA HANKAKU-KATAKANA), where |
| 64 | HIRAGANA and KATAKANA belong to `japanese-jisx0208', |
| 65 | HANKAKU-KATAKANA belongs to `japanese-jisx0201-kana'.") |
| 66 | |
| 67 | ;; Put properties 'katakana, 'hiragana, and 'jix0201 to each Japanese |
| 68 | ;; kana characters for conversion among them. |
| 69 | (let ((l japanese-kana-table) |
| 70 | slot hiragana katakana jisx0201) |
| 71 | (while l |
| 72 | (setq slot (car l) |
| 73 | hiragana (car slot) katakana (nth 1 slot) jisx0201 (nth 2 slot) |
| 74 | l (cdr l)) |
| 75 | (if hiragana |
| 76 | (if (stringp hiragana) |
| 77 | (if (> (length hiragana) 1) |
| 78 | (let ((hira (aref hiragana 0))) |
| 79 | (put-char-code-property |
| 80 | hira 'kana-composition |
| 81 | (cons (cons (aref hiragana 1) katakana) |
| 82 | (get-char-code-property hira 'kana-composition))))) |
| 83 | (put-char-code-property hiragana 'katakana katakana) |
| 84 | (put-char-code-property hiragana 'jisx0201 jisx0201))) |
| 85 | (when (integerp katakana) |
| 86 | (put-char-code-property katakana 'hiragana hiragana) |
| 87 | (put-char-code-property katakana 'jisx0201 jisx0201)) |
| 88 | (if jisx0201 |
| 89 | (if (stringp jisx0201) |
| 90 | (if (> (length jisx0201) 1) |
| 91 | (let ((kana (aref jisx0201 0))) |
| 92 | (put-char-code-property |
| 93 | kana 'kana-composition |
| 94 | (cons (cons (aref jisx0201 1) katakana) |
| 95 | (get-char-code-property kana 'kana-composition))))) |
| 96 | (put-char-code-property jisx0201 'hiragana hiragana) |
| 97 | (put-char-code-property jisx0201 'katakana katakana) |
| 98 | (put-char-code-property jisx0201 'jisx0208 katakana))))) |
| 99 | |
| 100 | (defconst japanese-symbol-table |
| 101 | '((?\\e$B!!\e(B ?\ ) (?\e$B!$\e(B ?, ?\e(I$\e(B) (?\e$B!%\e(B ?. ?\e(I!\e(B) (?\e$B!"\e(B ?, ?\e(I$\e(B) (?\e$B!#\e(B ?. ?\e(I!\e(B) (?\e$B!&\e(B nil ?\e(I%\e(B) |
| 102 | (?\e$B!'\e(B ?:) (?\e$B!(\e(B ?\;) (?\e$B!)\e(B ??) (?\e$B!*\e(B ?!) (?\e$B!+\e(B nil ?\e(I^\e(B) (?\e$B!,\e(B nil ?\e(I_\e(B) |
| 103 | (?\e$B!-\e(B ?') (?\e$B!.\e(B ?`) (?\e$B!0\e(B ?^) (?\e$B!2\e(B ?_) (?\e$B!<\e(B ?- ?\e(I0\e(B) (?\e$B!=\e(B ?-) (?\e$B!>\e(B ?-) |
| 104 | (?\e$B!?\e(B ?/) (?\e$B!@\e(B ?\\) (?\e$B!A\e(B ?~) (?\e$B!C\e(B ?|) (?\e$B!F\e(B ?`) (?\e$B!G\e(B ?') (?\e$B!H\e(B ?\") (?\e$B!I\e(B ?\") |
| 105 | (?\\e$B!J\e(B ?\() (?\\e$B!K\e(B ?\)) (?\\e$B!N\e(B ?[) (?\\e$B!O\e(B ?]) (?\\e$B!P\e(B ?{) (?\\e$B!Q\e(B ?}) |
| 106 | (?\e$B!R\e(B ?<) (?\e$B!S\e(B ?>) (?\\e$B!V\e(B nil ?\\e(I"\e(B) (?\\e$B!W\e(B nil ?\\e(I#\e(B) |
| 107 | (?\e$B!\\e(B ?+) (?\e$B!]\e(B ?-) (?\e$B!a\e(B ?=) (?\e$B!c\e(B ?<) (?\e$B!d\e(B ?>) |
| 108 | (?\e$B!l\e(B ?') (?\e$B!m\e(B ?\") (?\e$B!o\e(B ?\\) (?\e$B!p\e(B ?$) (?\e$B!s\e(B ?%) (?\e$B!t\e(B ?#) (?\e$B!u\e(B ?&) (?\e$B!v\e(B ?*) |
| 109 | (?\e$B!w\e(B ?@) |
| 110 | ;; cp932-2-byte |
| 111 | (#x2015 ?-) (#xFF5E ?~) (#xFF0D ?-)) |
| 112 | "Japanese JISX0208 and CP932 symbol character table. |
| 113 | Each element is of the form (SYMBOL ASCII HANKAKU), where SYMBOL |
| 114 | belongs to `japanese-jisx0208' or `cp932', ASCII belongs to `ascii', |
| 115 | and HANKAKU belongs to `japanese-jisx0201-kana'.") |
| 116 | |
| 117 | ;; Put properties 'jisx0208, 'jisx0201, and 'ascii to each Japanese |
| 118 | ;; symbol and ASCII characters for conversion among them. |
| 119 | (let ((l japanese-symbol-table) |
| 120 | slot jisx0208 ascii jisx0201) |
| 121 | (while l |
| 122 | (setq slot (car l) |
| 123 | jisx0208 (car slot) ascii (nth 1 slot) jisx0201 (nth 2 slot) |
| 124 | l (cdr l)) |
| 125 | (if ascii |
| 126 | (progn |
| 127 | (put-char-code-property jisx0208 'ascii ascii) |
| 128 | (if (encode-char jisx0208 'japanese-jisx0208) |
| 129 | (put-char-code-property ascii 'jisx0208 jisx0208)))) |
| 130 | (if jisx0201 |
| 131 | (progn |
| 132 | (put-char-code-property jisx0208 'jisx0201 jisx0201) |
| 133 | (if (encode-char jisx0208 'japanese-jisx0208) |
| 134 | (put-char-code-property jisx0201 'jisx0208 jisx0208)))))) |
| 135 | |
| 136 | (defconst japanese-alpha-numeric-table |
| 137 | '((?\e$B#0\e(B . ?0) (?\e$B#1\e(B . ?1) (?\e$B#2\e(B . ?2) (?\e$B#3\e(B . ?3) (?\e$B#4\e(B . ?4) |
| 138 | (?\e$B#5\e(B . ?5) (?\e$B#6\e(B . ?6) (?\e$B#7\e(B . ?7) (?\e$B#8\e(B . ?8) (?\e$B#9\e(B . ?9) |
| 139 | (?\e$B#A\e(B . ?A) (?\e$B#B\e(B . ?B) (?\e$B#C\e(B . ?C) (?\e$B#D\e(B . ?D) (?\e$B#E\e(B . ?E) |
| 140 | (?\e$B#F\e(B . ?F) (?\e$B#G\e(B . ?G) (?\e$B#H\e(B . ?H) (?\e$B#I\e(B . ?I) (?\e$B#J\e(B . ?J) |
| 141 | (?\e$B#K\e(B . ?K) (?\e$B#L\e(B . ?L) (?\e$B#M\e(B . ?M) (?\e$B#N\e(B . ?N) (?\e$B#O\e(B . ?O) |
| 142 | (?\e$B#P\e(B . ?P) (?\e$B#Q\e(B . ?Q) (?\e$B#R\e(B . ?R) (?\e$B#S\e(B . ?S) (?\e$B#T\e(B . ?T) |
| 143 | (?\e$B#U\e(B . ?U) (?\e$B#V\e(B . ?V) (?\e$B#W\e(B . ?W) (?\e$B#X\e(B . ?X) (?\e$B#Y\e(B . ?Y) (?\e$B#Z\e(B . ?Z) |
| 144 | (?\e$B#a\e(B . ?a) (?\e$B#b\e(B . ?b) (?\e$B#c\e(B . ?c) (?\e$B#d\e(B . ?d) (?\e$B#e\e(B . ?e) |
| 145 | (?\e$B#f\e(B . ?f) (?\e$B#g\e(B . ?g) (?\e$B#h\e(B . ?h) (?\e$B#i\e(B . ?i) (?\e$B#j\e(B . ?j) |
| 146 | (?\e$B#k\e(B . ?k) (?\e$B#l\e(B . ?l) (?\e$B#m\e(B . ?m) (?\e$B#n\e(B . ?n) (?\e$B#o\e(B . ?o) |
| 147 | (?\e$B#p\e(B . ?p) (?\e$B#q\e(B . ?q) (?\e$B#r\e(B . ?r) (?\e$B#s\e(B . ?s) (?\e$B#t\e(B . ?t) |
| 148 | (?\e$B#u\e(B . ?u) (?\e$B#v\e(B . ?v) (?\e$B#w\e(B . ?w) (?\e$B#x\e(B . ?x) (?\e$B#y\e(B . ?y) (?\e$B#z\e(B . ?z)) |
| 149 | "Japanese JISX0208 alpha numeric character table. |
| 150 | Each element is of the form (ALPHA-NUMERIC ASCII), where ALPHA-NUMERIC |
| 151 | belongs to `japanese-jisx0208', ASCII belongs to `ascii'.") |
| 152 | |
| 153 | ;; Put properties 'jisx0208 and 'ascii to each Japanese alpha numeric |
| 154 | ;; and ASCII characters for conversion between them. |
| 155 | (let ((l japanese-alpha-numeric-table) |
| 156 | slot jisx0208 ascii) |
| 157 | (while l |
| 158 | (setq slot (car l) |
| 159 | jisx0208 (car slot) ascii (cdr slot) |
| 160 | l (cdr l)) |
| 161 | (put-char-code-property jisx0208 'ascii ascii) |
| 162 | (put-char-code-property ascii 'jisx0208 jisx0208))) |
| 163 | |
| 164 | ;; Convert string STR by FUNC and return a resulting string. |
| 165 | (defun japanese-string-conversion (str func &rest args) |
| 166 | (let ((buf (get-buffer-create " *Japanese work*"))) |
| 167 | (with-current-buffer buf |
| 168 | (erase-buffer) |
| 169 | (insert str) |
| 170 | (apply func 1 (point) args) |
| 171 | (buffer-string)))) |
| 172 | |
| 173 | ;;;###autoload |
| 174 | (defun japanese-katakana (obj &optional hankaku) |
| 175 | "Convert argument to Katakana and return that. |
| 176 | The argument may be a character or string. The result has the same type. |
| 177 | The argument object is not altered--the value is a copy. |
| 178 | Optional argument HANKAKU t means to convert to `hankaku' Katakana |
| 179 | \(`japanese-jisx0201-kana'), in which case return value |
| 180 | may be a string even if OBJ is a character if two Katakanas are |
| 181 | necessary to represent OBJ." |
| 182 | (if (stringp obj) |
| 183 | (japanese-string-conversion obj 'japanese-katakana-region hankaku) |
| 184 | (or (get-char-code-property obj (if hankaku 'jisx0201 'katakana)) |
| 185 | obj))) |
| 186 | |
| 187 | ;;;###autoload |
| 188 | (defun japanese-hiragana (obj) |
| 189 | "Convert argument to Hiragana and return that. |
| 190 | The argument may be a character or string. The result has the same type. |
| 191 | The argument object is not altered--the value is a copy." |
| 192 | (if (stringp obj) |
| 193 | (japanese-string-conversion obj 'japanese-hiragana-region) |
| 194 | (or (get-char-code-property obj 'hiragana) |
| 195 | obj))) |
| 196 | |
| 197 | ;;;###autoload |
| 198 | (defun japanese-hankaku (obj &optional ascii-only) |
| 199 | "Convert argument to `hankaku' and return that. |
| 200 | The argument may be a character or string. The result has the same type. |
| 201 | The argument object is not altered--the value is a copy. |
| 202 | Optional argument ASCII-ONLY non-nil means to return only ASCII character." |
| 203 | (if (stringp obj) |
| 204 | (japanese-string-conversion obj 'japanese-hankaku-region ascii-only) |
| 205 | (or (and (not ascii-only) |
| 206 | (get-char-code-property obj 'jisx0201)) |
| 207 | (get-char-code-property obj 'ascii) |
| 208 | obj))) |
| 209 | |
| 210 | ;;;###autoload |
| 211 | (defun japanese-zenkaku (obj) |
| 212 | "Convert argument to `zenkaku' and return that. |
| 213 | The argument may be a character or string. The result has the same type. |
| 214 | The argument object is not altered--the value is a copy." |
| 215 | (if (stringp obj) |
| 216 | (japanese-string-conversion obj 'japanese-zenkaku-region) |
| 217 | (or (get-char-code-property obj 'jisx0208) |
| 218 | obj))) |
| 219 | |
| 220 | (defun japanese-replace-region (from to string) |
| 221 | "Replace the region specified by FROM and TO to STRING." |
| 222 | (goto-char from) |
| 223 | (insert string) |
| 224 | (delete-char (- to from))) |
| 225 | |
| 226 | ;;;###autoload |
| 227 | (defun japanese-katakana-region (from to &optional hankaku) |
| 228 | "Convert Japanese `hiragana' chars in the region to `katakana' chars. |
| 229 | Optional argument HANKAKU t means to convert to `hankaku katakana' character |
| 230 | of which charset is `japanese-jisx0201-kana'." |
| 231 | (interactive "r\nP") |
| 232 | (save-restriction |
| 233 | (narrow-to-region from to) |
| 234 | (save-excursion |
| 235 | (goto-char (point-min)) |
| 236 | (while (re-search-forward "\\cH\\|\\cK" nil t) |
| 237 | (let* ((kana (preceding-char)) |
| 238 | (composition |
| 239 | (and (not hankaku) |
| 240 | (get-char-code-property kana 'kana-composition))) |
| 241 | next slot) |
| 242 | (if (and composition (setq slot (assq (following-char) composition))) |
| 243 | (japanese-replace-region (match-beginning 0) (1+ (point)) |
| 244 | (cdr slot)) |
| 245 | (let ((kata (get-char-code-property |
| 246 | kana (if hankaku 'jisx0201 'katakana)))) |
| 247 | (if kata |
| 248 | (japanese-replace-region (match-beginning 0) (point) |
| 249 | kata))))))))) |
| 250 | |
| 251 | |
| 252 | ;;;###autoload |
| 253 | (defun japanese-hiragana-region (from to) |
| 254 | "Convert Japanese `katakana' chars in the region to `hiragana' chars." |
| 255 | (interactive "r") |
| 256 | (save-restriction |
| 257 | (narrow-to-region from to) |
| 258 | (save-excursion |
| 259 | (goto-char (point-min)) |
| 260 | (while (re-search-forward "\\cK\\|\\ck" nil t) |
| 261 | (let* ((kata (preceding-char)) |
| 262 | (composition (get-char-code-property kata 'kana-composition)) |
| 263 | next slot) |
| 264 | (if (and composition (setq slot (assq (following-char) composition))) |
| 265 | (japanese-replace-region (match-beginning 0) (1+ (point)) |
| 266 | (get-char-code-property |
| 267 | (cdr slot) 'hiragana)) |
| 268 | (let ((hira (get-char-code-property kata 'hiragana))) |
| 269 | (if hira |
| 270 | (japanese-replace-region (match-beginning 0) (point) |
| 271 | hira))))))))) |
| 272 | |
| 273 | ;;;###autoload |
| 274 | (defun japanese-hankaku-region (from to &optional ascii-only) |
| 275 | "Convert Japanese `zenkaku' chars in the region to `hankaku' chars. |
| 276 | `Zenkaku' chars belong to `japanese-jisx0208' |
| 277 | `Hankaku' chars belong to `ascii' or `japanese-jisx0201-kana'. |
| 278 | Optional argument ASCII-ONLY non-nil means to convert only to ASCII char." |
| 279 | (interactive "r\nP") |
| 280 | (save-restriction |
| 281 | (narrow-to-region from to) |
| 282 | (save-excursion |
| 283 | (goto-char (point-min)) |
| 284 | (while (re-search-forward "\\cj" nil t) |
| 285 | (let* ((zenkaku (preceding-char)) |
| 286 | (hankaku (or (and (not ascii-only) |
| 287 | (get-char-code-property zenkaku 'jisx0201)) |
| 288 | (get-char-code-property zenkaku 'ascii)))) |
| 289 | (if hankaku |
| 290 | (japanese-replace-region (match-beginning 0) (match-end 0) |
| 291 | hankaku))))))) |
| 292 | |
| 293 | ;;;###autoload |
| 294 | (defun japanese-zenkaku-region (from to &optional katakana-only) |
| 295 | "Convert hankaku' chars in the region to Japanese `zenkaku' chars. |
| 296 | `Zenkaku' chars belong to `japanese-jisx0208' |
| 297 | `Hankaku' chars belong to `ascii' or `japanese-jisx0201-kana'. |
| 298 | Optional argument KATAKANA-ONLY non-nil means to convert only KATAKANA char." |
| 299 | (interactive "r\nP") |
| 300 | (save-restriction |
| 301 | (narrow-to-region from to) |
| 302 | (save-excursion |
| 303 | (goto-char (point-min)) |
| 304 | (while (or (and katakana-only |
| 305 | (re-search-forward "\\ck" nil t)) |
| 306 | (and (not katakana-only) |
| 307 | (re-search-forward "\\ca\\|\\ck" nil t))) |
| 308 | (let* ((hankaku (preceding-char)) |
| 309 | (composition (get-char-code-property hankaku 'kana-composition)) |
| 310 | next slot) |
| 311 | (if (and composition (setq slot (assq (following-char) composition))) |
| 312 | (japanese-replace-region (match-beginning 0) (1+ (point)) |
| 313 | (cdr slot)) |
| 314 | (let ((zenkaku (japanese-zenkaku hankaku))) |
| 315 | (if zenkaku |
| 316 | (japanese-replace-region (match-beginning 0) (match-end 0) |
| 317 | zenkaku))))))))) |
| 318 | |
| 319 | ;;;###autoload |
| 320 | (defun read-hiragana-string (prompt &optional initial-input) |
| 321 | "Read a Hiragana string from the minibuffer, prompting with string PROMPT. |
| 322 | If non-nil, second arg INITIAL-INPUT is a string to insert before reading." |
| 323 | (read-multilingual-string prompt initial-input "japanese-hiragana")) |
| 324 | |
| 325 | ;; |
| 326 | (provide 'japan-util) |
| 327 | |
| 328 | ;; arch-tag: b579595c-c9ad-4b57-9314-98cd8b214f89 |
| 329 | ;;; japan-util.el ends here |