(*
 * Dynamic web page generation with Standard ML
 * Copyright (C) 2003  Adam Chlipala
 *
 * This library is free software; you can redistribute it and/or
 * modify it under the terms of the GNU Lesser General Public
 * License as published by the Free Software Foundation; either
 * version 2.1 of the License, or (at your option) any later version.
 *
 * This library is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
 * Lesser General Public License for more details.
 * 
 * You should have received a copy of the GNU Lesser General Public
 * License along with this library; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
 *)

(* CGI interaction *)

structure Web :> WEB =
struct
    val params : string StringMap.map ref = ref StringMap.empty

    val paramStack : string StringMap.map list ref = ref []

    fun setParam (n, v) = params := StringMap.insert (!params, n, v)

    fun getParam v =
	(case StringMap.find (!params, v) of
	     NONE => ""
	   | SOME s => s)

    fun pushParams nvs =
	(paramStack := (!params) :: (!paramStack);
	 app setParam nvs)

    fun popParams () =
	(case !paramStack of
	     [] => raise Fail "Empty params stack in popParams"
	   | h::t => (params := h;
		      paramStack := t))

    fun withParams f nvs =
	(pushParams nvs;
	 ((f ()) handle ex => (popParams (); raise ex))
	 before popParams ())

    val text = ref ([] : string list)

    fun print x = text := x :: (!text)

    fun output () =
	(TextIO.print "Status: 200\nContent-type: text/html\n\n";
	 TextIO.print (String.concat (List.rev (!text))))
end