[jackhill/guix/guix.git] / guix / import / crate.scm

;;; GNU Guix --- Functional package management for GNU
;;; Copyright © 2016 David Craven <david@craven.ch>
;;; Copyright © 2019, 2020 Ludovic Courtès <ludo@gnu.org>
;;; Copyright © 2019, 2020 Martin Becze <mjbecze@riseup.net>
;;;
;;; This file is part of GNU Guix.
;;;
;;; GNU Guix is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or (at
;;; your option) any later version.
;;;
;;; GNU Guix is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;;; GNU General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with GNU Guix.  If not, see <http://www.gnu.org/licenses/>.

(define-module (guix import crate)
  #:use-module (guix base32)
  #:use-module (guix build-system cargo)
  #:use-module ((guix download) #:prefix download:)
  #:use-module (gcrypt hash)
  #:use-module (guix http-client)
  #:use-module (guix import json)
  #:use-module (guix import utils)
  #:use-module ((guix licenses) #:prefix license:)
  #:use-module (guix memoization)
  #:use-module (guix monads)
  #:use-module (guix packages)
  #:use-module (guix upstream)
  #:use-module (guix utils)
  #:use-module (gnu packages)
  #:use-module (ice-9 match)
  #:use-module (ice-9 regex)
  #:use-module (json)
  #:use-module (srfi srfi-1)
  #:use-module (srfi srfi-2)
  #:use-module (srfi srfi-26)
  #:use-module (srfi srfi-71)
  #:export (crate->guix-package
            guix-package->crate-name
            string->license
            crate-recursive-import
            %crate-updater))

\f
;;;
;;; Interface to https://crates.io/api/v1.
;;;

;; Crates.  A crate is essentially a "package".  It can have several
;; "versions", each of which has its own set of dependencies, license,
;; etc.--see <crate-version> below.
(define-json-mapping <crate> make-crate crate?
  json->crate
  (name          crate-name)                      ;string
  (latest-version crate-latest-version "max_version") ;string
  (home-page     crate-home-page "homepage")      ;string | #nil
  (repository    crate-repository)                ;string
  (description   crate-description)               ;string
  (keywords      crate-keywords                   ;list of strings
                 "keywords" vector->list)
  (categories    crate-categories                 ;list of strings
                 "categories" vector->list)
  (versions      crate-versions "actual_versions" ;list of <crate-version>
                 (lambda (vector)
                   (map json->crate-version
                        (vector->list vector))))
  (links         crate-links))                    ;alist

;; Crate version.
(define-json-mapping <crate-version> make-crate-version crate-version?
  json->crate-version
  (id            crate-version-id)                ;integer
  (number        crate-version-number "num")      ;string
  (download-path crate-version-download-path "dl_path") ;string
  (readme-path   crate-version-readme-path "readme_path") ;string
  (license       crate-version-license "license") ;string
  (links         crate-version-links))            ;alist

;; Crate dependency.  Each dependency (each edge in the graph) is annotated as
;; being a "normal" dependency or a development dependency.  There also
;; information about the minimum required version, such as "^0.0.41".
(define-json-mapping <crate-dependency> make-crate-dependency
  crate-dependency?
  json->crate-dependency
  (id            crate-dependency-id "crate_id")  ;string
  (kind          crate-dependency-kind "kind"     ;'normal | 'dev | 'build
                 string->symbol)
  (requirement   crate-dependency-requirement "req")) ;string

(module-autoload! (current-module)
		  '(semver) '(string->semver semver->string semver<?))
(module-autoload! (current-module)
		  '(semver ranges) '(string->semver-range semver-range-contains?))

