[bpt/emacs.git] / lisp / mail / rmailkwd.el

;;; rmailkwd.el --- part of the "RMAIL" mail reader for Emacs

;; Copyright (C) 1985, 1988, 1994, 2001, 2002, 2003, 2004, 2005, 2006,
;;   2007, 2008, 2009  Free Software Foundation, Inc.

;; Maintainer: FSF
;; Keywords: mail

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;;; Code:

(require 'rmail)

;; Global to all RMAIL buffers.  It exists for the sake of completion.
;; It is better to use strings with the label functions and let them
;; worry about making the label.
(defvar rmail-label-obarray (make-vector 47 0)
  "Obarray of labels used by Rmail.
`rmail-read-label' uses this to offer completion.")

;; Initialize with the standard labels.
(mapc (lambda (s) (intern (cadr s) rmail-label-obarray))
      rmail-attr-array)

(defun rmail-make-label (s)
  "Intern string S as a downcased symbol in `rmail-label-obarray'."
  (intern (downcase s) rmail-label-obarray))
\f
;;;###autoload
(defun rmail-add-label (label)
  "Add LABEL to labels associated with current RMAIL message.
Completes (see `rmail-read-label') over known labels when reading.
LABEL may be a symbol or string."
  (interactive (list (rmail-read-label "Add label")))
  (rmail-set-label label t))

;;;###autoload
(defun rmail-kill-label (label)
  "Remove LABEL from labels associated with current RMAIL message.
Completes (see `rmail-read-label') over known labels when reading.
LABEL may be a symbol or string."
  (interactive (list (rmail-read-label "Remove label")))
  (rmail-set-label label nil))

;;;###autoload
(defun rmail-read-label (prompt)
  "Read a label with completion, prompting with PROMPT.
Completions are chosen from `rmail-label-obarray'.  The default
is `rmail-last-label', if that is non-nil.  Updates `rmail-last-label'
according to the choice made, and returns a symbol."
  (let* ((old nil)
	 (result
	  (progn
	    ;; If the summary exists, we've already read all the
	    ;; existing labels.  If not, read the ones in this message.
	    (or (eq major-mode 'rmail-summary-mode)
		(rmail-summary-exists)
		(and (setq old (rmail-get-keywords))
		     (mapc 'rmail-make-label (split-string old ", "))))
	    (completing-read (concat prompt
				     (if rmail-last-label
					 (concat " (default "
						 (symbol-name rmail-last-label)
						 "): ")
				       ": "))
			     rmail-label-obarray
			     nil
			     nil))))
    (if (string= result "")
	rmail-last-label
      (setq rmail-last-label (rmail-make-label result)))))

(declare-function rmail-summary-update-line "rmailsum" (n))

(defun rmail-set-label (label state &optional msg)
  "Set LABEL as present or absent according to STATE in message MSG.
LABEL may be a symbol or string."
  (or (stringp label) (setq label (symbol-name label)))
  (with-current-buffer rmail-buffer
    (rmail-maybe-set-message-counters)
    (or msg (setq msg rmail-current-message))
    ;; Force recalculation of summary for this message.
    (aset rmail-summary-vector (1- msg) nil)
    (let (attr-index)
      ;; Is this label an attribute?
      (dotimes (i (length rmail-attr-array))
	(if (string= (cadr (aref rmail-attr-array i)) label)
	    (setq attr-index i)))
      (if attr-index
	  ;; If so, set it as an attribute.
	  (rmail-set-attribute attr-index state msg)
	;; Is this keyword already present in msg's keyword list?
	(let* ((header (rmail-get-header rmail-keyword-header msg))
	       (regexp (concat ", " (regexp-quote label) ","))
	       (present (string-match regexp (concat ", " header ","))))
	  ;; If current state is not correct,
	  (unless (eq present state)
	    ;; either add it or delete it.
	    (rmail-set-header
	     rmail-keyword-header msg
	     (if state
		 ;; Add this keyword at the end.
		 (if (and header (not (string= header "")))
		     (concat header ", " label)
		   label)
	       ;; Delete this keyword.
	       (let ((before (substring header 0
					(max 0 (- (match-beginning 0) 2))))
		     (after (substring header
				       (min (length header)
					    (- (match-end 0) 1)))))
		 (cond ((string= before "")
			after)
		       ((string= after "")
			before)
		       (t (concat before ", " after))))))))))
    (if (rmail-summary-exists)
	(rmail-select-summary (rmail-summary-update-line msg)))
    (if (= msg rmail-current-message)
	(rmail-display-labels))))
\f
;; Motion on messages with keywords.

;;;###autoload
(defun rmail-previous-labeled-message (n labels)
  "Show previous message with one of the labels LABELS.
LABELS should be a comma-separated list of label names.
If LABELS is empty, the last set of labels specified is used.
With prefix argument N moves backward N messages with these labels."
  (interactive "p\nsMove to previous msg with labels: ")
  (rmail-next-labeled-message (- n) labels))

(declare-function mail-comma-list-regexp "mail-utils" (labels))

;;;###autoload
(defun rmail-next-labeled-message (n labels)
  "Show next message with one of the labels LABELS.
LABELS should be a comma-separated list of label names.
If LABELS is empty, the last set of labels specified is used.
With prefix argument N moves forward N messages with these labels."
  (interactive "p\nsMove to next msg with labels: ")
  (if (string= labels "")
      (setq labels rmail-last-multi-labels))
  (or labels
      (error "No labels to find have been specified previously"))
  (set-buffer rmail-buffer)
  (setq rmail-last-multi-labels labels)
  (rmail-maybe-set-message-counters)
  (let ((lastwin rmail-current-message)
	(current rmail-current-message)
	(regexp (concat " \\("
			(mail-comma-list-regexp labels)
			"\\)\\(,\\|\\'\\)")))
    (while (and (> n 0) (< current rmail-total-messages))
      (setq current (1+ current))
      (if (string-match regexp (rmail-get-labels current))
	  (setq lastwin current n (1- n))))
    (while (and (< n 0) (> current 1))
      (setq current (1- current))
      (if (string-match regexp (rmail-get-labels current))
	  (setq lastwin current n (1+ n))))
    (if (< n 0)
	(error "No previous message with labels %s" labels)
      (if (> n 0)
	  (error "No following message with labels %s" labels)
	(rmail-show-message lastwin)))))

(provide 'rmailkwd)

;; arch-tag: 1149979c-8e47-4333-9629-cf3dc887a6a7
;;; rmailkwd.el ends here
Commit	Line	Data
537ab246 BG	1	;;; rmailkwd.el --- part of the "RMAIL" mail reader for Emacs
	2
	3	;; Copyright (C) 1985, 1988, 1994, 2001, 2002, 2003, 2004, 2005, 2006,
	4	;; 2007, 2008, 2009 Free Software Foundation, Inc.
	5
	6	;; Maintainer: FSF
	7	;; Keywords: mail
	8
	9	;; This file is part of GNU Emacs.
	10
	11	;; GNU Emacs is free software: you can redistribute it and/or modify
	12	;; it under the terms of the GNU General Public License as published by
	13	;; the Free Software Foundation, either version 3 of the License, or
	14	;; (at your option) any later version.
	15
	16	;; GNU Emacs is distributed in the hope that it will be useful,
	17	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	18	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	19	;; GNU General Public License for more details.
	20
	21	;; You should have received a copy of the GNU General Public License
	22	;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
	23
	24	;;; Commentary:
	25
	26	;;; Code:
	27
	28	(require 'rmail)
	29
c36e6767 GM	30	;; Global to all RMAIL buffers. It exists for the sake of completion.
	31	;; It is better to use strings with the label functions and let them
	32	;; worry about making the label.
	33	(defvar rmail-label-obarray (make-vector 47 0)
	34	"Obarray of labels used by Rmail.
	35	`rmail-read-label' uses this to offer completion.")
537ab246	36
c36e6767 GM	37	;; Initialize with the standard labels.
	38	(mapc (lambda (s) (intern (cadr s) rmail-label-obarray))
	39	rmail-attr-array)
537ab246 BG	40
537ab246 BG	41	(defun rmail-make-label (s)
8e87c426	42	"Intern string S as a downcased symbol in `rmail-label-obarray'."
537ab246 BG	43	(intern (downcase s) rmail-label-obarray))
	44	\f
	45	;;;###autoload
c36e6767	46	(defun rmail-add-label (label)
537ab246	47	"Add LABEL to labels associated with current RMAIL message.
c36e6767 GM	48	Completes (see `rmail-read-label') over known labels when reading.
c36e6767 GM	49	LABEL may be a symbol or string."
537ab246	50	(interactive (list (rmail-read-label "Add label")))
c36e6767	51	(rmail-set-label label t))
537ab246 BG	52
537ab246 BG	53	;;;###autoload
c36e6767	54	(defun rmail-kill-label (label)
537ab246	55	"Remove LABEL from labels associated with current RMAIL message.
c36e6767 GM	56	Completes (see `rmail-read-label') over known labels when reading.
c36e6767 GM	57	LABEL may be a symbol or string."
537ab246	58	(interactive (list (rmail-read-label "Remove label")))
c36e6767	59	(rmail-set-label label nil))
537ab246 BG	60
	61	;;;###autoload
	62	(defun rmail-read-label (prompt)
c36e6767 GM	63	"Read a label with completion, prompting with PROMPT.
	64	Completions are chosen from `rmail-label-obarray'. The default
	65	is `rmail-last-label', if that is non-nil. Updates `rmail-last-label'
	66	according to the choice made, and returns a symbol."
28e50631 GM	67	(let* ((old nil)
	68	(result
	69	(progn
	70	;; If the summary exists, we've already read all the
	71	;; existing labels. If not, read the ones in this message.
	72	(or (eq major-mode 'rmail-summary-mode)
	73	(rmail-summary-exists)
	74	(and (setq old (rmail-get-keywords))
	75	(mapc 'rmail-make-label (split-string old ", "))))
	76	(completing-read (concat prompt
	77	(if rmail-last-label
	78	(concat " (default "
	79	(symbol-name rmail-last-label)
	80	"): ")
	81	": "))
	82	rmail-label-obarray
	83	nil
	84	nil))))
537ab246 BG	85	(if (string= result "")
	86	rmail-last-label
	87	(setq rmail-last-label (rmail-make-label result)))))
	88
314a8fc3 GM	89	(declare-function rmail-summary-update-line "rmailsum" (n))
314a8fc3 GM	90
537ab246	91	(defun rmail-set-label (label state &optional msg)
c36e6767 GM	92	"Set LABEL as present or absent according to STATE in message MSG.
	93	LABEL may be a symbol or string."
	94	(or (stringp label) (setq label (symbol-name label)))
537ab246 BG	95	(with-current-buffer rmail-buffer
537ab246 BG	96	(rmail-maybe-set-message-counters)
8e87c426	97	(or msg (setq msg rmail-current-message))
537ab246 BG	98	;; Force recalculation of summary for this message.
	99	(aset rmail-summary-vector (1- msg) nil)
	100	(let (attr-index)
	101	;; Is this label an attribute?
	102	(dotimes (i (length rmail-attr-array))
	103	(if (string= (cadr (aref rmail-attr-array i)) label)
	104	(setq attr-index i)))
	105	(if attr-index
	106	;; If so, set it as an attribute.
	107	(rmail-set-attribute attr-index state msg)
	108	;; Is this keyword already present in msg's keyword list?
	109	(let* ((header (rmail-get-header rmail-keyword-header msg))
c36e6767	110	(regexp (concat ", " (regexp-quote label) ","))
537ab246 BG	111	(present (string-match regexp (concat ", " header ","))))
	112	;; If current state is not correct,
	113	(unless (eq present state)
	114	;; either add it or delete it.
	115	(rmail-set-header
	116	rmail-keyword-header msg
	117	(if state
	118	;; Add this keyword at the end.
	119	(if (and header (not (string= header "")))
c36e6767 GM	120	(concat header ", " label)
c36e6767 GM	121	label)
537ab246 BG	122	;; Delete this keyword.
	123	(let ((before (substring header 0
	124	(max 0 (- (match-beginning 0) 2))))
	125	(after (substring header
	126	(min (length header)
	127	(- (match-end 0) 1)))))
	128	(cond ((string= before "")
	129	after)
	130	((string= after "")
	131	before)
c36e6767 GM	132	(t (concat before ", " after))))))))))
c36e6767 GM	133	(if (rmail-summary-exists)
8e87c426	134	(rmail-select-summary (rmail-summary-update-line msg)))
c36e6767 GM	135	(if (= msg rmail-current-message)
c36e6767 GM	136	(rmail-display-labels))))
537ab246 BG	137	\f
	138	;; Motion on messages with keywords.
	139
	140	;;;###autoload
	141	(defun rmail-previous-labeled-message (n labels)
	142	"Show previous message with one of the labels LABELS.
	143	LABELS should be a comma-separated list of label names.
	144	If LABELS is empty, the last set of labels specified is used.
	145	With prefix argument N moves backward N messages with these labels."
	146	(interactive "p\nsMove to previous msg with labels: ")
	147	(rmail-next-labeled-message (- n) labels))
	148
	149	(declare-function mail-comma-list-regexp "mail-utils" (labels))
	150
	151	;;;###autoload
	152	(defun rmail-next-labeled-message (n labels)
	153	"Show next message with one of the labels LABELS.
	154	LABELS should be a comma-separated list of label names.
	155	If LABELS is empty, the last set of labels specified is used.
	156	With prefix argument N moves forward N messages with these labels."
	157	(interactive "p\nsMove to next msg with labels: ")
	158	(if (string= labels "")
	159	(setq labels rmail-last-multi-labels))
	160	(or labels
	161	(error "No labels to find have been specified previously"))
	162	(set-buffer rmail-buffer)
	163	(setq rmail-last-multi-labels labels)
	164	(rmail-maybe-set-message-counters)
	165	(let ((lastwin rmail-current-message)
	166	(current rmail-current-message)
6e77127f	167	(regexp (concat " \\("
537ab246	168	(mail-comma-list-regexp labels)
ee1b0cc0	169	"\\)\\(,\\\|\\'\\)")))
537ab246 BG	170	(while (and (> n 0) (< current rmail-total-messages))
	171	(setq current (1+ current))
	172	(if (string-match regexp (rmail-get-labels current))
	173	(setq lastwin current n (1- n))))
	174	(while (and (< n 0) (> current 1))
	175	(setq current (1- current))
	176	(if (string-match regexp (rmail-get-labels current))
	177	(setq lastwin current n (1+ n))))
	178	(if (< n 0)
	179	(error "No previous message with labels %s" labels)
	180	(if (> n 0)
	181	(error "No following message with labels %s" labels)
	182	(rmail-show-message lastwin)))))
	183
	184	(provide 'rmailkwd)
	185
537ab246 BG	186	;; arch-tag: 1149979c-8e47-4333-9629-cf3dc887a6a7
537ab246 BG	187	;;; rmailkwd.el ends here