[clinton/parenscript.git] / src / ps-macrology.lisp

(in-package :parenscript)

;;;; The macrology of the Parenscript language.  Special forms and macros.

;;; parenscript gensyms
(defvar *ps-gensym-counter* 0)

(defun ps-gensym (&optional (prefix "_js"))
  (make-symbol (format nil "~A~A" prefix (incf *ps-gensym-counter*))))

(defmacro with-ps-gensyms (symbols &body body)
  "Evaluate BODY with SYMBOLS bound to unique ParenScript identifiers.

Each element of SYMBOLS is either a symbol or a list of (symbol
gensym-prefix-string)."
  `(let* ,(mapcar (lambda (symbol)
                    (destructuring-bind (symbol &optional prefix)
                        (if (consp symbol)
                            symbol
                            (list symbol))
                      (if prefix
                          `(,symbol (ps-gensym ,prefix))
                          `(,symbol (ps-gensym)))))
                  symbols)
     ,@body))

(defun constant-literal-form-p (form)
  (or (numberp form)
      (stringp form)
      (and (listp form)
           (eql 'js-literal (car form)))))

(defpsmacro defaultf (place value)
  `(setf ,place (or (and (=== undefined ,place) ,value)
		 ,place)))

;;; array literals
(defpsmacro list (&rest values)
  `(array ,@values))

(defpsmacro make-array (&rest inits)
  `(new (*array ,@inits)))

;;; slot access
(defpsmacro slot-value (obj &rest slots)
  (if (null (rest slots))
      `(%js-slot-value ,obj ,(first slots))
      `(slot-value (slot-value ,obj ,(first slots)) ,@(rest slots))))

(defpsmacro with-slots (slots object &rest body)
  (flet ((slot-var (slot) (if (listp slot) (first slot) slot))
	 (slot-symbol (slot) (if (listp slot) (second slot) slot)))
    `(symbol-macrolet ,(mapcar #'(lambda (slot)
				   `(,(slot-var slot) (slot-value ,object ',(slot-symbol slot))))
			       slots)
      ,@body)))

