[bpt/emacs.git] / lisp / gnus / gnus-async.el

;;; gnus-async.el --- asynchronous support for Gnus

;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
;;   2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.

;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
;; Keywords: news

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(eval-when-compile (require 'cl))

(require 'gnus)
(require 'gnus-sum)
(require 'nntp)

(defgroup gnus-asynchronous nil
  "Support for asynchronous operations."
  :group 'gnus)

(defcustom gnus-use-article-prefetch 30
  "*If non-nil, prefetch articles in groups that allow this.
If a number, prefetch only that many articles forward;
if t, prefetch as many articles as possible."
  :group 'gnus-asynchronous
  :type '(choice (const :tag "off" nil)
		 (const :tag "all" t)
		 (integer :tag "some" 0)))

(defcustom gnus-asynchronous nil
  "*If nil, inhibit all Gnus asynchronicity.
If non-nil, let the other asynch variables be heeded."
  :group 'gnus-asynchronous
  :type 'boolean)

(defcustom gnus-prefetched-article-deletion-strategy '(read exit)
  "List of symbols that say when to remove articles from the prefetch buffer.
Possible values in this list are `read', which means that
articles are removed as they are read, and `exit', which means
that all articles belonging to a group are removed on exit
from that group."
  :group 'gnus-asynchronous
  :type '(set (const read) (const exit)))

(defcustom gnus-use-header-prefetch nil
  "*If non-nil, prefetch the headers to the next group."
  :group 'gnus-asynchronous
  :type 'boolean)

(defcustom gnus-async-prefetch-article-p 'gnus-async-unread-p
  "Function called to say whether an article should be prefetched or not.
The function is called with one parameter -- the article data.
It should return non-nil if the article is to be prefetched."
  :group 'gnus-asynchronous
  :type 'function)

(defcustom gnus-async-post-fetch-function nil
  "Function called after an article has been prefetched.
The function will be called narrowed to the region of the article
that was fetched."
  :group 'gnus-asynchronous
  :type 'function)

;;; Internal variables.

(defvar gnus-async-prefetch-article-buffer " *Async Prefetch Article*")
(defvar gnus-async-article-alist nil)
(defvar gnus-async-article-semaphore '(nil))
(defvar gnus-async-fetch-list nil)
(defvar gnus-async-hashtb nil)
(defvar gnus-async-current-prefetch-group nil)
(defvar gnus-async-current-prefetch-article nil)
(defvar gnus-async-timer nil)

(defvar gnus-async-prefetch-headers-buffer " *Async Prefetch Headers*")
(defvar gnus-async-header-prefetched nil)

;;; Utility functions.

(defun gnus-group-asynchronous-p (group)
  "Say whether GROUP is fetched from a server that supports asynchronicity."
  (gnus-asynchronous-p (gnus-find-method-for-group group)))

;;; Somewhat bogus semaphores.

(defun gnus-async-get-semaphore (semaphore)
  "Wait until SEMAPHORE is released."
  (while (/= (length (nconc (symbol-value semaphore) (list nil))) 2)
    (sleep-for 1)))

(defun gnus-async-release-semaphore (semaphore)
  "Release SEMAPHORE."
  (setcdr (symbol-value semaphore) nil))

(defmacro gnus-async-with-semaphore (&rest forms)
  `(unwind-protect
       (progn
	 (gnus-async-get-semaphore 'gnus-async-article-semaphore)
	 ,@forms)
     (gnus-async-release-semaphore 'gnus-async-article-semaphore)))

(put 'gnus-async-with-semaphore 'lisp-indent-function 0)
(put 'gnus-async-with-semaphore 'edebug-form-spec '(body))

;;;
;;; Article prefetch
;;;

(gnus-add-shutdown 'gnus-async-close 'gnus)
(defun gnus-async-close ()
  (gnus-kill-buffer gnus-async-prefetch-article-buffer)
  (gnus-kill-buffer gnus-async-prefetch-headers-buffer)
  (setq gnus-async-hashtb nil
	gnus-async-article-alist nil
	gnus-async-header-prefetched nil))

(defun gnus-async-set-buffer ()
  (nnheader-set-temp-buffer gnus-async-prefetch-article-buffer t)
  (unless gnus-async-hashtb
    (setq gnus-async-hashtb (gnus-make-hashtable 1023))))

(defun gnus-async-halt-prefetch ()
  "Stop prefetching."
  (setq gnus-async-fetch-list nil))

(defun gnus-async-prefetch-next (group article summary)
  "Possibly prefetch several articles starting with the article after ARTICLE."
  (when (and (gnus-buffer-live-p summary)
	     gnus-asynchronous
	     (gnus-group-asynchronous-p group))
    (with-current-buffer gnus-summary-buffer
      (let ((next (caadr (gnus-data-find-list article))))
	(when next
	  (if (not (fboundp 'run-with-idle-timer))
	      ;; This is either an older Emacs or XEmacs, so we
	      ;; do this, which leads to slightly slower article
	      ;; buffer display.
	      (gnus-async-prefetch-article group next summary)
	    (when gnus-async-timer
	      (ignore-errors
		(nnheader-cancel-timer 'gnus-async-timer)))
	    (setq gnus-async-timer
		  (run-with-idle-timer
		   0.1 nil 'gnus-async-prefetch-article
		   group next summary))))))))

(defun gnus-async-prefetch-article (group article summary &optional next)
  "Possibly prefetch several articles starting with ARTICLE."
  (if (not (gnus-buffer-live-p summary))
      (gnus-async-with-semaphore
	(setq gnus-async-fetch-list nil))
    (when (and gnus-asynchronous
	       (gnus-alive-p))
      (when next
	(gnus-async-with-semaphore
	  (pop gnus-async-fetch-list)))
      (let ((do-fetch next)
	    (do-message t))		;(eq major-mode 'gnus-summary-mode)))
	(when (and (gnus-group-asynchronous-p group)
		   (gnus-buffer-live-p summary)
		   (or (not next)
		       gnus-async-fetch-list))
	  (gnus-async-with-semaphore
	    (unless next
	      (setq do-fetch (not gnus-async-fetch-list))
	      ;; Nix out any outstanding requests.
	      (setq gnus-async-fetch-list nil)
	      ;; Fill in the new list.
	      (let ((n gnus-use-article-prefetch)
		    (data (gnus-data-find-list article))
		    d)
		(while (and (setq d (pop data))
			    (if (numberp n)
				(natnump (decf n))
			      n))
		  (unless (or (gnus-async-prefetched-article-entry
			       group (setq article (gnus-data-number d)))
			      (not (natnump article))
			      (not (funcall gnus-async-prefetch-article-p d)))
		    ;; Not already fetched -- so we add it to the list.
		    (push article gnus-async-fetch-list)))
		(setq gnus-async-fetch-list
		      (nreverse gnus-async-fetch-list))))

	    (when do-fetch
	      (setq article (car gnus-async-fetch-list))))

	  (when (and do-fetch article)
	    ;; We want to fetch some more articles.
	    (with-current-buffer summary
	      (let (mark)
		(gnus-async-set-buffer)
		(goto-char (point-max))
		(setq mark (point-marker))
		(let ((nnheader-callback-function
		       (gnus-make-async-article-function
			group article mark summary next))
		      (nntp-server-buffer
		       (get-buffer gnus-async-prefetch-article-buffer)))
		  (when do-message
		    (gnus-message 9 "Prefetching article %d in group %s"
				  article group))
		  (setq gnus-async-current-prefetch-group group)
		  (setq gnus-async-current-prefetch-article article)
		  (gnus-request-article article group))))))))))

(defun gnus-make-async-article-function (group article mark summary next)
  "Return a callback function."
  `(lambda (arg)
     (gnus-async-article-callback arg ,group ,article ,mark ,summary ,next)))

(eval-when-compile
  (autoload 'gnus-html-prefetch-images "gnus-html"))

(defun gnus-async-article-callback (arg group article mark summary next)
  "Function called when an async article is done being fetched."
  (save-excursion
    (setq gnus-async-current-prefetch-article nil)
    (when arg
      (gnus-async-set-buffer)
      (save-excursion
	(save-restriction
	  (narrow-to-region mark (point-max))
	  ;; Prefetch images for the groups that want that.
	  (when (fboundp 'gnus-html-prefetch-images)
	    (gnus-html-prefetch-images summary))
	  (when gnus-async-post-fetch-function
	    (funcall gnus-async-post-fetch-function summary))))
      (gnus-async-with-semaphore
	(setq
	 gnus-async-article-alist
	 (cons (list (intern (format "%s-%d" group article)
			     gnus-async-hashtb)
		     mark (set-marker (make-marker) (point-max))
		     group article)
	       gnus-async-article-alist))))
    (if (not (gnus-buffer-live-p summary))
	(gnus-async-with-semaphore
	  (setq gnus-async-fetch-list nil))
      (gnus-async-prefetch-article group next summary t))))

(defun gnus-async-unread-p (data)
  "Return non-nil if DATA represents an unread article."
  (gnus-data-unread-p data))

(defun gnus-async-request-fetched-article (group article buffer)
  "See whether we have ARTICLE from GROUP and put it in BUFFER."
  (when (numberp article)
    (when (and (equal group gnus-async-current-prefetch-group)
	       (eq article gnus-async-current-prefetch-article))
      (gnus-async-wait-for-article article))
    (let ((entry (gnus-async-prefetched-article-entry group article)))
      (when entry
	(save-excursion
	  (gnus-async-set-buffer)
	  (copy-to-buffer buffer (cadr entry) (caddr entry))
	  ;; Remove the read article from the prefetch buffer.
	  (when (memq 'read gnus-prefetched-article-deletion-strategy)
	    (gnus-async-delete-prefetched-entry entry))
	  t)))))

(defun gnus-async-wait-for-article (article)
  "Wait until ARTICLE is no longer the currently-being-fetched article."
  (save-excursion
    (gnus-async-set-buffer)
    (let ((proc (nntp-find-connection (current-buffer)))
	  (nntp-server-buffer (current-buffer))
	  (nntp-have-messaged nil)
	  (tries 0))
      (when proc
	(condition-case nil
	    ;; FIXME: we could stop waiting after some
	    ;; timeout, but this is the wrong place to do it.
	    ;; rather than checking time-spent-waiting, we
	    ;; should check time-since-last-output, which
	    ;; needs to be done in nntp.el.
	    (while (eq article gnus-async-current-prefetch-article)
	      (incf tries)
	      (when (nntp-accept-process-output proc)
		(setq tries 0))
	      (when (and (not nntp-have-messaged)
			 (= tries 3))
		(gnus-message 5 "Waiting for async article...")
		(setq nntp-have-messaged t)))
	  (quit
	   ;; if the user interrupted on a slow/hung connection,
	   ;; do something friendly.
	   (when (> tries 3)
	     (setq gnus-async-current-prefetch-article nil))
	   (signal 'quit nil)))
	(when nntp-have-messaged
	  (gnus-message 5 ""))))))

(defun gnus-async-delete-prefetched-entry (entry)
  "Delete ENTRY from buffer and alist."
  (ignore-errors
    (delete-region (cadr entry) (caddr entry))
    (set-marker (cadr entry) nil)
    (set-marker (caddr entry) nil))
  (gnus-async-with-semaphore
    (setq gnus-async-article-alist
	  (delq entry gnus-async-article-alist))
    (unintern (car entry) gnus-async-hashtb)))

(defun gnus-async-prefetch-remove-group (group)
  "Remove all articles belonging to GROUP from the prefetch buffer."
  (when (and (gnus-group-asynchronous-p group)
	     (memq 'exit gnus-prefetched-article-deletion-strategy))
    (save-excursion
      (gnus-async-set-buffer)
      (dolist (entry gnus-async-article-alist)
	(when (equal group (nth 3 entry))
	  (gnus-async-delete-prefetched-entry entry))))))

(defun gnus-async-prefetched-article-entry (group article)
  "Return the entry for ARTICLE in GROUP if it has been prefetched."
  (let ((entry (save-excursion
		 (gnus-async-set-buffer)
		 (assq (intern-soft (format "%s-%d" group article)
				    gnus-async-hashtb)
		       gnus-async-article-alist))))
    ;; Perhaps something has emptied the buffer?
    (if (and entry
	     (= (cadr entry) (caddr entry)))
	(progn
	  (ignore-errors
	    (set-marker (cadr entry) nil)
	    (set-marker (caddr entry) nil))
	  (setq gnus-async-article-alist
		(delq entry gnus-async-article-alist))
	  nil)
      entry)))

;;;
;;; Header prefetch
;;;

(defun gnus-async-prefetch-headers (group)
  "Prefetch the headers for group GROUP."
  (save-excursion
    (let (unread)
      (when (and gnus-use-header-prefetch
		 gnus-asynchronous
		 (gnus-group-asynchronous-p group)
		 (listp gnus-async-header-prefetched)
		 (setq unread (gnus-list-of-unread-articles group)))
	;; Mark that a fetch is in progress.
	(setq gnus-async-header-prefetched t)
	(nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
	(erase-buffer)
	(let ((nntp-server-buffer (current-buffer))
	      (nnheader-callback-function
	       `(lambda (arg)
		  (setq gnus-async-header-prefetched
			,(cons group unread)))))
	  (gnus-retrieve-headers unread group gnus-fetch-old-headers))))))

(defun gnus-async-retrieve-fetched-headers (articles group)
  "See whether we have prefetched headers."
  (when (and gnus-use-header-prefetch
	     (gnus-group-asynchronous-p group)
	     (listp gnus-async-header-prefetched)
	     (equal group (car gnus-async-header-prefetched))
	     (equal articles (cdr gnus-async-header-prefetched)))
    (save-excursion
      (nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
      (nntp-decode-text)
      (copy-to-buffer nntp-server-buffer (point-min) (point-max))
      (erase-buffer)
      (setq gnus-async-header-prefetched nil)
      t)))

(provide 'gnus-async)

;;; gnus-async.el ends here
Commit	Line	Data
eec82323	1	;;; gnus-async.el --- asynchronous support for Gnus
e84b4b86	2
b6c2d8c6	3	;; Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
114f9c96	4	;; 2005, 2006, 2007, 2008, 2009, 2010 Free Software Foundation, Inc.
eec82323	5
6748645f	6	;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
eec82323 LMI	7	;; Keywords: news
	8
	9	;; This file is part of GNU Emacs.
	10
5e809f55	11	;; GNU Emacs is free software: you can redistribute it and/or modify
eec82323	12	;; it under the terms of the GNU General Public License as published by
5e809f55 GM	13	;; the Free Software Foundation, either version 3 of the License, or
5e809f55 GM	14	;; (at your option) any later version.
eec82323 LMI	15
	16	;; GNU Emacs is distributed in the hope that it will be useful,
	17	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
5e809f55	18	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
eec82323 LMI	19	;; GNU General Public License for more details.
	20
	21	;; You should have received a copy of the GNU General Public License
5e809f55	22	;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
eec82323 LMI	23
	24	;;; Commentary:
	25
	26	;;; Code:
	27
5ab7173c RS	28	(eval-when-compile (require 'cl))
5ab7173c RS	29
eec82323 LMI	30	(require 'gnus)
	31	(require 'gnus-sum)
	32	(require 'nntp)
	33
	34	(defgroup gnus-asynchronous nil
	35	"Support for asynchronous operations."
	36	:group 'gnus)
	37
eec82323 LMI	38	(defcustom gnus-use-article-prefetch 30
	39	"*If non-nil, prefetch articles in groups that allow this.
	40	If a number, prefetch only that many articles forward;
	41	if t, prefetch as many articles as possible."
	42	:group 'gnus-asynchronous
	43	:type '(choice (const :tag "off" nil)
16409b0b GM	44	(const :tag "all" t)
16409b0b GM	45	(integer :tag "some" 0)))
eec82323	46
23f87bed MB	47	(defcustom gnus-asynchronous nil
	48	"*If nil, inhibit all Gnus asynchronicity.
	49	If non-nil, let the other asynch variables be heeded."
	50	:group 'gnus-asynchronous
	51	:type 'boolean)
	52
eec82323 LMI	53	(defcustom gnus-prefetched-article-deletion-strategy '(read exit)
	54	"List of symbols that say when to remove articles from the prefetch buffer.
	55	Possible values in this list are `read', which means that
	56	articles are removed as they are read, and `exit', which means
	57	that all articles belonging to a group are removed on exit
	58	from that group."
	59	:group 'gnus-asynchronous
	60	:type '(set (const read) (const exit)))
	61
	62	(defcustom gnus-use-header-prefetch nil
	63	"*If non-nil, prefetch the headers to the next group."
	64	:group 'gnus-asynchronous
	65	:type 'boolean)
	66
	67	(defcustom gnus-async-prefetch-article-p 'gnus-async-unread-p
	68	"Function called to say whether an article should be prefetched or not.
	69	The function is called with one parameter -- the article data.
	70	It should return non-nil if the article is to be prefetched."
	71	:group 'gnus-asynchronous
	72	:type 'function)
	73
b1992461 KY	74	(defcustom gnus-async-post-fetch-function nil
	75	"Function called after an article has been prefetched.
	76	The function will be called narrowed to the region of the article
	77	that was fetched."
	78	:group 'gnus-asynchronous
	79	:type 'function)
	80
eec82323 LMI	81	;;; Internal variables.
	82
	83	(defvar gnus-async-prefetch-article-buffer " Async Prefetch Article")
	84	(defvar gnus-async-article-alist nil)
	85	(defvar gnus-async-article-semaphore '(nil))
	86	(defvar gnus-async-fetch-list nil)
16409b0b GM	87	(defvar gnus-async-hashtb nil)
	88	(defvar gnus-async-current-prefetch-group nil)
	89	(defvar gnus-async-current-prefetch-article nil)
	90	(defvar gnus-async-timer nil)
eec82323 LMI	91
	92	(defvar gnus-async-prefetch-headers-buffer " Async Prefetch Headers")
	93	(defvar gnus-async-header-prefetched nil)
	94
	95	;;; Utility functions.
	96
	97	(defun gnus-group-asynchronous-p (group)
	98	"Say whether GROUP is fetched from a server that supports asynchronicity."
	99	(gnus-asynchronous-p (gnus-find-method-for-group group)))
	100
	101	;;; Somewhat bogus semaphores.
	102
	103	(defun gnus-async-get-semaphore (semaphore)
	104	"Wait until SEMAPHORE is released."
	105	(while (/= (length (nconc (symbol-value semaphore) (list nil))) 2)
	106	(sleep-for 1)))
	107
	108	(defun gnus-async-release-semaphore (semaphore)
	109	"Release SEMAPHORE."
	110	(setcdr (symbol-value semaphore) nil))
	111
	112	(defmacro gnus-async-with-semaphore (&rest forms)
	113	`(unwind-protect
	114	(progn
	115	(gnus-async-get-semaphore 'gnus-async-article-semaphore)
	116	,@forms)
	117	(gnus-async-release-semaphore 'gnus-async-article-semaphore)))
	118
16409b0b GM	119	(put 'gnus-async-with-semaphore 'lisp-indent-function 0)
16409b0b GM	120	(put 'gnus-async-with-semaphore 'edebug-form-spec '(body))
eec82323 LMI	121
	122	;;;
	123	;;; Article prefetch
	124	;;;
	125
	126	(gnus-add-shutdown 'gnus-async-close 'gnus)
	127	(defun gnus-async-close ()
	128	(gnus-kill-buffer gnus-async-prefetch-article-buffer)
	129	(gnus-kill-buffer gnus-async-prefetch-headers-buffer)
16409b0b GM	130	(setq gnus-async-hashtb nil
16409b0b GM	131	gnus-async-article-alist nil
eec82323 LMI	132	gnus-async-header-prefetched nil))
	133
	134	(defun gnus-async-set-buffer ()
6748645f	135	(nnheader-set-temp-buffer gnus-async-prefetch-article-buffer t)
16409b0b GM	136	(unless gnus-async-hashtb
16409b0b GM	137	(setq gnus-async-hashtb (gnus-make-hashtable 1023))))
eec82323 LMI	138
	139	(defun gnus-async-halt-prefetch ()
	140	"Stop prefetching."
	141	(setq gnus-async-fetch-list nil))
	142
	143	(defun gnus-async-prefetch-next (group article summary)
	144	"Possibly prefetch several articles starting with the article after ARTICLE."
	145	(when (and (gnus-buffer-live-p summary)
	146	gnus-asynchronous
	147	(gnus-group-asynchronous-p group))
20a673b2	148	(with-current-buffer gnus-summary-buffer
eec82323 LMI	149	(let ((next (caadr (gnus-data-find-list article))))
	150	(when next
	151	(if (not (fboundp 'run-with-idle-timer))
	152	;; This is either an older Emacs or XEmacs, so we
	153	;; do this, which leads to slightly slower article
	154	;; buffer display.
	155	(gnus-async-prefetch-article group next summary)
16409b0b GM	156	(when gnus-async-timer
	157	(ignore-errors
	158	(nnheader-cancel-timer 'gnus-async-timer)))
	159	(setq gnus-async-timer
	160	(run-with-idle-timer
	161	0.1 nil 'gnus-async-prefetch-article
	162	group next summary))))))))
eec82323 LMI	163
	164	(defun gnus-async-prefetch-article (group article summary &optional next)
	165	"Possibly prefetch several articles starting with ARTICLE."
	166	(if (not (gnus-buffer-live-p summary))
	167	(gnus-async-with-semaphore
16409b0b	168	(setq gnus-async-fetch-list nil))
eec82323 LMI	169	(when (and gnus-asynchronous
	170	(gnus-alive-p))
	171	(when next
	172	(gnus-async-with-semaphore
16409b0b	173	(pop gnus-async-fetch-list)))
eec82323	174	(let ((do-fetch next)
16409b0b	175	(do-message t)) ;(eq major-mode 'gnus-summary-mode)))
eec82323 LMI	176	(when (and (gnus-group-asynchronous-p group)
	177	(gnus-buffer-live-p summary)
	178	(or (not next)
	179	gnus-async-fetch-list))
	180	(gnus-async-with-semaphore
16409b0b GM	181	(unless next
	182	(setq do-fetch (not gnus-async-fetch-list))
	183	;; Nix out any outstanding requests.
	184	(setq gnus-async-fetch-list nil)
	185	;; Fill in the new list.
	186	(let ((n gnus-use-article-prefetch)
	187	(data (gnus-data-find-list article))
	188	d)
	189	(while (and (setq d (pop data))
	190	(if (numberp n)
	191	(natnump (decf n))
	192	n))
	193	(unless (or (gnus-async-prefetched-article-entry
	194	group (setq article (gnus-data-number d)))
	195	(not (natnump article))
	196	(not (funcall gnus-async-prefetch-article-p d)))
	197	;; Not already fetched -- so we add it to the list.
	198	(push article gnus-async-fetch-list)))
	199	(setq gnus-async-fetch-list
	200	(nreverse gnus-async-fetch-list))))
	201
	202	(when do-fetch
	203	(setq article (car gnus-async-fetch-list))))
eec82323 LMI	204
	205	(when (and do-fetch article)
	206	;; We want to fetch some more articles.
20a673b2	207	(with-current-buffer summary
eec82323 LMI	208	(let (mark)
	209	(gnus-async-set-buffer)
	210	(goto-char (point-max))
	211	(setq mark (point-marker))
	212	(let ((nnheader-callback-function
	213	(gnus-make-async-article-function
	214	group article mark summary next))
	215	(nntp-server-buffer
	216	(get-buffer gnus-async-prefetch-article-buffer)))
	217	(when do-message
	218	(gnus-message 9 "Prefetching article %d in group %s"
	219	article group))
16409b0b GM	220	(setq gnus-async-current-prefetch-group group)
16409b0b GM	221	(setq gnus-async-current-prefetch-article article)
eec82323 LMI	222	(gnus-request-article article group))))))))))
	223
	224	(defun gnus-make-async-article-function (group article mark summary next)
	225	"Return a callback function."
	226	`(lambda (arg)
16409b0b GM	227	(gnus-async-article-callback arg ,group ,article ,mark ,summary ,next)))
16409b0b GM	228
16ec6ca4 KY	229	(eval-when-compile
	230	(autoload 'gnus-html-prefetch-images "gnus-html"))
	231
16409b0b GM	232	(defun gnus-async-article-callback (arg group article mark summary next)
	233	"Function called when an async article is done being fetched."
	234	(save-excursion
	235	(setq gnus-async-current-prefetch-article nil)
	236	(when arg
	237	(gnus-async-set-buffer)
724d30be KY	238	(save-excursion
	239	(save-restriction
	240	(narrow-to-region mark (point-max))
	241	;; Prefetch images for the groups that want that.
	242	(when (fboundp 'gnus-html-prefetch-images)
	243	(gnus-html-prefetch-images summary))
	244	(when gnus-async-post-fetch-function
b1992461	245	(funcall gnus-async-post-fetch-function summary))))
16409b0b GM	246	(gnus-async-with-semaphore
	247	(setq
	248	gnus-async-article-alist
	249	(cons (list (intern (format "%s-%d" group article)
	250	gnus-async-hashtb)
	251	mark (set-marker (make-marker) (point-max))
	252	group article)
	253	gnus-async-article-alist))))
	254	(if (not (gnus-buffer-live-p summary))
	255	(gnus-async-with-semaphore
	256	(setq gnus-async-fetch-list nil))
	257	(gnus-async-prefetch-article group next summary t))))
eec82323 LMI	258
	259	(defun gnus-async-unread-p (data)
	260	"Return non-nil if DATA represents an unread article."
	261	(gnus-data-unread-p data))
	262
	263	(defun gnus-async-request-fetched-article (group article buffer)
	264	"See whether we have ARTICLE from GROUP and put it in BUFFER."
	265	(when (numberp article)
16409b0b GM	266	(when (and (equal group gnus-async-current-prefetch-group)
	267	(eq article gnus-async-current-prefetch-article))
	268	(gnus-async-wait-for-article article))
eec82323 LMI	269	(let ((entry (gnus-async-prefetched-article-entry group article)))
	270	(when entry
	271	(save-excursion
	272	(gnus-async-set-buffer)
	273	(copy-to-buffer buffer (cadr entry) (caddr entry))
	274	;; Remove the read article from the prefetch buffer.
	275	(when (memq 'read gnus-prefetched-article-deletion-strategy)
16409b0b	276	(gnus-async-delete-prefetched-entry entry))
eec82323 LMI	277	t)))))
eec82323 LMI	278
16409b0b GM	279	(defun gnus-async-wait-for-article (article)
	280	"Wait until ARTICLE is no longer the currently-being-fetched article."
	281	(save-excursion
	282	(gnus-async-set-buffer)
	283	(let ((proc (nntp-find-connection (current-buffer)))
	284	(nntp-server-buffer (current-buffer))
	285	(nntp-have-messaged nil)
	286	(tries 0))
01c52d31 MB	287	(when proc
	288	(condition-case nil
	289	;; FIXME: we could stop waiting after some
	290	;; timeout, but this is the wrong place to do it.
	291	;; rather than checking time-spent-waiting, we
	292	;; should check time-since-last-output, which
	293	;; needs to be done in nntp.el.
	294	(while (eq article gnus-async-current-prefetch-article)
	295	(incf tries)
	296	(when (nntp-accept-process-output proc)
	297	(setq tries 0))
	298	(when (and (not nntp-have-messaged)
	299	(= tries 3))
	300	(gnus-message 5 "Waiting for async article...")
	301	(setq nntp-have-messaged t)))
	302	(quit
	303	;; if the user interrupted on a slow/hung connection,
	304	;; do something friendly.
	305	(when (> tries 3)
	306	(setq gnus-async-current-prefetch-article nil))
	307	(signal 'quit nil)))
	308	(when nntp-have-messaged
	309	(gnus-message 5 ""))))))
16409b0b GM	310
16409b0b GM	311	(defun gnus-async-delete-prefetched-entry (entry)
eec82323 LMI	312	"Delete ENTRY from buffer and alist."
	313	(ignore-errors
	314	(delete-region (cadr entry) (caddr entry))
	315	(set-marker (cadr entry) nil)
	316	(set-marker (caddr entry) nil))
	317	(gnus-async-with-semaphore
16409b0b	318	(setq gnus-async-article-alist
a3f57c41 G	319	(delq entry gnus-async-article-alist))
a3f57c41 G	320	(unintern (car entry) gnus-async-hashtb)))
eec82323 LMI	321
	322	(defun gnus-async-prefetch-remove-group (group)
	323	"Remove all articles belonging to GROUP from the prefetch buffer."
	324	(when (and (gnus-group-asynchronous-p group)
	325	(memq 'exit gnus-prefetched-article-deletion-strategy))
01c52d31 MB	326	(save-excursion
	327	(gnus-async-set-buffer)
	328	(dolist (entry gnus-async-article-alist)
	329	(when (equal group (nth 3 entry))
	330	(gnus-async-delete-prefetched-entry entry))))))
eec82323 LMI	331
eec82323 LMI	332	(defun gnus-async-prefetched-article-entry (group article)
e7f767c2	333	"Return the entry for ARTICLE in GROUP if it has been prefetched."
6748645f LMI	334	(let ((entry (save-excursion
6748645f LMI	335	(gnus-async-set-buffer)
a3f57c41 G	336	(assq (intern-soft (format "%s-%d" group article)
a3f57c41 G	337	gnus-async-hashtb)
6748645f	338	gnus-async-article-alist))))
eec82323 LMI	339	;; Perhaps something has emptied the buffer?
	340	(if (and entry
	341	(= (cadr entry) (caddr entry)))
	342	(progn
	343	(ignore-errors
	344	(set-marker (cadr entry) nil)
	345	(set-marker (caddr entry) nil))
	346	(setq gnus-async-article-alist
	347	(delq entry gnus-async-article-alist))
	348	nil)
	349	entry)))
	350
	351	;;;
	352	;;; Header prefetch
	353	;;;
	354
	355	(defun gnus-async-prefetch-headers (group)
	356	"Prefetch the headers for group GROUP."
	357	(save-excursion
	358	(let (unread)
	359	(when (and gnus-use-header-prefetch
	360	gnus-asynchronous
	361	(gnus-group-asynchronous-p group)
	362	(listp gnus-async-header-prefetched)
	363	(setq unread (gnus-list-of-unread-articles group)))
	364	;; Mark that a fetch is in progress.
	365	(setq gnus-async-header-prefetched t)
	366	(nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
	367	(erase-buffer)
	368	(let ((nntp-server-buffer (current-buffer))
	369	(nnheader-callback-function
	370	`(lambda (arg)
	371	(setq gnus-async-header-prefetched
	372	,(cons group unread)))))
	373	(gnus-retrieve-headers unread group gnus-fetch-old-headers))))))
	374
	375	(defun gnus-async-retrieve-fetched-headers (articles group)
	376	"See whether we have prefetched headers."
	377	(when (and gnus-use-header-prefetch
	378	(gnus-group-asynchronous-p group)
	379	(listp gnus-async-header-prefetched)
	380	(equal group (car gnus-async-header-prefetched))
	381	(equal articles (cdr gnus-async-header-prefetched)))
	382	(save-excursion
	383	(nnheader-set-temp-buffer gnus-async-prefetch-headers-buffer t)
	384	(nntp-decode-text)
	385	(copy-to-buffer nntp-server-buffer (point-min) (point-max))
	386	(erase-buffer)
	387	(setq gnus-async-header-prefetched nil)
	388	t)))
	389
	390	(provide 'gnus-async)
	391
	392	;;; gnus-async.el ends here