build-aux/git-authenticate.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2019, 2020 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 ;;;
  20 ;;; Authenticate a range of commits.
  21 ;;;
  22
  23 (use-modules (git)
  24              (guix git)
  25              (guix gnupg)
  26              (guix utils)
  27              ((guix build utils) #:select (mkdir-p))
  28              (guix i18n)
  29              (guix progress)
  30              (srfi srfi-1)
  31              (srfi srfi-11)
  32              (srfi srfi-26)
  33              (srfi srfi-34)
  34              (srfi srfi-35)
  35              (rnrs io ports)
  36              (ice-9 match)
  37              (ice-9 format)
  38              (ice-9 pretty-print))
  39
  40 \f
  41 (define %committers
  42   ;; List of committers.  These are the user names found on
  43   ;; <https://savannah.gnu.org/project/memberlist.php?group=guix> along with
  44   ;; the fingerprint of the signing (sub)key.
  45   ;;
  46   ;; TODO: Replace this statically-defined list by an in-repo list.
  47   '(("andreas"
  48      "AD17 A21E F8AE D8F1 CC02  DBD9 F7D5 C9BF 765C 61E3")
  49     ("ajgrf"
  50      "2A39 3FFF 68F4 EF7A 3D29  12AF 6F51 20A0 22FB B2D5")
  51     ("alexvong1995"
  52      "306F CB8F 2C01 C25D 29D3  0556 61EF 502E F602 52F2")
  53     ("alezost"
  54      "4FB9 9F49 2B12 A365 7997  E664 8246 0C08 2A0E E98F")
  55     ("ambrevar"
  56      "50F3 3E2E 5B0C 3D90 0424  ABE8 9BDC F497 A4BB CC7F")
  57     ("apteryx"
  58      "27D5 86A4 F890 0854 329F  F09F 1260 E464 82E6 3562")
  59     ("arunisaac"
  60      "7F73 0343 F2F0 9F3C 77BF  79D3 2E25 EE8B 6180 2BB3")
  61     ("atheia"
  62      ;; primary: "3B12 9196 AE30 0C3C 0E90  A26F A715 5567 3271 9948"
  63      "9A2B 401E D001 0650 1584  BAAC 8BC4 F447 6E8A 8E00")
  64     ("bavier"
  65      ;; primary: "34FF 38BC D151 25A6 E340  A0B5 3453 2F9F AFCA 8B8E"
  66      "A0C5 E352 2EF8 EF5C 64CD  B7F0 FD73 CAC7 19D3 2566")
  67     ("beffa"
  68      "3774 8024 880F D3FF DCA2  C9AB 5893 6E0E 2F1B 5A4C")
  69     ("benwoodcroft"
  70      "BCF8 F737 2CED 080A 67EB  592D 2A6A D9F4 AAC2 0DF6")
  71     ("biscuolo"
  72      "45CC 63B8 5258 C9D5 5F34  B239 D37D 0EA7 CECC 3912")
  73     ("boskovits"
  74      "7988 3B9F 7D6A 4DBF 3719  0367 2506 A96C CF63 0B21")
  75     ("brettgilio"
  76      "DFC0 C7F7 9EE6 0CA7 AE55  5E19 6722 43C4 A03F 0EEE")
  77     ("carl"
  78      ;; primary: "0401 7A2A 6D9A 0CCD C81D  8EC2 96AB 007F 1A7E D999"
  79      "09CD D25B 5244 A376 78F6  EEA8 0CC5 2153 1979 91A5")
  80     ("cbaines"
  81      "3E89 EEE7 458E 720D 9754  E0B2 5E28 A33B 0B84 F577")
  82     ("civodul"
  83      "3CE4 6455 8A84 FDC6 9DB4  0CFB 090B 1199 3D9A EBB5")
  84     ("cwebber"
  85      "510A 8628 E2A7 7678 8F8C  709C 4BC0 2592 5FF8 F4D3")
  86     ("dannym"
  87      ;; primary: "295A F991 6F46 F8A1 34B0  29DA 8086 3842 F0FE D83B"
  88      "76CE C6B1 7274 B465 C02D  B3D9 E71A 3554 2C30 BAA5")
  89     ("davexunit"
  90      "B3C0 DB4D AD73 BA5D 285E  19AE 5143 0234 CEFD 87C3")
  91     ("davexunit (2nd)"                            ;FIXME: to be confirmed!
  92      "8CCB A7F5 52B9 CBEA E1FB  2915 8328 C747 0FF1 D807")
  93     ("daviwil"
  94      "53C4 1E6E 41AA FE55 335A  CA5E 446A 2ED4 D940 BF14")
  95     ("dvc"
  96      "6909 6DFD D702 8BED ACC5  884B C5E0 51C7 9C0B ECDB")
  97     ("dvc (old)"
  98      "5F43 B681 0437 2F4B A898  A64B 33B9 E9FD E28D 2C23")
  99     ("efraim"
 100      "A28B F40C 3E55 1372 662D  14F7 41AA E7DC CA3D 8351")
 101     ("efraim (old)"
 102      "9157 41FE B22F A4E3 3B6E  8F8D F4C1 D391 7EAC EE93")
 103     ("glv"
 104      ;; primary: "2453 02B1 BAB1 F867 FDCA  96BC 8F3F 861F 82EB 7A9A"
 105      "CBC5 9C66 EC27 B971 7940  6B3E 6BE8 208A DF21 FE3F")
 106     ("hoebjo"
 107      "2219 43F4 9E9F 276F 9499  3382 BF28 6CB6 593E 5FFD")
 108     ("htgoebel"
 109      "B943 509D 633E 80DD 27FC  4EED 634A 8DFF D3F6 31DF")
 110     ("ipetkov"
 111      "7440 26BA 7CA3 C668 E940  1D53 0B43 1E98 3705 6942")
 112     ("iyzsong"
 113      ;; primary: "66A5 6D9C 9A98 BE7F 719A  B401 2652 5665 AE72 7D37"
 114      "0325 78A6 8298 94E7 2AA2  66F5 D415 BF25 3B51 5976")
 115
 116     ;; https://lists.gnu.org/archive/html/guix-devel/2018-04/msg00229.html
 117     ("janneke (old)"
 118      "DB34 CB51 D25C 9408 156F  CDD6 A12F 8797 8D70 1B99")
 119     ("janneke"
 120      "1A85 8392 E331 EAFD B8C2  7FFB F3C1 A0D9 C1D6 5273")
 121
 122     ("jlicht"
 123      ;; primary: "1BA4 08C5 8BF2 0EA7 3179  635A 865D C0A3 DED9 B5D0"
 124      "E31D 9DDE EBA5 4A14 8A20  4550 DA45 97F9 47B4 1025")
 125     ("jmd"
 126      "8797 A26D 0854 2EAB 0285  A290 8A67 719C 2DE8 27B3")
 127     ("kkebreau"
 128      "83B6 703A DCCA 3B69 4BCE  2DA6 E6A5 EE3C 1946 7A0D")
 129     ("leungbk"
 130      "45E5 75FA 53EA 8BD6 1BCE  0B4E 3ADC 75F0 13D6 78F9")
 131     ("lfam"
 132      ;; primary: "4F71 6F9A 8FA2 C80E F1B5  E1BA 5E35 F231 DE1A C5E0"
 133      "B051 5948 F1E7 D3C1 B980  38A0 2646 FA30 BACA 7F08")
 134     ("lsl88"
 135      "2AE3 1395 932B E642 FC0E  D99C 9BED 6EDA 32E5 B0BC")
 136     ("mab"
 137      "BE62 7373 8E61 6D6D 1B3A  08E8 A21A 0202 4881 6103")
 138     ("marusich"
 139      "CBF5 9755 CBE7 E7EF EF18  3FB1 DD40 9A15 D822 469D")
 140     ("mbakke"
 141      "BBB0 2DDF 2CEA F6A8 0D1D  E643 A2A0 6DF2 A33A 54FA")
 142     ("mhw"
 143      "D919 0965 CE03 199E AF28  B3BE 7CEF 2984 7562 C516")
 144     ("mothacehe"
 145      "4008 6A7E 0252 9B60 31FB  8607 8354 7635 3176 9CA6")
 146     ("mthl"
 147      "F2A3 8D7E EB2B 6640 5761  070D 0ADE E100 9460 4D37")
 148     ("nckx"
 149      ;; primary: "F5BC 5534 C36F 0087 B39D  36EF 1C9D C4FE B9DB 7C4B"
 150      "7E8F AED0 0944 78EF 72E6  4D16 D889 B0F0 18C5 493C")
 151     ("nckx (2nd)"
 152      ;; primary: "F5BC 5534 C36F 0087 B39D  36EF 1C9D C4FE B9DB 7C4B"
 153      "F5DA 2032 4B87 3D0B 7A38  7672 0DB0 FF88 4F55 6D79")
 154     ("niedzejkob"
 155      "E576 BFB2 CF6E B13D F571  33B9 E315 A758 4613 1564")
 156     ("ngz"
 157      "ED0E F1C8 E126 BA83 1B48  5FE9 DA00 B4F0 48E9 2F2D")
 158     ("pelzflorian"
 159      "CEF4 CB91 4856 BA38 0A20  A7E2 3008 88CB 39C6 3817")
 160     ("pgarlick"
 161      ;; primary: "B68B DF22 73F9 DA0E 63C1  8A32 515B F416 9242 D600"
 162      "C699 ED09 E51B CE89 FD1D  A078 AAC7 E891 896B 568A")
 163     ("phant0mas"
 164      "3A86 380E 58A8 B942 8D39  60E1 327C 1EF3 8DF5 4C32")
 165     ("reepca"
 166      "74D6 A930 F44B 9B84 9EA5  5606 C166 AA49 5F7F 189C")
 167     ("rekado"
 168      "BCA6 89B6 3655 3801 C3C6  2150 197A 5888 235F ACAC")
 169     ("rhelling"
 170      "0154 E1B9 1CC9 D9EF 7764  8DE7 F3A7 27DB 44FC CA36")
 171     ("roelj"
 172      "17CB 2812 EB63 3DFF 2C7F  0452 C3EC 1DCA 8430 72E1")
 173     ("roptat (old)"
 174      "B5FA E628 5B41 3728 B2A0  FAED 4311 1F45 2008 6A0C")
 175     ("roptat"
 176      ;; From commit 2cbede5935eb6a40173bbdf30a9ad22bf7574c22 (Jan. 2020).  See
 177      ;; <https://lists.gnu.org/archive/html/guix-devel/2020-01/msg00499.html>.
 178      "1EFB 0909 1F17 D28C CBF9  B13A 53D4 57B2 D636 EE82")
 179     ("samplet"
 180      ;; primary: "D6B0 C593 DA8C 5EDC A44C  7A58 C336 91F7 1188 B004"
 181      "A02C 2D82 0EF4 B25B A6B5  1D90 2AC6 A5EC 1C35 7C59")
 182     ("sleep_walker"
 183      "77DD AD2D 97F5 31BB C0F3  C7FD DFB5 EB09 AA62 5423")
 184     ("snape"
 185      "F494 72F4 7A59 00D5 C235  F212 89F9 6D48 08F3 59C7")
 186     ("snape"
 187      "F494 72F4 7A59 00D5 C235  F212 89F9 6D48 08F3 59C7")
 188     ("steap"
 189      "4E26 CCE9 578E 0828 9855  BDD4 1C79 95D2 D5A3 8336")
 190     ("taylanub"
 191      "9ADE 9ECF 2B19 C180 9C99  5CEA A1F4 CFCC 5283 6BAC")
 192
 193     ;; https://lists.gnu.org/archive/html/guix-devel/2017-03/msg00826.html
 194     ("thomasd"
 195      "1DD1 681F E285 E07F 11DC  0C59 2E15 A6BC D77D 54FD")
 196     ("thomasd (old)"
 197      "A5C5 92EA 606E 7106 A6A3  BC08 98B2 1575 91E1 2B08")
 198
 199     ("toothbrush"
 200      "D712 1D73 A40A 7264 9E43  ED7D F284 6B1A 0D32 C442")
 201     ("vagrantc"
 202      "6580 7361 3BFC C5C7 E2E4  5D45 DC51 8FC8 7F97 16AA")
 203     ("wigust"
 204      ;; primary: "C955 CC5D C048 7FB1 7966  40A9 199A F6A3 67E9 4ABB"
 205      "7238 7123 8EAC EB63 4548  5857 167F 8EA5 001A FA9C")
 206     ("wingo"
 207      "FF47 8FB2 64DE 32EC 2967  25A3 DDC0 F535 8812 F8F2")))
 208
 209 (define %authorized-signing-keys
 210   ;; Fingerprint of authorized signing keys.
 211   (map (match-lambda
 212          ((name fingerprint)
 213           (string-filter char-set:graphic fingerprint)))
 214        %committers))
 215
 216 (define %commits-with-bad-signature
 217   ;; Commits with a known-bad signature.
 218   '("6a34f4ccc8a5d4a48e25ad3c9c512f8634928b91"))  ;2016-12-29
 219
 220 (define %unsigned-commits
 221   ;; Commits lacking a signature.
 222   '())
 223
 224 (define-syntax-rule (with-temporary-files file1 file2 exp ...)
 225   (call-with-temporary-output-file
 226    (lambda (file1 port1)
 227      (call-with-temporary-output-file
 228       (lambda (file2 port2)
 229         exp ...)))))
 230
 231 (define (commit-signing-key repo commit-id)
 232   "Return the OpenPGP key ID that signed COMMIT-ID (an OID).  Raise an
 233 exception if the commit is unsigned or has an invalid signature."
 234   (let-values (((signature signed-data)
 235                 (catch 'git-error
 236                   (lambda ()
 237                     (commit-extract-signature repo commit-id))
 238                   (lambda _
 239                     (values #f #f)))))
 240     (if (not signature)
 241         (raise (condition
 242                 (&message
 243                  (message (format #f (G_ "commit ~a lacks a signature")
 244                                   commit-id)))))
 245         (begin
 246           (with-fluids ((%default-port-encoding "UTF-8"))
 247             (with-temporary-files data-file signature-file
 248               (call-with-output-file data-file
 249                 (cut display signed-data <>))
 250               (call-with-output-file signature-file
 251                 (cut display signature <>))
 252
 253               (let-values (((status data)
 254                             (with-error-to-port (%make-void-port "w")
 255                               (lambda ()
 256                                 (gnupg-verify* signature-file data-file
 257                                                #:key-download 'always)))))
 258                 (match status
 259                   ('invalid-signature
 260                    ;; There's a signature but it's invalid.
 261                    (raise (condition
 262                            (&message
 263                             (message (format #f (G_ "signature verification failed \
 264 for commit ~a")
 265                                              (oid->string commit-id)))))))
 266                   ('missing-key
 267                    (raise (condition
 268                            (&message
 269                             (message (format #f (G_ "could not authenticate \
 270 commit ~a: key ~a is missing")
 271                                              (oid->string commit-id)
 272                                              data))))))
 273                   ('valid-signature
 274                    (match data
 275                      ((fingerprint . user)
 276                       fingerprint)))))))))))
 277
 278 (define (authenticate-commit repository commit)
 279   "Authenticate COMMIT from REPOSITORY and return the signing key fingerprint.
 280 Raise an error when authentication fails."
 281   (define id
 282     (commit-id commit))
 283
 284   (define signing-key
 285     (commit-signing-key repository id))
 286
 287   (unless (member signing-key %authorized-signing-keys)
 288     (raise (condition
 289             (&message
 290              (message (format #f (G_ "commit ~a not signed by an authorized \
 291 key: ~a")
 292                               (oid->string id) signing-key))))))
 293
 294   signing-key)
 295
 296 (define* (authenticate-commits repository commits
 297                                #:key (report-progress (const #t)))
 298   "Authenticate COMMITS, a list of commit objects, calling REPORT-PROGRESS for
 299 each of them.  Return an alist showing the number of occurrences of each key."
 300   (parameterize ((current-keyring (string-append (config-directory)
 301                                                  "/keyrings/channels/guix.kbx")))
 302     (fold (lambda (commit stats)
 303             (report-progress)
 304             (let ((signer (authenticate-commit repository commit)))
 305               (match (assoc signer stats)
 306                 (#f          (cons `(,signer . 1) stats))
 307                 ((_ . count) (cons `(,signer . ,(+ count 1))
 308                                    (alist-delete signer stats))))))
 309           '()
 310           commits)))
 311
 312 (define commit-short-id
 313   (compose (cut string-take <> 7) oid->string commit-id))
 314
 315 \f
 316 ;;;
 317 ;;; Caching.
 318 ;;;
 319
 320 (define (authenticated-commit-cache-file)
 321   "Return the name of the file that contains the cache of
 322 previously-authenticated commits."
 323   (string-append (cache-directory) "/authentication/channels/guix"))
 324
 325 (define (previously-authenticated-commits)
 326   "Return the previously-authenticated commits as a list of commit IDs (hex
 327 strings)."
 328   (catch 'system-error
 329     (lambda ()
 330       (call-with-input-file (authenticated-commit-cache-file)
 331         read))
 332     (lambda args
 333       (if (= ENOENT (system-error-errno args))
 334           '()
 335           (apply throw args)))))
 336
 337 (define (cache-authenticated-commit commit-id)
 338   "Record in ~/.cache COMMIT-ID and its closure as authenticated (only
 339 COMMIT-ID is written to cache, though)."
 340   (define %max-cache-length
 341     ;; Maximum number of commits in cache.
 342     200)
 343
 344   (let ((lst  (delete-duplicates
 345                (cons commit-id (previously-authenticated-commits))))
 346         (file (authenticated-commit-cache-file)))
 347     (mkdir-p (dirname file))
 348     (with-atomic-file-output file
 349       (lambda (port)
 350         (let ((lst (if (> (length lst) %max-cache-length)
 351                        (take lst %max-cache-length) ;truncate
 352                        lst)))
 353           (chmod port #o600)
 354           (display ";; List of previously-authenticated commits.\n\n"
 355                    port)
 356           (pretty-print lst port))))))
 357
 358 \f
 359 ;;;
 360 ;;; Entry point.
 361 ;;;
 362
 363 (define (git-authenticate args)
 364   (define repository
 365     (repository-open "."))
 366
 367   (let loop ((args args))
 368     (match args
 369       ((_ start end)
 370        (define start-commit
 371          (commit-lookup repository (string->oid start)))
 372        (define end-commit
 373          (commit-lookup repository (string->oid end)))
 374
 375        (define authenticated-commits
 376          ;; Previously-authenticated commits that don't need to be checked
 377          ;; again.
 378          (filter-map (lambda (id)
 379                        (false-if-exception
 380                         (commit-lookup repository (string->oid id))))
 381                      (previously-authenticated-commits)))
 382
 383        (define commits
 384          ;; Commits to authenticate, excluding the closure of
 385          ;; AUTHENTICATED-COMMITS.
 386          (commit-difference end-commit start-commit
 387                             authenticated-commits))
 388
 389        (define reporter
 390          (progress-reporter/bar (length commits)))
 391
 392        (format #t (G_ "Authenticating ~a to ~a (~a commits)...~%")
 393                (commit-short-id start-commit)
 394                (commit-short-id end-commit)
 395                (length commits))
 396
 397        (let ((stats (call-with-progress-reporter reporter
 398                       (lambda (report)
 399                         (authenticate-commits repository commits
 400                                               #:report-progress report)))))
 401          (cache-authenticated-commit (oid->string (commit-id end-commit)))
 402
 403          (unless (null? stats)
 404            (format #t (G_ "Signing statistics:~%"))
 405            (for-each (match-lambda
 406                        ((signer . count)
 407                         (format #t "  ~a ~10d~%" signer count)))
 408                      (sort stats
 409                            (match-lambda*
 410                              (((_ . count1) (_ . count2))
 411                               (> count1 count2))))))))
 412       ((command start)
 413        (let* ((head (repository-head repository))
 414               (end  (reference-target head)))
 415          (loop (list command start (oid->string end)))))
 416       (_
 417        (format (current-error-port)
 418                (G_ "Usage: git-authenticate START [END]
 419
 420 Authenticate commits START to END or the current head.\n"))))))
 421
 422 ;;; Local Variables:
 423 ;;; eval: (put 'with-temporary-files 'scheme-indent-function 2)
 424 ;;; End: