Commit | Line | Data |
---|---|---|
55535639 | 1 | ;;; appt.el --- appointment notification functions |
c0274f38 | 2 | |
8d638c1b | 3 | ;; Copyright (C) 1989, 1990, 1994, 1998, 2004 Free Software Foundation, Inc. |
3a801d0c | 4 | |
e5167999 | 5 | ;; Author: Neil Mager <neilm@juliet.ll.mit.edu> |
0dba5606 | 6 | ;; Maintainer: FSF |
e5167999 ER |
7 | ;; Keywords: calendar |
8 | ||
902a0e3c JB |
9 | ;; This file is part of GNU Emacs. |
10 | ||
11 | ;; GNU Emacs is free software; you can redistribute it and/or modify | |
12 | ;; it under the terms of the GNU General Public License as published by | |
e5167999 | 13 | ;; the Free Software Foundation; either version 2, or (at your option) |
902a0e3c JB |
14 | ;; any later version. |
15 | ||
16 | ;; GNU Emacs is distributed in the hope that it will be useful, | |
17 | ;; but WITHOUT ANY WARRANTY; without even the implied warranty of | |
18 | ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the | |
19 | ;; GNU General Public License for more details. | |
20 | ||
21 | ;; You should have received a copy of the GNU General Public License | |
b578f267 EN |
22 | ;; along with GNU Emacs; see the file COPYING. If not, write to the |
23 | ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330, | |
24 | ;; Boston, MA 02111-1307, USA. | |
902a0e3c | 25 | |
e5167999 ER |
26 | ;;; Commentary: |
27 | ||
902a0e3c JB |
28 | ;; |
29 | ;; appt.el - visible and/or audible notification of | |
8d638c1b | 30 | ;; appointments from diary file. |
902a0e3c | 31 | ;; |
902a0e3c | 32 | ;;; |
d073fa5b | 33 | ;;; Thanks to Edward M. Reingold for much help and many suggestions, |
902a0e3c JB |
34 | ;;; And to many others for bug fixes and suggestions. |
35 | ;;; | |
36 | ;;; | |
a1506d29 | 37 | ;;; This functions in this file will alert the user of a |
8d638c1b GM |
38 | ;;; pending appointment based on his/her diary file. This package |
39 | ;;; is documented in the Emacs manual. | |
902a0e3c | 40 | ;;; |
8d638c1b GM |
41 | ;;; To activate this package, simply use (appt-activate 1). |
42 | ;;; A `diary-file' with appointments of the format described in the | |
43 | ;;; documentation of the function `appt-check' is required. | |
44 | ;;; Relevant customizable variables are also listed in the | |
45 | ;;; documentation of that function. | |
a19de628 | 46 | ;;; |
8d638c1b GM |
47 | ;;; Today's appointment list is initialized from the diary when this |
48 | ;;; package is activated. Additionally, the appointments list is | |
49 | ;;; recreated automatically at 12:01am for those who do not logout | |
50 | ;;; every day or are programming late. It is also updated when the | |
51 | ;;; `diary-file' is saved. Calling `appt-check' with an argument forces | |
52 | ;;; a re-initialization at any time. | |
902a0e3c | 53 | ;;; |
8d638c1b GM |
54 | ;;; In order to add or delete items from today's list, without |
55 | ;;; changing the diary file, use `appt-add' and `appt-delete'. | |
902a0e3c | 56 | ;;; |
8d638c1b | 57 | |
d073fa5b | 58 | ;;; Brief internal description - Skip this if you are not interested! |
902a0e3c | 59 | ;;; |
8d638c1b GM |
60 | ;;; The function `appt-make-list' creates the appointments list which |
61 | ;;; `appt-check' reads. | |
902a0e3c | 62 | ;;; |
5b586155 | 63 | ;;; You can change the way the appointment window is created/deleted by |
8d638c1b | 64 | ;;; setting the variables |
5b586155 RS |
65 | ;;; |
66 | ;;; appt-disp-window-function | |
67 | ;;; and | |
68 | ;;; appt-delete-window-function | |
69 | ;;; | |
8d638c1b | 70 | ;;; For instance, these variables could be set to functions that display |
5b586155 | 71 | ;;; appointments in pop-up frames, which are lowered or iconified after |
8d638c1b | 72 | ;;; `appt-display-interval' minutes. |
5b586155 | 73 | ;;; |
e5167999 ER |
74 | |
75 | ;;; Code: | |
76 | ||
6afadb57 RS |
77 | ;; Make sure calendar is loaded when we compile this. |
78 | (require 'calendar) | |
79 | ||
902a0e3c | 80 | |
30e8032d GM |
81 | ;;;###autoload |
82 | (defcustom appt-issue-message t | |
83 | "*Non-nil means check for appointments in the diary buffer. | |
84 | To be detected, the diary entry must have the format described in the | |
85 | documentation of the function `appt-check'." | |
86 | :type 'boolean | |
87 | :group 'appt) | |
88 | ||
89 | (make-obsolete-variable 'appt-issue-message | |
90 | "use the function `appt-activate', and the \ | |
91 | variable `appt-display-format' instead." "21.4") | |
92 | ||
7e1dae73 | 93 | ;;;###autoload |
8db540c5 RS |
94 | (defcustom appt-message-warning-time 12 |
95 | "*Time in minutes before an appointment that the warning begins." | |
96 | :type 'integer | |
97 | :group 'appt) | |
902a0e3c | 98 | |
7e1dae73 | 99 | ;;;###autoload |
8db540c5 RS |
100 | (defcustom appt-audible t |
101 | "*Non-nil means beep to indicate appointment." | |
102 | :type 'boolean | |
103 | :group 'appt) | |
902a0e3c | 104 | |
7e1dae73 | 105 | ;;;###autoload |
8db540c5 | 106 | (defcustom appt-visible t |
8d638c1b GM |
107 | "*Non-nil means display appointment message in echo area. |
108 | This variable is only relevant if `appt-msg-window' is nil." | |
8db540c5 RS |
109 | :type 'boolean |
110 | :group 'appt) | |
902a0e3c | 111 | |
8d638c1b GM |
112 | (make-obsolete-variable 'appt-visible 'appt-display-format "21.4") |
113 | ||
7e1dae73 | 114 | ;;;###autoload |
8d638c1b GM |
115 | (defcustom appt-msg-window t |
116 | "*Non-nil means display appointment message in another window. | |
117 | If non-nil, this variable overrides `appt-visible'." | |
8db540c5 RS |
118 | :type 'boolean |
119 | :group 'appt) | |
902a0e3c | 120 | |
8d638c1b GM |
121 | (make-obsolete-variable 'appt-msg-window 'appt-display-format "21.4") |
122 | ||
123 | ;; TODO - add popup. | |
a19de628 | 124 | (defcustom appt-display-format 'ignore |
8d638c1b GM |
125 | "How appointment reminders should be displayed. |
126 | The options are: | |
127 | window - use a separate window | |
128 | echo - use the echo area | |
129 | nil - no visible reminder. | |
a19de628 GM |
130 | See also `appt-audible' and `appt-display-mode-line'. |
131 | ||
132 | The default value is 'ignore, which means to fall back on the value | |
133 | of the (obsolete) variables `appt-msg-window' and `appt-visible'." | |
8d638c1b GM |
134 | :type '(choice |
135 | (const :tag "Separate window" window) | |
136 | (const :tag "Echo-area" echo) | |
137 | (const :tag "No visible display" nil)) | |
138 | :group 'appt | |
139 | :version "21.4") | |
140 | ||
7e1dae73 | 141 | ;;;###autoload |
8d638c1b GM |
142 | (defcustom appt-display-mode-line t |
143 | "*Non-nil means display minutes to appointment and time on the mode line. | |
144 | This is in addition to any other display of appointment messages." | |
8db540c5 RS |
145 | :type 'boolean |
146 | :group 'appt) | |
902a0e3c | 147 | |
7e1dae73 | 148 | ;;;###autoload |
8db540c5 | 149 | (defcustom appt-display-duration 10 |
8d638c1b GM |
150 | "*The number of seconds an appointment message is displayed. |
151 | Only relevant if reminders are to be displayed in their own window." | |
8db540c5 RS |
152 | :type 'integer |
153 | :group 'appt) | |
902a0e3c | 154 | |
7e1dae73 | 155 | ;;;###autoload |
8db540c5 | 156 | (defcustom appt-display-diary t |
8d638c1b | 157 | "*Non-nil displays the diary when the appointment list is first initialized. |
8db540c5 RS |
158 | This will occur at midnight when the appointment list is updated." |
159 | :type 'boolean | |
160 | :group 'appt) | |
902a0e3c | 161 | |
8db540c5 RS |
162 | (defcustom appt-display-interval 3 |
163 | "*Number of minutes to wait between checking the appointment list." | |
164 | :type 'integer | |
165 | :group 'appt) | |
a1506d29 | 166 | |
8d638c1b GM |
167 | (defcustom appt-disp-window-function 'appt-disp-window |
168 | "Function called to display appointment window. | |
169 | Only relevant if reminders are being displayed in a window." | |
170 | :type '(choice (const appt-disp-window) | |
171 | function) | |
172 | :group 'appt) | |
173 | ||
174 | (defcustom appt-delete-window-function 'appt-delete-window | |
175 | "Function called to remove appointment window and buffer. | |
176 | Only relevant if reminders are being displayed in a window." | |
177 | :type '(choice (const appt-delete-window) | |
178 | function) | |
179 | :group 'appt) | |
180 | ||
181 | ||
182 | ;;; Internal variables below this point. | |
183 | ||
5b586155 RS |
184 | (defvar appt-buffer-name " *appt-buf*" |
185 | "Name of the appointments buffer.") | |
a1506d29 | 186 | |
8d638c1b GM |
187 | (defvar appt-time-msg-list nil |
188 | "The list of appointments for today. | |
189 | Use `appt-add' and `appt-delete' to add and delete appointments. | |
190 | The original list is generated from today's `diary-entries-list', and | |
191 | can be regenerated using the function `appt-check'. | |
192 | Each element of the generated list has the form (MINUTES) STRING; where | |
193 | MINUTES is the time in minutes of the appointment after midnight, and | |
194 | STRING is the description of the appointment.") | |
a1506d29 | 195 | |
8d638c1b GM |
196 | (defconst appt-max-time 1439 |
197 | "11:59pm in minutes - number of minutes in a day minus 1.") | |
b570e652 | 198 | |
efa434d9 | 199 | (defvar appt-mode-string nil |
f3e7c0dc | 200 | "String being displayed in the mode line saying you have an appointment. |
8d638c1b GM |
201 | The actual string includes the amount of time till the appointment. |
202 | Only used if `appt-display-mode-line' is non-nil.") | |
f3e7c0dc KH |
203 | |
204 | (defvar appt-prev-comp-time nil | |
8d638c1b GM |
205 | "Time of day (mins since midnight) at which we last checked appointments. |
206 | A nil value forces the diary file to be (re-)checked for appointments.") | |
f3e7c0dc KH |
207 | |
208 | (defvar appt-now-displayed nil | |
209 | "Non-nil when we have started notifying about a appointment that is near.") | |
210 | ||
8d638c1b GM |
211 | (defvar appt-display-count nil |
212 | "Internal variable used to count number of consecutive reminders.") | |
efa434d9 | 213 | |
8d638c1b GM |
214 | (defvar appt-timer nil |
215 | "Timer used for diary appointment notifications (`appt-check'). | |
216 | If this is non-nil, appointment checking is active.") | |
217 | ||
218 | ||
219 | ;;; Functions. | |
220 | ||
221 | (defun appt-display-message (string mins) | |
222 | "Display a reminder about an appointment. | |
223 | The string STRING describes the appointment, due in integer MINS minutes. | |
224 | The format of the visible reminder is controlled by `appt-display-format'. | |
225 | The variable `appt-audible' controls the audible reminder." | |
a19de628 GM |
226 | ;; let binding for backwards compatability. Remove when obsolete |
227 | ;; vars appt-msg-window and appt-visible are dropped. | |
228 | (let ((appt-display-format | |
229 | (if (eq appt-display-format 'ignore) | |
230 | (cond (appt-msg-window 'window) | |
231 | (appt-visible 'echo)) | |
232 | appt-display-format))) | |
233 | (cond ((eq appt-display-format 'window) | |
234 | (funcall appt-disp-window-function | |
235 | (number-to-string mins) | |
236 | (format-time-string "%a %b %e " (current-time)) | |
237 | string) | |
238 | (run-at-time (format "%d sec" appt-display-duration) | |
239 | nil | |
240 | appt-delete-window-function)) | |
241 | ((eq appt-display-format 'echo) | |
242 | (message "%s" string))) | |
243 | (if appt-audible (beep 1)))) | |
8d638c1b GM |
244 | |
245 | ||
246 | (defun appt-check (&optional force) | |
247 | "Check for an appointment and update any reminder display. | |
248 | If optional argument FORCE is non-nil, reparse the diary file for | |
249 | appointments. Otherwise the diary file is only parsed once per day, | |
250 | and when saved. | |
902a0e3c | 251 | |
8d638c1b GM |
252 | Note: the time must be the first thing in the line in the diary |
253 | for a warning to be issued. The format of the time can be either | |
254 | 24 hour or am/pm. For example: | |
902a0e3c | 255 | |
8d638c1b GM |
256 | 02/23/89 |
257 | 18:00 Dinner | |
a1506d29 | 258 | |
902a0e3c JB |
259 | Thursday |
260 | 11:45am Lunch meeting. | |
261 | ||
f3e7c0dc KH |
262 | Appointments are checked every `appt-display-interval' minutes. |
263 | The following variables control appointment notification: | |
902a0e3c | 264 | |
8d638c1b GM |
265 | `appt-display-format' |
266 | Controls the format in which reminders are displayed. | |
902a0e3c | 267 | |
efa434d9 | 268 | `appt-audible' |
8d638c1b | 269 | Variable used to determine if reminder is audible. |
b570e652 | 270 | Default is t. |
902a0e3c | 271 | |
8d638c1b GM |
272 | `appt-message-warning-time' |
273 | Variable used to determine when appointment message | |
274 | should first be displayed. | |
275 | ||
276 | `appt-display-mode-line' | |
277 | If non-nil, a generic message giving the time remaining | |
278 | is shown in the mode-line when an appointment is due. | |
279 | ||
280 | `appt-display-interval' | |
281 | Interval in minutes at which to check for pending appointments. | |
902a0e3c | 282 | |
8d638c1b GM |
283 | `appt-display-diary' |
284 | Display the diary buffer when the appointment list is | |
285 | initialized for the first time in a day. | |
286 | ||
287 | The following variables are only relevant if reminders are being | |
288 | displayed in a window: | |
902a0e3c | 289 | |
efa434d9 | 290 | `appt-display-duration' |
8d638c1b | 291 | The number of seconds an appointment message is displayed. |
b570e652 | 292 | |
f3e7c0dc | 293 | `appt-disp-window-function' |
8d638c1b | 294 | Function called to display appointment window. |
a1506d29 | 295 | |
f3e7c0dc | 296 | `appt-delete-window-function' |
8d638c1b | 297 | Function called to remove appointment window and buffer." |
902a0e3c | 298 | |
f3e7c0dc | 299 | (let* ((min-to-app -1) |
f3e7c0dc KH |
300 | (prev-appt-mode-string appt-mode-string) |
301 | (prev-appt-display-count (or appt-display-count 0)) | |
302 | ;; Non-nil means do a full check for pending appointments | |
303 | ;; and display in whatever ways the user has selected. | |
304 | ;; When no appointment is being displayed, | |
305 | ;; we always do a full check. | |
306 | (full-check | |
307 | (or (not appt-now-displayed) | |
308 | ;; This is true every appt-display-interval minutes. | |
8d638c1b | 309 | (zerop (mod prev-appt-display-count appt-display-interval)))) |
f3e7c0dc KH |
310 | ;; Non-nil means only update the interval displayed in the mode line. |
311 | (mode-line-only | |
312 | (and (not full-check) appt-now-displayed))) | |
313 | ||
314 | (when (or full-check mode-line-only) | |
315 | (save-excursion | |
316 | ||
317 | ;; Get the current time and convert it to minutes | |
318 | ;; from midnight. ie. 12:01am = 1, midnight = 0. | |
902a0e3c | 319 | |
f3e7c0dc KH |
320 | (let* ((now (decode-time)) |
321 | (cur-hour (nth 2 now)) | |
322 | (cur-min (nth 1 now)) | |
323 | (cur-comp-time (+ (* cur-hour 60) cur-min))) | |
324 | ||
a1506d29 | 325 | ;; At the first check in any given day, update our |
f3e7c0dc KH |
326 | ;; appointments to today's list. |
327 | ||
359bff67 | 328 | (if (or force ; eg initialize, diary save |
8d638c1b GM |
329 | (null appt-prev-comp-time) ; first check |
330 | (< cur-comp-time appt-prev-comp-time)) ; new day | |
f3e7c0dc | 331 | (condition-case nil |
359bff67 GM |
332 | (if appt-display-diary |
333 | (let ((diary-hook | |
334 | (if (assoc 'appt-make-list diary-hook) | |
335 | diary-hook | |
336 | (cons 'appt-make-list diary-hook)))) | |
337 | (diary)) | |
338 | (let ((diary-display-hook 'appt-make-list) | |
339 | (d-buff (find-buffer-visiting | |
340 | (substitute-in-file-name diary-file))) | |
341 | selective) | |
342 | (if d-buff ; diary buffer exists | |
343 | (with-current-buffer d-buff | |
344 | (setq selective selective-display))) | |
345 | (diary) | |
346 | ;; If the diary buffer existed before this command, | |
347 | ;; restore its display state. Otherwise, kill it. | |
348 | (if d-buff | |
349 | ;; Displays the diary buffer. | |
350 | (or selective (show-all-diary-entries)) | |
351 | (and | |
352 | (setq d-buff (find-buffer-visiting | |
353 | (substitute-in-file-name diary-file))) | |
354 | (kill-buffer d-buff))))) | |
f3e7c0dc | 355 | (error nil))) |
f3e7c0dc | 356 | |
8d638c1b GM |
357 | (setq appt-prev-comp-time cur-comp-time |
358 | appt-mode-string nil | |
359 | appt-display-count nil) | |
f3e7c0dc KH |
360 | |
361 | ;; If there are entries in the list, and the | |
362 | ;; user wants a message issued, | |
363 | ;; get the first time off of the list | |
364 | ;; and calculate the number of minutes until the appointment. | |
365 | ||
9fa0334c | 366 | (if (and appt-issue-message appt-time-msg-list) |
f3e7c0dc KH |
367 | (let ((appt-comp-time (car (car (car appt-time-msg-list))))) |
368 | (setq min-to-app (- appt-comp-time cur-comp-time)) | |
369 | ||
a1506d29 | 370 | (while (and appt-time-msg-list |
f3e7c0dc | 371 | (< appt-comp-time cur-comp-time)) |
a1506d29 | 372 | (setq appt-time-msg-list (cdr appt-time-msg-list)) |
f3e7c0dc | 373 | (if appt-time-msg-list |
a1506d29 | 374 | (setq appt-comp-time |
f3e7c0dc KH |
375 | (car (car (car appt-time-msg-list)))))) |
376 | ||
377 | ;; If we have an appointment between midnight and | |
378 | ;; 'appt-message-warning-time' minutes after midnight, | |
379 | ;; we must begin to issue a message before midnight. | |
380 | ;; Midnight is considered 0 minutes and 11:59pm is | |
381 | ;; 1439 minutes. Therefore we must recalculate the minutes | |
a1506d29 JB |
382 | ;; to appointment variable. It is equal to the number of |
383 | ;; minutes before midnight plus the number of | |
f3e7c0dc KH |
384 | ;; minutes after midnight our appointment is. |
385 | ||
386 | (if (and (< appt-comp-time appt-message-warning-time) | |
387 | (> (+ cur-comp-time appt-message-warning-time) | |
388 | appt-max-time)) | |
389 | (setq min-to-app (+ (- (1+ appt-max-time) cur-comp-time)) | |
390 | appt-comp-time)) | |
391 | ||
a1506d29 | 392 | ;; issue warning if the appointment time is |
f3e7c0dc KH |
393 | ;; within appt-message-warning time |
394 | ||
395 | (when (and (<= min-to-app appt-message-warning-time) | |
396 | (>= min-to-app 0)) | |
8d638c1b GM |
397 | (setq appt-now-displayed t |
398 | appt-display-count (1+ prev-appt-display-count)) | |
f3e7c0dc | 399 | (unless mode-line-only |
8d638c1b GM |
400 | (appt-display-message (cadr (car appt-time-msg-list)) |
401 | min-to-app)) | |
f3e7c0dc KH |
402 | (when appt-display-mode-line |
403 | (setq appt-mode-string | |
8d638c1b | 404 | (format " App't in %s min." min-to-app))) |
f3e7c0dc KH |
405 | |
406 | ;; When an appointment is reached, | |
407 | ;; delete it from the list. | |
408 | ;; Reset the count to 0 in case we display another | |
409 | ;; appointment on the next cycle. | |
8d638c1b GM |
410 | (if (zerop min-to-app) |
411 | (setq appt-time-msg-list (cdr appt-time-msg-list) | |
f3e7c0dc KH |
412 | appt-display-count nil))))) |
413 | ||
414 | ;; If we have changed the mode line string, | |
415 | ;; redisplay all mode lines. | |
416 | (and appt-display-mode-line | |
417 | (not (equal appt-mode-string | |
418 | prev-appt-mode-string)) | |
419 | (progn | |
420 | (force-mode-line-update t) | |
421 | ;; If the string now has a notification, | |
422 | ;; redisplay right now. | |
423 | (if appt-mode-string | |
424 | (sit-for 0))))))))) | |
902a0e3c JB |
425 | |
426 | ||
902a0e3c | 427 | (defun appt-disp-window (min-to-app new-time appt-msg) |
8d638c1b GM |
428 | "Display appointment message APPT-MSG in a separate buffer. |
429 | The appointment is due in MIN-TO-APP (a string) minutes. | |
430 | NEW-TIME is a string giving the date." | |
902a0e3c | 431 | (require 'electric) |
5b586155 RS |
432 | |
433 | ;; Make sure we're not in the minibuffer | |
434 | ;; before splitting the window. | |
435 | ||
436 | (if (equal (selected-window) (minibuffer-window)) | |
a1506d29 | 437 | (if (other-window 1) |
5b586155 | 438 | (select-window (other-window 1)) |
fbebec27 | 439 | (if (display-multi-frame-p) |
5b586155 | 440 | (select-frame (other-frame 1))))) |
a1506d29 | 441 | |
8d638c1b GM |
442 | (let ((this-window (selected-window)) |
443 | (appt-disp-buf (set-buffer (get-buffer-create appt-buffer-name)))) | |
5b586155 | 444 | |
d5b22d88 RS |
445 | (if (cdr (assq 'unsplittable (frame-parameters))) |
446 | ;; In an unsplittable frame, use something somewhere else. | |
447 | (display-buffer appt-disp-buf) | |
058961dd RS |
448 | (unless (or (special-display-p (buffer-name appt-disp-buf)) |
449 | (same-window-p (buffer-name appt-disp-buf))) | |
450 | ;; By default, split the bottom window and use the lower part. | |
451 | (appt-select-lowest-window) | |
452 | (split-window)) | |
d5b22d88 | 453 | (pop-to-buffer appt-disp-buf)) |
a1506d29 | 454 | (setq mode-line-format |
5b586155 RS |
455 | (concat "-------------------- Appointment in " |
456 | min-to-app " minutes. " new-time " %-")) | |
efa434d9 | 457 | (erase-buffer) |
0e13751e | 458 | (insert appt-msg) |
d5b22d88 | 459 | (shrink-window-if-larger-than-buffer (get-buffer-window appt-disp-buf t)) |
5b586155 | 460 | (set-buffer-modified-p nil) |
725ec4bc | 461 | (raise-frame (selected-frame)) |
8d638c1b | 462 | (select-window this-window))) |
a1506d29 | 463 | |
5b586155 RS |
464 | (defun appt-delete-window () |
465 | "Function called to undisplay appointment messages. | |
466 | Usually just deletes the appointment buffer." | |
95cdbff5 RS |
467 | (let ((window (get-buffer-window appt-buffer-name t))) |
468 | (and window | |
d073fa5b | 469 | (or (eq window (frame-root-window (window-frame window))) |
95cdbff5 | 470 | (delete-window window)))) |
5b586155 RS |
471 | (kill-buffer appt-buffer-name) |
472 | (if appt-audible | |
473 | (beep 1))) | |
902a0e3c | 474 | |
902a0e3c | 475 | (defun appt-select-lowest-window () |
d073fa5b | 476 | "Select the lowest window on the frame." |
7c0d9b89 GM |
477 | (let ((lowest-window (selected-window)) |
478 | (bottom-edge (nth 3 (window-edges)))) | |
479 | (walk-windows (lambda (w) | |
480 | (let ((next-bottom-edge (nth 3 (window-edges w)))) | |
481 | (when (< bottom-edge next-bottom-edge) | |
482 | (setq bottom-edge next-bottom-edge | |
483 | lowest-window w))))) | |
484 | (select-window lowest-window))) | |
902a0e3c | 485 | |
f3e7c0dc | 486 | ;;;###autoload |
902a0e3c | 487 | (defun appt-add (new-appt-time new-appt-msg) |
d073fa5b | 488 | "Add an appointment for the day at NEW-APPT-TIME and issue message NEW-APPT-MSG. |
902a0e3c JB |
489 | The time should be in either 24 hour format or am/pm format." |
490 | ||
491 | (interactive "sTime (hh:mm[am/pm]): \nsMessage: ") | |
8d638c1b | 492 | (unless (string-match "[0-9]?[0-9][:.][0-9][0-9]\\(am\\|pm\\)?" |
3b42c185 | 493 | new-appt-time) |
902a0e3c | 494 | (error "Unacceptable time-string")) |
902a0e3c JB |
495 | (let* ((appt-time-string (concat new-appt-time " " new-appt-msg)) |
496 | (appt-time (list (appt-convert-time new-appt-time))) | |
497 | (time-msg (cons appt-time (list appt-time-string)))) | |
d073fa5b | 498 | (setq appt-time-msg-list (nconc appt-time-msg-list (list time-msg))) |
a1506d29 | 499 | (setq appt-time-msg-list (appt-sort-list appt-time-msg-list)))) |
902a0e3c | 500 | |
f3e7c0dc | 501 | ;;;###autoload |
902a0e3c JB |
502 | (defun appt-delete () |
503 | "Delete an appointment from the list of appointments." | |
504 | (interactive) | |
8d638c1b | 505 | (let ((tmp-msg-list appt-time-msg-list)) |
902a0e3c JB |
506 | (while tmp-msg-list |
507 | (let* ((element (car tmp-msg-list)) | |
a1506d29 | 508 | (prompt-string (concat "Delete " |
bf9a91d0 RS |
509 | ;; We want to quote any doublequotes |
510 | ;; in the string, as well as put | |
511 | ;; doublequotes around it. | |
512 | (prin1-to-string | |
513 | (substring-no-properties | |
a1506d29 | 514 | (car (cdr element)) 0)) |
902a0e3c JB |
515 | " from list? ")) |
516 | (test-input (y-or-n-p prompt-string))) | |
517 | (setq tmp-msg-list (cdr tmp-msg-list)) | |
518 | (if test-input | |
95cdbff5 | 519 | (setq appt-time-msg-list (delq element appt-time-msg-list))))) |
85bbde63 | 520 | (appt-check) |
902a0e3c | 521 | (message ""))) |
a1506d29 | 522 | |
902a0e3c | 523 | |
ea04824c DL |
524 | (eval-when-compile (defvar number) |
525 | (defvar original-date) | |
526 | (defvar diary-entries-list)) | |
637a8ae9 | 527 | ;;;###autoload |
902a0e3c | 528 | (defun appt-make-list () |
8d638c1b | 529 | "Create the appointments list from today's diary buffer. |
d073fa5b | 530 | The time must be at the beginning of a line for it to be |
8d638c1b GM |
531 | put in the appointments list (see examples in documentation of |
532 | the function `appt-check'). We assume that the variables DATE and | |
533 | NUMBER hold the arguments that `list-diary-entries' received. | |
d073fa5b DL |
534 | They specify the range of dates that the diary is being processed for." |
535 | ||
9c197f24 RS |
536 | ;; We have something to do if the range of dates that the diary is |
537 | ;; considering includes the current date. | |
538 | (if (and (not (calendar-date-compare | |
539 | (list (calendar-current-date)) | |
540 | (list original-date))) | |
541 | (calendar-date-compare | |
542 | (list (calendar-current-date)) | |
543 | (list (calendar-gregorian-from-absolute | |
544 | (+ (calendar-absolute-from-gregorian original-date) | |
545 | number))))) | |
546 | (save-excursion | |
547 | ;; Clear the appointments list, then fill it in from the diary. | |
548 | (setq appt-time-msg-list nil) | |
549 | (if diary-entries-list | |
550 | ||
551 | ;; Cycle through the entry-list (diary-entries-list) | |
a1506d29 | 552 | ;; looking for entries beginning with a time. If |
9c197f24 RS |
553 | ;; the entry begins with a time, add it to the |
554 | ;; appt-time-msg-list. Then sort the list. | |
555 | ||
556 | (let ((entry-list diary-entries-list) | |
557 | (new-time-string "")) | |
558 | ;; Skip diary entries for dates before today. | |
559 | (while (and entry-list | |
560 | (calendar-date-compare | |
561 | (car entry-list) (list (calendar-current-date)))) | |
562 | (setq entry-list (cdr entry-list))) | |
563 | ;; Parse the entries for today. | |
a1506d29 JB |
564 | (while (and entry-list |
565 | (calendar-date-equal | |
9c197f24 | 566 | (calendar-current-date) (car (car entry-list)))) |
bf9a91d0 | 567 | (let ((time-string (cadr (car entry-list)))) |
9c197f24 | 568 | (while (string-match |
3b42c185 | 569 | "\\([0-9]?[0-9][:.][0-9][0-9]\\(am\\|pm\\)?\\).*" |
9c197f24 | 570 | time-string) |
4e96d63b RS |
571 | (let* ((beg (match-beginning 0)) |
572 | ;; Get just the time for this appointment. | |
573 | (only-time (match-string 1 time-string)) | |
574 | ;; Find the end of this appointment | |
575 | ;; (the start of the next). | |
576 | (end (string-match | |
3b42c185 | 577 | "^[ \t]*[0-9]?[0-9][:.][0-9][0-9]\\(am\\|pm\\)?" |
4e96d63b RS |
578 | time-string |
579 | (match-end 0))) | |
580 | ;; Get the whole string for this appointment. | |
581 | (appt-time-string | |
582 | (substring time-string beg (if end (1- end))))) | |
583 | ||
584 | ;; Add this appointment to appt-time-msg-list. | |
585 | (let* ((appt-time (list (appt-convert-time only-time))) | |
586 | (time-msg (list appt-time appt-time-string))) | |
587 | (setq appt-time-msg-list | |
588 | (nconc appt-time-msg-list (list time-msg)))) | |
589 | ||
590 | ;; Discard this appointment from the string. | |
591 | (setq time-string | |
592 | (if end (substring time-string end) ""))))) | |
9c197f24 RS |
593 | (setq entry-list (cdr entry-list))))) |
594 | (setq appt-time-msg-list (appt-sort-list appt-time-msg-list)) | |
595 | ||
596 | ;; Get the current time and convert it to minutes | |
597 | ;; from midnight. ie. 12:01am = 1, midnight = 0, | |
598 | ;; so that the elements in the list | |
599 | ;; that are earlier than the present time can | |
600 | ;; be removed. | |
601 | ||
0d26feea KH |
602 | (let* ((now (decode-time)) |
603 | (cur-hour (nth 2 now)) | |
604 | (cur-min (nth 1 now)) | |
9c197f24 | 605 | (cur-comp-time (+ (* cur-hour 60) cur-min)) |
8d638c1b | 606 | (appt-comp-time (car (caar appt-time-msg-list)))) |
9c197f24 RS |
607 | |
608 | (while (and appt-time-msg-list (< appt-comp-time cur-comp-time)) | |
a1506d29 | 609 | (setq appt-time-msg-list (cdr appt-time-msg-list)) |
9c197f24 | 610 | (if appt-time-msg-list |
8d638c1b | 611 | (setq appt-comp-time (car (caar appt-time-msg-list))))))))) |
a1506d29 | 612 | |
902a0e3c | 613 | |
902a0e3c | 614 | (defun appt-sort-list (appt-list) |
8d638c1b GM |
615 | "Sort an appointment list, putting earlier items at the front. |
616 | APPT-LIST is a list of the same format as `appt-time-msg-list'." | |
617 | (sort appt-list (lambda (e1 e2) (< (caar e1) (caar e2))))) | |
902a0e3c JB |
618 | |
619 | ||
620 | (defun appt-convert-time (time2conv) | |
3b42c185 | 621 | "Convert hour:min[am/pm] format to minutes from midnight. |
8d638c1b GM |
622 | A period (.) can be used instead of a colon (:) to separate the |
623 | hour and minute parts." | |
902a0e3c JB |
624 | (let ((conv-time 0) |
625 | (hr 0) | |
626 | (min 0)) | |
627 | ||
3b42c185 | 628 | (string-match "[:.]\\([0-9][0-9]\\)" time2conv) |
a1506d29 | 629 | (setq min (string-to-int |
d073fa5b | 630 | (match-string 1 time2conv))) |
a1506d29 | 631 | |
3b42c185 | 632 | (string-match "[0-9]?[0-9][:.]" time2conv) |
a1506d29 | 633 | (setq hr (string-to-int |
d073fa5b | 634 | (match-string 0 time2conv))) |
a1506d29 | 635 | |
902a0e3c | 636 | ;; convert the time appointment time into 24 hour time |
a1506d29 | 637 | |
85bbde63 GM |
638 | (cond ((and (string-match "pm" time2conv) (< hr 12)) |
639 | (setq hr (+ 12 hr))) | |
640 | ((and (string-match "am" time2conv) (= hr 12)) | |
641 | (setq hr 0))) | |
a1506d29 | 642 | |
902a0e3c JB |
643 | ;; convert the actual time |
644 | ;; into minutes for comparison | |
645 | ;; against the actual time. | |
a1506d29 | 646 | |
902a0e3c JB |
647 | (setq conv-time (+ (* hr 60) min)) |
648 | conv-time)) | |
649 | ||
902a0e3c | 650 | |
8d638c1b GM |
651 | (defun appt-update-list () |
652 | "If the current buffer is visiting the diary, update appointments. | |
653 | This function is intended for use with `write-file-functions'." | |
359bff67 | 654 | (and (string-equal buffer-file-name (expand-file-name diary-file)) |
8d638c1b GM |
655 | appt-timer |
656 | (let ((appt-display-diary nil)) | |
657 | (appt-check t))) | |
658 | nil) | |
659 | ||
660 | ||
661 | ;;;###autoload | |
662 | (defun appt-activate (&optional arg) | |
663 | "Toggle checking of appointments. | |
664 | With optional numeric argument ARG, turn appointment checking on if | |
665 | ARG is positive, otherwise off." | |
666 | (interactive "P") | |
667 | (let ((appt-active appt-timer)) | |
668 | (setq appt-active (if arg (> (prefix-numeric-value arg) 0) | |
669 | (not appt-active))) | |
670 | (remove-hook 'write-file-functions 'appt-update-list) | |
671 | (or global-mode-string (setq global-mode-string '(""))) | |
672 | (delq 'appt-mode-string global-mode-string) | |
a19de628 GM |
673 | (when appt-timer |
674 | (cancel-timer appt-timer) | |
675 | (setq appt-timer nil)) | |
8d638c1b GM |
676 | (when appt-active |
677 | (add-hook 'write-file-functions 'appt-update-list) | |
678 | (setq appt-timer (run-at-time t 60 'appt-check) | |
679 | global-mode-string | |
680 | (append global-mode-string '(appt-mode-string))) | |
681 | (appt-check t)))) | |
682 | ||
efa434d9 | 683 | |
9fa0334c GM |
684 | ;; This is needed for backwards compatibility. Feh. |
685 | (appt-activate 1) | |
686 | ||
687 | ||
8d638c1b | 688 | (provide 'appt) |
5b586155 | 689 | |
ab5796a9 | 690 | ;;; arch-tag: bf5791c4-8921-499e-a26f-772b1788d347 |
efa434d9 | 691 | ;;; appt.el ends here |