(defpsmacro case (value &rest clauses)
  (labels ((make-clause (val body more)
             (cond ((listp val)
                    (append (mapcar #'list (butlast val))
                            (make-clause (first (last val)) body more)))
                   ((member val '(t otherwise))
                    (make-clause 'default body more))
                   (more `((,val ,@body break)))
                   (t `((,val ,@body))))))
    `(switch ,value ,@(mapcon (lambda (clause)
                                (make-clause (car (first clause))
                                             (cdr (first clause))
                                             (rest clause)))
                              clauses))))

(define-ps-special-form let (expecting bindings &rest body)
  (declare (ignore expecting))
  (let ((defvars (mapcar (lambda (binding) (if (atom binding)
                                               `(defvar ,binding)
                                               `(defvar ,@binding)))
                         bindings)))
    (compile-parenscript-form `(progn ,@defvars ,@body))))

;;; iteration
(defpsmacro dotimes (iter &rest body)
  (let ((var (first iter))
        (times (second iter)))
  `(do ((,var 0 (1+ ,var)))
       ((>= ,var ,times))
     ,@body)))

(defpsmacro dolist (i-array &rest body)
  (let ((var (first i-array))
	(array (second i-array))
	(arrvar (ps-gensym "tmp-arr"))
	(idx (ps-gensym "tmp-i")))
    `(let ((,arrvar ,array))
      (do ((,idx 0 (1+ ,idx)))
	  ((>= ,idx (slot-value ,arrvar 'length)))
	(let ((,var (aref ,arrvar ,idx)))
	  ,@body)))))

;;; macros
(defmacro with-temp-macro-environment ((var) &body body)
  `(let* ((,var (make-macro-env-dictionary))
          (*script-macro-env* (cons ,var *script-macro-env*)))
    ,@body))

(define-ps-special-form macrolet (expecting macros &body body)
  (declare (ignore expecting))
  (with-temp-macro-environment (macro-env-dict)
    (dolist (macro macros)
      (destructuring-bind (name arglist &body body)
          macro
	(setf (get-macro-spec name macro-env-dict)
	      (cons nil (make-ps-macro-function arglist body)))))
    (compile-parenscript-form `(progn ,@body))))

(define-ps-special-form symbol-macrolet (expecting symbol-macros &body body)
  (declare (ignore expecting))
  (with-temp-macro-environment (macro-env-dict)
    (dolist (macro symbol-macros)
      (destructuring-bind (name expansion)
          macro
	(setf (get-macro-spec name macro-env-dict)
	      (cons t (compile nil `(lambda () ',expansion))))))
    (compile-parenscript-form `(progn ,@body))))

(define-ps-special-form defmacro (expecting name args &body body)
  (declare (ignore expecting))
  (define-script-macro% name args body :symbol-macro-p nil)
  nil)

(define-ps-special-form define-symbol-macro (expecting name &body body)
  (declare (ignore expecting))
  (define-script-macro% name () body :symbol-macro-p t)
  nil)

(defpsmacro lisp (&body forms)
  "Evaluates the given forms in Common Lisp at ParenScript
macro-expansion time. The value of the last form is treated as a
ParenScript expression and is inserted into the generated Javascript
\(use nil for no-op)."
  (eval (cons 'progn forms)))

(defpsmacro rebind (variables &body body)
  "Creates a new js lexical environment and copies the given
variable(s) there. Executes the body in the new environment. This
has the same effect as a new (let () ...) form in lisp but works on
the js side for js closures."
  (unless (listp variables)
    (setf variables (list variables)))
  `((lambda ()
      (let ((new-context (new *object)))
        ,@(loop for variable in variables
                collect `(setf (slot-value new-context ,(symbol-to-js variable))
                               ,variable))
        (with new-context
          ,@body)))))

(eval-when (:compile-toplevel :load-toplevel :execute)
  (defun parse-function-body (body)
    ;; (format t "parsing function body ~A~%" body)
    (let* ((documentation
	    (when (stringp (first body))
	      (first body)))
	   (body-forms (if documentation (rest body) body)))
      (values
       body-forms
       documentation)))

  (defun parse-key-spec (key-spec)
    "parses an &key parameter.  Returns 4 values:
var, init-form,  keyword-name, supplied-p-var, init-form-supplied-p.

Syntax of key spec:
[&key {var | ({var | (keyword-name var)} [init-form [supplied-p-parameter]])}*
"
    (let* ((var (cond ((symbolp key-spec) key-spec)
		      ((and (listp key-spec) (symbolp (first key-spec))) (first key-spec))
		      ((and (listp key-spec) (listp (first key-spec)))   (second key-spec))))
	   (keyword-name (if (and (listp key-spec) (listp (first key-spec)))
			     (first (first key-spec))
			     (intern (string var) :keyword)))
	   (init-form (if (listp key-spec) (second key-spec) nil))
	   (init-form-supplied-p (if (listp key-spec) t nil))
	   (supplied-p-var (if (listp key-spec) (third key-spec) nil)))
      (values var init-form keyword-name supplied-p-var init-form-supplied-p)))

  (defun parse-optional-spec (spec)
    "Parses an &optional parameter.  Returns 3 values: var, init-form, supplied-p-var.
[&optional {var | (var [init-form [supplied-p-parameter]])}*] "
    (let* ((var (cond ((symbolp spec) spec)
		      ((and (listp spec) (first spec)))))
	   (init-form (if (listp spec) (second spec)))
	   (supplied-p-var (if (listp spec) (third spec))))
      (values var init-form supplied-p-var)))
  
  (defun parse-aux-spec (spec)
    "Returns two values: variable and init-form"
;; [&aux {var | (var [init-form])}*])
    (values (if (symbolp spec) spec (first spec))
	    (when (listp spec) (second spec))))

  (defun parse-extended-function (lambda-list body &optional name)
    "Returns two values: the effective arguments and body for a function with
the given lambda-list and body."

;; The lambda list is transformed as follows, since a javascript lambda list is just a 
;; list of variable names, and you have access to the arguments variable inside the function:
;; * standard variables are the mapped directly into the js-lambda list
;; * optional variables' variable names are mapped directly into the lambda list,
;;   and for each optional variable with name v and default value d, a form is produced
;;   (defaultf v d)
;; * when any keyword variables are in the lambda list, a single 'optional-args' variable is
;;   appended to the js-lambda list as the last argument.  WITH-SLOTS is used for all
;;   the variables with  inside the body of the function,
    ;;   a (with-slots ((var-name key-name)) optional-args ...)
    (declare (ignore name))
    (multiple-value-bind (requireds optionals rest? rest keys? keys allow? aux? aux
				    more? more-context more-count key-object)
	(parse-lambda-list lambda-list)
      (declare (ignore allow? aux? aux more? more-context more-count))
      (let* ((options-var (or key-object (ps-gensym)))
	     ;; optionals are of form (var default-value)
	     (effective-args
	      (remove-if
	       #'null
	       (append requireds
		       (mapcar #'parse-optional-spec optionals)
		       (when keys (list options-var)))))
	     ;; an alist of arg -> default val
	     (initform-pairs
	      (remove
	       nil
	       (append
		;; optional arguments first
		(mapcar #'(lambda (opt-spec)
			    (multiple-value-bind (var val) (parse-optional-spec opt-spec)
			      (cons var val)))
			optionals)
		(if keys? (list (cons options-var '(create))))
		(mapcar #'(lambda (key-spec)
			    (multiple-value-bind (var val x y specified?) (parse-key-spec key-spec)
			      (declare (ignore x y))
			      (when specified? (cons var val))))
			keys))))
	     (body-paren-forms (parse-function-body body)) ;remove documentation
	     ;;
	     (initform-forms
	      (mapcar #'(lambda (default-pair)
			  `(defaultf ,(car default-pair) ,(cdr default-pair)))
		      initform-pairs))
	     (rest-form
	      (if rest?
                  (with-ps-gensyms (i)
                    `(progn (defvar ,rest array)
                            (dotimes (,i (- arguments.length ,(length effective-args)))
                              (setf (aref ,rest ,i) (aref arguments (+ ,i ,(length effective-args)))))))
		  `(progn)))
	     (effective-body   (append initform-forms (list rest-form) body-paren-forms))
	     (effective-body
	      (if keys?
		  (list `(with-slots ,(mapcar #'(lambda (key-spec)
						  (multiple-value-bind (var x key-name)
						      (parse-key-spec key-spec)
						    (declare (ignore x))
						    (list var key-name)))
					      keys)
			  ,options-var
			  ,@effective-body))
		  effective-body)))
	(values effective-args effective-body)))))

(defpsmacro defun (name lambda-list &body body)
  "An extended defun macro that allows cool things like keyword arguments.
lambda-list::=
 (var* 
  [&optional {var | (var [init-form [supplied-p-parameter]])}*] 
  [&rest var] 
  [&key {var | ({var | (keyword-name var)} [init-form [supplied-p-parameter]])}* [&allow-other-keys]] 
  [&aux {var | (var [init-form])}*])"
  (if (symbolp name)
      `(defun-normal ,name ,lambda-list ,@body)
      (progn (assert (and (= (length name) 2) (eql 'setf (car name))) ()
                     "(defun ~s ~s ...) needs to have a symbol or (setf symbol) for a name." name lambda-list)
             `(defun-setf ,name ,lambda-list ,@body))))

(defpsmacro defun-normal (name lambda-list &body body)
  (multiple-value-bind (effective-args effective-body)
      (parse-extended-function lambda-list body name)
    `(%js-defun ,name ,effective-args
      ,@effective-body)))

(defvar *defun-setf-name-prefix* "__setf_")

(defpsmacro defun-setf (setf-name lambda-list &body body)
  (let ((mangled-function-name (intern (concatenate 'string *defun-setf-name-prefix* (symbol-name (second setf-name)))
                                       (symbol-package (second setf-name))))
        (function-args (cdr (ordered-set-difference lambda-list lambda-list-keywords))))
    `(progn (defsetf ,(second setf-name) ,(cdr lambda-list) (store-var)
              `(,',mangled-function-name ,store-var ,@(list ,@function-args)))
            (defun ,mangled-function-name ,lambda-list ,@body))))

(defpsmacro lambda (lambda-list &body body)
  "An extended defun macro that allows cool things like keyword arguments.
lambda-list::=
 (var* 
  [&optional {var | (var [init-form [supplied-p-parameter]])}*] 
  [&rest var] 
  [&key {var | ({var | (keyword-name var)} [init-form [supplied-p-parameter]])}* [&allow-other-keys]] 
  [&aux {var | (var [init-form])}*])"
  (multiple-value-bind (effective-args effective-body)
      (parse-extended-function lambda-list body)
    `(%js-lambda ,effective-args
      ,@effective-body)))

(defpsmacro defsetf-long (access-fn lambda-list (store-var) form)
  (setf (get-macro-spec access-fn *script-setf-expanders*)
        (compile nil
                 (let ((var-bindings (ordered-set-difference lambda-list lambda-list-keywords)))
                   `(lambda (access-fn-args store-form)
                     (destructuring-bind ,lambda-list
                               access-fn-args
                       (let* ((,store-var (ps-gensym))
                              (gensymed-names (loop repeat ,(length var-bindings) collecting (ps-gensym)))
                              (gensymed-arg-bindings (mapcar #'list gensymed-names (list ,@var-bindings))))
                         (destructuring-bind ,var-bindings
                             gensymed-names
                           `(let (,@gensymed-arg-bindings
                                  (,,store-var ,store-form))
                             ,,form))))))))
  nil)

(defpsmacro defsetf-short (access-fn update-fn &optional docstring)
  (declare (ignore docstring))
  (setf (get-macro-spec access-fn *script-setf-expanders*)
        (lambda (access-fn-args store-form)
          `(,update-fn ,@access-fn-args ,store-form)))
  nil)

(defpsmacro defsetf (access-fn &rest args)
  `(,(if (= (length args) 3) 'defsetf-long 'defsetf-short) ,access-fn ,@args))

(defpsmacro setf (&rest args)
  (flet ((process-setf-clause (place value-form)
           (if (and (listp place) (get-macro-spec (car place) *script-setf-expanders*))
               (funcall (get-macro-spec (car place) *script-setf-expanders*) (cdr place) value-form)
               (let ((exp-place (ps-macroexpand place)))
                 (if (and (listp exp-place) (get-macro-spec (car exp-place) *script-setf-expanders*))
                     (funcall (get-macro-spec (car exp-place) *script-setf-expanders*) (cdr exp-place) value-form)
                     `(setf1% ,exp-place ,value-form))))))
    (assert (evenp (length args)) ()
            "~s does not have an even number of arguments." (cons 'setf args))
    `(progn ,@(loop for (place value) on args by #'cddr collect (process-setf-clause place value)))))
Commit	Line	Data
5aa10005 RD	1	(in-package :parenscript)
	2
	3	;;;; The macrology of the Parenscript language. Special forms and macros.
	4
	5	;;; parenscript gensyms
4a987e2b	6	(defvar ps-gensym-counter 0)
5aa10005	7
4a987e2b	8	(defun ps-gensym (&optional (prefix "_js"))
0c542be0	9	(make-symbol (format nil "~A~A" prefix (incf ps-gensym-counter))))
5aa10005	10
4a987e2b VS	11	(defmacro with-ps-gensyms (symbols &body body)
4a987e2b VS	12	"Evaluate BODY with SYMBOLS bound to unique ParenScript identifiers.
5aa10005 RD	13
5aa10005 RD	14	Each element of SYMBOLS is either a symbol or a list of (symbol
4a987e2b	15	gensym-prefix-string)."
5aa10005 RD	16	`(let* ,(mapcar (lambda (symbol)
	17	(destructuring-bind (symbol &optional prefix)
	18	(if (consp symbol)
	19	symbol
	20	(list symbol))
	21	(if prefix
4a987e2b VS	22	`(,symbol (ps-gensym ,prefix))
4a987e2b VS	23	`(,symbol (ps-gensym)))))
5aa10005 RD	24	symbols)
	25	,@body))
	26
13b8268e VS	27	(defun constant-literal-form-p (form)
	28	(or (numberp form)
	29	(stringp form)
	30	(and (listp form)
	31	(eql 'js-literal (car form)))))
	32
4a987e2b	33	(defpsmacro defaultf (place value)
bbea4c83 RD	34	`(setf ,place (or (and (=== undefined ,place) ,value)
bbea4c83 RD	35	,place)))
46f794a4	36
5aa10005	37	;;; array literals
4a987e2b	38	(defpsmacro list (&rest values)
5aa10005 RD	39	`(array ,@values))
5aa10005 RD	40
4a987e2b	41	(defpsmacro make-array (&rest inits)
5aa10005 RD	42	`(new (*array ,@inits)))
5aa10005 RD	43
bbea4c83	44	;;; slot access
4a987e2b	45	(defpsmacro slot-value (obj &rest slots)
bbea4c83 RD	46	(if (null (rest slots))
	47	`(%js-slot-value ,obj ,(first slots))
	48	`(slot-value (slot-value ,obj ,(first slots)) ,@(rest slots))))
	49
4a987e2b	50	(defpsmacro with-slots (slots object &rest body)
bbea4c83 RD	51	(flet ((slot-var (slot) (if (listp slot) (first slot) slot))
	52	(slot-symbol (slot) (if (listp slot) (second slot) slot)))
	53	`(symbol-macrolet ,(mapcar #'(lambda (slot)
43a1d5c3	54	`(,(slot-var slot) (slot-value ,object ',(slot-symbol slot))))
bbea4c83 RD	55	slots)
	56	,@body)))
	57
4a987e2b	58	(defpsmacro case (value &rest clauses)
5aa10005 RD	59	(labels ((make-clause (val body more)
	60	(cond ((listp val)
	61	(append (mapcar #'list (butlast val))
	62	(make-clause (first (last val)) body more)))
	63	((member val '(t otherwise))
	64	(make-clause 'default body more))
	65	(more `((,val ,@body break)))
	66	(t `((,val ,@body))))))
4a987e2b VS	67	`(switch ,value ,@(mapcon (lambda (clause)
	68	(make-clause (car (first clause))
	69	(cdr (first clause))
	70	(rest clause)))
5aa10005 RD	71	clauses))))
5aa10005 RD	72
4a987e2b	73	(define-ps-special-form let (expecting bindings &rest body)
45f8fec1	74	(declare (ignore expecting))
4a987e2b VS	75	(let ((defvars (mapcar (lambda (binding) (if (atom binding)
	76	`(defvar ,binding)
	77	`(defvar ,@binding)))
	78	bindings)))
	79	(compile-parenscript-form `(progn ,@defvars ,@body))))
5aa10005 RD	80
5aa10005 RD	81	;;; iteration
4a987e2b	82	(defpsmacro dotimes (iter &rest body)
5aa10005 RD	83	(let ((var (first iter))
	84	(times (second iter)))
	85	`(do ((,var 0 (1+ ,var)))
	86	((>= ,var ,times))
	87	,@body)))
	88
4a987e2b	89	(defpsmacro dolist (i-array &rest body)
5aa10005 RD	90	(let ((var (first i-array))
5aa10005 RD	91	(array (second i-array))
4a987e2b VS	92	(arrvar (ps-gensym "tmp-arr"))
4a987e2b VS	93	(idx (ps-gensym "tmp-i")))
5aa10005 RD	94	`(let ((,arrvar ,array))
5aa10005 RD	95	(do ((,idx 0 (1+ ,idx)))
4a987e2b	96	((>= ,idx (slot-value ,arrvar 'length)))
5aa10005 RD	97	(let ((,var (aref ,arrvar ,idx)))
	98	,@body)))))
	99
	100	;;; macros
	101	(defmacro with-temp-macro-environment ((var) &body body)
	102	`(let* ((,var (make-macro-env-dictionary))
	103	(script-macro-env (cons ,var script-macro-env)))
	104	,@body))
	105
4a987e2b	106	(define-ps-special-form macrolet (expecting macros &body body)
45f8fec1	107	(declare (ignore expecting))
5aa10005 RD	108	(with-temp-macro-environment (macro-env-dict)
	109	(dolist (macro macros)
	110	(destructuring-bind (name arglist &body body)
	111	macro
	112	(setf (get-macro-spec name macro-env-dict)
921f2e02	113	(cons nil (make-ps-macro-function arglist body)))))
4a987e2b	114	(compile-parenscript-form `(progn ,@body))))
5aa10005	115
4a987e2b	116	(define-ps-special-form symbol-macrolet (expecting symbol-macros &body body)
45f8fec1	117	(declare (ignore expecting))
5aa10005 RD	118	(with-temp-macro-environment (macro-env-dict)
5aa10005 RD	119	(dolist (macro symbol-macros)
43a1d5c3	120	(destructuring-bind (name expansion)
5aa10005 RD	121	macro
5aa10005 RD	122	(setf (get-macro-spec name macro-env-dict)
43a1d5c3	123	(cons t (compile nil `(lambda () ',expansion))))))
4a987e2b	124	(compile-parenscript-form `(progn ,@body))))
5aa10005	125
4a987e2b	126	(define-ps-special-form defmacro (expecting name args &body body)
45f8fec1	127	(declare (ignore expecting))
d9fc64c9	128	(define-script-macro% name args body :symbol-macro-p nil)
4a987e2b	129	nil)
5aa10005	130
4a987e2b	131	(define-ps-special-form define-symbol-macro (expecting name &body body)
45f8fec1	132	(declare (ignore expecting))
d9fc64c9	133	(define-script-macro% name () body :symbol-macro-p t)
4a987e2b	134	nil)
46f794a4	135
4a987e2b	136	(defpsmacro lisp (&body forms)
5aa10005 RD	137	"Evaluates the given forms in Common Lisp at ParenScript
	138	macro-expansion time. The value of the last form is treated as a
	139	ParenScript expression and is inserted into the generated Javascript
1b2da35c	140	\(use nil for no-op)."
5aa10005 RD	141	(eval (cons 'progn forms)))
5aa10005 RD	142
4a987e2b	143	(defpsmacro rebind (variables &body body)
5aa10005	144	"Creates a new js lexical environment and copies the given
34896dae AL	145	variable(s) there. Executes the body in the new environment. This
	146	has the same effect as a new (let () ...) form in lisp but works on
	147	the js side for js closures."
5aa10005 RD	148	(unless (listp variables)
	149	(setf variables (list variables)))
	150	`((lambda ()
	151	(let ((new-context (new *object)))
	152	,@(loop for variable in variables
34896dae AL	153	collect `(setf (slot-value new-context ,(symbol-to-js variable))
34896dae AL	154	,variable))
5aa10005	155	(with new-context
34896dae	156	,@body)))))
46f794a4	157
46f794a4 RD	158	(eval-when (:compile-toplevel :load-toplevel :execute)
	159	(defun parse-function-body (body)
	160	;; (format t "parsing function body ~A~%" body)
	161	(let* ((documentation
	162	(when (stringp (first body))
	163	(first body)))
	164	(body-forms (if documentation (rest body) body)))
	165	(values
	166	body-forms
	167	documentation)))
	168
	169	(defun parse-key-spec (key-spec)
	170	"parses an &key parameter. Returns 4 values:
	171	var, init-form, keyword-name, supplied-p-var, init-form-supplied-p.
	172
	173	Syntax of key spec:
	174	[&key {var \| ({var \| (keyword-name var)} [init-form [supplied-p-parameter]])}*
	175	"
	176	(let* ((var (cond ((symbolp key-spec) key-spec)
	177	((and (listp key-spec) (symbolp (first key-spec))) (first key-spec))
	178	((and (listp key-spec) (listp (first key-spec))) (second key-spec))))
	179	(keyword-name (if (and (listp key-spec) (listp (first key-spec)))
	180	(first (first key-spec))
	181	(intern (string var) :keyword)))
	182	(init-form (if (listp key-spec) (second key-spec) nil))
	183	(init-form-supplied-p (if (listp key-spec) t nil))
	184	(supplied-p-var (if (listp key-spec) (third key-spec) nil)))
	185	(values var init-form keyword-name supplied-p-var init-form-supplied-p)))
	186
	187	(defun parse-optional-spec (spec)
	188	"Parses an &optional parameter. Returns 3 values: var, init-form, supplied-p-var.
	189	[&optional {var \| (var [init-form [supplied-p-parameter]])}*] "
	190	(let* ((var (cond ((symbolp spec) spec)
	191	((and (listp spec) (first spec)))))
	192	(init-form (if (listp spec) (second spec)))
	193	(supplied-p-var (if (listp spec) (third spec))))
	194	(values var init-form supplied-p-var)))
	195
	196	(defun parse-aux-spec (spec)
	197	"Returns two values: variable and init-form"
	198	;; [&aux {var \| (var [init-form])}*])
	199	(values (if (symbolp spec) spec (first spec))
	200	(when (listp spec) (second spec))))
	201
	202	(defun parse-extended-function (lambda-list body &optional name)
	203	"Returns two values: the effective arguments and body for a function with
	204	the given lambda-list and body."
	205
	206	;; The lambda list is transformed as follows, since a javascript lambda list is just a
	207	;; list of variable names, and you have access to the arguments variable inside the function:
	208	;; * standard variables are the mapped directly into the js-lambda list
	209	;; * optional variables' variable names are mapped directly into the lambda list,
	210	;; and for each optional variable with name v and default value d, a form is produced
	211	;; (defaultf v d)
d989d711	212	;; * when any keyword variables are in the lambda list, a single 'optional-args' variable is
46f794a4 RD	213	;; appended to the js-lambda list as the last argument. WITH-SLOTS is used for all
46f794a4 RD	214	;; the variables with inside the body of the function,
d989d711	215	;; a (with-slots ((var-name key-name)) optional-args ...)
46f794a4	216	(declare (ignore name))
bbea4c83 RD	217	(multiple-value-bind (requireds optionals rest? rest keys? keys allow? aux? aux
bbea4c83 RD	218	more? more-context more-count key-object)
46f794a4	219	(parse-lambda-list lambda-list)
bbea4c83	220	(declare (ignore allow? aux? aux more? more-context more-count))
2e593e4c	221	(let* ((options-var (or key-object (ps-gensym)))
46f794a4 RD	222	;; optionals are of form (var default-value)
	223	(effective-args
	224	(remove-if
	225	#'null
	226	(append requireds
	227	(mapcar #'parse-optional-spec optionals)
	228	(when keys (list options-var)))))
	229	;; an alist of arg -> default val
	230	(initform-pairs
	231	(remove
	232	nil
	233	(append
	234	;; optional arguments first
	235	(mapcar #'(lambda (opt-spec)
	236	(multiple-value-bind (var val) (parse-optional-spec opt-spec)
	237	(cons var val)))
	238	optionals)
	239	(if keys? (list (cons options-var '(create))))
	240	(mapcar #'(lambda (key-spec)
	241	(multiple-value-bind (var val x y specified?) (parse-key-spec key-spec)
	242	(declare (ignore x y))
	243	(when specified? (cons var val))))
	244	keys))))
	245	(body-paren-forms (parse-function-body body)) ;remove documentation
	246	;;
	247	(initform-forms
	248	(mapcar #'(lambda (default-pair)
	249	`(defaultf ,(car default-pair) ,(cdr default-pair)))
	250	initform-pairs))
	251	(rest-form
	252	(if rest?
44934751 VS	253	(with-ps-gensyms (i)
	254	`(progn (defvar ,rest array)
	255	(dotimes (,i (- arguments.length ,(length effective-args)))
	256	(setf (aref ,rest ,i) (aref arguments (+ ,i ,(length effective-args)))))))
46f794a4 RD	257	`(progn)))
	258	(effective-body (append initform-forms (list rest-form) body-paren-forms))
	259	(effective-body
	260	(if keys?
	261	(list `(with-slots ,(mapcar #'(lambda (key-spec)
	262	(multiple-value-bind (var x key-name)
	263	(parse-key-spec key-spec)
	264	(declare (ignore x))
	265	(list var key-name)))
	266	keys)
	267	,options-var
	268	,@effective-body))
	269	effective-body)))
	270	(values effective-args effective-body)))))
	271
4a987e2b	272	(defpsmacro defun (name lambda-list &body body)
46f794a4 RD	273	"An extended defun macro that allows cool things like keyword arguments.
	274	lambda-list::=
	275	(var*
	276	[&optional {var \| (var [init-form [supplied-p-parameter]])}*]
	277	[&rest var]
	278	[&key {var \| ({var \| (keyword-name var)} [init-form [supplied-p-parameter]])}* [&allow-other-keys]]
	279	[&aux {var \| (var [init-form])}*])"
dbb7017b VS	280	(if (symbolp name)
	281	`(defun-normal ,name ,lambda-list ,@body)
	282	(progn (assert (and (= (length name) 2) (eql 'setf (car name))) ()
	283	"(defun ~s ~s ...) needs to have a symbol or (setf symbol) for a name." name lambda-list)
	284	`(defun-setf ,name ,lambda-list ,@body))))
	285
4a987e2b	286	(defpsmacro defun-normal (name lambda-list &body body)
46f794a4 RD	287	(multiple-value-bind (effective-args effective-body)
	288	(parse-extended-function lambda-list body name)
	289	`(%js-defun ,name ,effective-args
	290	,@effective-body)))
	291
dbb7017b VS	292	(defvar defun-setf-name-prefix "__setf_")
dbb7017b VS	293
4a987e2b	294	(defpsmacro defun-setf (setf-name lambda-list &body body)
dbb7017b VS	295	(let ((mangled-function-name (intern (concatenate 'string defun-setf-name-prefix (symbol-name (second setf-name)))
	296	(symbol-package (second setf-name))))
	297	(function-args (cdr (ordered-set-difference lambda-list lambda-list-keywords))))
	298	`(progn (defsetf ,(second setf-name) ,(cdr lambda-list) (store-var)
	299	`(,',mangled-function-name ,store-var ,@(list ,@function-args)))
	300	(defun ,mangled-function-name ,lambda-list ,@body))))
46f794a4	301
4a987e2b	302	(defpsmacro lambda (lambda-list &body body)
46f794a4 RD	303	"An extended defun macro that allows cool things like keyword arguments.
	304	lambda-list::=
	305	(var*
	306	[&optional {var \| (var [init-form [supplied-p-parameter]])}*]
	307	[&rest var]
	308	[&key {var \| ({var \| (keyword-name var)} [init-form [supplied-p-parameter]])}* [&allow-other-keys]]
	309	[&aux {var \| (var [init-form])}*])"
	310	(multiple-value-bind (effective-args effective-body)
	311	(parse-extended-function lambda-list body)
	312	`(%js-lambda ,effective-args
72332f2a VS	313	,@effective-body)))
72332f2a VS	314
4a987e2b	315	(defpsmacro defsetf-long (access-fn lambda-list (store-var) form)
06babcf5	316	(setf (get-macro-spec access-fn script-setf-expanders)
72332f2a	317	(compile nil
cdf9ab0e	318	(let ((var-bindings (ordered-set-difference lambda-list lambda-list-keywords)))
72332f2a VS	319	`(lambda (access-fn-args store-form)
	320	(destructuring-bind ,lambda-list
	321	access-fn-args
4a987e2b VS	322	(let* ((,store-var (ps-gensym))
4a987e2b VS	323	(gensymed-names (loop repeat ,(length var-bindings) collecting (ps-gensym)))
72332f2a VS	324	(gensymed-arg-bindings (mapcar #'list gensymed-names (list ,@var-bindings))))
	325	(destructuring-bind ,var-bindings
	326	gensymed-names
cdf9ab0e	327	`(let (,@gensymed-arg-bindings
03eedaa5	328	(,,store-var ,store-form))
72332f2a VS	329	,,form))))))))
	330	nil)
	331
4a987e2b	332	(defpsmacro defsetf-short (access-fn update-fn &optional docstring)
750651b0	333	(declare (ignore docstring))
06babcf5	334	(setf (get-macro-spec access-fn script-setf-expanders)
750651b0 VS	335	(lambda (access-fn-args store-form)
	336	`(,update-fn ,@access-fn-args ,store-form)))
	337	nil)
	338
	339	(defpsmacro defsetf (access-fn &rest args)
	340	`(,(if (= (length args) 3) 'defsetf-long 'defsetf-short) ,access-fn ,@args))
	341
72332f2a VS	342	(defpsmacro setf (&rest args)
72332f2a VS	343	(flet ((process-setf-clause (place value-form)
06babcf5 VS	344	(if (and (listp place) (get-macro-spec (car place) script-setf-expanders))
06babcf5 VS	345	(funcall (get-macro-spec (car place) script-setf-expanders) (cdr place) value-form)
4a987e2b	346	(let ((exp-place (ps-macroexpand place)))
06babcf5 VS	347	(if (and (listp exp-place) (get-macro-spec (car exp-place) script-setf-expanders))
06babcf5 VS	348	(funcall (get-macro-spec (car exp-place) script-setf-expanders) (cdr exp-place) value-form)
4a987e2b	349	`(setf1% ,exp-place ,value-form))))))
72332f2a VS	350	(assert (evenp (length args)) ()
	351	"~s does not have an even number of arguments." (cons 'setf args))
	352	`(progn ,@(loop for (place value) on args by #'cddr collect (process-setf-clause place value)))))