| 1 | # sys_select_h.m4 serial 20 |
| 2 | dnl Copyright (C) 2006-2014 Free Software Foundation, Inc. |
| 3 | dnl This file is free software; the Free Software Foundation |
| 4 | dnl gives unlimited permission to copy and/or distribute it, |
| 5 | dnl with or without modifications, as long as this notice is preserved. |
| 6 | |
| 7 | AC_DEFUN([gl_HEADER_SYS_SELECT], |
| 8 | [ |
| 9 | AC_REQUIRE([AC_C_RESTRICT]) |
| 10 | AC_REQUIRE([gl_SYS_SELECT_H_DEFAULTS]) |
| 11 | AC_CACHE_CHECK([whether <sys/select.h> is self-contained], |
| 12 | [gl_cv_header_sys_select_h_selfcontained], |
| 13 | [ |
| 14 | dnl Test against two bugs: |
| 15 | dnl 1. On many platforms, <sys/select.h> assumes prior inclusion of |
| 16 | dnl <sys/types.h>. |
| 17 | dnl 2. On OSF/1 4.0, <sys/select.h> provides only a forward declaration |
| 18 | dnl of 'struct timeval', and no definition of this type. |
| 19 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/select.h>]], |
| 20 | [[struct timeval b;]])], |
| 21 | [gl_cv_header_sys_select_h_selfcontained=yes], |
| 22 | [gl_cv_header_sys_select_h_selfcontained=no]) |
| 23 | dnl Test against another bug: |
| 24 | dnl 3. On Solaris 10, <sys/select.h> provides an FD_ZERO implementation |
| 25 | dnl that relies on memset(), but without including <string.h>. |
| 26 | if test $gl_cv_header_sys_select_h_selfcontained = yes; then |
| 27 | AC_COMPILE_IFELSE( |
| 28 | [AC_LANG_PROGRAM([[#include <sys/select.h>]], |
| 29 | [[int memset; int bzero;]]) |
| 30 | ], |
| 31 | [AC_LINK_IFELSE( |
| 32 | [AC_LANG_PROGRAM([[#include <sys/select.h>]], [[ |
| 33 | #undef memset |
| 34 | #define memset nonexistent_memset |
| 35 | extern |
| 36 | #ifdef __cplusplus |
| 37 | "C" |
| 38 | #endif |
| 39 | void *memset (void *, int, unsigned long); |
| 40 | #undef bzero |
| 41 | #define bzero nonexistent_bzero |
| 42 | extern |
| 43 | #ifdef __cplusplus |
| 44 | "C" |
| 45 | #endif |
| 46 | void bzero (void *, unsigned long); |
| 47 | fd_set fds; |
| 48 | FD_ZERO (&fds); |
| 49 | ]]) |
| 50 | ], |
| 51 | [], |
| 52 | [gl_cv_header_sys_select_h_selfcontained=no]) |
| 53 | ]) |
| 54 | fi |
| 55 | ]) |
| 56 | dnl <sys/select.h> is always overridden, because of GNULIB_POSIXCHECK. |
| 57 | gl_CHECK_NEXT_HEADERS([sys/select.h]) |
| 58 | if test $ac_cv_header_sys_select_h = yes; then |
| 59 | HAVE_SYS_SELECT_H=1 |
| 60 | else |
| 61 | HAVE_SYS_SELECT_H=0 |
| 62 | fi |
| 63 | AC_SUBST([HAVE_SYS_SELECT_H]) |
| 64 | gl_PREREQ_SYS_H_WINSOCK2 |
| 65 | |
| 66 | dnl Check for declarations of anything we want to poison if the |
| 67 | dnl corresponding gnulib module is not in use. |
| 68 | gl_WARN_ON_USE_PREPARE([[ |
| 69 | /* Some systems require prerequisite headers. */ |
| 70 | #include <sys/types.h> |
| 71 | #if !(defined __GLIBC__ && !defined __UCLIBC__) && HAVE_SYS_TIME_H |
| 72 | # include <sys/time.h> |
| 73 | #endif |
| 74 | #include <sys/select.h> |
| 75 | ]], [pselect select]) |
| 76 | ]) |
| 77 | |
| 78 | AC_DEFUN([gl_SYS_SELECT_MODULE_INDICATOR], |
| 79 | [ |
| 80 | dnl Use AC_REQUIRE here, so that the default settings are expanded once only. |
| 81 | AC_REQUIRE([gl_SYS_SELECT_H_DEFAULTS]) |
| 82 | gl_MODULE_INDICATOR_SET_VARIABLE([$1]) |
| 83 | dnl Define it also as a C macro, for the benefit of the unit tests. |
| 84 | gl_MODULE_INDICATOR_FOR_TESTS([$1]) |
| 85 | ]) |
| 86 | |
| 87 | AC_DEFUN([gl_SYS_SELECT_H_DEFAULTS], |
| 88 | [ |
| 89 | GNULIB_PSELECT=0; AC_SUBST([GNULIB_PSELECT]) |
| 90 | GNULIB_SELECT=0; AC_SUBST([GNULIB_SELECT]) |
| 91 | dnl Assume proper GNU behavior unless another module says otherwise. |
| 92 | HAVE_PSELECT=1; AC_SUBST([HAVE_PSELECT]) |
| 93 | REPLACE_PSELECT=0; AC_SUBST([REPLACE_PSELECT]) |
| 94 | REPLACE_SELECT=0; AC_SUBST([REPLACE_SELECT]) |
| 95 | ]) |