[bpt/emacs.git] / lisp / autorevert.el

;;; autorevert.el --- revert buffers when files on disk change

;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.

;; Author: Anders Lindgren <andersl@andersl.com>
;; Keywords: convenience
;; Created: 1997-06-01
;; Date: 1999-11-30

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; Introduction:
;;
;; Whenever a file that Emacs is editing has been changed by another
;; program the user normally has to execute the command `revert-buffer'
;; to load the new content of the file into Emacs.
;;
;; This package contains two minor modes: Global Auto-Revert Mode and
;; Auto-Revert Mode.  Both modes automatically revert buffers
;; whenever the corresponding files have been changed on disk.
;;
;; Auto-Revert Mode can be activated for individual buffers.
;; Global Auto-Revert Mode applies to all file buffers.
;;
;; Both modes operate by checking the time stamp of all files at
;; intervals of `auto-revert-interval'.  The default is every five
;; seconds.  The check is aborted whenever the user actually uses
;; Emacs.  You should never even notice that this package is active
;; (except that your buffers will be reverted, of course).

;; Usage:
;;
;; Go to the appropriate buffer and press:
;;   M-x auto-revert-mode RET
;;
;; To activate Global Auto-Revert Mode, press:
;;   M-x global-auto-revert-mode RET
;;
;; To activate Global Auto-Revert Mode every time Emacs is started
;; customise the option `global-auto-revert-mode' or the following
;; line could be added to your ~/.emacs:
;;   (global-auto-revert-mode 1)
;;
;; The function `turn-on-auto-revert-mode' could be added to any major
;; mode hook to activate Auto-Revert Mode for all buffers in that
;; mode.  For example, the following line will activate Auto-Revert
;; Mode in all C mode buffers:
;;
;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)

;;; Code:

;; Dependencies:

