[bpt/emacs.git] / m4 / dup2.m4

#serial 19
dnl Copyright (C) 2002, 2005, 2007, 2009-2013 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_FUNC_DUP2],
[
  AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
  AC_REQUIRE([AC_CANONICAL_HOST])
  m4_ifdef([gl_FUNC_DUP2_OBSOLETE], [
    AC_CHECK_FUNCS_ONCE([dup2])
    if test $ac_cv_func_dup2 = no; then
      HAVE_DUP2=0
    fi
  ], [
    AC_DEFINE([HAVE_DUP2], [1], [Define to 1 if you have the 'dup2' function.])
  ])
  if test $HAVE_DUP2 = 1; then
    AC_CACHE_CHECK([whether dup2 works], [gl_cv_func_dup2_works],
      [AC_RUN_IFELSE([
         AC_LANG_PROGRAM([[#include <unistd.h>
#include <fcntl.h>
#include <errno.h>]],
           [int result = 0;
#ifdef FD_CLOEXEC
            if (fcntl (1, F_SETFD, FD_CLOEXEC) == -1)
              result |= 1;
#endif
            if (dup2 (1, 1) == 0)
              result |= 2;
#ifdef FD_CLOEXEC
            if (fcntl (1, F_GETFD) != FD_CLOEXEC)
              result |= 4;
#endif
            close (0);
            if (dup2 (0, 0) != -1)
              result |= 8;
            /* Many gnulib modules require POSIX conformance of EBADF.  */
            if (dup2 (2, 1000000) == -1 && errno != EBADF)
              result |= 16;
            /* Flush out a cygwin core dump.  */
            if (dup2 (2, -1) != -1 || errno != EBADF)
              result |= 32;
            return result;
           ])
        ],
        [gl_cv_func_dup2_works=yes], [gl_cv_func_dup2_works=no],
        [case "$host_os" in
           mingw*) # on this platform, dup2 always returns 0 for success
             gl_cv_func_dup2_works="guessing no" ;;
           cygwin*) # on cygwin 1.5.x, dup2(1,1) returns 0
             gl_cv_func_dup2_works="guessing no" ;;
           linux*) # On linux between 2008-07-27 and 2009-05-11, dup2 of a
                   # closed fd may yield -EBADF instead of -1 / errno=EBADF.
             gl_cv_func_dup2_works="guessing no" ;;
           freebsd*) # on FreeBSD 6.1, dup2(1,1000000) gives EMFILE, not EBADF.
             gl_cv_func_dup2_works="guessing no" ;;
           haiku*) # on Haiku alpha 2, dup2(1, 1) resets FD_CLOEXEC.
             gl_cv_func_dup2_works="guessing no" ;;
           *) gl_cv_func_dup2_works="guessing yes" ;;
         esac])
      ])
    case "$gl_cv_func_dup2_works" in
      *yes) ;;
      *)
        REPLACE_DUP2=1
        ;;
    esac
  fi
  dnl Replace dup2() for supporting the gnulib-defined fchdir() function,
  dnl to keep fchdir's bookkeeping up-to-date.
  m4_ifdef([gl_FUNC_FCHDIR], [
    gl_TEST_FCHDIR
    if test $HAVE_FCHDIR = 0; then
      if test $HAVE_DUP2 = 1; then
        REPLACE_DUP2=1
      fi
    fi
  ])
])

