| 1 | (* HCoop Domtool (http://hcoop.sourceforge.net/) |
| 2 | * Copyright (c) 2006, Adam Chlipala |
| 3 | * |
| 4 | * This program is free software; you can redistribute it and/or |
| 5 | * modify it under the terms of the GNU General Public License |
| 6 | * as published by the Free Software Foundation; either version 2 |
| 7 | * of the License, or (at your option) any later version. |
| 8 | * |
| 9 | * This program is distributed in the hope that it will be useful, |
| 10 | * but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 11 | * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 12 | * GNU General Public License for more details. |
| 13 | * |
| 14 | * You should have received a copy of the GNU General Public License |
| 15 | * along with this program; if not, write to the Free Software |
| 16 | * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA. |
| 17 | *) |
| 18 | |
| 19 | (* Network messages *) |
| 20 | |
| 21 | structure Msg :> MSG = struct |
| 22 | |
| 23 | open OpenSSL MsgTypes Slave |
| 24 | |
| 25 | val a2i = fn Add => 0 |
| 26 | | Delete true => 1 |
| 27 | | Modify => 2 |
| 28 | | Delete false => 3 |
| 29 | |
| 30 | val i2a = fn 0 => Add |
| 31 | | 1 => Delete true |
| 32 | | 2 => Modify |
| 33 | | 3 => Delete false |
| 34 | | _ => raise OpenSSL.OpenSSL "Bad action number to deserialize" |
| 35 | |
| 36 | fun sendAcl (bio, {user, class, value}) = |
| 37 | (OpenSSL.writeString (bio, user); |
| 38 | OpenSSL.writeString (bio, class); |
| 39 | OpenSSL.writeString (bio, value)) |
| 40 | |
| 41 | fun recvAcl bio = |
| 42 | case (OpenSSL.readString bio, OpenSSL.readString bio, OpenSSL.readString bio) of |
| 43 | (SOME user, SOME class, SOME value) => SOME {user = user, class = class, value = value} |
| 44 | | _ => NONE |
| 45 | |
| 46 | fun sendList f (bio, ls) = |
| 47 | (app (fn x => |
| 48 | (OpenSSL.writeInt (bio, 1); |
| 49 | f (bio, x))) ls; |
| 50 | OpenSSL.writeInt (bio, 0)) |
| 51 | |
| 52 | fun recvList f bio = |
| 53 | let |
| 54 | fun loop ls = |
| 55 | case OpenSSL.readInt bio of |
| 56 | SOME 0 => SOME (rev ls) |
| 57 | | SOME 1 => |
| 58 | (case f bio of |
| 59 | SOME x => loop (x :: ls) |
| 60 | | NONE => NONE) |
| 61 | | _ => NONE |
| 62 | in |
| 63 | loop [] |
| 64 | end |
| 65 | |
| 66 | fun sendOption f (bio, opt) = |
| 67 | case opt of |
| 68 | NONE => OpenSSL.writeInt (bio, 0) |
| 69 | | SOME x => (OpenSSL.writeInt (bio, 1); |
| 70 | f (bio, x)) |
| 71 | |
| 72 | fun recvOption f bio = |
| 73 | case OpenSSL.readInt bio of |
| 74 | SOME 0 => SOME NONE |
| 75 | | SOME 1 => |
| 76 | (case f bio of |
| 77 | SOME x => SOME (SOME x) |
| 78 | | NONE => NONE) |
| 79 | | _ => NONE |
| 80 | |
| 81 | fun sendBool (bio, b) = |
| 82 | if b then |
| 83 | OpenSSL.writeInt (bio, 1) |
| 84 | else |
| 85 | OpenSSL.writeInt (bio, 0) |
| 86 | |
| 87 | fun recvBool bio = |
| 88 | case OpenSSL.readInt bio of |
| 89 | SOME 0 => SOME false |
| 90 | | SOME 1 => SOME true |
| 91 | | _ => NONE |
| 92 | |
| 93 | fun sendSockPerm (bio, p) = |
| 94 | case p of |
| 95 | Any => OpenSSL.writeInt (bio, 0) |
| 96 | | Client => OpenSSL.writeInt (bio, 1) |
| 97 | | Server => OpenSSL.writeInt (bio, 2) |
| 98 | | Nada => OpenSSL.writeInt (bio, 3) |
| 99 | |
| 100 | fun recvSockPerm bio = |
| 101 | case OpenSSL.readInt bio of |
| 102 | SOME 0 => SOME Any |
| 103 | | SOME 1 => SOME Client |
| 104 | | SOME 2 => SOME Server |
| 105 | | SOME 3 => SOME Nada |
| 106 | | _ => NONE |
| 107 | |
| 108 | fun sendQuery (bio, q) = |
| 109 | case q of |
| 110 | QApt s => (OpenSSL.writeInt (bio, 0); |
| 111 | OpenSSL.writeString (bio, s)) |
| 112 | | QCron s => (OpenSSL.writeInt (bio, 1); |
| 113 | OpenSSL.writeString (bio, s)) |
| 114 | | QFtp s => (OpenSSL.writeInt (bio, 2); |
| 115 | OpenSSL.writeString (bio, s)) |
| 116 | | QTrustedPath s => (OpenSSL.writeInt (bio, 3); |
| 117 | OpenSSL.writeString (bio, s)) |
| 118 | | QSocket s => (OpenSSL.writeInt (bio, 4); |
| 119 | OpenSSL.writeString (bio, s)) |
| 120 | | QFirewall s => (OpenSSL.writeInt (bio, 5); |
| 121 | OpenSSL.writeString (bio, s)) |
| 122 | | QAptExists s => (OpenSSL.writeInt (bio, 6); |
| 123 | OpenSSL.writeString (bio, s)) |
| 124 | |
| 125 | fun recvQuery bio = |
| 126 | case OpenSSL.readInt bio of |
| 127 | SOME n => |
| 128 | (case n of |
| 129 | 0 => Option.map QApt (OpenSSL.readString bio) |
| 130 | | 1 => Option.map QCron (OpenSSL.readString bio) |
| 131 | | 2 => Option.map QFtp (OpenSSL.readString bio) |
| 132 | | 3 => Option.map QTrustedPath (OpenSSL.readString bio) |
| 133 | | 4 => Option.map QSocket (OpenSSL.readString bio) |
| 134 | | 5 => Option.map QFirewall (OpenSSL.readString bio) |
| 135 | | 6 => Option.map QAptExists (OpenSSL.readString bio) |
| 136 | | _ => NONE) |
| 137 | | NONE => NONE |
| 138 | |
| 139 | fun send (bio, m) = |
| 140 | case m of |
| 141 | MsgOk => OpenSSL.writeInt (bio, 1) |
| 142 | | MsgError s => (OpenSSL.writeInt (bio, 2); |
| 143 | OpenSSL.writeString (bio, s)) |
| 144 | | MsgConfig s => (OpenSSL.writeInt (bio, 3); |
| 145 | OpenSSL.writeString (bio, s)) |
| 146 | | MsgFile {action, domain, dir, file} => |
| 147 | (OpenSSL.writeInt (bio, 4); |
| 148 | OpenSSL.writeInt (bio, a2i action); |
| 149 | OpenSSL.writeString (bio, domain); |
| 150 | OpenSSL.writeString (bio, dir); |
| 151 | OpenSSL.writeString (bio, file)) |
| 152 | | MsgDoFiles => OpenSSL.writeInt (bio, 5) |
| 153 | | MsgGrant acl => (OpenSSL.writeInt (bio, 6); |
| 154 | sendAcl (bio, acl)) |
| 155 | | MsgRevoke acl => (OpenSSL.writeInt (bio, 7); |
| 156 | sendAcl (bio, acl)) |
| 157 | | MsgListPerms user => (OpenSSL.writeInt (bio, 8); |
| 158 | OpenSSL.writeString (bio, user)) |
| 159 | | MsgPerms classes => (OpenSSL.writeInt (bio, 9); |
| 160 | sendList (fn (bio, (class, values)) => |
| 161 | (OpenSSL.writeString (bio, class); |
| 162 | sendList OpenSSL.writeString (bio, values))) |
| 163 | (bio, classes)) |
| 164 | | MsgWhoHas {class, value} => (OpenSSL.writeInt (bio, 10); |
| 165 | OpenSSL.writeString (bio, class); |
| 166 | OpenSSL.writeString (bio, value)) |
| 167 | | MsgWhoHasResponse users => (OpenSSL.writeInt (bio, 11); |
| 168 | sendList OpenSSL.writeString (bio, users)) |
| 169 | | MsgMultiConfig codes => (OpenSSL.writeInt (bio, 12); |
| 170 | sendList OpenSSL.writeString (bio, codes)) |
| 171 | | MsgRmdom doms => (OpenSSL.writeInt (bio, 13); |
| 172 | sendList OpenSSL.writeString (bio, doms)) |
| 173 | | MsgRegenerate => OpenSSL.writeInt (bio, 14) |
| 174 | | MsgRmuser dom => (OpenSSL.writeInt (bio, 15); |
| 175 | OpenSSL.writeString (bio, dom)) |
| 176 | | MsgCreateDbUser {dbtype, passwd} => (OpenSSL.writeInt (bio, 16); |
| 177 | OpenSSL.writeString (bio, dbtype); |
| 178 | sendOption OpenSSL.writeString (bio, passwd)) |
| 179 | | MsgCreateDb {dbtype, dbname, encoding} => (OpenSSL.writeInt (bio, 17); |
| 180 | OpenSSL.writeString (bio, dbtype); |
| 181 | OpenSSL.writeString (bio, dbname); |
| 182 | sendOption OpenSSL.writeString (bio, encoding)) |
| 183 | | MsgNewMailbox {domain, user, passwd, mailbox} => |
| 184 | (OpenSSL.writeInt (bio, 18); |
| 185 | OpenSSL.writeString (bio, domain); |
| 186 | OpenSSL.writeString (bio, user); |
| 187 | OpenSSL.writeString (bio, passwd); |
| 188 | OpenSSL.writeString (bio, mailbox)) |
| 189 | | MsgPasswdMailbox {domain, user, passwd} => |
| 190 | (OpenSSL.writeInt (bio, 19); |
| 191 | OpenSSL.writeString (bio, domain); |
| 192 | OpenSSL.writeString (bio, user); |
| 193 | OpenSSL.writeString (bio, passwd)) |
| 194 | | MsgRmMailbox {domain, user} => |
| 195 | (OpenSSL.writeInt (bio, 20); |
| 196 | OpenSSL.writeString (bio, domain); |
| 197 | OpenSSL.writeString (bio, user)) |
| 198 | | MsgListMailboxes domain => |
| 199 | (OpenSSL.writeInt (bio, 21); |
| 200 | OpenSSL.writeString (bio, domain)) |
| 201 | | MsgMailboxes users => |
| 202 | (OpenSSL.writeInt (bio, 22); |
| 203 | sendList (fn (bio, {user, mailbox}) => |
| 204 | (OpenSSL.writeString (bio, user); |
| 205 | OpenSSL.writeString (bio, mailbox))) |
| 206 | (bio, users)) |
| 207 | | MsgSaQuery addr => (OpenSSL.writeInt (bio, 23); |
| 208 | OpenSSL.writeString (bio, addr)) |
| 209 | | MsgSaStatus b => (OpenSSL.writeInt (bio, 24); |
| 210 | sendBool (bio, b)) |
| 211 | | MsgSaSet (addr, b) => (OpenSSL.writeInt (bio, 25); |
| 212 | OpenSSL.writeString (bio, addr); |
| 213 | sendBool (bio, b)) |
| 214 | | MsgSmtpLogReq domain => (OpenSSL.writeInt (bio, 26); |
| 215 | OpenSSL.writeString (bio, domain)) |
| 216 | | MsgSmtpLogRes domain => (OpenSSL.writeInt (bio, 27); |
| 217 | OpenSSL.writeString (bio, domain)) |
| 218 | | MsgDbPasswd {dbtype, passwd} => (OpenSSL.writeInt (bio, 28); |
| 219 | OpenSSL.writeString (bio, dbtype); |
| 220 | OpenSSL.writeString (bio, passwd)) |
| 221 | | MsgShutdown => OpenSSL.writeInt (bio, 29) |
| 222 | | MsgYes => OpenSSL.writeInt (bio, 30) |
| 223 | | MsgNo => OpenSSL.writeInt (bio, 31) |
| 224 | | MsgQuery q => (OpenSSL.writeInt (bio, 32); |
| 225 | sendQuery (bio, q)) |
| 226 | | MsgSocket p => (OpenSSL.writeInt (bio, 33); |
| 227 | sendSockPerm (bio, p)) |
| 228 | | MsgFirewall ls => (OpenSSL.writeInt (bio, 34); |
| 229 | sendList OpenSSL.writeString (bio, ls)) |
| 230 | | MsgRegenerateTc => OpenSSL.writeInt (bio, 35) |
| 231 | | MsgDropDb {dbtype, dbname} => (OpenSSL.writeInt (bio, 36); |
| 232 | OpenSSL.writeString (bio, dbtype); |
| 233 | OpenSSL.writeString (bio, dbname)) |
| 234 | | MsgGrantDb {dbtype, dbname} => (OpenSSL.writeInt (bio, 37); |
| 235 | OpenSSL.writeString (bio, dbtype); |
| 236 | OpenSSL.writeString (bio, dbname)) |
| 237 | | MsgMysqlFixperms => OpenSSL.writeInt (bio, 38) |
| 238 | | MsgDescribe dom => (OpenSSL.writeInt (bio, 39); |
| 239 | OpenSSL.writeString (bio, dom)) |
| 240 | | MsgDescription s => (OpenSSL.writeInt (bio, 40); |
| 241 | OpenSSL.writeString (bio, s)) |
| 242 | | MsgReUsers => OpenSSL.writeInt (bio, 41) |
| 243 | | MsgVmailChanged => OpenSSL.writeInt (bio, 42) |
| 244 | | MsgFirewallRegen => OpenSSL.writeInt (bio, 43) |
| 245 | |
| 246 | fun checkIt v = |
| 247 | case v of |
| 248 | NONE => raise OpenSSL.OpenSSL "Bad Msg format" |
| 249 | | _ => v |
| 250 | |
| 251 | fun recv bio = |
| 252 | case OpenSSL.readInt bio of |
| 253 | NONE => NONE |
| 254 | | SOME n => |
| 255 | checkIt (case n of |
| 256 | 1 => SOME MsgOk |
| 257 | | 2 => Option.map MsgError (OpenSSL.readString bio) |
| 258 | | 3 => Option.map MsgConfig (OpenSSL.readString bio) |
| 259 | | 4 => (case (OpenSSL.readInt bio, |
| 260 | OpenSSL.readString bio, |
| 261 | OpenSSL.readString bio, |
| 262 | OpenSSL.readString bio) of |
| 263 | (SOME action, SOME domain, SOME dir, SOME file) => |
| 264 | SOME (MsgFile {action = i2a action, |
| 265 | domain = domain, |
| 266 | dir = dir, |
| 267 | file = file}) |
| 268 | | _ => NONE) |
| 269 | | 5 => SOME MsgDoFiles |
| 270 | | 6 => (case recvAcl bio of |
| 271 | SOME acl => SOME (MsgGrant acl) |
| 272 | | _ => NONE) |
| 273 | | 7 => (case recvAcl bio of |
| 274 | SOME acl => SOME (MsgRevoke acl) |
| 275 | | _ => NONE) |
| 276 | | 8 => (case OpenSSL.readString bio of |
| 277 | SOME user => SOME (MsgListPerms user) |
| 278 | | _ => NONE) |
| 279 | | 9 => Option.map MsgPerms |
| 280 | (recvList (fn bio => |
| 281 | case (OpenSSL.readString bio, |
| 282 | recvList OpenSSL.readString bio) of |
| 283 | (SOME class, SOME values) => SOME (class, values) |
| 284 | | _ => NONE) bio) |
| 285 | | 10 => (case (OpenSSL.readString bio, OpenSSL.readString bio) of |
| 286 | (SOME class, SOME value) => SOME (MsgWhoHas {class = class, value = value}) |
| 287 | | _ => NONE) |
| 288 | | 11 => Option.map MsgWhoHasResponse |
| 289 | (recvList OpenSSL.readString bio) |
| 290 | | 12 => Option.map MsgMultiConfig |
| 291 | (recvList OpenSSL.readString bio) |
| 292 | | 13 => Option.map MsgRmdom (recvList OpenSSL.readString bio) |
| 293 | | 14 => SOME MsgRegenerate |
| 294 | | 15 => Option.map MsgRmuser (OpenSSL.readString bio) |
| 295 | | 16 => (case (OpenSSL.readString bio, recvOption OpenSSL.readString bio) of |
| 296 | (SOME dbtype, SOME passwd) => |
| 297 | SOME (MsgCreateDbUser {dbtype = dbtype, passwd = passwd}) |
| 298 | | _ => NONE) |
| 299 | | 17 => (case (OpenSSL.readString bio, OpenSSL.readString bio, recvOption OpenSSL.readString bio) of |
| 300 | (SOME dbtype, SOME dbname, SOME encoding) => |
| 301 | SOME (MsgCreateDb {dbtype = dbtype, dbname = dbname, encoding = encoding}) |
| 302 | | _ => NONE) |
| 303 | | 18 => (case (OpenSSL.readString bio, OpenSSL.readString bio, |
| 304 | OpenSSL.readString bio, OpenSSL.readString bio) of |
| 305 | (SOME domain, SOME user, SOME passwd, SOME mailbox) => |
| 306 | SOME (MsgNewMailbox {domain = domain, user = user, |
| 307 | passwd = passwd, mailbox = mailbox}) |
| 308 | | _ => NONE) |
| 309 | | 19 => (case (OpenSSL.readString bio, OpenSSL.readString bio, |
| 310 | OpenSSL.readString bio) of |
| 311 | (SOME domain, SOME user, SOME passwd) => |
| 312 | SOME (MsgPasswdMailbox {domain = domain, user = user, |
| 313 | passwd = passwd}) |
| 314 | | _ => NONE) |
| 315 | | 20 => (case (OpenSSL.readString bio, OpenSSL.readString bio) of |
| 316 | (SOME domain, SOME user) => |
| 317 | SOME (MsgRmMailbox {domain = domain, user = user}) |
| 318 | | _ => NONE) |
| 319 | | 21 => Option.map MsgListMailboxes (OpenSSL.readString bio) |
| 320 | | 22 => Option.map MsgMailboxes (recvList |
| 321 | (fn bio => |
| 322 | case (OpenSSL.readString bio, |
| 323 | OpenSSL.readString bio) of |
| 324 | (SOME user, SOME mailbox) => |
| 325 | SOME {user = user, mailbox = mailbox} |
| 326 | | _ => NONE) |
| 327 | bio) |
| 328 | | 23 => Option.map MsgSaQuery (OpenSSL.readString bio) |
| 329 | | 24 => Option.map MsgSaStatus (recvBool bio) |
| 330 | | 25 => (case (OpenSSL.readString bio, recvBool bio) of |
| 331 | (SOME user, SOME b) => SOME (MsgSaSet (user, b)) |
| 332 | | _ => NONE) |
| 333 | | 26 => Option.map MsgSmtpLogReq (OpenSSL.readString bio) |
| 334 | | 27 => Option.map MsgSmtpLogRes (OpenSSL.readString bio) |
| 335 | | 28 => (case (OpenSSL.readString bio, OpenSSL.readString bio) of |
| 336 | (SOME dbtype, SOME passwd) => |
| 337 | SOME (MsgDbPasswd {dbtype = dbtype, passwd = passwd}) |
| 338 | | _ => NONE) |
| 339 | | 29 => SOME MsgShutdown |
| 340 | | 30 => SOME MsgYes |
| 341 | | 31 => SOME MsgNo |
| 342 | | 32 => Option.map MsgQuery (recvQuery bio) |
| 343 | | 33 => Option.map MsgSocket (recvSockPerm bio) |
| 344 | | 34 => Option.map MsgFirewall (recvList OpenSSL.readString bio) |
| 345 | | 35 => SOME MsgRegenerateTc |
| 346 | | 36 => (case (OpenSSL.readString bio, OpenSSL.readString bio) of |
| 347 | (SOME dbtype, SOME dbname) => |
| 348 | SOME (MsgDropDb {dbtype = dbtype, dbname = dbname}) |
| 349 | | _ => NONE) |
| 350 | | 37 => (case (OpenSSL.readString bio, OpenSSL.readString bio) of |
| 351 | (SOME dbtype, SOME dbname) => |
| 352 | SOME (MsgGrantDb {dbtype = dbtype, dbname = dbname}) |
| 353 | | _ => NONE) |
| 354 | | 38 => SOME MsgMysqlFixperms |
| 355 | | 39 => Option.map MsgDescribe (OpenSSL.readString bio) |
| 356 | | 40 => Option.map MsgDescription (OpenSSL.readString bio) |
| 357 | | 41 => SOME MsgReUsers |
| 358 | | 42 => SOME MsgVmailChanged |
| 359 | | 43 => SOME MsgFirewallRegen |
| 360 | | _ => NONE) |
| 361 | |
| 362 | end |