[bpt/emacs.git] / lisp / emacs-lisp / disass.el

;;; disass.el --- disassembler for compiled Emacs Lisp code

;; Copyright (C) 1986, 1991, 2002-2011 Free Software Foundation, Inc.

;; Author: Doug Cutting <doug@csli.stanford.edu>
;;	Jamie Zawinski <jwz@lucid.com>
;; Maintainer: FSF
;; Keywords: internal

;; This file is part of GNU Emacs.

;; GNU Emacs is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.

;;; Commentary:

;; The single entry point, `disassemble', disassembles a code object generated
;; by the Emacs Lisp byte-compiler.  This doesn't invert the compilation
;; operation, not by a long shot, but it's useful for debugging.

;;
;; Original version by Doug Cutting (doug@csli.stanford.edu)
;; Substantially modified by Jamie Zawinski <jwz@lucid.com> for
;; the new lapcode-based byte compiler.

;;; Code:

;;; The variable byte-code-vector is defined by the new bytecomp.el.
;;; The function byte-decompile-lapcode is defined in byte-opt.el.
;;; Since we don't use byte-decompile-lapcode, let's try not loading byte-opt.
(require 'byte-compile "bytecomp")

(defvar disassemble-column-1-indent 8 "*")
(defvar disassemble-column-2-indent 10 "*")

(defvar disassemble-recursive-indent 3 "*")

;;;###autoload
(defun disassemble (object &optional buffer indent interactive-p)
  "Print disassembled code for OBJECT in (optional) BUFFER.
OBJECT can be a symbol defined as a function, or a function itself
\(a lambda expression or a compiled-function object).
If OBJECT is not already compiled, we compile it, but do not
redefine OBJECT if it is a symbol."
  (interactive (list (intern (completing-read "Disassemble function: "
					      obarray 'fboundp t))
		     nil 0 t))
  (if (and (consp object) (not (eq (car object) 'lambda)))
      (setq object (list 'lambda () object)))
  (or indent (setq indent 0))		;Default indent to zero
  (save-excursion
    (if (or interactive-p (null buffer))
	(with-output-to-temp-buffer "*Disassemble*"
	  (set-buffer "*Disassemble*")
	  (disassemble-internal object indent (not interactive-p)))
      (set-buffer buffer)
      (disassemble-internal object indent nil)))
  nil)


(defun disassemble-internal (obj indent interactive-p)
  (let ((macro 'nil)
	(name 'nil)
	(doc 'nil)
	args)
    (while (symbolp obj)
      (setq name obj
	    obj (symbol-function obj)))
    (if (subrp obj)
	(error "Can't disassemble #<subr %s>" name))
    (when (and (listp obj) (eq (car obj) 'autoload))
      (load (nth 1 obj))
      (setq obj (symbol-function name)))
    (if (eq (car-safe obj) 'macro)	;handle macros
	(setq macro t
	      obj (cdr obj)))
    (when (and (listp obj) (eq (car obj) 'closure))
      (error "Don't know how to compile an interpreted closure"))
    (if (and (listp obj) (eq (car obj) 'byte-code))
	(setq obj (list 'lambda nil obj)))
    (if (and (listp obj) (not (eq (car obj) 'lambda)))
	(error "not a function"))
    (if (consp obj)
	(if (assq 'byte-code obj)
	    nil
	  (if interactive-p (message (if name
					 "Compiling %s's definition..."
				       "Compiling definition...")
				     name))
	  (setq obj (byte-compile obj))
	  (if interactive-p (message "Done compiling.  Disassembling..."))))
    (cond ((consp obj)
	   (setq obj (cdr obj))		;throw lambda away
	   (setq args (car obj))	;save arg list
	   (setq obj (cdr obj)))
	  ((byte-code-function-p obj)
	   (setq args (aref obj 0)))
          (t (error "Compilation failed")))
    (if (zerop indent) ; not a nested function
	(progn
	  (indent-to indent)
	  (insert (format "byte code%s%s%s:\n"
			  (if (or macro name) " for" "")
			  (if macro " macro" "")
			  (if name (format " %s" name) "")))))
    (let ((doc (if (consp obj)
		   (and (stringp (car obj)) (car obj))
		 ;; Use documentation to get lazy-loaded doc string
		 (documentation obj t))))
      (if (and doc (stringp doc))
	  (progn (and (consp obj) (setq obj (cdr obj)))
		 (indent-to indent)
		 (princ "  doc:  " (current-buffer))
		 (if (string-match "\n" doc)
		     (setq doc (concat (substring doc 0 (match-beginning 0))
				       " ...")))
		 (insert doc "\n"))))
    (indent-to indent)
    (insert "  args: ")
    (prin1 args (current-buffer))
    (insert "\n")
    (let ((interactive (cond ((consp obj)
			      (assq 'interactive obj))
			     ((> (length obj) 5)
			      (list 'interactive (aref obj 5))))))
      (if interactive
	  (progn
	    (setq interactive (nth 1 interactive))
	    (if (eq (car-safe (car-safe obj)) 'interactive)
		(setq obj (cdr obj)))
	    (indent-to indent)
	    (insert " interactive: ")
	    (if (eq (car-safe interactive) 'byte-code)
		(progn
		  (insert "\n")
		  (disassemble-1 interactive
				 (+ indent disassemble-recursive-indent)))
	      (let ((print-escape-newlines t))
		(prin1 interactive (current-buffer))))
	    (insert "\n"))))
    (cond ((and (consp obj) (assq 'byte-code obj))
	   (disassemble-1 (assq 'byte-code obj) indent))
	  ((byte-code-function-p obj)
	   (disassemble-1 obj indent))
	  (t
	   (insert "Uncompiled body:  ")
	   (let ((print-escape-newlines t))
	     (prin1 (if (cdr obj) (cons 'progn obj) (car obj))
		    (current-buffer))))))
  (if interactive-p
      (message "")))


(defun disassemble-1 (obj indent)
  "Prints the byte-code call OBJ in the current buffer.
OBJ should be a call to BYTE-CODE generated by the byte compiler."
  (let (bytes constvec)
    (if (consp obj)
	(setq bytes (car (cdr obj))		;the byte code
	      constvec (car (cdr (cdr obj))))	;constant vector
      ;; If it is lazy-loaded, load it now
      (fetch-bytecode obj)
      (setq bytes (aref obj 1)
	    constvec (aref obj 2)))
    (let ((lap (byte-decompile-bytecode (string-as-unibyte bytes) constvec))
	  op arg opname pc-value)
      (let ((tagno 0)
	    tmp
	    (lap lap))
	(while (setq tmp (assq 'TAG lap))
	  (setcar (cdr tmp) (setq tagno (1+ tagno)))
	  (setq lap (cdr (memq tmp lap)))))
      (while lap
	;; Take off the pc value of the next thing
	;; and put it in pc-value.
	(setq pc-value nil)
	(if (numberp (car lap))
	    (setq pc-value (car lap)
		  lap (cdr lap)))
	;; Fetch the next op and its arg.
	(setq op (car (car lap))
	      arg (cdr (car lap)))
	(setq lap (cdr lap))
	(indent-to indent)
	(if (eq 'TAG op)
	    (progn
	      ;; We have a label.  Display it, but first its pc value.
	      (if pc-value
		  (insert (format "%d:" pc-value)))
	      (insert (int-to-string (car arg))))
	  ;; We have an instruction.  Display its pc value first.
	  (if pc-value
	      (insert (format "%d" pc-value)))
	  (indent-to (+ indent disassemble-column-1-indent))
	  (if (and op
		   (string-match "^byte-" (setq opname (symbol-name op))))
	      (setq opname (substring opname 5))
	    (setq opname "<not-an-opcode>"))
	  (if (eq op 'byte-constant2)
	      (insert " #### shouldn't have seen constant2 here!\n  "))
	  (insert opname)
	  (indent-to (+ indent disassemble-column-1-indent
			disassemble-column-2-indent
			-1))
	  (insert " ")
	  (cond ((memq op byte-goto-ops)
		 (insert (int-to-string (nth 1 arg))))
		((memq op '(byte-call byte-unbind
			    byte-listN byte-concatN byte-insertN
			    byte-stack-ref byte-stack-set byte-stack-set2
			    byte-discardN byte-discardN-preserve-tos))
		 (insert (int-to-string arg)))
		((memq op '(byte-varref byte-varset byte-varbind))
		 (prin1 (car arg) (current-buffer)))
		((memq op '(byte-constant byte-constant2))
		 ;; it's a constant
		 (setq arg (car arg))
		 ;; but if the value of the constant is compiled code, then
		 ;; recursively disassemble it.
		 (cond ((or (byte-code-function-p arg)
			    (and (eq (car-safe arg) 'lambda)
				 (assq 'byte-code arg))
			    (and (eq (car-safe arg) 'macro)
				 (or (byte-code-function-p (cdr arg))
				     (and (eq (car-safe (cdr arg)) 'lambda)
					  (assq 'byte-code (cdr arg))))))
			(cond ((byte-code-function-p arg)
			       (insert "<compiled-function>\n"))
			      ((eq (car-safe arg) 'lambda)
			       (insert "<compiled lambda>"))
			      (t (insert "<compiled macro>\n")))
			(disassemble-internal
			 arg
			 (+ indent disassemble-recursive-indent 1)
			 nil))
		       ((eq (car-safe arg) 'byte-code)
			(insert "<byte code>\n")
			(disassemble-1	;recurse on byte-code object
			 arg
			 (+ indent disassemble-recursive-indent)))
		       ((eq (car-safe (car-safe arg)) 'byte-code)
			(insert "(<byte code>...)\n")
			(mapc ;recurse on list of byte-code objects
			 (lambda (obj)
                           (disassemble-1
                            obj
                            (+ indent disassemble-recursive-indent)))
			 arg))
		       (t
			;; really just a constant
			(let ((print-escape-newlines t))
			  (prin1 arg (current-buffer))))))
		)
	  (insert "\n")))))
  nil)

(provide 'disass)

;;; disass.el ends here
Commit	Line	Data
fd7fa35a ER	1	;;; disass.el --- disassembler for compiled Emacs Lisp code
fd7fa35a ER	2
73b0cd50	3	;; Copyright (C) 1986, 1991, 2002-2011 Free Software Foundation, Inc.
9750e079	4
fd7fa35a ER	5	;; Author: Doug Cutting <doug@csli.stanford.edu>
fd7fa35a ER	6	;; Jamie Zawinski <jwz@lucid.com>
dc0485c4	7	;; Maintainer: FSF
e9571d2a	8	;; Keywords: internal
fd7fa35a	9
1c393159 JB	10	;; This file is part of GNU Emacs.
1c393159 JB	11
d6cba7ae	12	;; GNU Emacs is free software: you can redistribute it and/or modify
1c393159	13	;; it under the terms of the GNU General Public License as published by
d6cba7ae GM	14	;; the Free Software Foundation, either version 3 of the License, or
d6cba7ae GM	15	;; (at your option) any later version.
1c393159 JB	16
	17	;; GNU Emacs is distributed in the hope that it will be useful,
	18	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	19	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	20	;; GNU General Public License for more details.
	21
	22	;; You should have received a copy of the GNU General Public License
d6cba7ae	23	;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
1c393159	24
fd7fa35a ER	25	;;; Commentary:
fd7fa35a ER	26
e41b2db1 ER	27	;; The single entry point, `disassemble', disassembles a code object generated
	28	;; by the Emacs Lisp byte-compiler. This doesn't invert the compilation
	29	;; operation, not by a long shot, but it's useful for debugging.
	30
	31	;;
	32	;; Original version by Doug Cutting (doug@csli.stanford.edu)
	33	;; Substantially modified by Jamie Zawinski <jwz@lucid.com> for
	34	;; the new lapcode-based byte compiler.