# Prerequisites of lib/dup2.c.
AC_DEFUN([gl_PREREQ_DUP2], [])
Commit	Line	Data
9ff99d22 PE	1	#serial 19
9ff99d22 PE	2	dnl Copyright (C) 2002, 2005, 2007, 2009-2013 Free Software Foundation, Inc.
7a7ef429 PE	3	dnl This file is free software; the Free Software Foundation
	4	dnl gives unlimited permission to copy and/or distribute it,
	5	dnl with or without modifications, as long as this notice is preserved.
	6
	7	AC_DEFUN([gl_FUNC_DUP2],
	8	[
	9	AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
	10	AC_REQUIRE([AC_CANONICAL_HOST])
	11	m4_ifdef([gl_FUNC_DUP2_OBSOLETE], [
	12	AC_CHECK_FUNCS_ONCE([dup2])
	13	if test $ac_cv_func_dup2 = no; then
	14	HAVE_DUP2=0
7a7ef429 PE	15	fi
	16	], [
	17	AC_DEFINE([HAVE_DUP2], [1], [Define to 1 if you have the 'dup2' function.])
	18	])
	19	if test $HAVE_DUP2 = 1; then
	20	AC_CACHE_CHECK([whether dup2 works], [gl_cv_func_dup2_works],
	21	[AC_RUN_IFELSE([
	22	AC_LANG_PROGRAM([[#include <unistd.h>
	23	#include <fcntl.h>
	24	#include <errno.h>]],
	25	[int result = 0;
	26	#ifdef FD_CLOEXEC
	27	if (fcntl (1, F_SETFD, FD_CLOEXEC) == -1)
	28	result \|= 1;
	29	#endif
	30	if (dup2 (1, 1) == 0)
	31	result \|= 2;
	32	#ifdef FD_CLOEXEC
	33	if (fcntl (1, F_GETFD) != FD_CLOEXEC)
	34	result \|= 4;
	35	#endif
	36	close (0);
	37	if (dup2 (0, 0) != -1)
	38	result \|= 8;
	39	/* Many gnulib modules require POSIX conformance of EBADF. */
	40	if (dup2 (2, 1000000) == -1 && errno != EBADF)
	41	result \|= 16;
9ff99d22 PE	42	/* Flush out a cygwin core dump. */
	43	if (dup2 (2, -1) != -1 \|\| errno != EBADF)
	44	result \|= 32;
7a7ef429 PE	45	return result;
	46	])
	47	],
	48	[gl_cv_func_dup2_works=yes], [gl_cv_func_dup2_works=no],
	49	[case "$host_os" in
	50	mingw*) # on this platform, dup2 always returns 0 for success
caf8a9b2	51	gl_cv_func_dup2_works="guessing no" ;;
7a7ef429	52	cygwin*) # on cygwin 1.5.x, dup2(1,1) returns 0
caf8a9b2	53	gl_cv_func_dup2_works="guessing no" ;;
7a7ef429 PE	54	linux*) # On linux between 2008-07-27 and 2009-05-11, dup2 of a
7a7ef429 PE	55	# closed fd may yield -EBADF instead of -1 / errno=EBADF.
caf8a9b2	56	gl_cv_func_dup2_works="guessing no" ;;
7a7ef429	57	freebsd*) # on FreeBSD 6.1, dup2(1,1000000) gives EMFILE, not EBADF.
caf8a9b2	58	gl_cv_func_dup2_works="guessing no" ;;
7a7ef429	59	haiku*) # on Haiku alpha 2, dup2(1, 1) resets FD_CLOEXEC.
caf8a9b2 PE	60	gl_cv_func_dup2_works="guessing no" ;;
caf8a9b2 PE	61	*) gl_cv_func_dup2_works="guessing yes" ;;
7a7ef429 PE	62	esac])
7a7ef429 PE	63	])
caf8a9b2 PE	64	case "$gl_cv_func_dup2_works" in
	65	*yes) ;;
	66	*)
	67	REPLACE_DUP2=1
	68	;;
	69	esac
7a7ef429	70	fi
54020294 PE	71	dnl Replace dup2() for supporting the gnulib-defined fchdir() function,
	72	dnl to keep fchdir's bookkeeping up-to-date.
	73	m4_ifdef([gl_FUNC_FCHDIR], [
	74	gl_TEST_FCHDIR
	75	if test $HAVE_FCHDIR = 0; then
caf8a9b2 PE	76	if test $HAVE_DUP2 = 1; then
	77	REPLACE_DUP2=1
	78	fi
54020294 PE	79	fi
54020294 PE	80	])
7a7ef429	81	])
316f8af0 PE	82
	83	# Prerequisites of lib/dup2.c.
	84	AC_DEFUN([gl_PREREQ_DUP2], [])