[bpt/emacs.git] / lisp / toolbar / tool-bar.el

;;; tool-bar.el --- setting up the tool bar
;;
;; Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc.
;;
;; Author: Dave Love <fx@gnu.org>
;; Keywords: mouse frames

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to the
;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
;; Boston, MA 02111-1307, USA.

;;; Commentary:

;; Provides `tool-bar-mode' to control display of the tool-bar and
;; bindings for the global tool bar with convenience functions
;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.

;; The normal global binding for [tool-bar] (below) uses the value of
;; `tool-bar-map' as the actual keymap to define the tool bar.  Modes
;; may either bind items under the [tool-bar] prefix key of the local
;; map to add to the global bar or may set `tool-bar-map'
;; buffer-locally to override it.  (Some items are removed from the
;; global bar in modes which have `special' as their `mode-class'
;; property.)

;; Todo: Somehow make tool bars easily customizable by the naive?

;;; Code:

;;;###autoload
(define-minor-mode tool-bar-mode
  "Toggle use of the tool bar.
With numeric ARG, display the tool bar if and only if ARG is positive.

See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
conveniently adding tool bar items."
  :init-value nil
  :global t
  :group 'mouse
  :group 'frames
  (and (display-images-p)
       (let ((lines (if tool-bar-mode 1 0)))
	 ;; Alter existing frames...
	 (mapc (lambda (frame)
		 (modify-frame-parameters frame
					  (list (cons 'tool-bar-lines lines))))
	       (frame-list))
	 ;; ...and future ones.
	 (let ((elt (assq 'tool-bar-lines default-frame-alist)))
	   (if elt
	       (setcdr elt lines)
	     (add-to-list 'default-frame-alist (cons 'tool-bar-lines lines)))))
       (if (and tool-bar-mode
		(display-graphic-p)
		(= 1 (length (default-value 'tool-bar-map)))) ; not yet setup
	   (tool-bar-setup))))

;;;###autoload
;; We want to pretend the toolbar by standard is on, as this will make
;; customize consider disabling the toolbar a customization, and save
;; that.  We could do this for real by setting :init-value above, but
;; that would turn on the toolbar in MS Windows where it is currently
;; useless, and it would overwrite disabling the tool bar from X
;; resources.  If anyone want to implement this in a cleaner way,
;; please do so.
;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2002-02-21.
(put 'tool-bar-mode 'standard-value '(t))

(defvar tool-bar-map (make-sparse-keymap)
  "Keymap for the tool bar.
Define this locally to override the global tool bar.")

(global-set-key [tool-bar]
		'(menu-item "tool bar" ignore
			    :filter (lambda (ignore) tool-bar-map)))

;;;###autoload
(defun tool-bar-add-item (icon def key &rest props)
  "Add an item to the tool bar.
ICON names the image, DEF is the key definition and KEY is a symbol
for the fake function key in the menu keymap.  Remaining arguments
PROPS are additional items to add to the menu item specification.  See
Info node `(elisp)Tool Bar'.  Items are added from left to right.

ICON is the base name of a file containing the image to use.  The
function will first try to use ICON.xpm, then ICON.pbm, and finally
ICON.xbm, using `find-image'.

Use this function only to make bindings in the global value of `tool-bar-map'.
To define items in any other map, use `tool-bar-local-item'."
  (apply 'tool-bar-local-item icon def key tool-bar-map props))

;;;###autoload
(defun tool-bar-local-item (icon def key map &rest props)
  "Add an item to the tool bar in map MAP.
ICON names the image, DEF is the key definition and KEY is a symbol
for the fake function key in the menu keymap.  Remaining arguments
PROPS are additional items to add to the menu item specification.  See
Info node `(elisp)Tool Bar'.  Items are added from left to right.

ICON is the base name of a file containing the image to use.  The
function will first try to use ICON.xpm, then ICON.pbm, and finally
ICON.xbm, using `find-image'."
  (let* ((fg (face-attribute 'tool-bar :foreground))
	 (bg (face-attribute 'tool-bar :background))
	 (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
			(if (eq bg 'unspecified) nil (list :background bg))))
	 (image (find-image
		(if (display-color-p)
		    (list (list :type 'xpm :file (concat icon ".xpm"))
			  (append (list :type 'pbm :file (concat icon ".pbm"))
				  colors)
			  (append (list :type 'xbm :file (concat icon ".xbm"))
				  colors))
		  (list (append (list :type 'pbm :file (concat icon ".pbm"))
				colors)
			(append (list :type 'xbm :file (concat icon ".xbm"))
				colors)
			(list :type 'xpm :file (concat icon ".xpm")))))))
    (when (and (display-images-p) image)
      (unless (image-mask-p image)
	(setq image (append image '(:mask heuristic))))
      (define-key-after map (vector key)
	`(menu-item ,(symbol-name key) ,def :image ,image ,@props)))))

;;;###autoload
(defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
  "Define tool bar binding for COMMAND using the given ICON in keymap MAP.
This makes a binding for COMMAND in `tool-bar-map', copying its
binding from the menu bar in MAP (which defaults to `global-map'), but
modifies the binding by adding an image specification for ICON.  It
finds ICON just like `tool-bar-add-item'.  PROPS are additional
properties to add to the binding.

MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.

Use this function only to make bindings in the global value of `tool-bar-map'.
To define items in any other map, use `tool-bar-local-item'."
  (apply 'tool-bar-local-item-from-menu command icon
	 (default-value 'tool-bar-map) map props))

;;;###autoload
(defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
  "Define tool bar binding for COMMAND using the given ICON in keymap MAP.
This makes a binding for COMMAND in IN-MAP, copying its binding from
the menu bar in FROM-MAP (which defaults to `global-map'), but
modifies the binding by adding an image specification for ICON.  It
finds ICON just like `tool-bar-add-item'.  PROPS are additional
properties to add to the binding.

MAP must contain appropriate binding for `[menu-bar]' which holds a keymap."
  (unless from-map
    (setq from-map global-map))
  (let* ((menu-bar-map (lookup-key from-map [menu-bar]))
	 (keys (where-is-internal command menu-bar-map))
	 (fg (face-attribute 'tool-bar :foreground))
	 (bg (face-attribute 'tool-bar :background))
	 (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
			(if (eq bg 'unspecified) nil (list :background bg))))
	 (spec (if (display-color-p)
		   (list (list :type 'xpm :file (concat icon ".xpm"))
			 (append (list :type 'pbm :file (concat icon ".pbm"))
				       colors)
			 (append (list :type 'xbm :file (concat icon ".xbm"))
				       colors))
		 (list (append (list :type 'pbm :file (concat icon ".pbm"))
				     colors)
		       (append (list :type 'xbm :file (concat icon ".xbm"))
				     colors)
		       (list :type 'xpm :file (concat icon ".xpm")))))
	 (image (find-image spec))
	 submap key)
    (when (and (display-images-p) image)
      ;; We'll pick up the last valid entry in the list of keys if
      ;; there's more than one.
      (dolist (k keys)
	;; We're looking for a binding of the command in a submap of
	;; the menu bar map, so the key sequence must be two or more
	;; long.
	(if (and (vectorp k)
		 (> (length k) 1))
	    (let ((m (lookup-key menu-bar-map (substring k 0 -1)))
		  ;; Last element in the bound key sequence:
		  (kk (aref k (1- (length k)))))
	      (if (and (keymapp m)
		       (symbolp kk))
		  (setq submap m
			key kk)))))
      (when (and (symbolp submap) (boundp submap))
	(setq submap (eval submap)))
      (unless (image-mask-p image)
	(setq image (append image '(:mask heuristic))))
      (let ((defn (assq key (cdr submap))))
	(if (eq (cadr defn) 'menu-item)
	    (define-key-after in-map (vector key)
	      (append (cdr defn) (list :image image) props))
	  (setq defn (cdr defn))
	  (define-key-after in-map (vector key)
	    (let ((rest (cdr defn)))
	      ;; If the rest of the definition starts
	      ;; with a list of menu cache info, get rid of that.
	      (if (and (consp rest) (consp (car rest)))
		  (setq rest (cdr rest)))
	      (append `(menu-item ,(car defn) ,rest)
		      (list :image image) props))))))))

;;; Set up some global items.  Additions/deletions up for grabs.

(defun tool-bar-setup ()
  ;; People say it's bad to have EXIT on the tool bar, since users
  ;; might inadvertently click that button.
  ;;(tool-bar-add-item-from-menu 'save-buffers-kill-emacs "exit")
  (tool-bar-add-item-from-menu 'find-file "new")
  (tool-bar-add-item-from-menu 'dired "open")
  (tool-bar-add-item-from-menu 'kill-this-buffer "close")
  (tool-bar-add-item-from-menu 'save-buffer "save" nil
			       :visible '(or buffer-file-name
					     (not (eq 'special
						      (get major-mode
							   'mode-class)))))
  (tool-bar-add-item-from-menu 'write-file "saveas" nil
			       :visible '(or buffer-file-name
					     (not (eq 'special
						      (get major-mode
							   'mode-class)))))
  (tool-bar-add-item-from-menu 'undo "undo" nil
			       :visible '(not (eq 'special (get major-mode
								'mode-class))))
  (tool-bar-add-item-from-menu 'kill-region "cut" nil
			       :visible '(not (eq 'special (get major-mode
								'mode-class))))
  (tool-bar-add-item-from-menu 'menu-bar-kill-ring-save "copy")
  (tool-bar-add-item-from-menu 'yank "paste" nil
			       :visible '(not (eq 'special (get major-mode
								'mode-class))))
  (tool-bar-add-item-from-menu 'nonincremental-search-forward "search")
  ;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")

  ;; There's no icon appropriate for News and we need a command rather
  ;; than a lambda for Read Mail.
  ;;(tool-bar-add-item-from-menu 'compose-mail "mail_compose")

  (tool-bar-add-item-from-menu 'print-buffer "print")
  (tool-bar-add-item "preferences" 'customize 'customize
		     :help "Edit preferences (customize)")

  (tool-bar-add-item "help" (lambda ()
			      (interactive)
			      (popup-menu menu-bar-help-menu))
		     'help
		     :help "Pop up the Help menu")
  )

(provide 'tool-bar)

;;; arch-tag: 15f30f0a-d0d7-4d50-bbb7-f48fd0c8582f
;;; tool-bar.el ends here
Commit	Line	Data
e8af40ee	1	;;; tool-bar.el --- setting up the tool bar
ec7f4585	2	;;
4f9b9060	3	;; Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc.
ec7f4585 DL	4	;;
	5	;; Author: Dave Love <fx@gnu.org>
	6	;; Keywords: mouse frames
	7
	8	;; This file is part of GNU Emacs.
	9
	10	;; GNU Emacs is free software; you can redistribute it and/or modify
	11	;; it under the terms of the GNU General Public License as published by
	12	;; the Free Software Foundation; either version 2, or (at your option)
	13	;; any later version.
	14
	15	;; GNU Emacs is distributed in the hope that it will be useful,
	16	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	17	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	18	;; GNU General Public License for more details.
	19
	20	;; You should have received a copy of the GNU General Public License
	21	;; along with GNU Emacs; see the file COPYING. If not, write to the
	22	;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
	23	;; Boston, MA 02111-1307, USA.
	24
	25	;;; Commentary:
	26
02d709c0	27	;; Provides `tool-bar-mode' to control display of the tool-bar and
ec7f4585 DL	28	;; bindings for the global tool bar with convenience functions
	29	;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.
	30
9a4b8870	31	;; The normal global binding for [tool-bar] (below) uses the value of
c129b5ef DL	32	;; `tool-bar-map' as the actual keymap to define the tool bar. Modes
	33	;; may either bind items under the [tool-bar] prefix key of the local
	34	;; map to add to the global bar or may set `tool-bar-map'
b28e72df	35	;; buffer-locally to override it. (Some items are removed from the
9a4b8870	36	;; global bar in modes which have `special' as their `mode-class'
b011dcb0	37	;; property.)
9a4b8870	38
adf7d3a8 DL	39	;; Todo: Somehow make tool bars easily customizable by the naive?
adf7d3a8 DL	40
ec7f4585 DL	41	;;; Code:
	42
	43	;;;###autoload
	44	(define-minor-mode tool-bar-mode
	45	"Toggle use of the tool bar.
a81fc510	46	With numeric ARG, display the tool bar if and only if ARG is positive.
ec7f4585 DL	47
	48	See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
	49	conveniently adding tool bar items."
929e8487	50	:init-value nil
ec7f4585 DL	51	:global t
	52	:group 'mouse
	53	:group 'frames
ef32aa02 EZ	54	(and (display-images-p)
	55	(let ((lines (if tool-bar-mode 1 0)))
	56	;; Alter existing frames...
	57	(mapc (lambda (frame)
	58	(modify-frame-parameters frame
	59	(list (cons 'tool-bar-lines lines))))
	60	(frame-list))
	61	;; ...and future ones.
	62	(let ((elt (assq 'tool-bar-lines default-frame-alist)))
	63	(if elt
	64	(setcdr elt lines)
	65	(add-to-list 'default-frame-alist (cons 'tool-bar-lines lines)))))
	66	(if (and tool-bar-mode
	67	(display-graphic-p)
	68	(= 1 (length (default-value 'tool-bar-map)))) ; not yet setup
	69	(tool-bar-setup))))
ec7f4585	70
929e8487 PA	71	;;;###autoload
	72	;; We want to pretend the toolbar by standard is on, as this will make
	73	;; customize consider disabling the toolbar a customization, and save
	74	;; that. We could do this for real by setting :init-value above, but
	75	;; that would turn on the toolbar in MS Windows where it is currently
	76	;; useless, and it would overwrite disabling the tool bar from X
	77	;; resources. If anyone want to implement this in a cleaner way,
	78	;; please do so.
	79	;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2002-02-21.
	80	(put 'tool-bar-mode 'standard-value '(t))
	81
9a4b8870 DL	82	(defvar tool-bar-map (make-sparse-keymap)
	83	"Keymap for the tool bar.
	84	Define this locally to override the global tool bar.")
	85
	86	(global-set-key [tool-bar]
	87	'(menu-item "tool bar" ignore
	88	:filter (lambda (ignore) tool-bar-map)))
ec7f4585 DL	89
ec7f4585 DL	90	;;;###autoload
9a4b8870	91	(defun tool-bar-add-item (icon def key &rest props)
ec7f4585 DL	92	"Add an item to the tool bar.
ec7f4585 DL	93	ICON names the image, DEF is the key definition and KEY is a symbol
9a4b8870 DL	94	for the fake function key in the menu keymap. Remaining arguments
	95	PROPS are additional items to add to the menu item specification. See
	96	Info node `(elisp)Tool Bar'. Items are added from left to right.
ec7f4585	97
cb4aae04 EZ	98	ICON is the base name of a file containing the image to use. The
	99	function will first try to use ICON.xpm, then ICON.pbm, and finally
	100	ICON.xbm, using `find-image'.
9a4b8870	101
ca1b34c8 RS	102	Use this function only to make bindings in the global value of `tool-bar-map'.
	103	To define items in any other map, use `tool-bar-local-item'."
	104	(apply 'tool-bar-local-item icon def key tool-bar-map props))
	105
	106	;;;###autoload
	107	(defun tool-bar-local-item (icon def key map &rest props)
	108	"Add an item to the tool bar in map MAP.
	109	ICON names the image, DEF is the key definition and KEY is a symbol
	110	for the fake function key in the menu keymap. Remaining arguments
	111	PROPS are additional items to add to the menu item specification. See
	112	Info node `(elisp)Tool Bar'. Items are added from left to right.
	113
	114	ICON is the base name of a file containing the image to use. The
	115	function will first try to use ICON.xpm, then ICON.pbm, and finally
	116	ICON.xbm, using `find-image'."
3fae165c GM	117	(let* ((fg (face-attribute 'tool-bar :foreground))
	118	(bg (face-attribute 'tool-bar :background))
	119	(colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
	120	(if (eq bg 'unspecified) nil (list :background bg))))
3b6d80f1	121	(image (find-image
34e86ea3	122	(if (display-color-p)
3fae165c GM	123	(list (list :type 'xpm :file (concat icon ".xpm"))
	124	(append (list :type 'pbm :file (concat icon ".pbm"))
	125	colors)
	126	(append (list :type 'xbm :file (concat icon ".xbm"))
	127	colors))
	128	(list (append (list :type 'pbm :file (concat icon ".pbm"))
	129	colors)
	130	(append (list :type 'xbm :file (concat icon ".xbm"))
	131	colors)
	132	(list :type 'xpm :file (concat icon ".xpm")))))))
196de866	133	(when (and (display-images-p) image)
ec7f4585 DL	134	(unless (image-mask-p image)
ec7f4585 DL	135	(setq image (append image '(:mask heuristic))))
ca1b34c8	136	(define-key-after map (vector key)
ec7f4585 DL	137	`(menu-item ,(symbol-name key) ,def :image ,image ,@props)))))
ec7f4585 DL	138
c2156508	139	;;;###autoload
ec7f4585 DL	140	(defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
ec7f4585 DL	141	"Define tool bar binding for COMMAND using the given ICON in keymap MAP.
ca1b34c8 RS	142	This makes a binding for COMMAND in `tool-bar-map', copying its
	143	binding from the menu bar in MAP (which defaults to `global-map'), but
	144	modifies the binding by adding an image specification for ICON. It
	145	finds ICON just like `tool-bar-add-item'. PROPS are additional
	146	properties to add to the binding.
	147
	148	MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.
	149
	150	Use this function only to make bindings in the global value of `tool-bar-map'.
	151	To define items in any other map, use `tool-bar-local-item'."
03a8bf7d SM	152	(apply 'tool-bar-local-item-from-menu command icon
03a8bf7d SM	153	(default-value 'tool-bar-map) map props))
ca1b34c8 RS	154
	155	;;;###autoload
	156	(defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
	157	"Define tool bar binding for COMMAND using the given ICON in keymap MAP.
	158	This makes a binding for COMMAND in IN-MAP, copying its binding from
	159	the menu bar in FROM-MAP (which defaults to `global-map'), but
	160	modifies the binding by adding an image specification for ICON. It
	161	finds ICON just like `tool-bar-add-item'. PROPS are additional
	162	properties to add to the binding.
	163
	164	MAP must contain appropriate binding for `[menu-bar]' which holds a keymap."
	165	(unless from-map
	166	(setq from-map global-map))
	167	(let* ((menu-bar-map (lookup-key from-map [menu-bar]))
ec7f4585	168	(keys (where-is-internal command menu-bar-map))
3fae165c GM	169	(fg (face-attribute 'tool-bar :foreground))
	170	(bg (face-attribute 'tool-bar :background))
	171	(colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
	172	(if (eq bg 'unspecified) nil (list :background bg))))
7e636904 GM	173	(spec (if (display-color-p)
	174	(list (list :type 'xpm :file (concat icon ".xpm"))
	175	(append (list :type 'pbm :file (concat icon ".pbm"))
	176	colors)
	177	(append (list :type 'xbm :file (concat icon ".xbm"))
	178	colors))
	179	(list (append (list :type 'pbm :file (concat icon ".pbm"))
	180	colors)
	181	(append (list :type 'xbm :file (concat icon ".xbm"))
	182	colors)
	183	(list :type 'xpm :file (concat icon ".xpm")))))
	184	(image (find-image spec))
ec7f4585	185	submap key)
196de866	186	(when (and (display-images-p) image)
ec7f4585 DL	187	;; We'll pick up the last valid entry in the list of keys if
	188	;; there's more than one.
	189	(dolist (k keys)
	190	;; We're looking for a binding of the command in a submap of
	191	;; the menu bar map, so the key sequence must be two or more
	192	;; long.
	193	(if (and (vectorp k)
	194	(> (length k) 1))
	195	(let ((m (lookup-key menu-bar-map (substring k 0 -1)))
	196	;; Last element in the bound key sequence:
	197	(kk (aref k (1- (length k)))))
	198	(if (and (keymapp m)
	199	(symbolp kk))
	200	(setq submap m
	201	key kk)))))
	202	(when (and (symbolp submap) (boundp submap))
	203	(setq submap (eval submap)))
ddba99ad MB	204	(unless (image-mask-p image)
ddba99ad MB	205	(setq image (append image '(:mask heuristic))))
98a8938c GM	206	(let ((defn (assq key (cdr submap))))
98a8938c GM	207	(if (eq (cadr defn) 'menu-item)
ca1b34c8	208	(define-key-after in-map (vector key)
98a8938c GM	209	(append (cdr defn) (list :image image) props))
98a8938c GM	210	(setq defn (cdr defn))
ca1b34c8	211	(define-key-after in-map (vector key)
2fab4328 RS	212	(let ((rest (cdr defn)))
	213	;; If the rest of the definition starts
	214	;; with a list of menu cache info, get rid of that.
	215	(if (and (consp rest) (consp (car rest)))
	216	(setq rest (cdr rest)))
	217	(append `(menu-item ,(car defn) ,rest)
	218	(list :image image) props))))))))
ec7f4585 DL	219
	220	;;; Set up some global items. Additions/deletions up for grabs.
	221
ebd4825d	222	(defun tool-bar-setup ()
7a03d9cd EZ	223	;; People say it's bad to have EXIT on the tool bar, since users
	224	;; might inadvertently click that button.
	225	;;(tool-bar-add-item-from-menu 'save-buffers-kill-emacs "exit")
ebd4825d DL	226	(tool-bar-add-item-from-menu 'find-file "new")
	227	(tool-bar-add-item-from-menu 'dired "open")
	228	(tool-bar-add-item-from-menu 'kill-this-buffer "close")
	229	(tool-bar-add-item-from-menu 'save-buffer "save" nil
5ec17636 DL	230	:visible '(or buffer-file-name
	231	(not (eq 'special
	232	(get major-mode
	233	'mode-class)))))
ebd4825d	234	(tool-bar-add-item-from-menu 'write-file "saveas" nil
5ec17636 DL	235	:visible '(or buffer-file-name
	236	(not (eq 'special
	237	(get major-mode
	238	'mode-class)))))
ebd4825d DL	239	(tool-bar-add-item-from-menu 'undo "undo" nil
	240	:visible '(not (eq 'special (get major-mode
	241	'mode-class))))
	242	(tool-bar-add-item-from-menu 'kill-region "cut" nil
	243	:visible '(not (eq 'special (get major-mode
	244	'mode-class))))
	245	(tool-bar-add-item-from-menu 'menu-bar-kill-ring-save "copy")
	246	(tool-bar-add-item-from-menu 'yank "paste" nil
	247	:visible '(not (eq 'special (get major-mode
	248	'mode-class))))
	249	(tool-bar-add-item-from-menu 'nonincremental-search-forward "search")
	250	;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")
	251
	252	;; There's no icon appropriate for News and we need a command rather
	253	;; than a lambda for Read Mail.
	254	;;(tool-bar-add-item-from-menu 'compose-mail "mail_compose")
	255
	256	(tool-bar-add-item-from-menu 'print-buffer "print")
9a4b8870	257	(tool-bar-add-item "preferences" 'customize 'customize
ebd4825d DL	258	:help "Edit preferences (customize)")
ebd4825d DL	259
9a4b8870 DL	260	(tool-bar-add-item "help" (lambda ()
	261	(interactive)
	262	(popup-menu menu-bar-help-menu))
	263	'help
	264	:help "Pop up the Help menu")
ebd4825d	265	)
ec7f4585 DL	266
	267	(provide 'tool-bar)
	268
ab5796a9	269	;;; arch-tag: 15f30f0a-d0d7-4d50-bbb7-f48fd0c8582f
ec7f4585	270	;;; tool-bar.el ends here