X-Git-Url: http://git.hcoop.net/jackhill/guix/guix.git/blobdiff_plain/ca8dbb7d4e663bcd9aed91606c253ac384124fa5..d17e085a59534a333cb8db028579fd0e6ec7f89b:/config-daemon.ac

diff --git a/config-daemon.ac b/config-daemon.ac
index 6420c86116..42b59819d3 100644
--- a/config-daemon.ac
+++ b/config-daemon.ac
@@ -1,18 +1,17 @@
 dnl -*- Autoconf -*- fragment for the C++ daemon.
 
-AC_ARG_ENABLE([daemon],
-  [AS_HELP_STRING([--enable-daemon], [build the Nix daemon (C++)])],
-  [guix_build_daemon="$enableval"],
-  [guix_build_daemon="no"])
-
 AC_MSG_CHECKING([whether to build daemon])
 AC_MSG_RESULT([$guix_build_daemon])
 
 dnl C++ environment.  This macro must be used unconditionnaly.
 AC_PROG_CXX
+AM_PROG_AR
+AC_LANG([C++])
 
 if test "x$guix_build_daemon" = "xyes"; then
 
+  GUIX_ASSERT_CXX11
+
   AC_PROG_RANLIB
   AC_CONFIG_HEADER([nix/config.h])
 
@@ -35,13 +34,21 @@ if test "x$guix_build_daemon" = "xyes"; then
   case "$LIBGCRYPT_PREFIX" in
     no)
       LIBGCRYPT_CFLAGS=""
-      LIBGCRYPT_LIBS=""
       ;;
     *)
       LIBGCRYPT_CFLAGS="-I$LIBGCRYPT_PREFIX/include"
-      LIBGCRYPT_LIBS="-L$LIBGCRYPT_PREFIX/lib -lgcrypt"
       ;;
   esac
+
+  case "$LIBGCRYPT_LIBDIR" in
+    no)
+      LIBGCRYPT_LIBS="-lgcrypt"
+      ;;
+    *)
+      LIBGCRYPT_LIBS="-L$LIBGCRYPT_LIBDIR -lgcrypt"
+      ;;
+  esac
+
   AC_SUBST([LIBGCRYPT_CFLAGS])
   AC_SUBST([LIBGCRYPT_LIBS])
 
@@ -59,6 +66,104 @@ if test "x$guix_build_daemon" = "xyes"; then
 
   CFLAGS="$save_CFLAGS"
   LDFLAGS="$save_LDFLAGS"
+
+  dnl Chroot support.
+  AC_CHECK_FUNCS([chroot unshare])
+  AC_CHECK_HEADERS([sched.h sys/param.h sys/mount.h sys/syscall.h])
+
+  if test "x$ac_cv_func_chroot" != "xyes"; then
+    AC_MSG_ERROR(['chroot' function missing, bailing out])
+  fi
+
+  dnl lutimes and lchown: used when canonicalizing store items.
+  dnl posix_fallocate: used when extracting archives.
+  dnl vfork: to speed up spawning of helper programs.
+  dnl   `--> now disabled because of unpredictable behavior:
+  dnl        see <http://lists.gnu.org/archive/html/guix-devel/2014-05/msg00036.html>
+  dnl        and Nix commit f794465c (Nov. 2012).
+  dnl sched_setaffinity: to improve RPC locality.
+  dnl statvfs: to detect disk-full conditions.
+  dnl strsignal: for error reporting.
+  AC_CHECK_FUNCS([lutimes lchown posix_fallocate sched_setaffinity \
+     statvfs nanosleep strsignal])
+
+  dnl Check whether the store optimiser can optimise symlinks.
+  AC_MSG_CHECKING([whether it is possible to create a link to a symlink])
+  ln -s bla tmp_link
+  if ln tmp_link tmp_link2 2> /dev/null; then
+      AC_MSG_RESULT(yes)
+      AC_DEFINE(CAN_LINK_SYMLINK, 1, [Whether link() works on symlinks.])
+  else
+      AC_MSG_RESULT(no)
+  fi
+  rm -f tmp_link tmp_link2
+
+  dnl Check for <locale>.
+  AC_LANG_PUSH(C++)
+  AC_CHECK_HEADERS([locale])
+  AC_LANG_POP(C++)
+
+
+  dnl Check whether we have the `personality' syscall, which allows us
+  dnl to do i686-linux builds on x86_64-linux machines.
+  AC_CHECK_HEADERS([sys/personality.h])
+
+  dnl Check for <linux/fs.h> (for immutable file support).
+  AC_CHECK_HEADERS([linux/fs.h])
+
+  dnl Determine the appropriate default list of substitute URLs.
+  GUILE_MODULE_AVAILABLE([have_gnutls], [(gnutls)])
+  if test "x$have_gnutls" = "xyes"; then
+    guix_substitute_urls="https://mirror.hydra.gnu.org"
+  else
+    AC_MSG_WARN([GnuTLS is missing, substitutes will be downloaded in the clear])
+    guix_substitute_urls="http://mirror.hydra.gnu.org"
+  fi
+  AC_MSG_CHECKING([for default substitute URLs])
+  AC_MSG_RESULT([$guix_substitute_urls])
+
+  AC_DEFINE_UNQUOTED([GUIX_SUBSTITUTE_URLS], ["$guix_substitute_urls"],
+    [Default list of substitute URLs used by 'guix-daemon'.])
+
+  dnl Check whether the 'offload' build hook can be built (uses
+  dnl 'restore-file-set', which requires unbuffered custom binary input
+  dnl ports from Guile >= 2.0.10.)
+  GUIX_CHECK_UNBUFFERED_CBIP
+
+  dnl Check for Guile-SSH, which is required by 'guix offload'.
+  GUIX_CHECK_GUILE_SSH
+
+  case "x$ac_cv_guix_cbips_support_setvbuf$guix_cv_have_recent_guile_ssh" in
+    xyesyes)
+      guix_build_daemon_offload="yes"
+      AC_DEFINE([HAVE_DAEMON_OFFLOAD_HOOK], [1],
+	[Define if the daemon's 'offload' build hook is being built (requires Guile-SSH).])
+      ;;
+    *)
+      guix_build_daemon_offload="no"
+      ;;
+  esac
+
+  dnl Temporary directory used to store the daemon's data.
+  GUIX_TEST_ROOT_DIRECTORY
+  GUIX_TEST_ROOT="$ac_cv_guix_test_root"
+  AC_SUBST([GUIX_TEST_ROOT])
+
+  GUIX_CHECK_LOCALSTATEDIR
+
+  AC_CONFIG_FILES([nix/scripts/list-runtime-roots],
+    [chmod +x nix/scripts/list-runtime-roots])
+  AC_CONFIG_FILES([nix/scripts/download],
+    [chmod +x nix/scripts/download])
+  AC_CONFIG_FILES([nix/scripts/substitute],
+    [chmod +x nix/scripts/substitute])
+  AC_CONFIG_FILES([nix/scripts/guix-authenticate],
+    [chmod +x nix/scripts/guix-authenticate])
+  AC_CONFIG_FILES([nix/scripts/offload],
+    [chmod +x nix/scripts/offload])
 fi
 
 AM_CONDITIONAL([BUILD_DAEMON], [test "x$guix_build_daemon" = "xyes"])
+AM_CONDITIONAL([BUILD_DAEMON_OFFLOAD],			\
+  [test "x$guix_build_daemon" = "xyes"			\
+   && test "x$guix_build_daemon_offload" = "xyes"])