[bpt/emacs.git] / lisp / indent.el

;;; indent.el --- indentation commands for Emacs

;; Copyright (C) 1985 Free Software Foundation, Inc.

;; Maintainer: FSF

;; This file is part of GNU Emacs.

;; GNU Emacs is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 2, or (at your option)
;; any later version.

;; GNU Emacs is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with GNU Emacs; see the file COPYING.  If not, write to
;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.

;;; Commentary:

;; Commands for making and changing indentation in text.  These are
;; described in the Emacs manual.

;;; Code:

(defvar indent-line-function 'indent-to-left-margin "\
Function to indent current line.")

(defun indent-according-to-mode ()
  "Indent line in proper way for current major mode."
  (interactive)
  (funcall indent-line-function))

(defun indent-for-tab-command ()
  "Indent line in proper way for current major mode."
  (interactive)
  (if (eq indent-line-function 'indent-to-left-margin)
      (insert-tab)
    (funcall indent-line-function)))

(defun insert-tab ()
  (if abbrev-mode
      (expand-abbrev))
  (if indent-tabs-mode
      (insert ?\t)
    (indent-to (* tab-width (1+ (/ (current-column) tab-width))))))

(defun indent-rigidly (start end arg)
  "Indent all lines starting in the region sideways by ARG columns.
Called from a program, takes three arguments, START, END and ARG."
  (interactive "r\np")
  (save-excursion
    (goto-char end)
    (setq end (point-marker))
    (goto-char start)
    (or (bolp) (forward-line 1))
    (while (< (point) end)
      (let ((indent (current-indentation)))
	(delete-region (point) (progn (skip-chars-forward " \t") (point)))
	(or (eolp)
	    (indent-to (max 0 (+ indent arg)) 0)))
      (forward-line 1))
    (move-marker end nil)))

;; This is the default indent-line-function,
;; used in Fundamental Mode, Text Mode, etc.
(defun indent-to-left-margin ()
  (or (= (current-indentation) left-margin)
      (let (epos)
	(save-excursion
	 (beginning-of-line)
	 (delete-region (point)
			(progn (skip-chars-forward " \t")
			       (point)))
	 (indent-to left-margin)
	 (setq epos (point)))
	(if (< (point) epos)
	    (goto-char epos)))))

(defvar indent-region-function nil
  "Function which is short cut to indent region using indent-according-to-mode.
A value of nil means really run indent-according-to-mode on each line.")

(defun indent-region (start end column)
  "Indent each nonblank line in the region.
With no argument, indent each line using `indent-according-to-mode',
or use `indent-region-function' to do the whole region if that's non-nil.
If there is a fill prefix, make each line start with the fill prefix.
With argument COLUMN, indent each line to that column.
Called from a program, takes three args: START, END and COLUMN."
  (interactive "r\nP")
  (if (null column)
      (if fill-prefix
	  (save-excursion
	    (goto-char end)
	    (setq end (point-marker))
	    (goto-char start)
	    (let ((regexp (regexp-quote fill-prefix)))
	      (while (< (point) end)
		(or (looking-at regexp)
		    (and (bolp) (eolp))
		    (insert fill-prefix))
		(forward-line 1))))
	(if indent-region-function
	    (funcall indent-region-function start end)
	  (save-excursion
	    (goto-char end)
	    (setq end (point-marker))
	    (goto-char start)
	    (or (bolp) (forward-line 1))
	    (while (< (point) end)
	      (or (and (bolp) (eolp))
		  (funcall indent-line-function))
	      (forward-line 1))
	    (move-marker end nil))))
    (setq column (prefix-numeric-value column))
    (save-excursion
      (goto-char end)
      (setq end (point-marker))
      (goto-char start)
      (or (bolp) (forward-line 1))
      (while (< (point) end)
	(delete-region (point) (progn (skip-chars-forward " \t") (point)))
	(or (eolp)
	(indent-to column 0))
	(forward-line 1))
      (move-marker end nil))))

(defun indent-relative-maybe ()
  "Indent a new line like previous nonblank line."
  (interactive)
  (indent-relative t))

(defun indent-relative (&optional unindented-ok)
  "Space out to under next indent point in previous nonblank line.
An indent point is a non-whitespace character following whitespace.
If the previous nonblank line has no indent points beyond the
column point starts at, `tab-to-tab-stop' is done instead."
  (interactive "P")
  (if abbrev-mode (expand-abbrev))
  (let ((start-column (current-column))
	indent)
    (save-excursion
      (beginning-of-line)
      (if (re-search-backward "^[^\n]" nil t)
	  (let ((end (save-excursion (forward-line 1) (point))))
	    (move-to-column start-column)
	    ;; Is start-column inside a tab on this line?
	    (if (> (current-column) start-column)
		(backward-char 1))
	    (or (looking-at "[ \t]")
		unindented-ok
		(skip-chars-forward "^ \t" end))
	    (skip-chars-forward " \t" end)
	    (or (= (point) end) (setq indent (current-column))))))
    (if indent
	(let ((opoint (point-marker)))
	  (delete-region (point) (progn (skip-chars-backward " \t") (point)))
	  (indent-to indent 0)
	  (if (> opoint (point))
	      (goto-char opoint))
	  (move-marker opoint nil))
      (tab-to-tab-stop))))

(defvar tab-stop-list
  '(8 16 24 32 40 48 56 64 72 80 88 96 104 112 120)
  "*List of tab stop positions used by `tab-to-tab-stops'.
This should be a list of integers, ordered from smallest to largest.")

(defvar edit-tab-stops-map nil "Keymap used in `edit-tab-stops'.")
(if edit-tab-stops-map
    nil
  (setq edit-tab-stops-map (make-sparse-keymap))
  (define-key edit-tab-stops-map "\C-x\C-s" 'edit-tab-stops-note-changes)
  (define-key edit-tab-stops-map "\C-c\C-c" 'edit-tab-stops-note-changes))

(defvar edit-tab-stops-buffer nil
  "Buffer whose tab stops are being edited--in case
the variable `tab-stop-list' is local in that buffer.")

(defun edit-tab-stops ()
  "Edit the tab stops used by `tab-to-tab-stop'.
Creates a buffer *Tab Stops* containing text describing the tab stops.
A colon indicates a column where there is a tab stop.
You can add or remove colons and then do \\<edit-tab-stops-map>\\[edit-tab-stops-note-changes] to make changes take effect."
  (interactive)
  (setq edit-tab-stops-buffer (current-buffer))
  (switch-to-buffer (get-buffer-create "*Tab Stops*"))
  (use-local-map edit-tab-stops-map)
  (make-local-variable 'indent-tabs-mode)
  (setq indent-tabs-mode nil)
  (overwrite-mode 1)
  (setq truncate-lines t)
  (erase-buffer)
  (let ((tabs tab-stop-list))
    (while tabs
      (indent-to (car tabs) 0)
      (insert ?:)
      (setq tabs (cdr tabs))))
  (let ((count 0))
    (insert ?\n)
    (while (< count 8)
      (insert (+ count ?0))
    (insert "         ")
      (setq count (1+ count)))
    (insert ?\n)
    (while (> count 0)
      (insert "0123456789")
      (setq count (1- count))))
  (insert "\nTo install changes, type C-c C-c")
  (goto-char (point-min)))

(defun edit-tab-stops-note-changes ()
  "Put edited tab stops into effect."
  (interactive)
    (let (tabs)
      (save-excursion
	(goto-char 1)
	(end-of-line)
	(while (search-backward ":" nil t)
	  (setq tabs (cons (current-column) tabs))))
      (bury-buffer (prog1 (current-buffer)
			  (switch-to-buffer edit-tab-stops-buffer)))
      (setq tab-stop-list tabs))
  (message "Tab stops installed"))

(defun tab-to-tab-stop ()
  "Insert spaces or tabs to next defined tab-stop column.
The variable `tab-stop-list' is a list of columns at which there are tab stops.
Use \\[edit-tab-stops] to edit them interactively."
  (interactive)
  (if abbrev-mode (expand-abbrev))
  (let ((tabs tab-stop-list))
    (while (and tabs (>= (current-column) (car tabs)))
      (setq tabs (cdr tabs)))
    (if tabs
	(let ((opoint (point)))
	  (skip-chars-backward " \t")
	  (delete-region (point) opoint)
	  (indent-to (car tabs)))
      (insert ?\ ))))

(defun move-to-tab-stop ()
  "Move point to next defined tab-stop column.
The variable `tab-stop-list' is a list of columns at which there are tab stops.
Use \\[edit-tab-stops] to edit them interactively."
  (interactive)
  (let ((tabs tab-stop-list))
    (while (and tabs (>= (current-column) (car tabs)))
      (setq tabs (cdr tabs)))
    (if tabs
	(progn
	  (if (eq last-command 'move-to-tab-stop)
	      (let ((opoint (point)))
		(skip-chars-backward " \t")
		(delete-region (point) opoint)))
	  (move-to-column (car tabs) t)))))

(define-key global-map "\t" 'indent-for-tab-command)
(define-key esc-map "\034" 'indent-region)
(define-key ctl-x-map "\t" 'indent-rigidly)
(define-key esc-map "i" 'tab-to-tab-stop)

;;; indent.el ends here
Commit	Line	Data
1a06eabd ER	1	;;; indent.el --- indentation commands for Emacs
1a06eabd ER	2
483e630e RM	3	;; Copyright (C) 1985 Free Software Foundation, Inc.
483e630e RM	4
9750e079 ER	5	;; Maintainer: FSF
9750e079 ER	6
483e630e RM	7	;; This file is part of GNU Emacs.
	8
	9	;; GNU Emacs is free software; you can redistribute it and/or modify
	10	;; it under the terms of the GNU General Public License as published by
e5167999	11	;; the Free Software Foundation; either version 2, or (at your option)
483e630e RM	12	;; any later version.
	13
	14	;; GNU Emacs is distributed in the hope that it will be useful,
	15	;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	16	;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	17	;; GNU General Public License for more details.
	18
	19	;; You should have received a copy of the GNU General Public License
	20	;; along with GNU Emacs; see the file COPYING. If not, write to
	21	;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
	22
e41b2db1 ER	23	;;; Commentary:
	24
	25	;; Commands for making and changing indentation in text. These are
	26	;; described in the Emacs manual.
	27
e5167999	28	;;; Code:
483e630e	29
6503cec3	30	(defvar indent-line-function 'indent-to-left-margin "\
7cf2444d	31	Function to indent current line.")
483e630e RM	32
	33	(defun indent-according-to-mode ()
	34	"Indent line in proper way for current major mode."
	35	(interactive)
	36	(funcall indent-line-function))
	37
	38	(defun indent-for-tab-command ()
	39	"Indent line in proper way for current major mode."
	40	(interactive)
	41	(if (eq indent-line-function 'indent-to-left-margin)
	42	(insert-tab)
	43	(funcall indent-line-function)))
	44
	45	(defun insert-tab ()
	46	(if abbrev-mode
	47	(expand-abbrev))
	48	(if indent-tabs-mode
	49	(insert ?\t)
	50	(indent-to (* tab-width (1+ (/ (current-column) tab-width))))))
	51
	52	(defun indent-rigidly (start end arg)
	53	"Indent all lines starting in the region sideways by ARG columns.
	54	Called from a program, takes three arguments, START, END and ARG."
	55	(interactive "r\np")
	56	(save-excursion
	57	(goto-char end)
	58	(setq end (point-marker))
	59	(goto-char start)
	60	(or (bolp) (forward-line 1))
	61	(while (< (point) end)
	62	(let ((indent (current-indentation)))
	63	(delete-region (point) (progn (skip-chars-forward " \t") (point)))
	64	(or (eolp)
	65	(indent-to (max 0 (+ indent arg)) 0)))
	66	(forward-line 1))
	67	(move-marker end nil)))
	68
	69	;; This is the default indent-line-function,
	70	;; used in Fundamental Mode, Text Mode, etc.
	71	(defun indent-to-left-margin ()
	72	(or (= (current-indentation) left-margin)
	73	(let (epos)
	74	(save-excursion
	75	(beginning-of-line)
	76	(delete-region (point)
	77	(progn (skip-chars-forward " \t")
	78	(point)))
	79	(indent-to left-margin)
	80	(setq epos (point)))
	81	(if (< (point) epos)
	82	(goto-char epos)))))
	83
	84	(defvar indent-region-function nil
797d8537 JB	85	"Function which is short cut to indent region using indent-according-to-mode.
797d8537 JB	86	A value of nil means really run indent-according-to-mode on each line.")
483e630e	87
88a2603a	88	(defun indent-region (start end column)
483e630e	89	"Indent each nonblank line in the region.
88a2603a RS	90	With no argument, indent each line using `indent-according-to-mode',
	91	or use `indent-region-function' to do the whole region if that's non-nil.
	92	If there is a fill prefix, make each line start with the fill prefix.
483e630e RM	93	With argument COLUMN, indent each line to that column.
	94	Called from a program, takes three args: START, END and COLUMN."
	95	(interactive "r\nP")
88a2603a	96	(if (null column)
483e630e RM	97	(if fill-prefix
	98	(save-excursion
	99	(goto-char end)
	100	(setq end (point-marker))
	101	(goto-char start)
	102	(let ((regexp (regexp-quote fill-prefix)))
88a2603a RS	103	(while (< (point) end)
	104	(or (looking-at regexp)
	105	(and (bolp) (eolp))
	106	(insert fill-prefix))
	107	(forward-line 1))))
483e630e RM	108	(if indent-region-function
	109	(funcall indent-region-function start end)
	110	(save-excursion
88a2603a RS	111	(goto-char end)
	112	(setq end (point-marker))
	113	(goto-char start)
	114	(or (bolp) (forward-line 1))
	115	(while (< (point) end)
232acca7	116	(or (and (bolp) (eolp))
88a2603a RS	117	(funcall indent-line-function))
	118	(forward-line 1))
	119	(move-marker end nil))))
	120	(setq column (prefix-numeric-value column))
483e630e RM	121	(save-excursion
	122	(goto-char end)
	123	(setq end (point-marker))
	124	(goto-char start)
	125	(or (bolp) (forward-line 1))
	126	(while (< (point) end)
	127	(delete-region (point) (progn (skip-chars-forward " \t") (point)))
	128	(or (eolp)
88a2603a	129	(indent-to column 0))
483e630e RM	130	(forward-line 1))
	131	(move-marker end nil))))
	132
	133	(defun indent-relative-maybe ()
	134	"Indent a new line like previous nonblank line."
	135	(interactive)
	136	(indent-relative t))
	137
	138	(defun indent-relative (&optional unindented-ok)
	139	"Space out to under next indent point in previous nonblank line.
	140	An indent point is a non-whitespace character following whitespace.
	141	If the previous nonblank line has no indent points beyond the
	142	column point starts at, `tab-to-tab-stop' is done instead."
	143	(interactive "P")
	144	(if abbrev-mode (expand-abbrev))
	145	(let ((start-column (current-column))
	146	indent)
	147	(save-excursion
	148	(beginning-of-line)
	149	(if (re-search-backward "^[^\n]" nil t)
	150	(let ((end (save-excursion (forward-line 1) (point))))
	151	(move-to-column start-column)
	152	;; Is start-column inside a tab on this line?
	153	(if (> (current-column) start-column)
	154	(backward-char 1))
	155	(or (looking-at "[ \t]")
	156	unindented-ok
	157	(skip-chars-forward "^ \t" end))
	158	(skip-chars-forward " \t" end)
	159	(or (= (point) end) (setq indent (current-column))))))
	160	(if indent
	161	(let ((opoint (point-marker)))
	162	(delete-region (point) (progn (skip-chars-backward " \t") (point)))
	163	(indent-to indent 0)
	164	(if (> opoint (point))
	165	(goto-char opoint))
	166	(move-marker opoint nil))
	167	(tab-to-tab-stop))))
	168
	169	(defvar tab-stop-list
	170	'(8 16 24 32 40 48 56 64 72 80 88 96 104 112 120)
7ad68ead RS	171	"*List of tab stop positions used by `tab-to-tab-stops'.
7ad68ead RS	172	This should be a list of integers, ordered from smallest to largest.")
483e630e RM	173
	174	(defvar edit-tab-stops-map nil "Keymap used in `edit-tab-stops'.")
	175	(if edit-tab-stops-map
	176	nil
	177	(setq edit-tab-stops-map (make-sparse-keymap))
	178	(define-key edit-tab-stops-map "\C-x\C-s" 'edit-tab-stops-note-changes)
	179	(define-key edit-tab-stops-map "\C-c\C-c" 'edit-tab-stops-note-changes))
	180
	181	(defvar edit-tab-stops-buffer nil
	182	"Buffer whose tab stops are being edited--in case
	183	the variable `tab-stop-list' is local in that buffer.")
	184
	185	(defun edit-tab-stops ()
	186	"Edit the tab stops used by `tab-to-tab-stop'.
	187	Creates a buffer Tab Stops containing text describing the tab stops.
	188	A colon indicates a column where there is a tab stop.
	189	You can add or remove colons and then do \\<edit-tab-stops-map>\\[edit-tab-stops-note-changes] to make changes take effect."
	190	(interactive)
	191	(setq edit-tab-stops-buffer (current-buffer))
	192	(switch-to-buffer (get-buffer-create "Tab Stops"))
	193	(use-local-map edit-tab-stops-map)
	194	(make-local-variable 'indent-tabs-mode)
	195	(setq indent-tabs-mode nil)
	196	(overwrite-mode 1)
	197	(setq truncate-lines t)
	198	(erase-buffer)
	199	(let ((tabs tab-stop-list))
	200	(while tabs
	201	(indent-to (car tabs) 0)
	202	(insert ?:)
	203	(setq tabs (cdr tabs))))
	204	(let ((count 0))
	205	(insert ?\n)
	206	(while (< count 8)
	207	(insert (+ count ?0))
	208	(insert " ")
	209	(setq count (1+ count)))
	210	(insert ?\n)
	211	(while (> count 0)
	212	(insert "0123456789")
	213	(setq count (1- count))))
	214	(insert "\nTo install changes, type C-c C-c")
	215	(goto-char (point-min)))
	216
	217	(defun edit-tab-stops-note-changes ()
	218	"Put edited tab stops into effect."
	219	(interactive)
	220	(let (tabs)
	221	(save-excursion
	222	(goto-char 1)
	223	(end-of-line)
	224	(while (search-backward ":" nil t)
	225	(setq tabs (cons (current-column) tabs))))
	226	(bury-buffer (prog1 (current-buffer)
	227	(switch-to-buffer edit-tab-stops-buffer)))
	228	(setq tab-stop-list tabs))
	229	(message "Tab stops installed"))
	230
	231	(defun tab-to-tab-stop ()
	232	"Insert spaces or tabs to next defined tab-stop column.
	233	The variable `tab-stop-list' is a list of columns at which there are tab stops.
	234	Use \\[edit-tab-stops] to edit them interactively."
	235	(interactive)
	236	(if abbrev-mode (expand-abbrev))
237	(let ((tabs tab-stop-list))
238	(while (and tabs (>= (current-column) (car tabs)))
239	(setq tabs (cdr tabs)))
240	(if tabs
9d840bec RS	241	(let ((opoint (point)))
	242	(skip-chars-backward " \t")
	243	(delete-region (point) opoint)
	244	(indent-to (car tabs)))
483e630e RM	245	(insert ?\ ))))
	246
	247	(defun move-to-tab-stop ()
	248	"Move point to next defined tab-stop column.
	249	The variable `tab-stop-list' is a list of columns at which there are tab stops.
	250	Use \\[edit-tab-stops] to edit them interactively."
	251	(interactive)
	252	(let ((tabs tab-stop-list))
	253	(while (and tabs (>= (current-column) (car tabs)))
	254	(setq tabs (cdr tabs)))
	255	(if tabs
f787c66b RS	256	(progn
	257	(if (eq last-command 'move-to-tab-stop)
	258	(let ((opoint (point)))
	259	(skip-chars-backward " \t")
	260	(delete-region (point) opoint)))
	261	(move-to-column (car tabs) t)))))
483e630e RM	262
	263	(define-key global-map "\t" 'indent-for-tab-command)
	264	(define-key esc-map "\034" 'indent-region)
	265	(define-key ctl-x-map "\t" 'indent-rigidly)
	266	(define-key esc-map "i" 'tab-to-tab-stop)
1a06eabd ER	267
1a06eabd ER	268	;;; indent.el ends here