| 1 | dnl -*- Autoconf -*- fragment for the C++ daemon. |
| 2 | |
| 3 | AC_ARG_ENABLE([daemon], |
| 4 | [AS_HELP_STRING([--enable-daemon], [build the Nix daemon (C++)])], |
| 5 | [guix_build_daemon="$enableval"], |
| 6 | [guix_build_daemon="no"]) |
| 7 | |
| 8 | AC_MSG_CHECKING([whether to build daemon]) |
| 9 | AC_MSG_RESULT([$guix_build_daemon]) |
| 10 | |
| 11 | dnl C++ environment. This macro must be used unconditionnaly. |
| 12 | AC_PROG_CXX |
| 13 | |
| 14 | if test "x$guix_build_daemon" = "xyes"; then |
| 15 | |
| 16 | AC_PROG_RANLIB |
| 17 | AC_CONFIG_HEADER([nix/config.h]) |
| 18 | |
| 19 | dnl Use 64-bit file system calls so that we can support files > 2 GiB. |
| 20 | AC_SYS_LARGEFILE |
| 21 | |
| 22 | dnl Look for libbz2, a required dependency. |
| 23 | AC_CHECK_LIB([bz2], [BZ2_bzWriteOpen], [true], |
| 24 | [AC_MSG_ERROR([Guix requires libbz2, which is part of bzip2. See http://www.bzip.org/.])]) |
| 25 | AC_CHECK_HEADERS([bzlib.h], [true], |
| 26 | [AC_MSG_ERROR([Guix requires libbz2, which is part of bzip2. See http://www.bzip.org/.])]) |
| 27 | |
| 28 | dnl Look for SQLite, a required dependency. |
| 29 | PKG_CHECK_MODULES([SQLITE3], [sqlite3 >= 3.6.19]) |
| 30 | |
| 31 | AC_DEFINE([NIX_VERSION], ["0.0.0"], [Fake Nix version number.]) |
| 32 | AC_DEFINE_UNQUOTED([SYSTEM], ["$guix_system"], |
| 33 | [Guix host system type--i.e., platform and OS kernel tuple.]) |
| 34 | |
| 35 | case "$LIBGCRYPT_PREFIX" in |
| 36 | no) |
| 37 | LIBGCRYPT_CFLAGS="" |
| 38 | LIBGCRYPT_LIBS="" |
| 39 | ;; |
| 40 | *) |
| 41 | LIBGCRYPT_CFLAGS="-I$LIBGCRYPT_PREFIX/include" |
| 42 | LIBGCRYPT_LIBS="-L$LIBGCRYPT_PREFIX/lib -lgcrypt" |
| 43 | ;; |
| 44 | esac |
| 45 | AC_SUBST([LIBGCRYPT_CFLAGS]) |
| 46 | AC_SUBST([LIBGCRYPT_LIBS]) |
| 47 | |
| 48 | save_CFLAGS="$CFLAGS" |
| 49 | save_LDFLAGS="$LDFLAGS" |
| 50 | CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS" |
| 51 | LDFLAGS="$LDFLAGS $LIBGCRYPT_LDFLAGS" |
| 52 | |
| 53 | have_gcrypt=yes |
| 54 | AC_CHECK_LIB([gcrypt], [gcry_md_open], [:], [have_gcrypt=no]) |
| 55 | AC_CHECK_HEADER([gcrypt.h], [:], [have_gcrypt=no]) |
| 56 | if test "x$have_gcrypt" != "xyes"; then |
| 57 | AC_MSG_ERROR([GNU libgcrypt not found; please install it.]) |
| 58 | fi |
| 59 | |
| 60 | CFLAGS="$save_CFLAGS" |
| 61 | LDFLAGS="$save_LDFLAGS" |
| 62 | fi |
| 63 | |
| 64 | AM_CONDITIONAL([BUILD_DAEMON], [test "x$guix_build_daemon" = "xyes"]) |