(require 'timer)
(eval-when-compile (require 'cl))


;; Custom Group:
;;
;; The two modes will be placed next to Auto Save Mode under the
;; Files group under Emacs.

(defgroup auto-revert nil
  "Revert individual buffers when files on disk change.

Auto-Revert Mode can be activated for individual buffer.
Global Auto-Revert Mode applies to all buffers."
  :group 'files
  :group 'convenience)


;; Variables:

;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
;;;###autoload
(defvar auto-revert-mode nil
  "*Non-nil when Auto-Revert Mode is active.
Never set this variable directly, use the command `auto-revert-mode' instead.")
(put 'auto-revert-mode 'permanent-local t)

(defcustom auto-revert-interval 5
  "Time, in seconds, between Auto-Revert Mode file checks.
Setting this variable has no effect on buffers that are already in
auto-revert-mode; it only affects buffers that are put into
auto-revert-mode afterwards."
  :group 'auto-revert
  :type 'integer)

(defcustom auto-revert-stop-on-user-input t
  "When non-nil Auto-Revert Mode stops checking files on user input."
  :group 'auto-revert
  :type 'boolean)

(defcustom auto-revert-verbose t
  "When nil, Auto-Revert Mode will not generate any messages.

Currently, messages are generated when the mode is activated or
deactivated, and whenever a file is reverted."
  :group 'auto-revert
  :type 'boolean)

(defcustom auto-revert-mode-text " ARev"
  "String to display in the mode line when Auto-Revert Mode is active.

\(When the string is not empty, make sure that it has a leading space.)"
  :tag "Auto Revert Mode Text"		; To separate it from `global-...'
  :group 'auto-revert
  :type 'string)

(defcustom auto-revert-mode-hook nil
  "Functions to run when Auto-Revert Mode is activated."
  :tag "Auto Revert Mode Hook"		; To separate it from `global-...'
  :group 'auto-revert
  :type 'hook)

(defcustom global-auto-revert-mode-text ""
  "String to display when Global Auto-Revert Mode is active.

The default is nothing since when this mode is active this text doesn't
vary over time, or between buffers.  Hence mode line text
would only waste precious space."
  :group 'auto-revert
  :type 'string)

(defcustom global-auto-revert-mode-hook nil
  "Hook called when Global Auto-Revert Mode is activated."
  :group 'auto-revert
  :type 'hook)

(defcustom global-auto-revert-non-file-buffers nil
  "When nil only file buffers are reverted by Global Auto-Revert Mode.

When non-nil, both file buffers and buffers with a custom
`revert-buffer-function' are reverted by Global Auto-Revert Mode.

Use this option with care since it could lead to excessive reverts."
  :group 'auto-revert
  :type 'boolean)

(defcustom global-auto-revert-ignore-modes '()
  "List of major modes Global Auto-Revert Mode should not check."
  :group 'auto-revert
  :type '(repeat sexp))

(defcustom auto-revert-load-hook nil
  "Functions to run when Auto-Revert Mode is first loaded."
  :tag "Load Hook"
  :group 'auto-revert
  :type 'hook)

(defvar global-auto-revert-ignore-buffer nil
  "*When non-nil, Global Auto-Revert Mode will not revert this buffer.

This variable becomes buffer local when set in any fashion.")
(make-variable-buffer-local 'global-auto-revert-ignore-buffer)


;; Internal variables:

(defvar auto-revert-buffer-list '()
  "List of buffers in Auto-Revert Mode.

Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
buffers to this list.

The timer function `auto-revert-buffers' is responsible for purging
the list of old buffers.")

(defvar auto-revert-timer nil
  "Timer used by Auto-Revert Mode.")

(defvar auto-revert-remaining-buffers '()
  "Buffers not checked when user input stopped execution.")


;; Functions:

;;;###autoload
(define-minor-mode auto-revert-mode
  "Toggle reverting buffer when file on disk changes.

With arg, turn Auto Revert mode on if and only if arg is positive.
This is a minor mode that affects only the current buffer.
Use `global-auto-revert-mode' to automatically revert all buffers."
  nil auto-revert-mode-text nil
  (if auto-revert-mode
      (if (not (memq (current-buffer) auto-revert-buffer-list))
	  (push (current-buffer) auto-revert-buffer-list))
    (setq auto-revert-buffer-list
	  (delq (current-buffer) auto-revert-buffer-list)))
  (auto-revert-set-timer)
  (when auto-revert-mode
    (auto-revert-buffers)))


;;;###autoload
(defun turn-on-auto-revert-mode ()
  "Turn on Auto-Revert Mode.

This function is designed to be added to hooks, for example:
  (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
  (auto-revert-mode 1))


;;;###autoload
(define-minor-mode global-auto-revert-mode
  "Revert any buffer when file on disk change.

With arg, turn Auto Revert mode on globally if and only if arg is positive.
This is a minor mode that affects all buffers.
Use `auto-revert-mode' to revert a particular buffer."
  :global t :group 'auto-revert :lighter global-auto-revert-mode-text
  (auto-revert-set-timer)
  (when global-auto-revert-mode
    (auto-revert-buffers)))


(defun auto-revert-set-timer ()
  "Restart or cancel the timer."
  (if (timerp auto-revert-timer)
      (cancel-timer auto-revert-timer))
  (setq auto-revert-timer
	(if (or global-auto-revert-mode auto-revert-buffer-list)
	    (run-with-timer auto-revert-interval
			    auto-revert-interval
			    'auto-revert-buffers)
	  nil)))

(defun auto-revert-active-p ()
  "Check if auto-revert is active (in current buffer or globally)."
  (or auto-revert-mode
      (and
       global-auto-revert-mode
       (not global-auto-revert-ignore-buffer)
       (not (memq major-mode
		  global-auto-revert-ignore-modes)))))

(defun auto-revert-list-diff (a b)
  "Check if strings in list A differ from list B."
  (when (and a b)
    (setq a (sort a 'string-lessp))
    (setq b (sort b 'string-lessp))
    (let (elt1 elt2)
      (catch 'break
	(while (and (setq elt1 (and a (pop a)))
		    (setq elt2 (and b (pop b))))
	  (if (not (string= elt1 elt2))
	      (throw 'break t)))))))

(defun auto-revert-dired-file-list ()
  "Return list of dired files."
  (let (list)
    (save-excursion
      (goto-char (point-min))
      (while (not (eobp))
	(if (setq file (dired-get-filename t t))
	    (push file list))
	(forward-line 1)))
    list))

(defun auto-revert-dired-changed-p ()
  "Check if dired buffer has changed."
  (when (and (stringp dired-directory)
	     ;;	  Exclude remote buffers, would be too slow for user
	     ;;	  modem, timeouts, network lag ... all is possible
	     (not (string-match "@" dired-directory))
	     (file-directory-p dired-directory))
    (let ((files (directory-files dired-directory))
	  (dired (auto-revert-dired-file-list)))
      (or (not (eq (length files) (length dired)))
	  (auto-revert-list-diff files dired)))))

(defun auto-revert-buffer-p ()
  "Check if current buffer should be reverted."
  ;;  Always include dired buffers to list. It would be too expensive
  ;;  to test the "revert" status here each time timer launches.
  (or (eq major-mode 'dired-mode)
      (and (not (buffer-modified-p))
	   (if (buffer-file-name)
	       (and (file-readable-p (buffer-file-name))
		    (not (verify-visited-file-modtime buf)))
	     (and revert-buffer-function
		  (or (and global-auto-revert-mode
			   global-auto-revert-non-file-buffers)
		      auto-revert-mode))))))

(defun auto-revert-handler ()
  "Revert current buffer."
  (let (done)
    (cond
     ((eq major-mode 'dired-mode)
      ;;  Dired includes revert-buffer-function
      (when (and revert-buffer-function
		 (auto-revert-dired-changed-p))
	(setq done t)
	(revert-buffer t t t)))
     ((or (buffer-file-name)
	  revert-buffer-function)
      (setq done t)
      (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)))
    (if (and done
	     auto-revert-verbose)
	(message "Reverting buffer `%s'." (buffer-name)))))

(defun auto-revert-buffers ()
  "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.

Should `global-auto-revert-mode' be active all file buffers are checked.

Should `auto-revert-mode' be active in some buffers, those buffers
are checked.

Non-file buffers that have a custom `revert-buffer-function' are
reverted either when Auto-Revert Mode is active in that buffer, or
when the variable `global-auto-revert-non-file-buffers' is non-nil
and Global Auto-Revert Mode is active.

This function stops whenever there is user input.  The buffers not
checked are stored in the variable `auto-revert-remaining-buffers'.

To avoid starvation, the buffers in `auto-revert-remaining-buffers'
are checked first the next time this function is called.

This function is also responsible for removing buffers no longer in
Auto-Revert mode from `auto-revert-buffer-list', and for canceling
the timer when no buffers need to be checked."
  (let ((bufs (if global-auto-revert-mode
		  (buffer-list)
		auto-revert-buffer-list))
	(remaining '())
	(new '()))
    ;; Partition `bufs' into two halves depending on whether or not
    ;; the buffers are in `auto-revert-remaining-buffers'.  The two
    ;; halves are then re-joined with the "remaining" buffers at the
    ;; head of the list.
    (dolist (buf auto-revert-remaining-buffers)
      (if (memq buf bufs)
	  (push buf remaining)))
    (dolist (buf bufs)
      (if (not (memq buf remaining))
	  (push buf new)))
    (setq bufs (nreverse (nconc new remaining)))
    (while (and bufs
		(not (and auto-revert-stop-on-user-input
			  (input-pending-p))))
      (let ((buf (car bufs)))
	(if (buffer-name buf)		; Buffer still alive?
	    (with-current-buffer buf
	      ;; Test if someone has turned off Auto-Revert Mode in a
	      ;; non-standard way, for example by changing major mode.
	      (if (and (not auto-revert-mode)
		       (memq buf auto-revert-buffer-list))
		  (setq auto-revert-buffer-list
			(delq buf auto-revert-buffer-list)))
	      (when (and (auto-revert-active-p)
			 (auto-revert-buffer-p))
		(auto-revert-handler)
		;; `preserve-modes' avoids changing the (minor) modes.  But we
		;; do want to reset the mode for VC, so we do it explicitly.
		(vc-find-file-hook)))
	  ;; Remove dead buffer from `auto-revert-buffer-list'.
	  (setq auto-revert-buffer-list
		(delq buf auto-revert-buffer-list))))
      (setq bufs (cdr bufs)))
    (setq auto-revert-remaining-buffers bufs)
    ;; Check if we should cancel the timer.
    (when (and (not global-auto-revert-mode)
	       (null auto-revert-buffer-list))
      (cancel-timer auto-revert-timer)
      (setq auto-revert-timer nil))))


;; The end:
(provide 'autorevert)

(run-hooks 'auto-revert-load-hook)

;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
;;; autorevert.el ends here
Commit	Line	Data
e8af40ee	1	;;; autorevert.el --- revert buffers when files on disk change
4a35aff3	2
bf2150fa	3	;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
4a35aff3	4
a468671a	5	;; Author: Anders Lindgren <andersl@andersl.com>
f5f727f8	6	;; Keywords: convenience
a468671a GM	7	;; Created: 1997-06-01
a468671a GM	8	;; Date: 1999-11-30
4a35aff3 RS	9
	10	;; This file is part of GNU Emacs.
	11
	12	;; GNU Emacs is free software; you can redistribute it and/or modify
	13	;; it under the terms of the GNU General Public License as published by
	14	;; the Free Software Foundation; either version 2, or (at your option)
	15	;; any later version.
	16
	17	;; GNU Emacs is distributed in the hope that it will be useful,
	18	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	19	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	20	;; GNU General Public License for more details.
	21
	22	;; You should have received a copy of the GNU General Public License
	23	;; along with GNU Emacs; see the file COPYING. If not, write to the
	24	;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
	25	;; Boston, MA 02111-1307, USA.
	26
	27	;;; Commentary:
	28
	29	;; Introduction:
	30	;;
	31	;; Whenever a file that Emacs is editing has been changed by another
48764ae2	32	;; program the user normally has to execute the command `revert-buffer'
4a35aff3 RS	33	;; to load the new content of the file into Emacs.
	34	;;
	35	;; This package contains two minor modes: Global Auto-Revert Mode and
48764ae2	36	;; Auto-Revert Mode. Both modes automatically revert buffers
4a35aff3 RS	37	;; whenever the corresponding files have been changed on disk.
	38	;;
	39	;; Auto-Revert Mode can be activated for individual buffers.
	40	;; Global Auto-Revert Mode applies to all file buffers.
	41	;;
48764ae2 DL	42	;; Both modes operate by checking the time stamp of all files at
	43	;; intervals of `auto-revert-interval'. The default is every five
	44	;; seconds. The check is aborted whenever the user actually uses
	45	;; Emacs. You should never even notice that this package is active
	46	;; (except that your buffers will be reverted, of course).
4a35aff3 RS	47
	48	;; Usage:
	49	;;
	50	;; Go to the appropriate buffer and press:
	51	;; M-x auto-revert-mode RET
	52	;;
	53	;; To activate Global Auto-Revert Mode, press:
	54	;; M-x global-auto-revert-mode RET
	55	;;
48764ae2 DL	56	;; To activate Global Auto-Revert Mode every time Emacs is started
	57	;; customise the option `global-auto-revert-mode' or the following
	58	;; line could be added to your ~/.emacs:
4a35aff3 RS	59	;; (global-auto-revert-mode 1)
	60	;;
	61	;; The function `turn-on-auto-revert-mode' could be added to any major
	62	;; mode hook to activate Auto-Revert Mode for all buffers in that
	63	;; mode. For example, the following line will activate Auto-Revert
	64	;; Mode in all C mode buffers:
	65	;;
	66	;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
	67
	68	;;; Code:
	69
	70	;; Dependencies:
	71
	72	(require 'timer)
	73	(eval-when-compile (require 'cl))
	74
	75
	76	;; Custom Group:
	77	;;
	78	;; The two modes will be placed next to Auto Save Mode under the
	79	;; Files group under Emacs.
	80
	81	(defgroup auto-revert nil
48764ae2	82	"Revert individual buffers when files on disk change.
4a35aff3 RS	83
	84	Auto-Revert Mode can be activated for individual buffer.
	85	Global Auto-Revert Mode applies to all buffers."
f5f727f8 DN	86	:group 'files
f5f727f8 DN	87	:group 'convenience)
4a35aff3 RS	88
	89
	90	;; Variables:
	91
00d0fda8 DL	92	;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
00d0fda8 DL	93	;;;###autoload
4a35aff3 RS	94	(defvar auto-revert-mode nil
4a35aff3 RS	95	"*Non-nil when Auto-Revert Mode is active.
0e4f9468 SM	96	Never set this variable directly, use the command `auto-revert-mode' instead.")
0e4f9468 SM	97	(put 'auto-revert-mode 'permanent-local t)
4a35aff3 RS	98
4a35aff3 RS	99	(defcustom auto-revert-interval 5
ad660075 EZ	100	"Time, in seconds, between Auto-Revert Mode file checks.
	101	Setting this variable has no effect on buffers that are already in
	102	auto-revert-mode; it only affects buffers that are put into
	103	auto-revert-mode afterwards."
4a35aff3 RS	104	:group 'auto-revert
	105	:type 'integer)
	106
	107	(defcustom auto-revert-stop-on-user-input t
	108	"When non-nil Auto-Revert Mode stops checking files on user input."
	109	:group 'auto-revert
	110	:type 'boolean)
	111
	112	(defcustom auto-revert-verbose t
	113	"When nil, Auto-Revert Mode will not generate any messages.
	114
	115	Currently, messages are generated when the mode is activated or
	116	deactivated, and whenever a file is reverted."
	117	:group 'auto-revert
	118	:type 'boolean)
	119
	120	(defcustom auto-revert-mode-text " ARev"
	121	"String to display in the mode line when Auto-Revert Mode is active.
	122
	123	\(When the string is not empty, make sure that it has a leading space.)"
	124	:tag "Auto Revert Mode Text" ; To separate it from `global-...'
	125	:group 'auto-revert
	126	:type 'string)
	127
	128	(defcustom auto-revert-mode-hook nil
	129	"Functions to run when Auto-Revert Mode is activated."
	130	:tag "Auto Revert Mode Hook" ; To separate it from `global-...'
	131	:group 'auto-revert
	132	:type 'hook)
	133
	134	(defcustom global-auto-revert-mode-text ""
	135	"String to display when Global Auto-Revert Mode is active.
	136
	137	The default is nothing since when this mode is active this text doesn't
48764ae2	138	vary over time, or between buffers. Hence mode line text
4a35aff3 RS	139	would only waste precious space."
	140	:group 'auto-revert
	141	:type 'string)
	142
	143	(defcustom global-auto-revert-mode-hook nil
	144	"Hook called when Global Auto-Revert Mode is activated."
	145	:group 'auto-revert
	146	:type 'hook)
	147
	148	(defcustom global-auto-revert-non-file-buffers nil
0e4f9468	149	"When nil only file buffers are reverted by Global Auto-Revert Mode.
4a35aff3 RS	150
4a35aff3 RS	151	When non-nil, both file buffers and buffers with a custom
0e4f9468 SM	152	`revert-buffer-function' are reverted by Global Auto-Revert Mode.
	153
	154	Use this option with care since it could lead to excessive reverts."
4a35aff3 RS	155	:group 'auto-revert
	156	:type 'boolean)
	157
4a35aff3 RS	158	(defcustom global-auto-revert-ignore-modes '()
	159	"List of major modes Global Auto-Revert Mode should not check."
	160	:group 'auto-revert
	161	:type '(repeat sexp))
	162
	163	(defcustom auto-revert-load-hook nil
	164	"Functions to run when Auto-Revert Mode is first loaded."
	165	:tag "Load Hook"
	166	:group 'auto-revert
	167	:type 'hook)
	168
	169	(defvar global-auto-revert-ignore-buffer nil
f1e3ff80	170	"*When non-nil, Global Auto-Revert Mode will not revert this buffer.
4a35aff3	171
48764ae2	172	This variable becomes buffer local when set in any fashion.")
4a35aff3 RS	173	(make-variable-buffer-local 'global-auto-revert-ignore-buffer)
	174
	175
	176	;; Internal variables:
	177
	178	(defvar auto-revert-buffer-list '()
	179	"List of buffers in Auto-Revert Mode.
	180
	181	Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
	182	buffers to this list.
	183
	184	The timer function `auto-revert-buffers' is responsible for purging
	185	the list of old buffers.")
	186
	187	(defvar auto-revert-timer nil
	188	"Timer used by Auto-Revert Mode.")
	189
	190	(defvar auto-revert-remaining-buffers '()
	191	"Buffers not checked when user input stopped execution.")
	192
	193
	194	;; Functions:
	195
	196	;;;###autoload
0e4f9468	197	(define-minor-mode auto-revert-mode
48764ae2	198	"Toggle reverting buffer when file on disk changes.
4a35aff3	199
48764ae2 DL	200	With arg, turn Auto Revert mode on if and only if arg is positive.
48764ae2 DL	201	This is a minor mode that affects only the current buffer.
4a35aff3	202	Use `global-auto-revert-mode' to automatically revert all buffers."
0e4f9468	203	nil auto-revert-mode-text nil
4a35aff3 RS	204	(if auto-revert-mode
	205	(if (not (memq (current-buffer) auto-revert-buffer-list))
	206	(push (current-buffer) auto-revert-buffer-list))
	207	(setq auto-revert-buffer-list
	208	(delq (current-buffer) auto-revert-buffer-list)))
	209	(auto-revert-set-timer)
	210	(when auto-revert-mode
0e4f9468	211	(auto-revert-buffers)))
4a35aff3 RS	212
	213
	214	;;;###autoload
	215	(defun turn-on-auto-revert-mode ()
	216	"Turn on Auto-Revert Mode.
	217
	218	This function is designed to be added to hooks, for example:
	219	(add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
	220	(auto-revert-mode 1))
	221
	222
	223	;;;###autoload
0e4f9468	224	(define-minor-mode global-auto-revert-mode
4a35aff3 RS	225	"Revert any buffer when file on disk change.
4a35aff3 RS	226
48764ae2 DL	227	With arg, turn Auto Revert mode on globally if and only if arg is positive.
48764ae2 DL	228	This is a minor mode that affects all buffers.
4a35aff3	229	Use `auto-revert-mode' to revert a particular buffer."
0e4f9468	230	:global t :group 'auto-revert :lighter global-auto-revert-mode-text
4a35aff3 RS	231	(auto-revert-set-timer)
4a35aff3 RS	232	(when global-auto-revert-mode
0e4f9468	233	(auto-revert-buffers)))
4a35aff3 RS	234
	235
	236	(defun auto-revert-set-timer ()
	237	"Restart or cancel the timer."
	238	(if (timerp auto-revert-timer)
	239	(cancel-timer auto-revert-timer))
0e4f9468 SM	240	(setq auto-revert-timer
	241	(if (or global-auto-revert-mode auto-revert-buffer-list)
	242	(run-with-timer auto-revert-interval
	243	auto-revert-interval
	244	'auto-revert-buffers)
	245	nil)))
4a35aff3	246
ed35db71 EZ	247	(defun auto-revert-active-p ()
	248	"Check if auto-revert is active (in current buffer or globally)."
	249	(or auto-revert-mode
	250	(and
	251	global-auto-revert-mode
	252	(not global-auto-revert-ignore-buffer)
	253	(not (memq major-mode
	254	global-auto-revert-ignore-modes)))))
	255
	256	(defun auto-revert-list-diff (a b)
	257	"Check if strings in list A differ from list B."
	258	(when (and a b)
	259	(setq a (sort a 'string-lessp))
	260	(setq b (sort b 'string-lessp))
	261	(let (elt1 elt2)
	262	(catch 'break
	263	(while (and (setq elt1 (and a (pop a)))
	264	(setq elt2 (and b (pop b))))
	265	(if (not (string= elt1 elt2))
	266	(throw 'break t)))))))
	267
	268	(defun auto-revert-dired-file-list ()
	269	"Return list of dired files."
	270	(let (list)
	271	(save-excursion
	272	(goto-char (point-min))
	273	(while (not (eobp))
	274	(if (setq file (dired-get-filename t t))
	275	(push file list))
	276	(forward-line 1)))
	277	list))
	278
	279	(defun auto-revert-dired-changed-p ()
	280	"Check if dired buffer has changed."
	281	(when (and (stringp dired-directory)
	282	;; Exclude remote buffers, would be too slow for user
	283	;; modem, timeouts, network lag ... all is possible
	284	(not (string-match "@" dired-directory))
	285	(file-directory-p dired-directory))
	286	(let ((files (directory-files dired-directory))
	287	(dired (auto-revert-dired-file-list)))
	288	(or (not (eq (length files) (length dired)))
	289	(auto-revert-list-diff files dired)))))
	290
	291	(defun auto-revert-buffer-p ()
	292	"Check if current buffer should be reverted."
	293	;; Always include dired buffers to list. It would be too expensive
	294	;; to test the "revert" status here each time timer launches.
	295	(or (eq major-mode 'dired-mode)
	296	(and (not (buffer-modified-p))
	297	(if (buffer-file-name)
	298	(and (file-readable-p (buffer-file-name))
	299	(not (verify-visited-file-modtime buf)))
	300	(and revert-buffer-function
	301	(or (and global-auto-revert-mode
	302	global-auto-revert-non-file-buffers)
	303	auto-revert-mode))))))
	304
	305	(defun auto-revert-handler ()
	306	"Revert current buffer."
	307	(let (done)
	308	(cond
	309	((eq major-mode 'dired-mode)
	310	;; Dired includes revert-buffer-function
311	(when (and revert-buffer-function
312	(auto-revert-dired-changed-p))
313	(setq done t)
314	(revert-buffer t t t)))
315	((or (buffer-file-name)
316	revert-buffer-function)
317	(setq done t)
318	(revert-buffer 'ignore-auto 'dont-ask 'preserve-modes)))
319	(if (and done
320	auto-revert-verbose)
321	(message "Reverting buffer `%s'." (buffer-name)))))
322
4a35aff3 RS	323	(defun auto-revert-buffers ()
	324	"Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
	325
	326	Should `global-auto-revert-mode' be active all file buffers are checked.
	327
	328	Should `auto-revert-mode' be active in some buffers, those buffers
	329	are checked.
	330
	331	Non-file buffers that have a custom `revert-buffer-function' are
	332	reverted either when Auto-Revert Mode is active in that buffer, or
	333	when the variable `global-auto-revert-non-file-buffers' is non-nil
	334	and Global Auto-Revert Mode is active.
	335
48764ae2	336	This function stops whenever there is user input. The buffers not
4a35aff3 RS	337	checked are stored in the variable `auto-revert-remaining-buffers'.
	338
	339	To avoid starvation, the buffers in `auto-revert-remaining-buffers'
	340	are checked first the next time this function is called.
	341
48764ae2	342	This function is also responsible for removing buffers no longer in
4a35aff3 RS	343	Auto-Revert mode from `auto-revert-buffer-list', and for canceling
	344	the timer when no buffers need to be checked."
	345	(let ((bufs (if global-auto-revert-mode
	346	(buffer-list)
	347	auto-revert-buffer-list))
	348	(remaining '())
	349	(new '()))
	350	;; Partition `bufs' into two halves depending on whether or not
	351	;; the buffers are in `auto-revert-remaining-buffers'. The two
	352	;; halves are then re-joined with the "remaining" buffers at the
	353	;; head of the list.
	354	(dolist (buf auto-revert-remaining-buffers)
	355	(if (memq buf bufs)
	356	(push buf remaining)))
	357	(dolist (buf bufs)
	358	(if (not (memq buf remaining))
	359	(push buf new)))
	360	(setq bufs (nreverse (nconc new remaining)))
	361	(while (and bufs
	362	(not (and auto-revert-stop-on-user-input
	363	(input-pending-p))))
	364	(let ((buf (car bufs)))
	365	(if (buffer-name buf) ; Buffer still alive?
0e4f9468	366	(with-current-buffer buf
4a35aff3 RS	367	;; Test if someone has turned off Auto-Revert Mode in a
	368	;; non-standard way, for example by changing major mode.
	369	(if (and (not auto-revert-mode)
	370	(memq buf auto-revert-buffer-list))
	371	(setq auto-revert-buffer-list
	372	(delq buf auto-revert-buffer-list)))
ed35db71 EZ	373	(when (and (auto-revert-active-p)
	374	(auto-revert-buffer-p))
	375	(auto-revert-handler)
0e4f9468 SM	376	;; `preserve-modes' avoids changing the (minor) modes. But we
	377	;; do want to reset the mode for VC, so we do it explicitly.
	378	(vc-find-file-hook)))
4a35aff3 RS	379	;; Remove dead buffer from `auto-revert-buffer-list'.
	380	(setq auto-revert-buffer-list
	381	(delq buf auto-revert-buffer-list))))
	382	(setq bufs (cdr bufs)))
	383	(setq auto-revert-remaining-buffers bufs)
	384	;; Check if we should cancel the timer.
	385	(when (and (not global-auto-revert-mode)
	386	(null auto-revert-buffer-list))
	387	(cancel-timer auto-revert-timer)
	388	(setq auto-revert-timer nil))))
	389
	390
	391	;; The end:
4a35aff3 RS	392	(provide 'autorevert)
	393
	394	(run-hooks 'auto-revert-load-hook)
	395
ab5796a9	396	;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
e8af40ee	397	;;; autorevert.el ends here