Simpler version of strtoumax module.

[bpt/emacs.git] / m4 / strtoumax.m4

# strtoumax.m4 serial 9
dnl Copyright (C) 2002-2004, 2006, 2009-2011 Free Software Foundation, Inc.
dnl This file is free software; the Free Software Foundation
dnl gives unlimited permission to copy and/or distribute it,
dnl with or without modifications, as long as this notice is preserved.

AC_DEFUN([gl_FUNC_STRTOUMAX],
[
  AC_REQUIRE([gl_INTTYPES_H_DEFAULTS])

  AC_CHECK_DECLS_ONCE([strtoumax])
  if test "$ac_cv_have_decl_strtoumax" != yes; then
    HAVE_DECL_STRTOUMAX=0

    AC_CACHE_CHECK([whether <inttypes.h> defines strtoumax as a macro],
      gl_cv_func_strtoumax_macro,
      [AC_EGREP_CPP([inttypes_h_defines_strtoumax], [#include <inttypes.h>
	   #ifdef strtoumax
	    inttypes_h_defines_strtoumax
	   #endif],
	 gl_cv_func_strtoumax_macro=yes,
	 gl_cv_func_strtoumax_macro=no)])

    if test "$gl_cv_func_strtoumax_macro" != yes; then
      AC_REPLACE_FUNCS([strtoumax])
      if test $ac_cv_func_strtoumax = no; then
	gl_PREREQ_STRTOUMAX
      fi
    fi
  fi
])

# Prerequisites of lib/strtoumax.c.
AC_DEFUN([gl_PREREQ_STRTOUMAX], [
  AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
  gl_FUNC_STRTOULL
])