module/srfi/srfi-45.scm

   1 ;;; srfi-45.scm -- Primitives for Expressing Iterative Lazy Algorithms
   2
   3 ;; Copyright (C) 2010, 2011, 2013 Free Software Foundation, Inc.
   4 ;; Copyright (C) 2003 André van Tonder. All Rights Reserved.
   5
   6 ;; Permission is hereby granted, free of charge, to any person
   7 ;; obtaining a copy of this software and associated documentation
   8 ;; files (the "Software"), to deal in the Software without
   9 ;; restriction, including without limitation the rights to use, copy,
  10 ;; modify, merge, publish, distribute, sublicense, and/or sell copies
  11 ;; of the Software, and to permit persons to whom the Software is
  12 ;; furnished to do so, subject to the following conditions:
  13
  14 ;; The above copyright notice and this permission notice shall be
  15 ;; included in all copies or substantial portions of the Software.
  16
  17 ;; THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  18 ;; EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  19 ;; MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  20 ;; NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS
  21 ;; BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN
  22 ;; ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  23 ;; CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  24 ;; SOFTWARE.
  25
  26 ;;; Commentary:
  27
  28 ;; This is the code of the reference implementation of SRFI-45,
  29 ;; modified to use SRFI-9 and to support multiple values.
  30
  31 ;; This module is documented in the Guile Reference Manual.
  32
  33 ;;; Code:
  34
  35 (define-module (srfi srfi-45)
  36   #:export (delay
  37              lazy
  38              force
  39              eager
  40              promise?)
  41   #:replace (delay force promise?)
  42   #:use-module (srfi srfi-9))
  43
  44 (define-record-type promise (make-promise val) promise?
  45   (val promise-val promise-val-set!))
  46
  47 (define-record-type value (make-value tag proc) value?
  48   (tag value-tag value-tag-set!)
  49   (proc value-proc value-proc-set!))
  50
  51 (define-syntax-rule (lazy exp)
  52   (make-promise (make-value 'lazy (lambda () exp))))
  53
  54 (define (eager . xs)
  55   (make-promise (make-value 'eager xs)))
  56
  57 (define-syntax-rule (delay exp)
  58   (lazy (call-with-values
  59             (lambda () exp)
  60           eager)))
  61
  62 (define (force promise)
  63   (let ((content (promise-val promise)))
  64     (case (value-tag content)
  65       ((eager) (apply values (value-proc content)))
  66       ((lazy)  (let* ((promise* ((value-proc content)))
  67                       (content  (promise-val promise)))        ; *
  68                  (if (not (eqv? (value-tag content) 'eager))   ; *
  69                      (begin (value-tag-set! content
  70                                             (value-tag (promise-val promise*)))
  71                             (value-proc-set! content
  72                                              (value-proc (promise-val promise*)))
  73                             (promise-val-set! promise* content)))
  74                  (force promise))))))
  75
  76 ;; (*) These two lines re-fetch and check the original promise in case
  77 ;;     the first line of the let* caused it to be forced.  For an example
  78 ;;     where this happens, see reentrancy test 3 below.