(define (lookup-crate name)
  "Look up NAME on https://crates.io and return the corresopnding <crate>
record or #f if it was not found."
  (let ((json (json-fetch (string-append (%crate-base-url) "/api/v1/crates/"
                                         name))))
    (and=> (and json (assoc-ref json "crate"))
           (lambda (alist)
             ;; The "versions" field of ALIST is simply a list of version IDs
             ;; (integers).  Here, we squeeze in the actual version
             ;; dictionaries that are not part of ALIST but are just more
             ;; convenient handled this way.
             (let ((versions (or (assoc-ref json "versions") '#())))
               (json->crate `(,@alist
                              ("actual_versions" . ,versions))))))))

(define lookup-crate* (memoize lookup-crate))

(define (crate-version-dependencies version)
  "Return the list of <crate-dependency> records of VERSION, a
<crate-version>."
  (let* ((path (assoc-ref (crate-version-links version) "dependencies"))
         (url  (string-append (%crate-base-url) path)))
    (match (assoc-ref (or (json-fetch url) '()) "dependencies")
      ((? vector? vector)
       (delete-duplicates (map json->crate-dependency (vector->list vector))))
      (_
       '()))))

\f
;;;
;;; Converting crates to Guix packages.
;;;

(define (maybe-cargo-inputs package-names)
  (match (package-names->package-inputs package-names)
    (()
     '())
    ((package-inputs ...)
     `(#:cargo-inputs ,package-inputs))))

(define (maybe-cargo-development-inputs package-names)
  (match (package-names->package-inputs package-names)
    (()
     '())
    ((package-inputs ...)
     `(#:cargo-development-inputs ,package-inputs))))

(define (maybe-arguments arguments)
  (match arguments
    (()
     '())
    ((args ...)
     `((arguments (,'quasiquote ,args))))))

(define (version->semver-prefix version)
  "Return the version up to and including the first non-zero part"
  (first
   (map match:substring
        (list-matches "^(0+\\.){,2}[0-9]+" version))))

(define* (make-crate-sexp #:key name version cargo-inputs cargo-development-inputs
                          home-page synopsis description license build?)
  "Return the `package' s-expression for a rust package with the given NAME,
VERSION, CARGO-INPUTS, CARGO-DEVELOPMENT-INPUTS, HOME-PAGE, SYNOPSIS, DESCRIPTION,
and LICENSE."
  (define (format-inputs inputs)
    (map
     (match-lambda
      ((name version)
       (list (crate-name->package-name name)
             (version->semver-prefix version))))
     inputs))

  (let* ((port (http-fetch (crate-uri name version)))
         (guix-name (crate-name->package-name name))
         (cargo-inputs (format-inputs cargo-inputs))
         (cargo-development-inputs (format-inputs cargo-development-inputs))
         (pkg `(package
                   (name ,guix-name)
                   (version ,version)
                   (source (origin
                             (method url-fetch)
                             (uri (crate-uri ,name version))
                             (file-name (string-append name "-" version ".tar.gz"))
                             (sha256
                              (base32
                               ,(bytevector->nix-base32-string (port-sha256 port))))))
                   (build-system cargo-build-system)
                   ,@(maybe-arguments (append (if build?
                                                 '()
                                                 '(#:skip-build? #t))
                                              (maybe-cargo-inputs cargo-inputs)
                                              (maybe-cargo-development-inputs
                                                cargo-development-inputs)))
                   (home-page ,(match home-page
                                 ('null "")
                                 (_ home-page)))
                   (synopsis ,synopsis)
                   (description ,(beautify-description description))
                   (license ,(match license
                               (() #f)
                               ((license) license)
                               (_ `(list ,@license)))))))
         (close-port port)
         (package->definition pkg (version->semver-prefix version))))

(define (string->license string)
  (filter-map (lambda (license)
                (and (not (string-null? license))
                     (not (any (lambda (elem) (string=? elem license))
                               '("AND" "OR" "WITH")))
                     (or (spdx-string->license license)
                         'unknown-license!)))
              (string-split string (string->char-set " /"))))

(define* (crate->guix-package crate-name #:key version include-dev-deps? repo)
  "Fetch the metadata for CRATE-NAME from crates.io, and return the
`package' s-expression corresponding to that package, or #f on failure.
When VERSION is specified, convert it into a semver range and attempt to fetch
the latest version matching this semver range; otherwise fetch the latest
version of CRATE-NAME. If INCLUDE-DEV-DEPS is true then this will also
look up the development dependencs for the given crate."

  (define (semver-range-contains-string? range version)
    (semver-range-contains? (string->semver-range range)
                            (string->semver version)))

  (define (normal-dependency? dependency)
    (or (eq? (crate-dependency-kind dependency) 'build)
        (eq? (crate-dependency-kind dependency) 'normal)))

  (define crate
    (lookup-crate* crate-name))

  (define version-number
    (and crate
         (or version
             (crate-latest-version crate))))

  ;; find the highest existing package that fulfills the semver <range>
  (define (find-package-version name range)
    (let* ((semver-range (string->semver-range range))
           (versions
            (sort
             (filter (lambda (version)
                       (semver-range-contains? semver-range version))
                     (map (lambda (pkg)
                            (string->semver (package-version pkg)))
                          (find-packages-by-name
                           (crate-name->package-name name))))
             semver<?)))
      (and (not (null-list? versions))
           (semver->string (last versions)))))

  ;; find the highest version of a crate that fulfills the semver <range>
  (define (find-crate-version crate range)
    (let* ((semver-range (string->semver-range range))
           (versions
            (sort
             (filter (lambda (entry)
                       (semver-range-contains? semver-range (first entry)))
                     (map (lambda (ver)
                            (list (string->semver (crate-version-number ver))
                                  ver))
                          (crate-versions crate)))
             (match-lambda* (((semver _) ...)
                             (apply semver<? semver))))))
      (and (not (null-list? versions))
           (second (last versions)))))

  (define (dependency-name+version dep)
    (let* ((name (crate-dependency-id dep))
           (req (crate-dependency-requirement dep))
           (existing-version (find-package-version name req)))
      (if existing-version
          (list name existing-version)
          (let* ((crate (lookup-crate* name))
                 (ver (find-crate-version crate req)))
            (list name
                  (crate-version-number ver))))))

  (define version*
    (and crate
         (find-crate-version crate version-number)))

  ;; sort and map the dependencies to a list containing
  ;; pairs of (name version)
  (define (sort-map-dependencies deps)
    (sort (map dependency-name+version
               deps)
          (match-lambda* (((name _) ...)
                          (apply string-ci<? name)))))

  (and crate version*
       (let* ((dependencies (crate-version-dependencies version*))
              (dep-crates dev-dep-crates (partition normal-dependency? dependencies))
              (cargo-inputs (sort-map-dependencies dep-crates))
              (cargo-development-inputs (if include-dev-deps?
                                            (sort-map-dependencies dev-dep-crates)
                                            '())))
         (values
          (make-crate-sexp #:build? include-dev-deps?
                           #:name crate-name
                           #:version (crate-version-number version*)
                           #:cargo-inputs cargo-inputs
                           #:cargo-development-inputs cargo-development-inputs
                           #:home-page (or (crate-home-page crate)
                                           (crate-repository crate))
                           #:synopsis (crate-description crate)
                           #:description (crate-description crate)
                           #:license (and=> (crate-version-license version*)
                                            string->license))
          (append cargo-inputs cargo-development-inputs)))))

(define* (crate-recursive-import crate-name #:key version)
  (recursive-import crate-name
                    #:repo->guix-package (lambda* params
                      ;; download development dependencies only for the top level package
                      (let ((include-dev-deps? (equal? (car params) crate-name))
                            (crate->guix-package* (memoize crate->guix-package)))
                        (apply crate->guix-package*
                               (append params `(#:include-dev-deps? ,include-dev-deps?)))))
                    #:version version
                    #:guix-name crate-name->package-name))

(define (guix-package->crate-name package)
  "Return the crate name of PACKAGE."
  (and-let* ((origin (package-source package))
             (uri (origin-uri origin))
             (crate-url? uri)
             (len (string-length crate-url))
             (path (xsubstring uri len))
             (parts (string-split path #\/)))
    (match parts
      ((name _ ...) name))))

(define (crate-name->package-name name)
  (guix-name "rust-" name))

\f
;;;
;;; Updater
;;;

(define crate-package?
  (url-predicate crate-url?))

(define (latest-release package)
  "Return an <upstream-source> for the latest release of PACKAGE."
  (let* ((crate-name (guix-package->crate-name package))
         (crate      (lookup-crate crate-name))
         (version    (crate-latest-version crate))
         (url        (crate-uri crate-name version)))
    (upstream-source
     (package (package-name package))
     (version version)
     (urls (list url)))))

(define %crate-updater
  (upstream-updater
   (name 'crates)
   (description "Updater for crates.io packages")
   (pred crate-package?)
   (latest latest-release)))
Commit	Line	Data
3e0c0365 DC	1	;;; GNU Guix --- Functional package management for GNU
3e0c0365 DC	2	;;; Copyright © 2016 David Craven <david@craven.ch>
72c678af	3	;;; Copyright © 2019, 2020 Ludovic Courtès <ludo@gnu.org>
269c1db4	4	;;; Copyright © 2019, 2020 Martin Becze <mjbecze@riseup.net>
3e0c0365 DC	5	;;;
	6	;;; This file is part of GNU Guix.
	7	;;;
	8	;;; GNU Guix is free software; you can redistribute it and/or modify it
	9	;;; under the terms of the GNU General Public License as published by
	10	;;; the Free Software Foundation; either version 3 of the License, or (at
	11	;;; your option) any later version.
	12	;;;
	13	;;; GNU Guix is distributed in the hope that it will be useful, but
	14	;;; WITHOUT ANY WARRANTY; without even the implied warranty of
	15	;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	16	;;; GNU General Public License for more details.
	17	;;;
	18	;;; You should have received a copy of the GNU General Public License
	19	;;; along with GNU Guix. If not, see <http://www.gnu.org/licenses/>.
	20
	21	(define-module (guix import crate)
	22	#:use-module (guix base32)
	23	#:use-module (guix build-system cargo)
	24	#:use-module ((guix download) #:prefix download:)
ca719424	25	#:use-module (gcrypt hash)
3e0c0365 DC	26	#:use-module (guix http-client)
	27	#:use-module (guix import json)
	28	#:use-module (guix import utils)
	29	#:use-module ((guix licenses) #:prefix license:)
d9feb23e	30	#:use-module (guix memoization)
3e0c0365 DC	31	#:use-module (guix monads)
	32	#:use-module (guix packages)
	33	#:use-module (guix upstream)
	34	#:use-module (guix utils)
054e308f	35	#:use-module (gnu packages)
3e0c0365	36	#:use-module (ice-9 match)
191668bc	37	#:use-module (ice-9 regex)
3e0c0365 DC	38	#:use-module (json)
	39	#:use-module (srfi srfi-1)
	40	#:use-module (srfi srfi-2)
	41	#:use-module (srfi srfi-26)
269c1db4	42	#:use-module (srfi srfi-71)
3e0c0365	43	#:export (crate->guix-package
8ac52987	44	guix-package->crate-name
72c678af	45	string->license
f8372932	46	crate-recursive-import
8ac52987	47	%crate-updater))
3e0c0365	48
2791870d LC	49	\f
	50	;;;
	51	;;; Interface to https://crates.io/api/v1.
	52	;;;
3e0c0365	53
2791870d LC	54	;; Crates. A crate is essentially a "package". It can have several
	55	;; "versions", each of which has its own set of dependencies, license,
	56	;; etc.--see <crate-version> below.
	57	(define-json-mapping <crate> make-crate crate?
	58	json->crate
	59	(name crate-name) ;string
	60	(latest-version crate-latest-version "max_version") ;string
	61	(home-page crate-home-page "homepage") ;string \| #nil
	62	(repository crate-repository) ;string
	63	(description crate-description) ;string
	64	(keywords crate-keywords ;list of strings
	65	"keywords" vector->list)
	66	(categories crate-categories ;list of strings
	67	"categories" vector->list)
	68	(versions crate-versions "actual_versions" ;list of <crate-version>
	69	(lambda (vector)
	70	(map json->crate-version
	71	(vector->list vector))))
	72	(links crate-links)) ;alist
3e0c0365	73
2791870d LC	74	;; Crate version.
	75	(define-json-mapping <crate-version> make-crate-version crate-version?
	76	json->crate-version
	77	(id crate-version-id) ;integer
	78	(number crate-version-number "num") ;string
	79	(download-path crate-version-download-path "dl_path") ;string
	80	(readme-path crate-version-readme-path "readme_path") ;string
	81	(license crate-version-license "license") ;string
	82	(links crate-version-links)) ;alist
	83
	84	;; Crate dependency. Each dependency (each edge in the graph) is annotated as
	85	;; being a "normal" dependency or a development dependency. There also
	86	;; information about the minimum required version, such as "^0.0.41".
	87	(define-json-mapping <crate-dependency> make-crate-dependency
	88	crate-dependency?
	89	json->crate-dependency
	90	(id crate-dependency-id "crate_id") ;string
269c1db4	91	(kind crate-dependency-kind "kind" ;'normal \| 'dev \| 'build
2791870d LC	92	string->symbol)
	93	(requirement crate-dependency-requirement "req")) ;string
	94
269c1db4	95	(module-autoload! (current-module)
054e308f	96	'(semver) '(string->semver semver->string semver<?))
269c1db4 MB	97	(module-autoload! (current-module)
	98	'(semver ranges) '(string->semver-range semver-range-contains?))
	99
2791870d LC	100	(define (lookup-crate name)
	101	"Look up NAME on https://crates.io and return the corresopnding <crate>
	102	record or #f if it was not found."
	103	(let ((json (json-fetch (string-append (%crate-base-url) "/api/v1/crates/"
	104	name))))
	105	(and=> (and json (assoc-ref json "crate"))
	106	(lambda (alist)
	107	;; The "versions" field of ALIST is simply a list of version IDs
	108	;; (integers). Here, we squeeze in the actual version
	109	;; dictionaries that are not part of ALIST but are just more
	110	;; convenient handled this way.
	111	(let ((versions (or (assoc-ref json "versions") '#())))
	112	(json->crate `(,@alist
	113	("actual_versions" . ,versions))))))))
	114
d9feb23e MB	115	(define lookup-crate* (memoize lookup-crate))
d9feb23e MB	116
2791870d LC	117	(define (crate-version-dependencies version)
	118	"Return the list of <crate-dependency> records of VERSION, a
	119	<crate-version>."
	120	(let* ((path (assoc-ref (crate-version-links version) "dependencies"))
	121	(url (string-append (%crate-base-url) path)))
	122	(match (assoc-ref (or (json-fetch url) '()) "dependencies")
	123	((? vector? vector)
cf2b91aa	124	(delete-duplicates (map json->crate-dependency (vector->list vector))))
2791870d LC	125	(_
2791870d LC	126	'()))))
3e0c0365	127
2791870d LC	128	\f
	129	;;;
	130	;;; Converting crates to Guix packages.
	131	;;;
3e0c0365	132
5a9ef8a9 IP	133	(define (maybe-cargo-inputs package-names)
	134	(match (package-names->package-inputs package-names)
	135	(()
	136	'())
	137	((package-inputs ...)
022288ba	138	`(#:cargo-inputs ,package-inputs))))
5a9ef8a9 IP	139
	140	(define (maybe-cargo-development-inputs package-names)
	141	(match (package-names->package-inputs package-names)
	142	(()
	143	'())
	144	((package-inputs ...)
022288ba	145	`(#:cargo-development-inputs ,package-inputs))))
5a9ef8a9 IP	146
	147	(define (maybe-arguments arguments)
	148	(match arguments
	149	(()
	150	'())
	151	((args ...)
	152	`((arguments (,'quasiquote ,args))))))
	153
45584061 HG	154	(define (version->semver-prefix version)
	155	"Return the version up to and including the first non-zero part"
	156	(first
	157	(map match:substring
	158	(list-matches "^(0+\\.){,2}[0-9]+" version))))
	159
5a9ef8a9	160	(define* (make-crate-sexp #:key name version cargo-inputs cargo-development-inputs
50fbb3f0	161	home-page synopsis description license build?)
3e0c0365	162	"Return the `package' s-expression for a rust package with the given NAME,
5a9ef8a9 IP	163	VERSION, CARGO-INPUTS, CARGO-DEVELOPMENT-INPUTS, HOME-PAGE, SYNOPSIS, DESCRIPTION,
5a9ef8a9 IP	164	and LICENSE."
269c1db4 MB	165	(define (format-inputs inputs)
	166	(map
	167	(match-lambda
	168	((name version)
9a48e35b	169	(list (crate-name->package-name name)
45584061	170	(version->semver-prefix version))))
269c1db4 MB	171	inputs))
269c1db4 MB	172
3e0c0365 DC	173	(let* ((port (http-fetch (crate-uri name version)))
3e0c0365 DC	174	(guix-name (crate-name->package-name name))
269c1db4 MB	175	(cargo-inputs (format-inputs cargo-inputs))
269c1db4 MB	176	(cargo-development-inputs (format-inputs cargo-development-inputs))
3e0c0365 DC	177	(pkg `(package
	178	(name ,guix-name)
	179	(version ,version)
	180	(source (origin
	181	(method url-fetch)
	182	(uri (crate-uri ,name version))
	183	(file-name (string-append name "-" version ".tar.gz"))
	184	(sha256
	185	(base32
	186	,(bytevector->nix-base32-string (port-sha256 port))))))
	187	(build-system cargo-build-system)
50fbb3f0 MB	188	,@(maybe-arguments (append (if build?
	189	'()
	190	'(#:skip-build? #t))
269c1db4	191	(maybe-cargo-inputs cargo-inputs)
5a9ef8a9 IP	192	(maybe-cargo-development-inputs
5a9ef8a9 IP	193	cargo-development-inputs)))
f53a5514	194	(home-page ,(match home-page
c949530b	195	('null "")
f53a5514	196	(_ home-page)))
3e0c0365 DC	197	(synopsis ,synopsis)
	198	(description ,(beautify-description description))
	199	(license ,(match license
	200	(() #f)
	201	((license) license)
	202	(_ `(list ,@license)))))))
	203	(close-port port)
45584061	204	(package->definition pkg (version->semver-prefix version))))
3e0c0365	205
263a267b BW	206	(define (string->license string)
	207	(filter-map (lambda (license)
	208	(and (not (string-null? license))
	209	(not (any (lambda (elem) (string=? elem license))
	210	'("AND" "OR" "WITH")))
	211	(or (spdx-string->license license)
	212	'unknown-license!)))
	213	(string-split string (string->char-set " /"))))
191668bc	214
50fbb3f0	215	(define* (crate->guix-package crate-name #:key version include-dev-deps? repo)
3e0c0365	216	"Fetch the metadata for CRATE-NAME from crates.io, and return the
fd63ecbe	217	`package' s-expression corresponding to that package, or #f on failure.
269c1db4 MB	218	When VERSION is specified, convert it into a semver range and attempt to fetch
269c1db4 MB	219	the latest version matching this semver range; otherwise fetch the latest
50fbb3f0 MB	220	version of CRATE-NAME. If INCLUDE-DEV-DEPS is true then this will also
50fbb3f0 MB	221	look up the development dependencs for the given crate."
269c1db4 MB	222
	223	(define (semver-range-contains-string? range version)
	224	(semver-range-contains? (string->semver-range range)
	225	(string->semver version)))
2791870d LC	226
2791870d LC	227	(define (normal-dependency? dependency)
269c1db4 MB	228	(or (eq? (crate-dependency-kind dependency) 'build)
269c1db4 MB	229	(eq? (crate-dependency-kind dependency) 'normal)))
2791870d LC	230
2791870d LC	231	(define crate
d9feb23e	232	(lookup-crate* crate-name))
2791870d	233
fd63ecbe	234	(define version-number
5fbc753a LC	235	(and crate
	236	(or version
	237	(crate-latest-version crate))))
fd63ecbe	238
054e308f HG	239	;; find the highest existing package that fulfills the semver <range>
	240	(define (find-package-version name range)
	241	(let* ((semver-range (string->semver-range range))
	242	(versions
	243	(sort
	244	(filter (lambda (version)
	245	(semver-range-contains? semver-range version))
	246	(map (lambda (pkg)
	247	(string->semver (package-version pkg)))
	248	(find-packages-by-name
	249	(crate-name->package-name name))))
	250	semver<?)))
	251	(and (not (null-list? versions))
	252	(semver->string (last versions)))))
	253
269c1db4 MB	254	;; find the highest version of a crate that fulfills the semver <range>
	255	(define (find-crate-version crate range)
	256	(let* ((semver-range (string->semver-range range))
	257	(versions
	258	(sort
	259	(filter (lambda (entry)
	260	(semver-range-contains? semver-range (first entry)))
	261	(map (lambda (ver)
	262	(list (string->semver (crate-version-number ver))
	263	ver))
	264	(crate-versions crate)))
	265	(match-lambda* (((semver _) ...)
	266	(apply semver<? semver))))))
	267	(and (not (null-list? versions))
	268	(second (last versions)))))
	269
054e308f HG	270	(define (dependency-name+version dep)
	271	(let* ((name (crate-dependency-id dep))
	272	(req (crate-dependency-requirement dep))
	273	(existing-version (find-package-version name req)))
	274	(if existing-version
	275	(list name existing-version)
	276	(let* ((crate (lookup-crate* name))
	277	(ver (find-crate-version crate req)))
	278	(list name
	279	(crate-version-number ver))))))
	280
fd63ecbe	281	(define version*
5fbc753a	282	(and crate
269c1db4 MB	283	(find-crate-version crate version-number)))
	284
	285	;; sort and map the dependencies to a list containing
	286	;; pairs of (name version)
	287	(define (sort-map-dependencies deps)
054e308f	288	(sort (map dependency-name+version
269c1db4 MB	289	deps)
	290	(match-lambda* (((name _) ...)
	291	(apply string-ci<? name)))))
fd63ecbe MB	292
fd63ecbe MB	293	(and crate version*
269c1db4 MB	294	(let* ((dependencies (crate-version-dependencies version*))
	295	(dep-crates dev-dep-crates (partition normal-dependency? dependencies))
	296	(cargo-inputs (sort-map-dependencies dep-crates))
50fbb3f0 MB	297	(cargo-development-inputs (if include-dev-deps?
	298	(sort-map-dependencies dev-dep-crates)
	299	'())))
f8372932	300	(values
50fbb3f0 MB	301	(make-crate-sexp #:build? include-dev-deps?
50fbb3f0 MB	302	#:name crate-name
f8372932 MB	303	#:version (crate-version-number version*)
	304	#:cargo-inputs cargo-inputs
	305	#:cargo-development-inputs cargo-development-inputs
	306	#:home-page (or (crate-home-page crate)
	307	(crate-repository crate))
	308	#:synopsis (crate-description crate)
	309	#:description (crate-description crate)
	310	#:license (and=> (crate-version-license version*)
	311	string->license))
	312	(append cargo-inputs cargo-development-inputs)))))
	313
bea3b177 MB	314	(define* (crate-recursive-import crate-name #:key version)
bea3b177 MB	315	(recursive-import crate-name
50fbb3f0 MB	316	#:repo->guix-package (lambda* params
	317	;; download development dependencies only for the top level package
	318	(let ((include-dev-deps? (equal? (car params) crate-name))
	319	(crate->guix-package* (memoize crate->guix-package)))
	320	(apply crate->guix-package*
	321	(append params `(#:include-dev-deps? ,include-dev-deps?)))))
bea3b177	322	#:version version
f8372932	323	#:guix-name crate-name->package-name))
3e0c0365 DC	324
	325	(define (guix-package->crate-name package)
	326	"Return the crate name of PACKAGE."
	327	(and-let* ((origin (package-source package))
	328	(uri (origin-uri origin))
	329	(crate-url? uri)
	330	(len (string-length crate-url))
	331	(path (xsubstring uri len))
	332	(parts (string-split path #\/)))
	333	(match parts
	334	((name _ ...) name))))
	335
	336	(define (crate-name->package-name name)
269c1db4	337	(guix-name "rust-" name))
3e0c0365	338
2791870d	339	\f
8ac52987 DC	340	;;;
	341	;;; Updater
	342	;;;
	343
00290e73 LC	344	(define crate-package?
00290e73 LC	345	(url-predicate crate-url?))
8ac52987 DC	346
	347	(define (latest-release package)
	348	"Return an <upstream-source> for the latest release of PACKAGE."
	349	(let* ((crate-name (guix-package->crate-name package))
2791870d LC	350	(crate (lookup-crate crate-name))
	351	(version (crate-latest-version crate))
	352	(url (crate-uri crate-name version)))
8ac52987 DC	353	(upstream-source
	354	(package (package-name package))
	355	(version version)
	356	(urls (list url)))))
	357
	358	(define %crate-updater
	359	(upstream-updater
	360	(name 'crates)
	361	(description "Updater for crates.io packages")
	362	(pred crate-package?)
	363	(latest latest-release)))
	364