+
+dnl GUILE_GNU_LD_RELRO
+dnl
+dnl Check whether GNU ld's read-only relocations (the `PT_GNU_RELRO'
+dnl ELF segment header) are supported. This allows things like
+dnl statically allocated cells (1) to eventually be remapped read-only
+dnl by the loader, and (2) to be identified as pointerless by the
+dnl garbage collector. Substitute `GNU_LD_FLAGS' with the relevant
+dnl flags.
+AC_DEFUN([GUILE_GNU_LD_RELRO], [
+ AC_MSG_CHECKING([whether the linker understands `-z relro'])
+
+ GNU_LD_FLAGS="-Wl,-z -Wl,relro"
+
+ save_LDFLAGS="$LDFLAGS"
+ LDFLAGS="$LDFLAGS $GNU_LD_FLAGS"
+ AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
+ [AC_MSG_RESULT([yes])],
+ [AC_MSG_RESULT([no])
+ GNU_LD_FLAGS=""])
+ LDFLAGS="$save_LDFLAGS"
+
+ AC_SUBST([GNU_LD_FLAGS])
+])
+
+dnl GUILE_THREAD_LOCAL_STORAGE
+dnl
+dnl Check for compiler thread-local storage (TLS) support.
+AC_DEFUN([GUILE_THREAD_LOCAL_STORAGE], [
+ AC_REQUIRE([AC_CANONICAL_HOST])
+
+ AC_CACHE_CHECK([whether the `__thread' storage class is available],
+ [ac_cv_have_thread_storage_class],
+ [dnl On some systems, e.g., NetBSD 5.0 with GCC 4.1, `__thread' is
+ dnl properly compiled but fails to link due to the lack of TLS
+ dnl support in the C library. Thus we try to link, not just
+ dnl compile. Unfortunately, this test is not enough, so we
+ dnl explicitly check for known-broken systems. See
+ dnl http://lists.gnu.org/archive/html/guile-devel/2009-10/msg00138.html
+ dnl for details.
+ dnl
+ dnl Known broken systems includes:
+ dnl - x86_64-unknown-netbsd5.0.
+ dnl - x86_64-unknown-netbsd5.1
+ dnl - sparc-sun-solaris2.8
+ dnl
+ dnl On `x86_64-unknown-freebsd8.0', thread-local storage appears to
+ dnl be reclaimed at the wrong time, leading to a segfault when
+ dnl running `threads.test'. So disable it.
+ case "$enable_shared--$host_os" in
+ [yes--netbsd[0-5].[0-9]*|yes--solaris2.8|yes--freebsd[0-8]*])
+ ac_cv_have_thread_storage_class="no"
+ ;;
+ *)
+ AC_LINK_IFELSE([AC_LANG_PROGRAM([__thread int tls_integer;],
+ [tls_integer = 123;])],
+ [ac_cv_have_thread_storage_class="yes"],
+ [ac_cv_have_thread_storage_class="no"])
+ ;;
+ esac])
+
+ if test "x$ac_cv_have_thread_storage_class" = "xyes"; then
+ SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=1
+ else
+ SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0
+ fi
+
+ AC_SUBST([SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS])
+])
+
+dnl GUILE_READLINE
+dnl
+dnl Check all the things needed by `guile-readline', the Readline
+dnl bindings.
+AC_DEFUN([GUILE_READLINE], [
+ for termlib in ncurses curses termcap terminfo termlib pdcurses ; do
+ AC_CHECK_LIB(${termlib}, [tgoto],
+ [READLINE_LIBS="-l${termlib} $READLINE_LIBS"; break])
+ done
+
+ AC_LIB_LINKFLAGS([readline])
+
+ if test "x$LTLIBREADLINE" = "x"; then
+ AC_MSG_WARN([GNU Readline was not found on your system.])
+ else
+ rl_save_LIBS="$LIBS"
+ LIBS="$LIBREADLINE $READLINE_LIBS $LIBS"
+
+ AC_CHECK_FUNCS([siginterrupt rl_clear_signals rl_cleanup_after_signal])
+
+ dnl Check for modern readline naming
+ AC_CHECK_FUNCS([rl_filename_completion_function])
+ AC_CHECK_DECLS([rl_catch_signals, rl_catch_sigwinch], [], [],
+ [[#include <stdio.h>]
+ [#include <readline/readline.h>]])
+
+ dnl Check for rl_get_keymap. We only use this for deciding whether to
+ dnl install paren matching on the Guile command line (when using
+ dnl readline for input), so it's completely optional.
+ AC_CHECK_FUNCS([rl_get_keymap])
+
+ AC_CACHE_CHECK([for rl_getc_function pointer in readline],
+ ac_cv_var_rl_getc_function,
+ [AC_TRY_LINK([
+ #include <stdio.h>
+ #include <readline/readline.h>],
+ [printf ("%ld", (long) rl_getc_function)],
+ [ac_cv_var_rl_getc_function=yes],
+ [ac_cv_var_rl_getc_function=no])])
+ if test "${ac_cv_var_rl_getc_function}" = "yes"; then
+ AC_DEFINE([HAVE_RL_GETC_FUNCTION], 1,
+ [Define if your readline library has the rl_getc_function variable.])
+ fi
+
+ if test $ac_cv_var_rl_getc_function = no; then
+ AC_MSG_WARN([*** GNU Readline is too old on your system.])
+ AC_MSG_WARN([*** You need readline version 2.1 or later.])
+ LTLIBREADLINE=""
+ LIBREADLINE=""
+ fi
+
+ LIBS="$rl_save_LIBS"
+
+ READLINE_LIBS="$LTLIBREADLINE $READLINE_LIBS"
+ fi
+
+ AM_CONDITIONAL([HAVE_READLINE], [test "x$LTLIBREADLINE" != "x"])
+
+ AC_CHECK_FUNCS([strdup])
+
+ AC_SUBST([READLINE_LIBS])
+])
+
+dnl GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT
+dnl
+dnl Check whether libunistring has iconv support. When it lacks iconv
+dnl support, `mem_iconveh' returns -1 (ENOSYS) and conversions from one
+dnl codeset to another do not work.
+AC_DEFUN([GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT], [
+ AC_CACHE_CHECK([whether libunistring was built with iconv support],
+ [ac_cv_libunistring_with_iconv_support], [
+ save_LIBS=$LIBS
+ LIBS="$LIBS $LIBUNISTRING"
+ AC_RUN_IFELSE([AC_LANG_SOURCE([[
+ #include <uniconv.h>
+ #include <unistring/iconveh.h>
+ int
+ main (int argc, char *argv[])
+ {
+ size_t result_size;
+ return (NULL == u32_conv_from_encoding ("ASCII", iconveh_question_mark,
+ "a", 1,
+ NULL, NULL, &result_size));
+ }
+ ]])],
+ [ac_cv_libunistring_with_iconv_support=yes],
+ [ac_cv_libunistring_with_iconv_support=no],
+ [ac_cv_libunistring_with_iconv_support=yes])
+ LIBS=$save_LIBS
+ ])
+])
+
+dnl GUILE_UNISTRING_CONSTANT NAME
+dnl
+dnl Determine the compile-time value of NAME and define/substitute
+dnl `SCM_I_GSC_NAME'.
+AC_DEFUN([GUILE_UNISTRING_CONSTANT], [
+ m4_pushdef([UPPER_CASE_NAME],
+ [m4_translit([$1],[abcdefghijklmnopqrstuvwxyz],
+ [ABCDEFGHIJKLMNOPQRSTUVWXYZ])])
+
+ AC_CACHE_CHECK([the value of `$1'], [ac_cv_]$1, [
+ AC_COMPUTE_INT([ac_cv_]$1, [$1],
+ [AC_INCLUDES_DEFAULT
+#include <uniconv.h>
+],
+ [AC_MSG_ERROR([failed to determine the value of `$1'])])
+ ])
+
+ [SCM_I_GSC_]UPPER_CASE_NAME="$ac_cv_[]$1"
+ AC_SUBST([SCM_I_GSC_]UPPER_CASE_NAME)
+ m4_popdef([UPPER_CASE_NAME])])
+
+dnl GUILE_UNISTRING_ICONVEH_VALUES
+dnl
+dnl Determine the values of the `iconveh_' libunistring constants.
+AC_DEFUN([GUILE_UNISTRING_ICONVEH_VALUES], [
+ GUILE_UNISTRING_CONSTANT([iconveh_error])
+ GUILE_UNISTRING_CONSTANT([iconveh_question_mark])
+ GUILE_UNISTRING_CONSTANT([iconveh_escape_sequence])
+])
+
+dnl GUILE_CHECK_VERSION
+dnl
+dnl Ensure that $GUILE_FOR_BUILD has the same version as ourselves.
+AC_DEFUN([GUILE_CHECK_VERSION], [
+ if ! "$GUILE_FOR_BUILD" --version > /dev/null 2>&1; then
+ AC_MSG_ERROR([failed to run `$GUILE_FOR_BUILD'])
+ fi
+
+ dnl Use MAJOR.MINOR.MICRO instead of (version) so that developers can
+ dnl freely shoot themselves in the foot by using, say, 2.0.3.80 and
+ dnl 2.0.3.42.
+ AC_CACHE_CHECK([the version of $GUILE_FOR_BUILD],
+ [ac_cv_guile_for_build_version],
+ [ac_cv_guile_for_build_version="`"$GUILE_FOR_BUILD" \
+ -c '(format #t "~a.~a.~a" (major-version) (minor-version) (micro-version))'`"
+ ])
+
+ if test "$ac_cv_guile_for_build_version" != \
+ "$GUILE_MAJOR_VERSION.$GUILE_MINOR_VERSION.$GUILE_MICRO_VERSION"
+ then
+ AC_MSG_ERROR([building Guile $PACKAGE_VERSION but `$GUILE_FOR_BUILD' has version $ac_cv_guile_for_build_version"])
+ fi
+])
+
+dnl GUILE_CHECK_GUILE_FOR_BUILD
+dnl
+dnl When cross-compiling, ensure that $GUILE_FOR_BUILD is suitable.
+AC_DEFUN([GUILE_CHECK_GUILE_FOR_BUILD], [
+ if test "$cross_compiling" = "yes"; then
+ if test "x$GUILE_FOR_BUILD" = "x"; then
+ AC_PATH_PROG([GUILE_FOR_BUILD], [guile], [not-found])
+ if test "$GUILE_FOR_BUILD" = "not-found"; then
+ AC_MSG_ERROR([a native Guile $PACKAGE_VERSION is required to cross-build Guile])
+ fi
+ fi
+ AC_MSG_CHECKING([guile for build])
+ AC_MSG_RESULT([$GUILE_FOR_BUILD])
+
+ dnl Since there is currently no distinction between the run-time
+ dnl search path, %load-path, and the compiler's search path,
+ dnl $GUILE_FOR_BUILD must be a native build of the very same version.
+ GUILE_CHECK_VERSION
+ else
+ GUILE_FOR_BUILD='this-value-will-never-be-used'
+ fi
+
+ AC_ARG_VAR([GUILE_FOR_BUILD], [guile for the build system])
+ AM_SUBST_NOTMAKE([GUILE_FOR_BUILD])
+])
+
+dnl Declare file $1 to be a script that needs configuring,
+dnl and arrange to make it executable in the process.
+AC_DEFUN([GUILE_CONFIG_SCRIPT],[AC_CONFIG_FILES([$1],[chmod +x $1])])