guix/grafts.scm

   1 ;;; GNU Guix --- Functional package management for GNU
   2 ;;; Copyright © 2014, 2015, 2016, 2017, 2018 Ludovic Courtès <ludo@gnu.org>
   3 ;;;
   4 ;;; This file is part of GNU Guix.
   5 ;;;
   6 ;;; GNU Guix is free software; you can redistribute it and/or modify it
   7 ;;; under the terms of the GNU General Public License as published by
   8 ;;; the Free Software Foundation; either version 3 of the License, or (at
   9 ;;; your option) any later version.
  10 ;;;
  11 ;;; GNU Guix is distributed in the hope that it will be useful, but
  12 ;;; WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;; GNU General Public License for more details.
  15 ;;;
  16 ;;; You should have received a copy of the GNU General Public License
  17 ;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-module (guix grafts)
  20   #:use-module (guix store)
  21   #:use-module (guix monads)
  22   #:use-module (guix records)
  23   #:use-module (guix derivations)
  24   #:use-module ((guix utils) #:select (%current-system))
  25   #:use-module (srfi srfi-1)
  26   #:use-module (srfi srfi-9 gnu)
  27   #:use-module (srfi srfi-11)
  28   #:use-module (srfi srfi-26)
  29   #:use-module (srfi srfi-34)
  30   #:use-module (ice-9 match)
  31   #:use-module (ice-9 vlist)
  32   #:export (graft?
  33             graft
  34             graft-origin
  35             graft-replacement
  36             graft-origin-output
  37             graft-replacement-output
  38
  39             graft-derivation
  40             graft-derivation/shallow
  41
  42             %graft?
  43             set-grafting))
  44
  45 (define-record-type* <graft> graft make-graft
  46   graft?
  47   (origin             graft-origin)               ;derivation | store item
  48   (origin-output      graft-origin-output         ;string | #f
  49                       (default "out"))
  50   (replacement        graft-replacement)          ;derivation | store item
  51   (replacement-output graft-replacement-output    ;string | #f
  52                       (default "out")))
  53
  54 (define (write-graft graft port)
  55   "Write a concise representation of GRAFT to PORT."
  56   (define (->string thing output)
  57     (if (derivation? thing)
  58         (derivation->output-path thing output)
  59         thing))
  60
  61   (match graft
  62     (($ <graft> origin origin-output replacement replacement-output)
  63      (format port "#<graft ~a ==> ~a ~a>"
  64              (->string origin origin-output)
  65              (->string replacement replacement-output)
  66              (number->string (object-address graft) 16)))))
  67
  68 (set-record-type-printer! <graft> write-graft)
  69
  70 (define (graft-origin-file-name graft)
  71   "Return the output file name of the origin of GRAFT."
  72   (match graft
  73     (($ <graft> (? derivation? origin) output)
  74      (derivation->output-path origin output))
  75     (($ <graft> (? string? item))
  76      item)))
  77
  78 (define* (graft-derivation/shallow store drv grafts
  79                                    #:key
  80                                    (name (derivation-name drv))
  81                                    (outputs (derivation-output-names drv))
  82                                    (guile (%guile-for-build))
  83                                    (system (%current-system)))
  84   "Return a derivation called NAME, which applies GRAFTS to the specified
  85 OUTPUTS of DRV.  This procedure performs \"shallow\" grafting in that GRAFTS
  86 are not recursively applied to dependencies of DRV."
  87   ;; XXX: Someday rewrite using gexps.
  88   (define mapping
  89     ;; List of store item pairs.
  90     (map (match-lambda
  91           (($ <graft> source source-output target target-output)
  92            (cons (if (derivation? source)
  93                      (derivation->output-path source source-output)
  94                      source)
  95                  (if (derivation? target)
  96                      (derivation->output-path target target-output)
  97                      target))))
  98          grafts))
  99
 100   (define output-pairs
 101     (map (lambda (output)
 102            (cons output
 103                  (derivation-output-path
 104                   (assoc-ref (derivation-outputs drv) output))))
 105          outputs))
 106
 107   (define build
 108     `(begin
 109        (use-modules (guix build graft)
 110                     (guix build utils)
 111                     (ice-9 match))
 112
 113        (let* ((old-outputs ',output-pairs)
 114               (mapping (append ',mapping
 115                                (map (match-lambda
 116                                       ((name . file)
 117                                        (cons (assoc-ref old-outputs name)
 118                                              file)))
 119                                     %outputs))))
 120          (graft old-outputs %outputs mapping))))
 121
 122   (define add-label
 123     (cut cons "x" <>))
 124
 125   (match grafts
 126     ((($ <graft> sources source-outputs targets target-outputs) ...)
 127      (let ((sources (zip sources source-outputs))
 128            (targets (zip targets target-outputs)))
 129        (build-expression->derivation store name build
 130                                      #:system system
 131                                      #:guile-for-build guile
 132                                      #:modules '((guix build graft)
 133                                                  (guix build utils))
 134                                      #:inputs `(,@(map (lambda (out)
 135                                                          `("x" ,drv ,out))
 136                                                        outputs)
 137                                                 ,@(append (map add-label sources)
 138                                                           (map add-label targets)))
 139                                      #:outputs outputs
 140                                      #:local-build? #t)))))
 141 (define (item->deriver store item)
 142   "Return two values: the derivation that led to ITEM (a store item), and the
 143 name of the output of that derivation ITEM corresponds to (for example
 144 \"out\").  When ITEM has no deriver, for instance because it is a plain file,
 145 #f and #f are returned."
 146   (match (valid-derivers store item)
 147     (()                                           ;ITEM is a plain file
 148      (values #f #f))
 149     ((drv-file _ ...)
 150      (let ((drv (read-derivation-from-file drv-file)))
 151        (values drv
 152                (any (match-lambda
 153                       ((name . path)
 154                        (and (string=? item path) name)))
 155                     (derivation->output-paths drv)))))))
 156
 157 (define (non-self-references references drv outputs)
 158   "Return the list of references of the OUTPUTS of DRV, excluding self
 159 references.  Call REFERENCES to get the list of references."
 160   (let ((refs (append-map (compose references
 161                                    (cut derivation->output-path drv <>))
 162                           outputs))
 163         (self (match (derivation->output-paths drv)
 164                 (((names . items) ...)
 165                  items))))
 166     (remove (cut member <> self) refs)))
 167
 168 (define (references-oracle store drv)
 169   "Return a one-argument procedure that, when passed the file name of DRV's
 170 outputs or their dependencies, returns the list of references of that item.
 171 Use either local info or substitute info; build DRV if no information is
 172 available."
 173   (define (output-paths drv)
 174     (match (derivation->output-paths drv)
 175       (((names . items) ...)
 176        items)))
 177
 178   (define (references* items)
 179     (guard (c ((nix-protocol-error? c)
 180                ;; As a last resort, build DRV and query the references of the
 181                ;; build result.
 182
 183                ;; Warm up the narinfo cache, otherwise each derivation build
 184                ;; will result in one HTTP request to get one narinfo, which is
 185                ;; much less efficient than fetching them all upfront.
 186                (substitution-oracle store (list drv))
 187
 188                (and (build-derivations store (list drv))
 189                     (map (cut references store <>) items))))
 190       (references/substitutes store items)))
 191
 192   (let loop ((items (output-paths drv))
 193              (result vlist-null))
 194     (match items
 195       (()
 196        (lambda (item)
 197          (match (vhash-assoc item result)
 198            ((_ . refs) refs)
 199            (#f         #f))))
 200       (_
 201        (let* ((refs   (references* items))
 202               (result (fold vhash-cons result items refs)))
 203          (loop (remove (cut vhash-assoc <> result)
 204                        (delete-duplicates (concatenate refs) string=?))
 205                result))))))
 206
 207 (define-syntax-rule (with-cache key exp ...)
 208   "Cache the value of monadic expression EXP under KEY."
 209   (mlet %state-monad ((cache (current-state)))
 210     (match (vhash-assoc key cache)
 211       ((_ . result)                               ;cache hit
 212        (return result))
 213       (#f                                         ;cache miss
 214        (mlet %state-monad ((result (begin exp ...))
 215                            (cache  (current-state)))
 216          (mbegin %state-monad
 217            (set-current-state (vhash-cons key result cache))
 218            (return result)))))))
 219
 220 (define* (cumulative-grafts store drv grafts
 221                             references
 222                             #:key
 223                             (outputs (derivation-output-names drv))
 224                             (guile (%guile-for-build))
 225                             (system (%current-system)))
 226   "Augment GRAFTS with additional grafts resulting from the application of
 227 GRAFTS to the dependencies of DRV; REFERENCES must be a one-argument procedure
 228 that returns the list of references of the store item it is given.  Return the
 229 resulting list of grafts.
 230
 231 This is a monadic procedure in %STATE-MONAD where the state is a vhash mapping
 232 derivations to the corresponding set of grafts."
 233   (define (graft-origin? drv graft)
 234     ;; Return true if DRV corresponds to the origin of GRAFT.
 235     (match graft
 236       (($ <graft> (? derivation? origin) output)
 237        (match (assoc-ref (derivation->output-paths drv) output)
 238          ((? string? result)
 239           (string=? result
 240                     (derivation->output-path origin output)))
 241          (_
 242           #f)))
 243       (_
 244        #f)))
 245
 246   (define (dependency-grafts item)
 247     (let-values (((drv output) (item->deriver store item)))
 248       (if drv
 249           ;; If GRAFTS already contains a graft from DRV, do not override it.
 250           (if (find (cut graft-origin? drv <>) grafts)
 251               (state-return grafts)
 252               (cumulative-grafts store drv grafts references
 253                                  #:outputs (list output)
 254                                  #:guile guile
 255                                  #:system system))
 256           (state-return grafts))))
 257
 258   (with-cache (cons (derivation-file-name drv) outputs)
 259     (match (non-self-references references drv outputs)
 260       (()                                         ;no dependencies
 261        (return grafts))
 262       (deps                                       ;one or more dependencies
 263        (mlet %state-monad ((grafts (mapm %state-monad dependency-grafts deps)))
 264          (let ((grafts (delete-duplicates (concatenate grafts) equal?)))
 265            (match (filter (lambda (graft)
 266                             (member (graft-origin-file-name graft) deps))
 267                           grafts)
 268              (()
 269               (return grafts))
 270              ((applicable ..1)
 271               ;; Use APPLICABLE, the subset of GRAFTS that is really
 272               ;; applicable to DRV, to avoid creating several identical
 273               ;; grafted variants of DRV.
 274               (let* ((new    (graft-derivation/shallow store drv applicable
 275                                                        #:outputs outputs
 276                                                        #:guile guile
 277                                                        #:system system))
 278                      (grafts (append (map (lambda (output)
 279                                             (graft
 280                                               (origin drv)
 281                                               (origin-output output)
 282                                               (replacement new)
 283                                               (replacement-output output)))
 284                                           outputs)
 285                                      grafts)))
 286                 (return grafts))))))))))
 287
 288 (define* (graft-derivation store drv grafts
 289                            #:key
 290                            (guile (%guile-for-build))
 291                            (outputs (derivation-output-names drv))
 292                            (system (%current-system)))
 293   "Apply GRAFTS to the OUTPUTS of DRV and all their dependencies, recursively.
 294 That is, if GRAFTS apply only indirectly to DRV, graft the dependencies of
 295 DRV, and graft DRV itself to refer to those grafted dependencies."
 296
 297   ;; First, pre-compute the dependency tree of the outputs of DRV.  Do this
 298   ;; upfront to have as much parallelism as possible when querying substitute
 299   ;; info or when building DRV.
 300   (define references
 301     (references-oracle store drv))
 302
 303   (match (run-with-state
 304              (cumulative-grafts store drv grafts references
 305                                 #:outputs outputs
 306                                 #:guile guile #:system system)
 307            vlist-null)                            ;the initial cache
 308     ((first . rest)
 309      ;; If FIRST is not a graft for DRV, it means that GRAFTS are not
 310      ;; applicable to DRV and nothing needs to be done.
 311      (if (equal? drv (graft-origin first))
 312          (graft-replacement first)
 313          drv))))
 314
 315 \f
 316 ;; The following might feel more at home in (guix packages) but since (guix
 317 ;; gexp), which is a lower level, needs them, we put them here.
 318
 319 (define %graft?
 320   ;; Whether to honor package grafts by default.
 321   (make-parameter #t))
 322
 323 (define (set-grafting enable?)
 324   "This monadic procedure enables grafting when ENABLE? is true, and disables
 325 it otherwise.  It returns the previous setting."
 326   (lambda (store)
 327     (values (%graft? enable?) store)))
 328
 329 ;; Local Variables:
 330 ;; eval: (put 'with-cache 'scheme-indent-function 1)
 331 ;; End:
 332
 333 ;;; grafts.scm ends here