Merge from gnus--devo--0

[bpt/emacs.git] / lisp / linum.el

;;; linum.el --- display line numbers in the left margin\r
\r
;; Copyright (C) 2008 Free Software Foundation, Inc.\r
\r
;; Author: Markus Triska <markus.triska@gmx.at>\r
;; Maintainer: FSF\r
;; Keywords: convenience\r
\r
;; This file is part of GNU Emacs.\r
\r
;; GNU Emacs is free software: you can redistribute it and/or modify\r
;; it under the terms of the GNU General Public License as published by\r
;; the Free Software Foundation, either version 3 of the License, or\r
;; (at your option) any later version.\r
\r
;; GNU Emacs is distributed in the hope that it will be useful,\r
;; but WITHOUT ANY WARRANTY; without even the implied warranty of\r
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the\r
;; GNU General Public License for more details.\r
\r
;; You should have received a copy of the GNU General Public License\r
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.\r
\r
;;; Commentary:\r
\r
;; Display line numbers for the current buffer.\r
;;\r
;; Toggle display of line numbers with M-x linum-mode.  To enable\r
;; line numbering in all buffers, use M-x global-linum-mode.\r
\r
;;; Code:\r
\r
(defconst linum-version "0.9x")\r
\r
(defvar linum-overlays nil "Overlays used in this buffer.")\r
(defvar linum-available nil "Overlays available for reuse.")\r
(defvar linum-before-numbering-hook nil\r
  "Functions run in each buffer before line numbering starts.")\r
