carriage adapter/itty-wilson.scad

   1 /*
   2 min y = 0
   3 max y = 100
   4 min x = 1205
   5 max x = 1254
   6
   7 Makerfair X carriage plate adapter for the Wilson RepRap.
   8 Copyright (c) 2015 Clinton Ebadi <clinton@unknownlamer.org>
   9
  10     This program is free software: you can redistribute it and/or modify
  11     it under the terms of the GNU General Public License as published by
  12     the Free Software Foundation, either version 3 of the License, or
  13     (at your option) any later version.
  14
  15     This program is distributed in the hope that it will be useful,
  16     but WITHOUT ANY WARRANTY; without even the implied warranty of
  17     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18     GNU General Public License for more details.
  19
  20     You should have received a copy of the GNU General Public License
  21     along with this program.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 Measurements reverse engineered from
  24 https://github.com/RickSisco/MakerFarm-Prusa-i3v-12-Inch
  25
  26 Intended for use with the itty bitty dual extruder series.
  27
  28 Source needs a good cleanup. Evil loops that don't take advantage of
  29 the geometry of the object abound.
  30
  31 major todo:
  32
  33  - square hole placement is a total mess
  34
  35 */
  36
  37 use <MCAD/nuts_and_bolts.scad>
  38
  39 $fn = 64;
  40
  41 hole_tolerance = 0.3; // widen holes a bit, may still need to drill out
  42
  43 // Size of mounting bolt heads so they can be recessed
  44 bolthead_depth = 2;
  45 bolthead_diameter = 5.5 + hole_tolerance;
  46
  47 carriage_height = 64;
  48 carriage_width = 51;
  49
  50 plate_width = 75; // wilson carriage is only 50mm wide!
  51 plate_depth = 6 + bolthead_depth; // wilson default depth = 8, makerfarm = 6
  52
  53 plate_cut_height = 6.5;
  54 plate_cut_width = 6;
  55 plate_cut_distance = 13.3;
  56 plate_cut_y_offset = 27;
  57 plate_cut_bolt = 3 + hole_tolerance;
  58 plate_cut_x_bolt_offset = plate_cut_distance + plate_cut_bolt / 2;
  59
  60 plate_extra_height = 6; // make plate a bit taller so it is structurally sound
  61
  62 plate_height = plate_cut_height + plate_cut_y_offset + plate_extra_height;
  63
  64 lower_cut_y_offset = 5.33; // 5.325 in CAD
  65 lower_bolt_x_offset = 1.5 + plate_cut_bolt / 2;
  66 lower_bolt_y_offset = 3.275 + plate_cut_bolt / 2;
  67
  68 carriage_bolt = 4 + hole_tolerance;
  69 carriage_hole_spacing = 23;
  70 carriage_clearance = 20; // holes are 20mm from bottom of plate
  71 carriage_y_offset =  plate_cut_y_offset + plate_cut_height + carriage_clearance;
  72 carriage_nut_depth = 3.2 + 3.2/2 + 0.1; // m4 nut depth + half of an m4 nut + tolerance
  73 carriage_offset = [(plate_width - carriage_width) / 2, 0 , 0];
  74
  75 corner_radius = 3; // round off the corners to make it look nicer
  76
  77 module itty_wilson () {
  78      difference () {
  79           union () {
  80                translate (carriage_offset) carriage_mount_base ();
  81                shelf_mount_base ();
  82           }
  83           translate (carriage_offset) carriage_mount_holes ();
  84           shelf_mount_holes ();
  85      }
  86 }
  87
  88 itty_wilson ();
  89
  90 // mount to wilson x-carriage
  91 module carriage_mount_base () {
  92      linear_extrude (height = plate_depth, convexity = 8) {
  93           // outline of plate + bolt holes
  94           translate ([corner_radius, corner_radius, 0]) {
  95                minkowski () {
  96                     square ([carriage_width - corner_radius*2, carriage_height - corner_radius*2]);
  97                     circle (r = corner_radius);
  98                }
  99           }
 100      }
 101 }
 102
 103 module carriage_mount_holes () {
 104      #translate ([(carriage_width - carriage_hole_spacing) / 2, (carriage_height - carriage_hole_spacing) /2, 0])
 105      for (x = [0, carriage_hole_spacing], y = [0, carriage_hole_spacing]) {
 106           translate ([x, y, -50.1]) cylinder (d = carriage_bolt, h = plate_depth+100);
 107      }
 108
 109      // after extruding, cut out spaces for M4 hex nuts.
 110      translate ([(carriage_width - carriage_hole_spacing) / 2, (carriage_height - carriage_hole_spacing) /2, plate_depth - carriage_nut_depth]) {
 111           for (x = [0, carriage_hole_spacing], y = [0, carriage_hole_spacing]) {
 112                translate ([x, y, 0]) linear_extrude (height = carriage_nut_depth + 0.01) nutHole (size = carriage_bolt, proj = 1);
 113           }
 114      }
 115 }
 116
 117 // mount for makerfarm extruder shelf
 118 module shelf_mount_base () {
 119      linear_extrude (height = plate_depth, convexity = 8) {
 120           translate ([corner_radius, corner_radius, 0]) {
 121                minkowski () {
 122                     square ([plate_width - corner_radius*2, plate_height - corner_radius*2]);
 123                     circle (r = corner_radius);
 124                }
 125           }
 126      }
 127 }
 128
 129 module shelf_mount_holes () {
 130      depth = plate_depth*2+0.4;
 131      translate ([0, 0, -0.1]) {
 132           // upper shelf mount
 133           translate ([plate_cut_width/2, plate_cut_y_offset, 0]) {
 134                for (x = [-0.001, plate_cut_width + plate_cut_distance,
 135                               plate_width - plate_cut_width + 0.001, plate_width - plate_cut_width*2 - plate_cut_distance])
 136                          translate ([x, plate_cut_height/2, 0]) cube ([plate_cut_width + hole_tolerance, plate_cut_height, depth], center = true);
 137
 138                          // looks like the bolt is at the midpoint between the cut outs
 139                          for (x = [plate_cut_x_bolt_offset - plate_cut_width, plate_width - plate_cut_x_bolt_offset])
 140                               translate ([x, plate_cut_height / 2, 0]) {
 141                                    #cylinder (d = plate_cut_bolt, h = depth);
 142                                    cylinder (d = bolthead_diameter, h = bolthead_depth+0.1);
 143                               }
 144
 145                }
 146
 147                // lower shelf mount
 148                translate ([0, lower_cut_y_offset, 0]) {
 149                     for (x = [plate_cut_width/2 - 0.01, plate_width - plate_cut_width/2 + 0.01]) {
 150                          // lower cut out is closer to 6mm than 6.5mm in cad drawings
 151                          translate ([x, plate_cut_height/2, 0]) cube ([plate_cut_width, plate_cut_height - 0.5, depth*2], center=true);
 152                }
 153                     // I think the intention is for the screw holes to be centered over the cut out
 154                     for (x = [lower_bolt_x_offset, plate_width - lower_bolt_x_offset])
 155                          translate ([x, plate_cut_height + lower_bolt_y_offset, 0]) {
 156                               cylinder (d = plate_cut_bolt, h = depth);
 157                               cylinder (d = bolthead_diameter, h = bolthead_depth+0.1);
 158                          }
 159                }
 160           }
 161 }