src/exiqsumm.src

   1 #! PERL_COMMAND
   2
   3 # Mail Queue Summary
   4 # Christoph Lameter, 21 May 1997
   5 # Modified by Philip Hazel, June 1997
   6 # Bug fix: June 1998 by Philip Hazel
   7 #   Message sizes not listed by -bp with K or M
   8 #   suffixes were getting divided by 10.
   9 # Bug fix: October 1998 by Philip Hazel
  10 #   Sorting wasn't working right with Perl 5.005
  11 #   Fix provided by John Horne
  12 # Bug fix: November 1998 by Philip Hazel
  13 #   Failing to recognize domain literals in recipient addresses
  14 #   Fix provided by Malcolm Ray
  15 # Bug fix: July 2002 by Philip Hazel
  16 #   Not handling time periods of more than 100 days
  17 #   Fix provided by Randy Banks
  18 # Added summary line: September 2002 by Philip Hazel
  19 #   Code provided by Joachim Wieland
  20 # June 2003 by Philip Hazel
  21 #   Initialize $size, $age, $id to avoid warnings when bad
  22 #   data is provided
  23 # Bug fix: July 2003 by Philip Hazel
  24 #   Incorrectly skipping the first lines of messages whose
  25 #   message ID ends in 'D'! Before Exim 4.14 this didn't
  26 #   matter because they never did. Looks like an original
  27 #   typo. Fix provided by Chris Liddiard.
  28 # November 2006 by Jori Hamalainen
  29 #   Added feature to separate frozen and bounced messages from queue
  30 #   Added feature to list queue per source - destination pair
  31 #   Changed regexps to compile once to very minor speed optimization
  32 #   Short circuit for empty lines
  33 #
  34 # Usage: mailq | exiqsumm [-a] [-b] [-c] [-f] [-s]
  35 #   Default sorting is by domain name
  36 #   -a sorts by age of oldest message
  37 #   -b enables bounce message separation
  38 #   -c sorts by count of message
  39 #   -f enables frozen message separation
  40 #   -s enables source destination separation
  41
  42 # Slightly modified sub from eximstats
  43
  44 use warnings;
  45 BEGIN { pop @INC if $INC[-1] eq '.' };
  46
  47 sub print_volume_rounded {
  48 my($x) = pop @_;
  49 if ($x < 10000)
  50   {
  51   return sprintf("%6d", $x);
  52   }
  53 elsif ($x < 10000000)
  54   {
  55   return sprintf("%4dKB", ($x + 512)/1024);
  56   }
  57 else
  58   {
  59   return sprintf("%4dMB", ($x + 512*1024)/(1024*1024));
  60   }
  61 }
  62
  63 sub s_conv {
  64   my($x) = @_;
  65   my($v,$s) = $x =~ /([\d\.]+)([A-Z]|)/o;
  66   if ($s eq "K") { return $v * 1024 };
  67   if ($s eq "M") { return $v * 1024 * 1024 };
  68   return $v;
  69 }
  70
  71 sub older {
  72   my($x1,$x2) = @_;
  73   my($v1,$s1) = $x1 =~ /(\d+)(\w)/o;
  74   my($v2,$s2) = $x2 =~ /(\d+)(\w)/o;
  75   return $v1 <=> $v2 if ($s1 eq $s2);
  76   return (($s2 eq "m") ||
  77           ($s2 eq "h" && $s1 eq "d") ||
  78           ($s2 eq "d" && $s1 eq "w"))? 1 : -1;
  79 }
  80
  81 #
  82 # Main Program
  83 #
  84
  85 $sort_by_count = 0;
  86 $sort_by_age = 0;
  87
  88 $size = "0";
  89 $age = "0d";
  90 $id = "";
  91
  92
  93 while (@ARGV > 0 && substr($ARGV[0], 0, 1) eq "-")
  94   {
  95   if ($ARGV[0] eq "-a") { $sort_by_age = 1; }
  96   if ($ARGV[0] eq "-c") { $sort_by_count = 1; }
  97   if ($ARGV[0] eq "-f") { $enable_frozen = 1; }
  98   if ($ARGV[0] eq "-b") { $enable_bounces = 1; }
  99   if ($ARGV[0] eq "-s") { $enable_source = 1; }
 100   shift @ARGV;
 101   }
 102
 103 while (<>)
 104 {
 105 # Skip empty and already delivered lines
 106
 107 if (/^$/o || /^\s*D\s\S+/o) { next; }
 108
 109 # If it's the first line of a message, pick out the data. Note: it may
 110 # have text after the final > (e.g. frozen) so don't insist that it ends >.
 111
 112 if (/^([\d\s]{2,3}\w)\s+(\S+)\s(\S+)\s\<(\S*)\>/o)
 113   {
 114   ($age,$size,$id,$src)=($1,$2,$3,$4);
 115   $src =~ s/([^\@]*)\@(.*?)$/$2/o;
 116   if (/\*\*\*\sfrozen\s\*\*\*/o) { $frozen=1; } else { $frozen=0; }
 117   if ($src eq "") { $bounce=1; $src="<>"; } else { $bounce=0; }
 118   }
 119
 120 # Else check for a recipient line: to handle source-routed addresses, just
 121 # pick off the first domain.
 122
 123 elsif (/^\s+[^@]*\@([\w\.\-]+|\[(\d+\.){3}\d+\])/o)
 124   {
 125   if ($enable_source) {
 126       $domain = "\L$src > $1";
 127   } else {
 128       $domain = "\L$1";
 129   }
 130   $domain .= " (b)" if ($bounce && $enable_bounces);
 131   $domain .= " (f)" if ($frozen && $enable_frozen);
 132   $queue{$domain}++;
 133   $q_oldest{$domain} = $age
 134     if (!defined $q_oldest{$domain} || &older($age,$q_oldest{$domain}) > 0);
 135   $q_recent{$domain} = $age
 136     if (!defined $q_recent{$domain} || &older($q_recent{$domain},$age) > 0);
 137   $q_size{$domain} = 0 if (!defined $q_size{$domain});
 138   $q_size{$domain} += &s_conv($size);
 139   }
 140 }
 141
 142 print "\nCount  Volume  Oldest  Newest  Domain";
 143 print "\n-----  ------  ------  ------  ------\n\n";
 144
 145 my ($count, $volume, $max_age, $min_age) = (0, 0, "0m", undef);
 146
 147 foreach $id (sort
 148             {
 149             $sort_by_age? &older($q_oldest{$b}, $q_oldest{$a}) :
 150             $sort_by_count? ($queue{$b} <=> $queue{$a}) :
 151             $a cmp $b
 152             }
 153             keys %queue)
 154   {
 155   printf("%5d  %.6s  %6s  %6s  %.80s\n",
 156     $queue{$id}, &print_volume_rounded($q_size{$id}), $q_oldest{$id},
 157     $q_recent{$id}, $id);
 158     $max_age = $q_oldest{$id} if &older($q_oldest{$id}, $max_age) > 0;
 159     $min_age = $q_recent{$id}
 160       if (!defined $min_age || &older($min_age, $q_recent{$id}) > 0);
 161     $volume += $q_size{$id};
 162     $count += $queue{$id};
 163   }
 164   $min_age ||= "0000d";
 165 printf("---------------------------------------------------------------\n");
 166 printf("%5d  %.6s  %6s  %6s  %.80s\n",
 167   $count, &print_volume_rounded($volume), $max_age, $min_age, "TOTAL");
 168 print "\n";
 169
 170 # End