fd7fa35a ER	35
fd7fa35a ER	36	;;; Code:
1c393159 JB	37
1c393159 JB	38	;;; The variable byte-code-vector is defined by the new bytecomp.el.
c29118da JB	39	;;; The function byte-decompile-lapcode is defined in byte-opt.el.
c29118da JB	40	;;; Since we don't use byte-decompile-lapcode, let's try not loading byte-opt.
d28a1925	41	(require 'byte-compile "bytecomp")
1c393159	42
3c7e6b9d	43	(defvar disassemble-column-1-indent 8 "*")
1c393159 JB	44	(defvar disassemble-column-2-indent 10 "*")
	45
	46	(defvar disassemble-recursive-indent 3 "*")
	47
dbc4e1c1	48	;;;###autoload
1c393159 JB	49	(defun disassemble (object &optional buffer indent interactive-p)
	50	"Print disassembled code for OBJECT in (optional) BUFFER.
	51	OBJECT can be a symbol defined as a function, or a function itself
	52	\(a lambda expression or a compiled-function object).
	53	If OBJECT is not already compiled, we compile it, but do not
	54	redefine OBJECT if it is a symbol."
	55	(interactive (list (intern (completing-read "Disassemble function: "
	56	obarray 'fboundp t))
	57	nil 0 t))
dc0485c4	58	(if (and (consp object) (not (eq (car object) 'lambda)))
1c393159 JB	59	(setq object (list 'lambda () object)))
	60	(or indent (setq indent 0)) ;Default indent to zero
	61	(save-excursion
	62	(if (or interactive-p (null buffer))
	63	(with-output-to-temp-buffer "Disassemble"
	64	(set-buffer "Disassemble")
	65	(disassemble-internal object indent (not interactive-p)))
	66	(set-buffer buffer)
	67	(disassemble-internal object indent nil)))
	68	nil)
	69
	70
	71	(defun disassemble-internal (obj indent interactive-p)
	72	(let ((macro 'nil)
	73	(name 'nil)
	74	(doc 'nil)
	75	args)
	76	(while (symbolp obj)
	77	(setq name obj
	78	obj (symbol-function obj)))
	79	(if (subrp obj)
	80	(error "Can't disassemble #<subr %s>" name))
b9598260 SM	81	(when (and (listp obj) (eq (car obj) 'autoload))
	82	(load (nth 1 obj))
	83	(setq obj (symbol-function name)))
1c393159 JB	84	(if (eq (car-safe obj) 'macro) ;handle macros
	85	(setq macro t
	86	obj (cdr obj)))
b9598260	87	(when (and (listp obj) (eq (car obj) 'closure))
23aba0ea	88	(error "Don't know how to compile an interpreted closure"))
8dff74b7	89	(if (and (listp obj) (eq (car obj) 'byte-code))
a1506d29	90	(setq obj (list 'lambda nil obj)))
1c393159 JB	91	(if (and (listp obj) (not (eq (car obj) 'lambda)))
	92	(error "not a function"))
	93	(if (consp obj)
	94	(if (assq 'byte-code obj)
	95	nil
	96	(if interactive-p (message (if name
	97	"Compiling %s's definition..."
	98	"Compiling definition...")
	99	name))
	100	(setq obj (byte-compile obj))
	101	(if interactive-p (message "Done compiling. Disassembling..."))))
	102	(cond ((consp obj)
	103	(setq obj (cdr obj)) ;throw lambda away
	104	(setq args (car obj)) ;save arg list
	105	(setq obj (cdr obj)))
c757fb07 RS	106	((byte-code-function-p obj)
	107	(setq args (aref obj 0)))
	108	(t (error "Compilation failed")))
1c393159 JB	109	(if (zerop indent) ; not a nested function
	110	(progn
	111	(indent-to indent)
	112	(insert (format "byte code%s%s%s:\n"
	113	(if (or macro name) " for" "")
	114	(if macro " macro" "")
	115	(if name (format " %s" name) "")))))
	116	(let ((doc (if (consp obj)
	117	(and (stringp (car obj)) (car obj))
3fd4909e RS	118	;; Use documentation to get lazy-loaded doc string
3fd4909e RS	119	(documentation obj t))))
1c393159 JB	120	(if (and doc (stringp doc))
	121	(progn (and (consp obj) (setq obj (cdr obj)))
	122	(indent-to indent)
	123	(princ " doc: " (current-buffer))
	124	(if (string-match "\n" doc)
	125	(setq doc (concat (substring doc 0 (match-beginning 0))
	126	" ...")))
	127	(insert doc "\n"))))
	128	(indent-to indent)
	129	(insert " args: ")
	130	(prin1 args (current-buffer))
	131	(insert "\n")
	132	(let ((interactive (cond ((consp obj)
	133	(assq 'interactive obj))
	134	((> (length obj) 5)
	135	(list 'interactive (aref obj 5))))))
	136	(if interactive
	137	(progn
	138	(setq interactive (nth 1 interactive))
	139	(if (eq (car-safe (car-safe obj)) 'interactive)
	140	(setq obj (cdr obj)))
	141	(indent-to indent)
	142	(insert " interactive: ")
	143	(if (eq (car-safe interactive) 'byte-code)
	144	(progn
	145	(insert "\n")
	146	(disassemble-1 interactive
	147	(+ indent disassemble-recursive-indent)))
	148	(let ((print-escape-newlines t))
	149	(prin1 interactive (current-buffer))))
	150	(insert "\n"))))
	151	(cond ((and (consp obj) (assq 'byte-code obj))
	152	(disassemble-1 (assq 'byte-code obj) indent))
dbc4e1c1	153	((byte-code-function-p obj)
1c393159 JB	154	(disassemble-1 obj indent))
	155	(t
	156	(insert "Uncompiled body: ")
	157	(let ((print-escape-newlines t))
	158	(prin1 (if (cdr obj) (cons 'progn obj) (car obj))
	159	(current-buffer))))))
	160	(if interactive-p
	161	(message "")))
	162
	163
	164	(defun disassemble-1 (obj indent)
	165	"Prints the byte-code call OBJ in the current buffer.
	166	OBJ should be a call to BYTE-CODE generated by the byte compiler."
	167	(let (bytes constvec)
	168	(if (consp obj)
	169	(setq bytes (car (cdr obj)) ;the byte code
	170	constvec (car (cdr (cdr obj)))) ;constant vector
3fd4909e RS	171	;; If it is lazy-loaded, load it now
3fd4909e RS	172	(fetch-bytecode obj)
d18a808f	173	(setq bytes (aref obj 1)
1c393159	174	constvec (aref obj 2)))
d18a808f	175	(let ((lap (byte-decompile-bytecode (string-as-unibyte bytes) constvec))
3c7e6b9d	176	op arg opname pc-value)
1c393159 JB	177	(let ((tagno 0)
	178	tmp
	179	(lap lap))
	180	(while (setq tmp (assq 'TAG lap))
	181	(setcar (cdr tmp) (setq tagno (1+ tagno)))
	182	(setq lap (cdr (memq tmp lap)))))
	183	(while lap
3c7e6b9d RS	184	;; Take off the pc value of the next thing
	185	;; and put it in pc-value.
	186	(setq pc-value nil)
	187	(if (numberp (car lap))
	188	(setq pc-value (car lap)
	189	lap (cdr lap)))
	190	;; Fetch the next op and its arg.
1c393159 JB	191	(setq op (car (car lap))
1c393159 JB	192	arg (cdr (car lap)))
3c7e6b9d	193	(setq lap (cdr lap))
1c393159 JB	194	(indent-to indent)
1c393159 JB	195	(if (eq 'TAG op)
3c7e6b9d RS	196	(progn
	197	;; We have a label. Display it, but first its pc value.
	198	(if pc-value
	199	(insert (format "%d:" pc-value)))
	200	(insert (int-to-string (car arg))))
	201	;; We have an instruction. Display its pc value first.
	202	(if pc-value
	203	(insert (format "%d" pc-value)))
1c393159 JB	204	(indent-to (+ indent disassemble-column-1-indent))
	205	(if (and op
	206	(string-match "^byte-" (setq opname (symbol-name op))))
	207	(setq opname (substring opname 5))
	208	(setq opname "<not-an-opcode>"))
	209	(if (eq op 'byte-constant2)
	210	(insert " #### shouldn't have seen constant2 here!\n "))
	211	(insert opname)
	212	(indent-to (+ indent disassemble-column-1-indent
	213	disassemble-column-2-indent
	214	-1))
	215	(insert " ")
	216	(cond ((memq op byte-goto-ops)
	217	(insert (int-to-string (nth 1 arg))))
	218	((memq op '(byte-call byte-unbind
b9598260 SM	219	byte-listN byte-concatN byte-insertN
	220	byte-stack-ref byte-stack-set byte-stack-set2
	221	byte-discardN byte-discardN-preserve-tos))
1c393159 JB	222	(insert (int-to-string arg)))
	223	((memq op '(byte-varref byte-varset byte-varbind))
	224	(prin1 (car arg) (current-buffer)))
	225	((memq op '(byte-constant byte-constant2))
	226	;; it's a constant
	227	(setq arg (car arg))
	228	;; but if the value of the constant is compiled code, then
	229	;; recursively disassemble it.
dbc4e1c1	230	(cond ((or (byte-code-function-p arg)
1c393159 JB	231	(and (eq (car-safe arg) 'lambda)
	232	(assq 'byte-code arg))
	233	(and (eq (car-safe arg) 'macro)
dbc4e1c1	234	(or (byte-code-function-p (cdr arg))
1c393159 JB	235	(and (eq (car-safe (cdr arg)) 'lambda)
1c393159 JB	236	(assq 'byte-code (cdr arg))))))
dbc4e1c1	237	(cond ((byte-code-function-p arg)
1c393159 JB	238	(insert "<compiled-function>\n"))
	239	((eq (car-safe arg) 'lambda)
	240	(insert "<compiled lambda>"))
	241	(t (insert "<compiled macro>\n")))
	242	(disassemble-internal
	243	arg
	244	(+ indent disassemble-recursive-indent 1)
	245	nil))
	246	((eq (car-safe arg) 'byte-code)
	247	(insert "<byte code>\n")
	248	(disassemble-1 ;recurse on byte-code object
	249	arg
	250	(+ indent disassemble-recursive-indent)))
	251	((eq (car-safe (car-safe arg)) 'byte-code)
	252	(insert "(<byte code>...)\n")
56a1431a	253	(mapc ;recurse on list of byte-code objects
4f91a816 SM	254	(lambda (obj)
	255	(disassemble-1
	256	obj
	257	(+ indent disassemble-recursive-indent)))
1c393159 JB	258	arg))
	259	(t
	260	;; really just a constant
	261	(let ((print-escape-newlines t))
	262	(prin1 arg (current-buffer))))))
	263	)
3c7e6b9d	264	(insert "\n")))))
1c393159	265	nil)
fd7fa35a	266
896546cd RS	267	(provide 'disass)
896546cd RS	268
fd7fa35a	269	;;; disass.el ends here