\r
(mapc #'make-variable-buffer-local '(linum-overlays linum-available))\r
\r
(defgroup linum nil\r
  "Show line numbers in the left margin."\r
  :group 'convenience)\r
\r
;;;###autoload\r
(defcustom linum-format 'dynamic\r
  "Format used to display line numbers.\r
Either a format string like \"%7d\", `dynamic' to adapt the width\r
as needed, or a function that is called with a line number as its\r
argument and should evaluate to a string to be shown on that line.\r
See also `linum-before-numbering-hook'."\r
  :group 'linum\r
  :type 'sexp)\r
\r
(defface linum\r
  '((t :inherit (shadow default)))\r
  "Face for displaying line numbers in the display margin."\r
  :group 'linum)\r
\r
(defcustom linum-eager t\r
  "Whether line numbers should be updated after each command.\r
The conservative setting `nil' might miss some buffer changes,\r
and you have to scroll or press \\[recenter-top-bottom] to update the numbers."\r
  :group 'linum\r
  :type 'boolean)\r
\r
(defcustom linum-delay nil\r
  "Delay updates to give Emacs a chance for other changes."\r
  :group 'linum\r
  :type 'boolean)\r
\r
;;;###autoload\r
(define-minor-mode linum-mode\r
  "Toggle display of line numbers in the left margin."\r
  :lighter ""                           ; for desktop.el\r
  (if linum-mode\r
      (progn\r
        (if linum-eager\r
            (add-hook 'post-command-hook (if linum-delay\r
                                             'linum-schedule\r
                                           'linum-update-current) nil t)\r
          (add-hook 'after-change-functions 'linum-after-change nil t))\r
        (add-hook 'window-scroll-functions 'linum-after-scroll nil t)\r
        (add-hook 'window-size-change-functions 'linum-after-size nil t)\r
        (add-hook 'change-major-mode-hook 'linum-delete-overlays nil t)\r
        (add-hook 'window-configuration-change-hook\r
                  'linum-after-config nil t)\r
        (linum-update-current))\r
    (remove-hook 'post-command-hook 'linum-update-current t)\r
    (remove-hook 'post-command-hook 'linum-schedule t)\r
    (remove-hook 'window-size-change-functions 'linum-after-size t)\r
    (remove-hook 'window-scroll-functions 'linum-after-scroll t)\r
    (remove-hook 'after-change-functions 'linum-after-change t)\r
    (remove-hook 'window-configuration-change-hook 'linum-after-config t)\r
    (remove-hook 'change-major-mode-hook 'linum-delete-overlays t)\r
    (linum-delete-overlays)))\r
\r
;;;###autoload\r
(define-globalized-minor-mode global-linum-mode linum-mode linum-on)\r
\r
(defun linum-on ()\r
  (unless (minibufferp)\r
    (linum-mode 1)))\r
\r
(defun linum-delete-overlays ()\r
  "Delete all overlays displaying line numbers for this buffer."\r
  (mapc #'delete-overlay linum-overlays)\r
  (setq linum-overlays nil)\r
  (dolist (w (get-buffer-window-list (current-buffer) nil t))\r
    (set-window-margins w 0)))\r
\r
(defun linum-update-current ()\r
  "Update line numbers for the current buffer."\r
  (linum-update (current-buffer)))\r
\r
(defun linum-update (buffer)\r
  "Update line numbers for all windows displaying BUFFER."\r
  (with-current-buffer buffer\r
    (when linum-mode\r
      (setq linum-available linum-overlays)\r
      (setq linum-overlays nil)\r
      (save-excursion\r
        (mapc #'linum-update-window\r
              (get-buffer-window-list buffer nil 'visible)))\r
      (mapc #'delete-overlay linum-available)\r
      (setq linum-available nil))))\r
\r
(defun linum-update-window (win)\r
  "Update line numbers for the portion visible in window WIN."\r
  (goto-char (window-start win))\r
  (let ((line (line-number-at-pos))\r
        (limit (window-end win t))\r
        (fmt (cond ((stringp linum-format) linum-format)\r
                   ((eq linum-format 'dynamic)\r
                    (let ((w (length (number-to-string\r
                                      (count-lines (point-min) (point-max))))))\r
                      (concat "%" (number-to-string w) "d")))))\r
        (width 0))\r
    (run-hooks 'linum-before-numbering-hook)\r
    ;; Create an overlay (or reuse an existing one) for each\r
    ;; line visible in this window, if necessary.\r
    (while (and (not (eobp)) (<= (point) limit))\r
      (let* ((str (if fmt\r
                      (propertize (format fmt line) 'face 'linum)\r
                    (funcall linum-format line)))\r
             (visited (catch 'visited\r
                        (dolist (o (overlays-in (point) (point)))\r
                          (when (string= (overlay-get o 'linum-str) str)\r
                            (unless (memq o linum-overlays)\r
                              (push o linum-overlays))\r
                            (setq linum-available (delete o linum-available))\r
                            (throw 'visited t))))))\r
        (setq width (max width (length str)))\r
        (unless visited\r
          (let ((ov (if (null linum-available)\r
                        (make-overlay (point) (point))\r
                      (move-overlay (pop linum-available) (point) (point)))))\r
            (push ov linum-overlays)\r
            (overlay-put ov 'before-string\r
                         (propertize " " 'display `((margin left-margin) ,str)))\r
            (overlay-put ov 'linum-str str))))\r
      (forward-line)\r
      (setq line (1+ line)))\r
    (set-window-margins win width)))\r
\r
(defun linum-after-change (beg end len)\r
  ;; update overlays on deletions, and after newlines are inserted\r
  (when (or (= beg end)\r
            (= end (point-max))\r
            (string-match-p "\n" (buffer-substring-no-properties beg end)))\r
    (linum-update-current)))\r
\r
(defun linum-after-scroll (win start)\r
  (linum-update (window-buffer win)))\r
\r
(defun linum-after-size (frame)\r
  (linum-after-config))\r
\r
(defun linum-schedule ()\r
  ;; schedule an update; the delay gives Emacs a chance for display changes\r
  (run-with-idle-timer 0 nil #'linum-update-current))\r
\r
(defun linum-after-config ()\r
  (walk-windows (lambda (w) (linum-update (window-buffer w))) nil 'visible))\r
\r
(defun linum-unload-function ()\r
  "Unload the Linum library."\r
  (global-linum-mode -1)\r
  ;; continue standard unloading\r
  nil)\r
\r
(provide 'linum)\r
\r
;; arch-tag: dea45631-ed3c-4867-8b49-1c41c80aec6a\r
;;; linum.el ends here\r