| 1 | dnl configuration script for Guile |
| 2 | dnl Process this file with autoconf to produce configure. |
| 3 | dnl |
| 4 | |
| 5 | define(GUILE_CONFIGURE_COPYRIGHT,[[ |
| 6 | |
| 7 | Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006, |
| 8 | 2007, 2008, 2009, 2010, 2011, 2012, 2013 Free Software Foundation, Inc. |
| 9 | |
| 10 | This file is part of GUILE |
| 11 | |
| 12 | GUILE is free software; you can redistribute it and/or modify it under |
| 13 | the terms of the GNU Lesser General Public License as published by the |
| 14 | Free Software Foundation; either version 3, or (at your option) any |
| 15 | later version. |
| 16 | |
| 17 | GUILE is distributed in the hope that it will be useful, but WITHOUT |
| 18 | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or |
| 19 | FITNESS FOR A PARTICULAR PURPOSE. See the GNU Lesser General Public |
| 20 | License for more details. |
| 21 | |
| 22 | You should have received a copy of the GNU Lesser General Public |
| 23 | License along with GUILE; see the file COPYING.LESSER. If not, write |
| 24 | to the Free Software Foundation, Inc., 51 Franklin Street, Fifth |
| 25 | Floor, Boston, MA 02110-1301, USA. |
| 26 | |
| 27 | ]]) |
| 28 | |
| 29 | AC_PREREQ(2.61) |
| 30 | |
| 31 | AC_INIT([GNU Guile], |
| 32 | m4_esyscmd([build-aux/git-version-gen --match v2.\[12\].\* .tarball-version]), |
| 33 | [bug-guile@gnu.org]) |
| 34 | AC_CONFIG_AUX_DIR([build-aux]) |
| 35 | AC_CONFIG_MACRO_DIR([m4]) |
| 36 | AC_CONFIG_SRCDIR(GUILE-VERSION) |
| 37 | |
| 38 | dnl Use `serial-tests' so the output `check-guile' is not hidden |
| 39 | dnl (`parallel-tests' is the default in Automake 1.13.) |
| 40 | dnl `serial-tests' was introduced in Automake 1.12. |
| 41 | AM_INIT_AUTOMAKE([1.12 gnu no-define -Wall -Wno-override \ |
| 42 | serial-tests color-tests dist-xz]) |
| 43 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [AC_SUBST([AM_DEFAULT_VERBOSITY],1)]) |
| 44 | |
| 45 | AC_COPYRIGHT(GUILE_CONFIGURE_COPYRIGHT) |
| 46 | AC_CONFIG_SRCDIR([GUILE-VERSION]) |
| 47 | |
| 48 | . $srcdir/GUILE-VERSION |
| 49 | GUILE_VERSION="$PACKAGE_VERSION" |
| 50 | |
| 51 | AC_CONFIG_HEADERS([config.h]) |
| 52 | AH_TOP(/*GUILE_CONFIGURE_COPYRIGHT*/) |
| 53 | |
| 54 | #-------------------------------------------------------------------- |
| 55 | |
| 56 | AC_LANG([C]) |
| 57 | |
| 58 | dnl Some more checks for Win32 |
| 59 | AC_CANONICAL_HOST |
| 60 | |
| 61 | AC_LIBTOOL_WIN32_DLL |
| 62 | |
| 63 | AC_PROG_INSTALL |
| 64 | AC_PROG_CC |
| 65 | gl_EARLY |
| 66 | AC_PROG_CPP |
| 67 | AC_PROG_SED |
| 68 | AC_PROG_AWK |
| 69 | AC_PROG_LN_S |
| 70 | AM_PROG_AR |
| 71 | |
| 72 | dnl Gnulib. |
| 73 | gl_INIT |
| 74 | |
| 75 | AC_PROG_CC_C89 |
| 76 | |
| 77 | # for per-target cflags in the libguile subdir |
| 78 | AM_PROG_CC_C_O |
| 79 | |
| 80 | AC_LIBTOOL_DLOPEN |
| 81 | AC_PROG_LIBTOOL |
| 82 | |
| 83 | AM_CONDITIONAL([HAVE_SHARED_LIBRARIES], [test "x$enable_shared" = "xyes"]) |
| 84 | |
| 85 | dnl Check for libltdl. |
| 86 | AC_LIB_HAVE_LINKFLAGS([ltdl], [], [#include <ltdl.h>], |
| 87 | [lt_dlopenext ("foo");]) |
| 88 | if test "x$HAVE_LIBLTDL" != "xyes"; then |
| 89 | AC_MSG_ERROR([GNU libltdl (Libtool) not found, see README.]) |
| 90 | fi |
| 91 | |
| 92 | AC_CHECK_PROG(have_makeinfo, makeinfo, yes, no) |
| 93 | AM_CONDITIONAL(HAVE_MAKEINFO, test "$have_makeinfo" = yes) |
| 94 | |
| 95 | AM_PATH_LISPDIR |
| 96 | |
| 97 | AC_DEFINE_UNQUOTED([HOST_TYPE], ["$host"], |
| 98 | [Define to the host's GNU triplet.]) |
| 99 | |
| 100 | #-------------------------------------------------------------------- |
| 101 | # |
| 102 | # User options (after above tests that may set default CFLAGS etc.) |
| 103 | # |
| 104 | #-------------------------------------------------------------------- |
| 105 | |
| 106 | GUILE_ERROR_ON_WARNING="no" |
| 107 | |
| 108 | AC_ARG_ENABLE(error-on-warning, |
| 109 | [ --enable-error-on-warning treat compile warnings as errors], |
| 110 | [case "${enableval}" in |
| 111 | yes | y) GUILE_ERROR_ON_WARNING="yes" ;; |
| 112 | no | n) GUILE_ERROR_ON_WARNING="no" ;; |
| 113 | *) AC_MSG_ERROR(bad value ${enableval} for --enable-error-on-warning) ;; |
| 114 | esac]) |
| 115 | |
| 116 | AC_ARG_ENABLE(debug-malloc, |
| 117 | [ --enable-debug-malloc include malloc debugging code], |
| 118 | if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then |
| 119 | AC_DEFINE([GUILE_DEBUG_MALLOC], 1, |
| 120 | [Define this if you want to debug scm_must_malloc/realloc/free calls.]) |
| 121 | fi) |
| 122 | |
| 123 | SCM_I_GSC_GUILE_DEBUG=0 |
| 124 | AC_ARG_ENABLE(guile-debug, |
| 125 | [AS_HELP_STRING([--enable-guile-debug], |
| 126 | [include internal debugging functions])], |
| 127 | if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then |
| 128 | SCM_I_GSC_GUILE_DEBUG=1 |
| 129 | fi) |
| 130 | |
| 131 | AC_ARG_ENABLE(posix, |
| 132 | [ --disable-posix omit non-essential POSIX interfaces],, |
| 133 | enable_posix=yes) |
| 134 | |
| 135 | AC_ARG_ENABLE(networking, |
| 136 | [ --disable-networking omit networking interfaces],, |
| 137 | enable_networking=yes) |
| 138 | |
| 139 | AC_ARG_ENABLE(regex, |
| 140 | [ --disable-regex omit regular expression interfaces],, |
| 141 | enable_regex=yes) |
| 142 | |
| 143 | AC_ARG_ENABLE([deprecated], |
| 144 | AS_HELP_STRING([--disable-deprecated],[omit deprecated features])) |
| 145 | |
| 146 | if test "$enable_deprecated" = no; then |
| 147 | SCM_I_GSC_ENABLE_DEPRECATED=0 |
| 148 | warn_default=no |
| 149 | else |
| 150 | if test "$enable_deprecated" = yes || test "$enable_deprecated" = ""; then |
| 151 | warn_default=summary |
| 152 | elif test "$enable_deprecated" = shutup; then |
| 153 | warn_default=no |
| 154 | else |
| 155 | warn_default=$enable_deprecated |
| 156 | fi |
| 157 | SCM_I_GSC_ENABLE_DEPRECATED=1 |
| 158 | fi |
| 159 | AC_DEFINE_UNQUOTED([SCM_WARN_DEPRECATED_DEFAULT], "$warn_default", |
| 160 | [Define this to control the default warning level for deprecated features.]) |
| 161 | |
| 162 | dnl Added the following configure option in January 2008 following |
| 163 | dnl investigation of problems with "64" system and library calls on |
| 164 | dnl Darwin (MacOS X). The libguile code (_scm.h) assumes that if a |
| 165 | dnl system has stat64, it will have all the other 64 APIs too; but on |
| 166 | dnl Darwin, stat64 is there but other APIs are missing. |
| 167 | dnl |
| 168 | dnl It also appears, from the Darwin docs, that most system call APIs |
| 169 | dnl there (i.e. the traditional ones _without_ "64" in their names) have |
| 170 | dnl been 64-bit-capable for a long time now, so it isn't necessary to |
| 171 | dnl use "64" versions anyway. For example, Darwin's off_t is 64-bit. |
| 172 | dnl |
| 173 | dnl A similar problem has been reported for HP-UX: |
| 174 | dnl http://www.nabble.com/Building-guile-1.8.2-on-hpux-td13106681.html |
| 175 | dnl |
| 176 | dnl Therefore, and also because a Guile without LARGEFILE64 support is |
| 177 | dnl better than no Guile at all, we provide this option to suppress |
| 178 | dnl trying to use "64" calls. |
| 179 | dnl |
| 180 | dnl It may be that for some 64-bit function on Darwin/HP-UX we do need |
| 181 | dnl to use a "64" call, and hence that by using --without-64-calls we're |
| 182 | dnl missing out on that. If so, someone can work on that in the future. |
| 183 | dnl For now, --without-64-calls allows Guile to build on OSs where it |
| 184 | dnl wasn't building before. |
| 185 | AC_MSG_CHECKING([whether to use system and library "64" calls]) |
| 186 | AC_ARG_WITH([64-calls], |
| 187 | AS_HELP_STRING([--without-64-calls], |
| 188 | [don't attempt to use system and library calls with "64" in their names]), |
| 189 | [use_64_calls=$withval], |
| 190 | [use_64_calls=yes |
| 191 | case $host in |
| 192 | *-apple-darwin* ) |
| 193 | use_64_calls=no |
| 194 | ;; |
| 195 | powerpc-ibm-aix* ) |
| 196 | use_64_calls=no |
| 197 | ;; |
| 198 | esac]) |
| 199 | AC_MSG_RESULT($use_64_calls) |
| 200 | case "$use_64_calls" in |
| 201 | y* ) |
| 202 | AC_DEFINE([GUILE_USE_64_CALLS], 1, |
| 203 | [Define to 1 in order to try to use "64" versions of system and library calls.]) |
| 204 | ;; |
| 205 | esac |
| 206 | |
| 207 | #-------------------------------------------------------------------- |
| 208 | |
| 209 | dnl Check for dynamic linking |
| 210 | |
| 211 | use_modules=yes |
| 212 | AC_ARG_WITH(modules, |
| 213 | [ --with-modules[=FILES] Add support for dynamic modules], |
| 214 | use_modules="$withval") |
| 215 | test -z "$use_modules" && use_modules=yes |
| 216 | DLPREOPEN= |
| 217 | if test "$use_modules" != no; then |
| 218 | if test "$use_modules" = yes; then |
| 219 | DLPREOPEN="-dlpreopen force" |
| 220 | else |
| 221 | DLPREOPEN="-export-dynamic" |
| 222 | for module in $use_modules; do |
| 223 | DLPREOPEN="$DLPREOPEN -dlopen $module" |
| 224 | done |
| 225 | fi |
| 226 | fi |
| 227 | |
| 228 | dnl files which are destined for separate modules. |
| 229 | |
| 230 | if test "$use_modules" != no; then |
| 231 | AC_LIBOBJ([dynl]) |
| 232 | AC_DEFINE([HAVE_MODULES], 1, |
| 233 | [Define this if you want support for dynamically loaded modules in Guile.]) |
| 234 | fi |
| 235 | |
| 236 | if test "$enable_posix" = yes; then |
| 237 | AC_LIBOBJ([posix]) |
| 238 | AC_DEFINE([HAVE_POSIX], 1, |
| 239 | [Define this if you want support for non-essential POSIX system calls in Guile.]) |
| 240 | fi |
| 241 | |
| 242 | if test "$enable_networking" = yes; then |
| 243 | AC_LIBOBJ([net_db]) |
| 244 | AC_LIBOBJ([socket]) |
| 245 | AC_DEFINE([HAVE_NETWORKING], 1, |
| 246 | [Define this if you want support for networking in Guile.]) |
| 247 | fi |
| 248 | |
| 249 | if test "$enable_debug_malloc" = yes; then |
| 250 | AC_LIBOBJ([debug-malloc]) |
| 251 | fi |
| 252 | |
| 253 | AC_CHECK_LIB(uca, __uc_get_ar_bsp) |
| 254 | |
| 255 | AC_C_CONST |
| 256 | |
| 257 | # "volatile" is used in a couple of tests below. |
| 258 | AC_C_VOLATILE |
| 259 | |
| 260 | AC_C_INLINE |
| 261 | if test "$ac_cv_c_inline" != no; then |
| 262 | SCM_I_GSC_C_INLINE="\"${ac_cv_c_inline}\"" |
| 263 | else |
| 264 | SCM_I_GSC_C_INLINE=NULL |
| 265 | fi |
| 266 | AC_CHECK_LIB(uca, __uc_get_ar_bsp) |
| 267 | |
| 268 | AC_C_BIGENDIAN |
| 269 | |
| 270 | AC_C_LABELS_AS_VALUES |
| 271 | |
| 272 | AC_CHECK_SIZEOF(char) |
| 273 | AC_CHECK_SIZEOF(unsigned char) |
| 274 | AC_CHECK_SIZEOF(short) |
| 275 | AC_CHECK_SIZEOF(unsigned short) |
| 276 | AC_CHECK_SIZEOF(int) |
| 277 | AC_CHECK_SIZEOF(unsigned int) |
| 278 | AC_CHECK_SIZEOF(long) |
| 279 | AC_CHECK_SIZEOF(unsigned long) |
| 280 | AC_CHECK_SIZEOF(size_t) |
| 281 | AC_CHECK_SIZEOF(long long) |
| 282 | AC_CHECK_SIZEOF(unsigned long long) |
| 283 | AC_CHECK_SIZEOF(__int64) |
| 284 | AC_CHECK_SIZEOF(unsigned __int64) |
| 285 | AC_CHECK_SIZEOF(void *) |
| 286 | AC_CHECK_SIZEOF(intptr_t) |
| 287 | AC_CHECK_SIZEOF(uintptr_t) |
| 288 | AC_CHECK_SIZEOF(ptrdiff_t) |
| 289 | AC_CHECK_SIZEOF(size_t) |
| 290 | AC_CHECK_SIZEOF(off_t) |
| 291 | |
| 292 | if test "$ac_cv_sizeof_long" -gt "$ac_cv_sizeof_void_p"; then |
| 293 | AC_MSG_ERROR(long does not fit into a void*) |
| 294 | fi |
| 295 | |
| 296 | if test "$ac_cv_sizeof_ptrdiff_t" -ne 0; then |
| 297 | SCM_I_GSC_T_PTRDIFF='"ptrdiff_t"' |
| 298 | else |
| 299 | SCM_I_GSC_T_PTRDIFF='"long"' |
| 300 | fi |
| 301 | AC_SUBST([SCM_I_GSC_T_PTRDIFF]) |
| 302 | |
| 303 | AC_CHECK_HEADERS([stdint.h]) |
| 304 | AC_CHECK_HEADERS([inttypes.h]) |
| 305 | |
| 306 | AC_CHECK_SIZEOF(intmax_t) |
| 307 | |
| 308 | SCM_I_GSC_NEEDS_STDINT_H=0 |
| 309 | SCM_I_GSC_NEEDS_INTTYPES_H=0 |
| 310 | |
| 311 | ### intptr and uintptr (try not to use inttypes if we don't have to) |
| 312 | if test "$ac_cv_header_inttypes_h" = yes; then |
| 313 | if test "$ac_cv_sizeof_intptr_t" -eq 0; then |
| 314 | AC_CHECK_SIZEOF([intptr_t],,[#include <inttypes.h> |
| 315 | #include <stdio.h>]) |
| 316 | if test "$ac_cv_sizeof_intptr_t" -ne 0; then |
| 317 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 318 | fi |
| 319 | fi |
| 320 | if test "$ac_cv_sizeof_uintptr_t" -eq 0; then |
| 321 | AC_CHECK_SIZEOF([uintptr_t],,[#include <inttypes.h> |
| 322 | #include <stdio.h>]) |
| 323 | if test "$ac_cv_sizeof_uintptr_t" -ne 0; then |
| 324 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 325 | fi |
| 326 | fi |
| 327 | fi |
| 328 | |
| 329 | ### See what's provided by stdint.h |
| 330 | if test "$ac_cv_header_stdint_h" = yes; then |
| 331 | AC_CHECK_TYPE([int8_t],[scm_stdint_has_int8=1],,[#include <stdint.h>]) |
| 332 | AC_CHECK_TYPE([uint8_t],[scm_stdint_has_uint8=1],,[#include <stdint.h>]) |
| 333 | AC_CHECK_TYPE([int16_t],[scm_stdint_has_int16=1],,[#include <stdint.h>]) |
| 334 | AC_CHECK_TYPE([uint16_t],[scm_stdint_has_uint16=1],,[#include <stdint.h>]) |
| 335 | AC_CHECK_TYPE([int32_t],[scm_stdint_has_int32=1],,[#include <stdint.h>]) |
| 336 | AC_CHECK_TYPE([uint32_t],[scm_stdint_has_uint32=1],,[#include <stdint.h>]) |
| 337 | AC_CHECK_TYPE([int64_t],[scm_stdint_has_int64=1],,[#include <stdint.h>]) |
| 338 | AC_CHECK_TYPE([uint64_t],[scm_stdint_has_uint64=1],,[#include <stdint.h>]) |
| 339 | AC_CHECK_TYPE([intmax_t],[scm_stdint_has_intmax=1],,[#include <stdint.h>]) |
| 340 | AC_CHECK_TYPE([uintmax_t],[scm_stdint_has_uintmax=1],,[#include <stdint.h>]) |
| 341 | AC_CHECK_TYPE([intptr_t],[scm_stdint_has_intptr=1],,[#include <stdint.h>]) |
| 342 | AC_CHECK_TYPE([uintptr_t],[scm_stdint_has_uintptr=1],,[#include <stdint.h>]) |
| 343 | fi |
| 344 | |
| 345 | # so we don't get confused by the cache (wish there was a better way |
| 346 | # to check particular headers for the same type...) |
| 347 | |
| 348 | unset ac_cv_type_int8_t |
| 349 | unset ac_cv_type_uint8_t |
| 350 | unset ac_cv_type_int16_t |
| 351 | unset ac_cv_type_uint16_t |
| 352 | unset ac_cv_type_int32_t |
| 353 | unset ac_cv_type_uint32_t |
| 354 | unset ac_cv_type_int64_t |
| 355 | unset ac_cv_type_uint64_t |
| 356 | unset ac_cv_type_intmax_t |
| 357 | unset ac_cv_type_uintmax_t |
| 358 | |
| 359 | ### See what's provided by inttypes.h |
| 360 | if test "$ac_cv_header_inttypes_h" = yes; then |
| 361 | AC_CHECK_TYPE([int8_t],[scm_inttypes_has_int8=1],,[#include <inttypes.h>]) |
| 362 | AC_CHECK_TYPE([uint8_t],[scm_inttypes_has_uint8=1],,[#include <inttypes.h>]) |
| 363 | AC_CHECK_TYPE([int16_t],[scm_inttypes_has_int16=1],,[#include <inttypes.h>]) |
| 364 | AC_CHECK_TYPE([uint16_t],[scm_inttypes_has_uint16=1],,[#include <inttypes.h>]) |
| 365 | AC_CHECK_TYPE([int32_t],[scm_inttypes_has_int32=1],,[#include <inttypes.h>]) |
| 366 | AC_CHECK_TYPE([uint32_t],[scm_inttypes_has_uint32=1],,[#include <inttypes.h>]) |
| 367 | AC_CHECK_TYPE([int64_t],[scm_inttypes_has_int64=1],,[#include <inttypes.h>]) |
| 368 | AC_CHECK_TYPE([uint64_t],[scm_inttypes_has_uint64=1],,[#include <inttypes.h>]) |
| 369 | AC_CHECK_TYPE([intmax_t],[scm_inttypes_has_intmax=1],,[#include <inttypes.h>]) |
| 370 | AC_CHECK_TYPE([uintmax_t],[scm_inttypes_has_uintmax=1],,[#include <inttypes.h>]) |
| 371 | AC_CHECK_TYPE([intptr_t],[scm_inttypes_has_intptr=1],,[#include <inttypes.h>]) |
| 372 | AC_CHECK_TYPE([uintptr_t],[scm_inttypes_has_uintptr=1],,[#include <inttypes.h>]) |
| 373 | fi |
| 374 | |
| 375 | # Try hard to find definitions for some required scm_t_*int* types. |
| 376 | |
| 377 | ### Required type scm_t_int8 |
| 378 | if test "$scm_stdint_has_int8"; then |
| 379 | SCM_I_GSC_T_INT8='"int8_t"' |
| 380 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 381 | elif test "$scm_inttypes_has_int8"; then |
| 382 | SCM_I_GSC_T_INT8='"int8_t"' |
| 383 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 384 | elif test "$ac_cv_sizeof_char" -eq 1; then |
| 385 | SCM_I_GSC_T_INT8='"signed char"' |
| 386 | else |
| 387 | AC_MSG_ERROR([Can't find appropriate type for scm_t_int8.]) |
| 388 | fi |
| 389 | AC_SUBST([SCM_I_GSC_T_INT8]) |
| 390 | |
| 391 | ### Required type scm_t_uint8 |
| 392 | if test "$scm_stdint_has_uint8"; then |
| 393 | SCM_I_GSC_T_UINT8='"uint8_t"' |
| 394 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 395 | elif test "$scm_inttypes_has_uint8"; then |
| 396 | SCM_I_GSC_T_UINT8='"uint8_t"' |
| 397 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 398 | elif test "$ac_cv_sizeof_unsigned_char" -eq 1; then |
| 399 | SCM_I_GSC_T_UINT8='"unsigned char"' |
| 400 | else |
| 401 | AC_MSG_ERROR([Can't find appropriate type for scm_t_uint8.]) |
| 402 | fi |
| 403 | AC_SUBST([SCM_I_GSC_T_UINT8]) |
| 404 | |
| 405 | ### Required type scm_t_int16 (ANSI C says int or short might work) |
| 406 | if test "$scm_stdint_has_int16"; then |
| 407 | SCM_I_GSC_T_INT16='"int16_t"' |
| 408 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 409 | elif test "$scm_inttypes_has_int16"; then |
| 410 | SCM_I_GSC_T_INT16='"int16_t"' |
| 411 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 412 | elif test "$ac_cv_sizeof_int" -eq 2; then |
| 413 | SCM_I_GSC_T_INT16='"int"' |
| 414 | elif test "$ac_cv_sizeof_short" -eq 2; then |
| 415 | SCM_I_GSC_T_INT16='"short"' |
| 416 | else |
| 417 | AC_MSG_ERROR([Can't find appropriate type for scm_t_int16.]) |
| 418 | fi |
| 419 | AC_SUBST([SCM_I_GSC_T_INT16]) |
| 420 | |
| 421 | ### Required type scm_t_uint16 (ANSI C says int or short might work) |
| 422 | if test "$scm_stdint_has_uint16"; then |
| 423 | SCM_I_GSC_T_UINT16='"uint16_t"' |
| 424 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 425 | elif test "$scm_inttypes_has_uint16"; then |
| 426 | SCM_I_GSC_T_UINT16='"uint16_t"' |
| 427 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 428 | elif test "$ac_cv_sizeof_unsigned_int" -eq 2; then |
| 429 | SCM_I_GSC_T_UINT16='"unsigned int"' |
| 430 | elif test "$ac_cv_sizeof_unsigned_short" -eq 2; then |
| 431 | SCM_I_GSC_T_UINT16='"unsigned short"' |
| 432 | else |
| 433 | AC_MSG_ERROR([Can't find appropriate type for scm_t_uint16.]) |
| 434 | fi |
| 435 | AC_SUBST([SCM_I_GSC_T_UINT16]) |
| 436 | |
| 437 | |
| 438 | ### Required type scm_t_int32 (ANSI C says int, short, or long might work) |
| 439 | if test "$scm_stdint_has_int32"; then |
| 440 | SCM_I_GSC_T_INT32='"int32_t"' |
| 441 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 442 | elif test "$scm_inttypes_has_int32"; then |
| 443 | SCM_I_GSC_T_INT32='"int32_t"' |
| 444 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 445 | elif test "$ac_cv_sizeof_int" -eq 4; then |
| 446 | SCM_I_GSC_T_INT32='"int"' |
| 447 | elif test "$ac_cv_sizeof_long" -eq 4; then |
| 448 | SCM_I_GSC_T_INT32='"long"' |
| 449 | elif test "$ac_cv_sizeof_short" -eq 4; then |
| 450 | SCM_I_GSC_T_INT32='"short"' |
| 451 | else |
| 452 | AC_MSG_ERROR([Can't find appropriate type for scm_t_int32.]) |
| 453 | fi |
| 454 | AC_SUBST([SCM_I_GSC_T_INT32]) |
| 455 | |
| 456 | ### Required type scm_t_uint32 (ANSI C says int, short, or long might work) |
| 457 | if test "$scm_stdint_has_uint32"; then |
| 458 | SCM_I_GSC_T_UINT32='"uint32_t"' |
| 459 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 460 | elif test "$scm_inttypes_has_uint32"; then |
| 461 | SCM_I_GSC_T_UINT32='"uint32_t"' |
| 462 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 463 | elif test "$ac_cv_sizeof_unsigned_int" -eq 4; then |
| 464 | SCM_I_GSC_T_UINT32='"unsigned int"' |
| 465 | elif test "$ac_cv_sizeof_unsigned_long" -eq 4; then |
| 466 | SCM_I_GSC_T_UINT32='"unsigned long"' |
| 467 | elif test "$ac_cv_sizeof_unsigned_short" -eq 4; then |
| 468 | SCM_I_GSC_T_UINT32='"unsigned short"' |
| 469 | else |
| 470 | AC_MSG_ERROR([Can't find appropriate type for scm_t_uint32.]) |
| 471 | fi |
| 472 | AC_SUBST([SCM_I_GSC_T_UINT32]) |
| 473 | |
| 474 | ### Optional type scm_t_int64 (ANSI C says int, short, or long might work) |
| 475 | ### Also try 'long long' and '__int64' if we have it. |
| 476 | SCM_I_GSC_T_INT64=0 |
| 477 | if test "$scm_stdint_has_int64"; then |
| 478 | SCM_I_GSC_T_INT64='"int64_t"' |
| 479 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 480 | elif test "$scm_inttypes_has_int64"; then |
| 481 | SCM_I_GSC_T_INT64='"int64_t"' |
| 482 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 483 | elif test "$ac_cv_sizeof_int" -eq 8; then |
| 484 | SCM_I_GSC_T_INT64='"int"' |
| 485 | elif test "$ac_cv_sizeof_long" -eq 8; then |
| 486 | SCM_I_GSC_T_INT64='"long"' |
| 487 | elif test "$ac_cv_sizeof_short" -eq 8; then |
| 488 | SCM_I_GSC_T_INT64='"short"' |
| 489 | elif test "$ac_cv_sizeof_long_long" -eq 8; then |
| 490 | SCM_I_GSC_T_INT64='"long long"' |
| 491 | elif test "$ac_cv_sizeof___int64" -eq 8; then |
| 492 | SCM_I_GSC_T_INT64='"__int64"' |
| 493 | else |
| 494 | AC_MSG_ERROR([Can't find appropriate type for scm_t_int64.]) |
| 495 | fi |
| 496 | AC_SUBST([SCM_I_GSC_T_INT64]) |
| 497 | |
| 498 | |
| 499 | ### Optional type scm_t_uint64 (ANSI C says int, short, or long might work) |
| 500 | ### Also try 'long long' and '__int64' if we have it. |
| 501 | SCM_I_GSC_T_UINT64=0 |
| 502 | if test "$scm_stdint_has_uint64"; then |
| 503 | SCM_I_GSC_T_UINT64='"uint64_t"' |
| 504 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 505 | elif test "$scm_inttypes_has_uint64"; then |
| 506 | SCM_I_GSC_T_UINT64='"uint64_t"' |
| 507 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 508 | elif test "$ac_cv_sizeof_unsigned_int" -eq 8; then |
| 509 | SCM_I_GSC_T_UINT64='"unsigned int"' |
| 510 | elif test "$ac_cv_sizeof_unsigned_long" -eq 8; then |
| 511 | SCM_I_GSC_T_UINT64='"unsigned long"' |
| 512 | elif test "$ac_cv_sizeof_unsigned_short" -eq 8; then |
| 513 | SCM_I_GSC_T_UINT64='"unsigned short"' |
| 514 | elif test "$ac_cv_sizeof_unsigned_long_long" -eq 8; then |
| 515 | SCM_I_GSC_T_UINT64='"unsigned long long"' |
| 516 | elif test "$ac_cv_sizeof_unsigned___int64" -eq 8; then |
| 517 | SCM_I_GSC_T_UINT64='"unsigned __int64"' |
| 518 | else |
| 519 | AC_MSG_ERROR([Can't find appropriate type for scm_t_uint64.]) |
| 520 | fi |
| 521 | AC_SUBST([SCM_I_GSC_T_UINT64]) |
| 522 | |
| 523 | ### Required type scm_t_intmax |
| 524 | ### |
| 525 | ### We try 'intmax_t', '__int64', 'long long' in this order. When |
| 526 | ### none of them is available, we use 'long'. |
| 527 | ### |
| 528 | SCM_I_GSC_T_INTMAX=0 |
| 529 | if test "$scm_stdint_has_intmax"; then |
| 530 | SCM_I_GSC_T_INTMAX='"intmax_t"' |
| 531 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 532 | elif test "$scm_inttypes_has_intmax"; then |
| 533 | SCM_I_GSC_T_INTMAX='"intmax_t"' |
| 534 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 535 | elif test "$ac_cv_sizeof___int64" -ne 0; then |
| 536 | SCM_I_GSC_T_INTMAX='"__int64"' |
| 537 | elif test "$ac_cv_sizeof_long_long" -ne 0; then |
| 538 | SCM_I_GSC_T_INTMAX='"long long"' |
| 539 | else |
| 540 | SCM_I_GSC_T_INTMAX='"long"' |
| 541 | fi |
| 542 | AC_SUBST([SCM_I_GSC_T_INTMAX]) |
| 543 | |
| 544 | ### Required type scm_t_uintmax |
| 545 | ### |
| 546 | ### We try 'uintmax_t', 'unsigned __int64', 'unsigned long long' in |
| 547 | ### this order. When none of them is available, we use 'unsigned long'. |
| 548 | ### |
| 549 | SCM_I_GSC_T_UINTMAX=0 |
| 550 | if test "$scm_stdint_has_uintmax"; then |
| 551 | SCM_I_GSC_T_UINTMAX='"uintmax_t"' |
| 552 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 553 | elif test "$scm_inttypes_has_uintmax"; then |
| 554 | SCM_I_GSC_T_UINTMAX='"uintmax_t"' |
| 555 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 556 | elif test "$ac_cv_sizeof_unsigned___int64" -ne 0; then |
| 557 | SCM_I_GSC_T_UINTMAX='"unsigned __int64"' |
| 558 | elif test "$ac_cv_sizeof_unsigned_long_long" -ne 0; then |
| 559 | SCM_I_GSC_T_UINTMAX='"unsigned long long"' |
| 560 | else |
| 561 | SCM_I_GSC_T_UINTMAX='"unsigned long"' |
| 562 | fi |
| 563 | AC_SUBST([SCM_I_GSC_T_UINTMAX]) |
| 564 | |
| 565 | ### Required type scm_t_intptr |
| 566 | ### |
| 567 | SCM_I_GSC_T_INTPTR=0 |
| 568 | if test "$scm_stdint_has_intptr"; then |
| 569 | SCM_I_GSC_T_INTPTR='"intptr_t"' |
| 570 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 571 | elif test "$scm_inttypes_has_intptr"; then |
| 572 | SCM_I_GSC_T_INTPTR='"intptr_t"' |
| 573 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 574 | elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then |
| 575 | SCM_I_GSC_T_INTPTR='"int"' |
| 576 | elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then |
| 577 | SCM_I_GSC_T_INTPTR='"long"' |
| 578 | elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then |
| 579 | SCM_I_GSC_T_INTPTR='"long long"' |
| 580 | else |
| 581 | AC_MSG_ERROR([Can't find appropriate type for `scm_t_intptr'.]) |
| 582 | fi |
| 583 | AC_SUBST([SCM_I_GSC_T_INTPTR]) |
| 584 | |
| 585 | ### Required type scm_t_uintptr |
| 586 | ### |
| 587 | SCM_I_GSC_T_UINTPTR=0 |
| 588 | if test "$scm_stdint_has_uintptr"; then |
| 589 | SCM_I_GSC_T_UINTPTR='"uintptr_t"' |
| 590 | SCM_I_GSC_NEEDS_STDINT_H=1 |
| 591 | elif test "$scm_inttypes_has_uintptr"; then |
| 592 | SCM_I_GSC_T_UINTPTR='"uintptr_t"' |
| 593 | SCM_I_GSC_NEEDS_INTTYPES_H=1 |
| 594 | elif test "$ac_cv_sizeof_int" = "$ac_cv_sizeof_void_p"; then |
| 595 | SCM_I_GSC_T_UINTPTR='"unsigned int"' |
| 596 | elif test "$ac_cv_sizeof_long" = "$ac_cv_sizeof_void_p"; then |
| 597 | SCM_I_GSC_T_UINTPTR='"unsigned long"' |
| 598 | elif test "$ac_cv_sizeof_long_long" = "$ac_cv_sizeof_void_p"; then |
| 599 | SCM_I_GSC_T_UINTPTR='"unsigned long long"' |
| 600 | else |
| 601 | AC_MSG_ERROR([Can't find appropriate type for `scm_t_uintptr'.]) |
| 602 | fi |
| 603 | AC_SUBST([SCM_I_GSC_T_UINTPTR]) |
| 604 | |
| 605 | |
| 606 | AC_SUBST([SCM_I_GSC_NEEDS_STDINT_H]) |
| 607 | AC_SUBST([SCM_I_GSC_NEEDS_INTTYPES_H]) |
| 608 | |
| 609 | AC_HEADER_STDC |
| 610 | AC_HEADER_TIME |
| 611 | AC_HEADER_SYS_WAIT |
| 612 | AC_HEADER_DIRENT |
| 613 | |
| 614 | # Reason for checking: |
| 615 | # |
| 616 | # HP-UX 11.11 (at least) doesn't provide `struct dirent64', even |
| 617 | # with `_LARGEFILE64_SOURCE', so check whether it's available. |
| 618 | # |
| 619 | AC_CHECK_MEMBER([struct dirent64.d_name], |
| 620 | [SCM_I_GSC_HAVE_STRUCT_DIRENT64=1], [SCM_I_GSC_HAVE_STRUCT_DIRENT64=0], |
| 621 | [ #ifndef _LARGEFILE64_SOURCE |
| 622 | # define _LARGEFILE64_SOURCE |
| 623 | #endif |
| 624 | |
| 625 | /* Per Autoconf manual. */ |
| 626 | #include <sys/types.h> |
| 627 | #ifdef HAVE_DIRENT_H |
| 628 | # include <dirent.h> |
| 629 | #else |
| 630 | # define dirent direct |
| 631 | # ifdef HAVE_SYS_NDIR_H |
| 632 | # include <sys/ndir.h> |
| 633 | # endif |
| 634 | # ifdef HAVE_SYS_DIR_H |
| 635 | # include <sys/dir.h> |
| 636 | # endif |
| 637 | # ifdef HAVE_NDIR_H |
| 638 | # include <ndir.h> |
| 639 | # endif |
| 640 | #endif ]) |
| 641 | AC_SUBST([SCM_I_GSC_HAVE_STRUCT_DIRENT64]) |
| 642 | |
| 643 | # Reasons for testing: |
| 644 | # complex.h - new in C99 |
| 645 | # fenv.h - available in C99, but not older systems |
| 646 | # machine/fpu.h - on Tru64 5.1b, the declaration of fesetround(3) is in |
| 647 | # this file instead of <fenv.h> |
| 648 | # process.h - mingw specific |
| 649 | # sched.h - missing on MinGW |
| 650 | # sys/sendfile.h - non-POSIX, found in glibc |
| 651 | # |
| 652 | AC_CHECK_HEADERS([complex.h fenv.h io.h libc.h limits.h memory.h process.h string.h \ |
| 653 | sys/dir.h sys/ioctl.h sys/select.h \ |
| 654 | sys/time.h sys/timeb.h sys/times.h sys/stdtypes.h sys/types.h \ |
| 655 | sys/utime.h time.h unistd.h utime.h pwd.h grp.h sys/utsname.h \ |
| 656 | direct.h machine/fpu.h sched.h sys/sendfile.h]) |
| 657 | |
| 658 | # "complex double" is new in C99, and "complex" is only a keyword if |
| 659 | # <complex.h> is included |
| 660 | AC_CHECK_TYPES(complex double,,, |
| 661 | [#if HAVE_COMPLEX_H |
| 662 | #include <complex.h> |
| 663 | #endif]) |
| 664 | |
| 665 | # On MacOS X <sys/socklen.h> contains socklen_t, so must include that |
| 666 | # when testing. |
| 667 | AC_CHECK_TYPE(socklen_t, , |
| 668 | [AC_DEFINE_UNQUOTED([socklen_t], int, |
| 669 | [Define to `int' if <sys/socket.h> does not define.])], |
| 670 | [#if HAVE_SYS_TYPES_H |
| 671 | #include <sys/types.h> |
| 672 | #endif |
| 673 | #include <sys/socket.h> |
| 674 | ]) |
| 675 | |
| 676 | AC_CHECK_TYPES([struct ip_mreq], , , [#include <netinet/in.h>]) |
| 677 | |
| 678 | GUILE_HEADER_LIBC_WITH_UNISTD |
| 679 | |
| 680 | AC_TYPE_GETGROUPS |
| 681 | AC_TYPE_SIGNAL |
| 682 | AC_TYPE_MODE_T |
| 683 | |
| 684 | # On mingw -lm is empty, so this test is unnecessary, but it's |
| 685 | # harmless so we don't hard-code to suppress it. |
| 686 | # |
| 687 | AC_CHECK_LIB(m, cos) |
| 688 | |
| 689 | AC_CHECK_FUNCS(gethostbyname) |
| 690 | if test $ac_cv_func_gethostbyname = no; then |
| 691 | AC_CHECK_LIB(nsl, gethostbyname) |
| 692 | fi |
| 693 | |
| 694 | AC_CHECK_FUNCS(connect) |
| 695 | if test $ac_cv_func_connect = no; then |
| 696 | AC_CHECK_LIB(socket, connect) |
| 697 | fi |
| 698 | |
| 699 | dnl |
| 700 | dnl Check for Winsock and other functionality on Win32 (*not* CygWin) |
| 701 | dnl |
| 702 | EXTRA_DEFS="" |
| 703 | case $host in |
| 704 | *-*-mingw*) |
| 705 | AC_CHECK_HEADER(winsock2.h, [AC_DEFINE([HAVE_WINSOCK2_H], 1, |
| 706 | [Define if you have the <winsock2.h> header file.])]) |
| 707 | AC_CHECK_LIB(ws2_32, main) |
| 708 | AC_LIBOBJ([win32-uname]) |
| 709 | if test "$enable_shared" = yes ; then |
| 710 | EXTRA_DEFS="-DSCM_IMPORT" |
| 711 | AC_DEFINE([USE_DLL_IMPORT], 1, |
| 712 | [Define if you need additional CPP macros on Win32 platforms.]) |
| 713 | fi |
| 714 | ;; |
| 715 | esac |
| 716 | AC_SUBST(EXTRA_DEFS) |
| 717 | |
| 718 | # Reasons for testing: |
| 719 | # crt_externs.h - Darwin specific |
| 720 | # |
| 721 | AC_CHECK_HEADERS([assert.h crt_externs.h]) |
| 722 | |
| 723 | # Reasons for testing: |
| 724 | # DINFINITY - OSF specific |
| 725 | # DQNAN - OSF specific |
| 726 | # (DINFINITY and DQNAN are actually global variables, not functions) |
| 727 | # chsize - an MS-DOS-ism, found in mingw |
| 728 | # cexp, clog - not in various pre-c99 systems, and note that it's possible |
| 729 | # for gcc to provide the "complex double" type but the system to not |
| 730 | # have functions like cexp and clog |
| 731 | # clog10 - not in mingw (though others like clog and csqrt are) |
| 732 | # fesetround - available in C99, but not older systems |
| 733 | # ftruncate - posix, but probably not older systems (current mingw |
| 734 | # has it as an inline for chsize) |
| 735 | # ioctl - not in mingw. |
| 736 | # gmtime_r - recent posix, not on old systems |
| 737 | # readdir_r - recent posix, not on old systems |
| 738 | # readdir64_r - not available on HP-UX 11.11 |
| 739 | # stat64 - SuS largefile stuff, not on old systems |
| 740 | # sysconf - not on old systems |
| 741 | # truncate - not in mingw |
| 742 | # isblank - available as a GNU extension or in C99 |
| 743 | # _NSGetEnviron - Darwin specific |
| 744 | # strcoll_l, newlocale - GNU extensions (glibc), also available on Darwin |
| 745 | # fork - unavailable on Windows |
| 746 | # utimensat - posix.1-2008 |
| 747 | # sched_getaffinity, sched_setaffinity - GNU extensions (glibc) |
| 748 | # sendfile - non-POSIX, found in glibc |
| 749 | # |
| 750 | AC_CHECK_FUNCS([DINFINITY DQNAN cexp chsize clog clog10 ctermid \ |
| 751 | fesetround ftime ftruncate fchown fchmod getcwd geteuid getsid \ |
| 752 | gettimeofday gmtime_r ioctl lstat mkdir mknod nice \ |
| 753 | readdir_r readdir64_r readlink rename rmdir setegid seteuid \ |
| 754 | setlocale setpgid setsid sigaction siginterrupt stat64 \ |
| 755 | strptime symlink sync sysconf tcgetpgrp tcsetpgrp uname waitpid \ |
| 756 | strdup system usleep atexit on_exit chown link fcntl ttyname getpwent \ |
| 757 | getgrent kill getppid getpgrp fork setitimer getitimer strchr strcmp \ |
| 758 | index bcopy memcpy rindex truncate unsetenv isblank _NSGetEnviron \ |
| 759 | strcoll strcoll_l newlocale utimensat sched_getaffinity \ |
| 760 | sched_setaffinity sendfile]) |
| 761 | |
| 762 | AM_CONDITIONAL([BUILD_ICE_9_POPEN], |
| 763 | [test "x$enable_posix" = "xyes" && test "x$ac_cv_func_fork" = "xyes"]) |
| 764 | |
| 765 | # Reasons for testing: |
| 766 | # netdb.h - not in mingw |
| 767 | # sys/param.h - not in mingw |
| 768 | # pthread.h - only available with pthreads. ACX_PTHREAD doesn't |
| 769 | # check this specifically, we need it for the timespec test below. |
| 770 | # pthread_np.h - available on FreeBSD |
| 771 | # sethostname - the function itself check because it's not in mingw, |
| 772 | # the DECL is checked because Solaris 10 doens't have in any header |
| 773 | # hstrerror - on Tru64 5.1b the symbol is available in libc but the |
| 774 | # declaration isn't anywhere. |
| 775 | # cuserid - on Tru64 5.1b the declaration is documented to be available |
| 776 | # only with `_XOPEN_SOURCE' or some such. |
| 777 | # |
| 778 | AC_CHECK_HEADERS([crypt.h netdb.h pthread.h pthread_np.h sys/param.h sys/resource.h sys/file.h sys/mman.h]) |
| 779 | AC_CHECK_FUNCS(chroot flock getlogin cuserid getpriority setpriority getpass sethostname gethostname) |
| 780 | AC_CHECK_DECLS([sethostname, hstrerror, cuserid]) |
| 781 | |
| 782 | # crypt() may or may not be available, for instance in some countries there |
| 783 | # are restrictions on cryptography. |
| 784 | # |
| 785 | # crypt() might be in libc (eg. OpenBSD), or it might be in a separate |
| 786 | # -lcrypt library (eg. Debian GNU/Linux). |
| 787 | # |
| 788 | # On HP-UX 11, crypt() is in libc and there's a dummy libcrypt.a. We must |
| 789 | # be careful to avoid -lcrypt in this case, since libtool will see there's |
| 790 | # only a static libcrypt and decide to build only a static libguile. |
| 791 | # |
| 792 | # AC_SEARCH_LIBS lets us add -lcrypt to LIBS only if crypt() is not in the |
| 793 | # libraries already in that list. |
| 794 | # |
| 795 | AC_SEARCH_LIBS(crypt, crypt, |
| 796 | [AC_DEFINE([HAVE_CRYPT],1, |
| 797 | [Define to 1 if you have the `crypt' function.])]) |
| 798 | |
| 799 | # When compiling with GCC on some OSs (Solaris, AIX), _Complex_I doesn't |
| 800 | # work; in the reported cases so far, 1.0fi works well instead. According |
| 801 | # to the C99 spec, the complex.h header must provide a working definition |
| 802 | # of _Complex_I, so we always try _Complex_I first. The 1.0fi fallback |
| 803 | # is a workaround for the failure of some systems to conform to C99. |
| 804 | if test "$ac_cv_type_complex_double" = yes; then |
| 805 | AC_MSG_CHECKING([for i]) |
| 806 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 807 | #if HAVE_COMPLEX_H |
| 808 | #include <complex.h> |
| 809 | #endif |
| 810 | complex double z; |
| 811 | ]], [[ |
| 812 | z = _Complex_I; |
| 813 | ]])], |
| 814 | [AC_DEFINE([GUILE_I],_Complex_I,[The imaginary unit (positive square root of -1).]) |
| 815 | AC_MSG_RESULT([_Complex_I])], |
| 816 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 817 | #if HAVE_COMPLEX_H |
| 818 | #include <complex.h> |
| 819 | #endif |
| 820 | complex double z; |
| 821 | ]],[[ |
| 822 | z = 1.0fi; |
| 823 | ]])], |
| 824 | [AC_DEFINE([GUILE_I],1.0fi) |
| 825 | AC_MSG_RESULT([1.0fi])], |
| 826 | [ac_cv_type_complex_double=no |
| 827 | AC_MSG_RESULT([not available])])]) |
| 828 | fi |
| 829 | |
| 830 | # glibc 2.3.6 (circa 2006) and various prior versions had a bug where |
| 831 | # csqrt(-i) returned a negative real part, when it should be positive |
| 832 | # for the principal root. |
| 833 | # |
| 834 | if test "$ac_cv_type_complex_double" = yes; then |
| 835 | |
| 836 | AC_CACHE_CHECK([whether csqrt is usable], |
| 837 | guile_cv_use_csqrt, |
| 838 | [AC_RUN_IFELSE([AC_LANG_SOURCE([[ |
| 839 | #include <complex.h> |
| 840 | /* "volatile" is meant to prevent gcc from calculating the sqrt as a |
| 841 | constant, we want to test libc. */ |
| 842 | volatile complex double z = - _Complex_I; |
| 843 | int |
| 844 | main (void) |
| 845 | { |
| 846 | z = csqrt (z); |
| 847 | if (creal (z) > 0.0) |
| 848 | return 0; /* good */ |
| 849 | else |
| 850 | return 1; /* bad */ |
| 851 | }]])], |
| 852 | [guile_cv_use_csqrt=yes], |
| 853 | [guile_cv_use_csqrt="no, glibc 2.3 bug"], |
| 854 | [guile_cv_use_csqrt="yes, hopefully (cross-compiling)"])]) |
| 855 | case $guile_cv_use_csqrt in |
| 856 | yes*) |
| 857 | AC_DEFINE([HAVE_USABLE_CSQRT], 1, [Define to 1 if csqrt is bug-free]) |
| 858 | ;; |
| 859 | esac |
| 860 | fi |
| 861 | |
| 862 | AC_CACHE_SAVE |
| 863 | |
| 864 | dnl GMP tests |
| 865 | AC_LIB_HAVE_LINKFLAGS([gmp], |
| 866 | [], |
| 867 | [#include <gmp.h>], |
| 868 | [mpz_import (0, 0, 0, 0, 0, 0, 0);]) |
| 869 | |
| 870 | if test "x$HAVE_LIBGMP" != "xyes"; then |
| 871 | AC_MSG_ERROR([GNU MP 4.1 or greater not found, see README]) |
| 872 | fi |
| 873 | |
| 874 | dnl `mpz_inits' and `mpz_clears' appeared in GMP 5.0.0. |
| 875 | save_CPPFLAGS="$CPPFLAGS" |
| 876 | if test "x$LIBGMP_PREFIX" != "x"; then |
| 877 | CPPFLAGS="-I$LIBGMP_PREFIX $CPPFLAGS" |
| 878 | fi |
| 879 | AC_CHECK_DECLS([mpz_inits], [], [], [[#include <gmp.h>]]) |
| 880 | CPPFLAGS="$save_CPPFLAGS" |
| 881 | |
| 882 | dnl GNU libunistring is checked for by Gnulib's `libunistring' module. |
| 883 | if test "x$LTLIBUNISTRING" = "x"; then |
| 884 | AC_MSG_ERROR([GNU libunistring is required, please install it.]) |
| 885 | fi |
| 886 | |
| 887 | GUILE_LIBUNISTRING_WITH_ICONV_SUPPORT |
| 888 | if test "x$ac_cv_libunistring_with_iconv_support" != "xyes"; then |
| 889 | AC_MSG_ERROR([No iconv support. Please recompile libunistring with iconv enabled.]) |
| 890 | fi |
| 891 | |
| 892 | dnl Libffi is needed to compile Guile's foreign function interface, but its |
| 893 | dnl interface isn't exposed in Guile's API. |
| 894 | PKG_CHECK_MODULES(LIBFFI, libffi) |
| 895 | AC_SUBST(LIBFFI_CFLAGS) |
| 896 | AC_SUBST(LIBFFI_LIBS) |
| 897 | |
| 898 | dnl figure out approriate ffi type for size_t |
| 899 | AC_CHECK_SIZEOF(size_t) |
| 900 | AC_CHECK_SIZEOF(ssize_t) |
| 901 | ffi_size_type=uint$(($ac_cv_sizeof_size_t*8)) |
| 902 | ffi_ssize_type=sint$(($ac_cv_sizeof_ssize_t*8)) |
| 903 | AC_DEFINE_UNQUOTED([ffi_type_size_t], ffi_type_${ffi_size_type}, |
| 904 | [ffi type for size_t]) |
| 905 | AC_DEFINE_UNQUOTED([ffi_type_ssize_t], ffi_type_${ffi_ssize_type}, |
| 906 | [ffi type for ssize_t]) |
| 907 | |
| 908 | dnl i18n tests |
| 909 | #AC_CHECK_HEADERS([libintl.h]) |
| 910 | #AC_CHECK_FUNCS(gettext) |
| 911 | #if test $ac_cv_func_gettext = no; then |
| 912 | # AC_CHECK_LIB(intl, gettext) |
| 913 | #fi |
| 914 | #AC_CHECK_FUNCS([bindtextdomain textdomain]) |
| 915 | AM_GNU_GETTEXT([external], [need-ngettext]) |
| 916 | |
| 917 | ### Some systems don't declare some functions. On such systems, we |
| 918 | ### need to at least provide our own K&R-style declarations. |
| 919 | |
| 920 | ### GUILE_FUNC_DECLARED(function, headerfile) |
| 921 | |
| 922 | ### Check for a declaration of FUNCTION in HEADERFILE; if it is |
| 923 | ### not there, #define MISSING_FUNCTION_DECL. |
| 924 | AC_DEFUN([GUILE_FUNC_DECLARED], [ |
| 925 | AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared, |
| 926 | AC_EGREP_HEADER($1, $2, |
| 927 | guile_cv_func_$1_declared=yes, |
| 928 | guile_cv_func_$1_declared=no)) |
| 929 | if test [x$guile_cv_func_]$1[_declared] = xno; then |
| 930 | AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL], 1, |
| 931 | [Define if the operating system supplies $1 without declaring it.]) |
| 932 | fi |
| 933 | ]) |
| 934 | |
| 935 | GUILE_FUNC_DECLARED(sleep, unistd.h) |
| 936 | GUILE_FUNC_DECLARED(usleep, unistd.h) |
| 937 | |
| 938 | AC_CHECK_DECLS([getlogin, alarm]) |
| 939 | |
| 940 | AC_CHECK_DECLS([strptime],,, |
| 941 | [#define _GNU_SOURCE /* ask glibc to give strptime prototype */ |
| 942 | #include <time.h>]) |
| 943 | |
| 944 | ### On some systems usleep has no return value. If it does have one, |
| 945 | ### we'd like to return it; otherwise, we'll fake it. |
| 946 | AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type, |
| 947 | [AC_EGREP_HEADER(changequote(<, >)<void[ ]+usleep>changequote([, ]), |
| 948 | unistd.h, |
| 949 | [guile_cv_func_usleep_return_type=void], |
| 950 | [guile_cv_func_usleep_return_type=int])]) |
| 951 | case "$guile_cv_func_usleep_return_type" in |
| 952 | "void" ) |
| 953 | AC_DEFINE([USLEEP_RETURNS_VOID], 1, |
| 954 | [Define if the system headers declare usleep to return void.]) |
| 955 | ;; |
| 956 | esac |
| 957 | |
| 958 | AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1) |
| 959 | if test -n "$have_sys_un_h" ; then |
| 960 | AC_DEFINE([HAVE_UNIX_DOMAIN_SOCKETS], 1, |
| 961 | [Define if the system supports Unix-domain (file-domain) sockets.]) |
| 962 | fi |
| 963 | |
| 964 | AC_CHECK_FUNCS(getrlimit setrlimit) |
| 965 | |
| 966 | AC_CHECK_FUNCS(socketpair getgroups setgroups setpwent pause tzset) |
| 967 | |
| 968 | AC_CHECK_FUNCS(sethostent gethostent endhostent dnl |
| 969 | setnetent getnetent endnetent dnl |
| 970 | setprotoent getprotoent endprotoent dnl |
| 971 | setservent getservent endservent dnl |
| 972 | getnetbyaddr getnetbyname dnl |
| 973 | inet_lnaof inet_makeaddr inet_netof hstrerror) |
| 974 | |
| 975 | AC_CHECK_MEMBERS([struct sockaddr_in.sin_len],,, |
| 976 | [#ifdef HAVE_SYS_TYPES_H |
| 977 | #include <sys/types.h> |
| 978 | #endif |
| 979 | #include <netinet/in.h>]) |
| 980 | |
| 981 | AC_MSG_CHECKING(for __libc_stack_end) |
| 982 | AC_CACHE_VAL(guile_cv_have_libc_stack_end, |
| 983 | [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdio.h> |
| 984 | extern char *__libc_stack_end;]], |
| 985 | [[printf("%p", (char*) __libc_stack_end);]])], |
| 986 | [guile_cv_have_libc_stack_end=yes], |
| 987 | [guile_cv_have_libc_stack_end=no])]) |
| 988 | AC_MSG_RESULT($guile_cv_have_libc_stack_end) |
| 989 | |
| 990 | if test $guile_cv_have_libc_stack_end = yes; then |
| 991 | AC_DEFINE([HAVE_LIBC_STACK_END], 1, |
| 992 | [Define if you have the __libc_stack_end variable.]) |
| 993 | fi |
| 994 | |
| 995 | dnl Some systems do not declare this. Some systems do declare it, as a |
| 996 | dnl macro. With cygwin it may be in a DLL. |
| 997 | |
| 998 | AC_MSG_CHECKING(whether netdb.h declares h_errno) |
| 999 | AC_CACHE_VAL(guile_cv_have_h_errno, |
| 1000 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], |
| 1001 | [[int a = h_errno;]])], |
| 1002 | [guile_cv_have_h_errno=yes], |
| 1003 | [guile_cv_have_h_errno=no])]) |
| 1004 | AC_MSG_RESULT($guile_cv_have_h_errno) |
| 1005 | if test $guile_cv_have_h_errno = yes; then |
| 1006 | AC_DEFINE([HAVE_H_ERRNO], 1, [Define if h_errno is declared in netdb.h.]) |
| 1007 | fi |
| 1008 | |
| 1009 | AC_MSG_CHECKING(whether uint32_t is defined) |
| 1010 | AC_CACHE_VAL(guile_cv_have_uint32_t, |
| 1011 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h> |
| 1012 | #if HAVE_STDINT_H |
| 1013 | #include <stdint.h> |
| 1014 | #endif |
| 1015 | #ifndef HAVE_NETDB_H |
| 1016 | #include <netdb.h> |
| 1017 | #endif]], |
| 1018 | [[uint32_t a;]])], |
| 1019 | [guile_cv_have_uint32_t=yes], |
| 1020 | [guile_cv_have_uint32_t=no])]) |
| 1021 | AC_MSG_RESULT($guile_cv_have_uint32_t) |
| 1022 | if test $guile_cv_have_uint32_t = yes; then |
| 1023 | AC_DEFINE([HAVE_UINT32_T], 1, |
| 1024 | [Define if uint32_t typedef is defined when netdb.h is include.]) |
| 1025 | fi |
| 1026 | |
| 1027 | AC_MSG_CHECKING(for working IPv6 support) |
| 1028 | AC_CACHE_VAL(guile_cv_have_ipv6, |
| 1029 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 1030 | #ifdef HAVE_SYS_TYPES_H |
| 1031 | #include <sys/types.h> |
| 1032 | #endif |
| 1033 | #include <netinet/in.h> |
| 1034 | #include <sys/socket.h>]], |
| 1035 | [[struct sockaddr_in6 a; a.sin6_family = AF_INET6;]])], |
| 1036 | [guile_cv_have_ipv6=yes], |
| 1037 | [guile_cv_have_ipv6=no])]) |
| 1038 | AC_MSG_RESULT($guile_cv_have_ipv6) |
| 1039 | if test $guile_cv_have_ipv6 = yes; then |
| 1040 | AC_DEFINE([HAVE_IPV6], 1, [Define if you want support for IPv6.]) |
| 1041 | fi |
| 1042 | |
| 1043 | # included in rfc2553 but not in older implementations, e.g., glibc 2.1.3. |
| 1044 | AC_MSG_CHECKING(whether sockaddr_in6 has sin6_scope_id) |
| 1045 | AC_CACHE_VAL(guile_cv_have_sin6_scope_id, |
| 1046 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 1047 | #ifdef HAVE_SYS_TYPES_H |
| 1048 | #include <sys/types.h> |
| 1049 | #endif |
| 1050 | #include <netinet/in.h>]], |
| 1051 | [[struct sockaddr_in6 sok; sok.sin6_scope_id = 0;]])], |
| 1052 | [guile_cv_have_sin6_scope_id=yes], |
| 1053 | [guile_cv_have_sin6_scope_id=no])]) |
| 1054 | AC_MSG_RESULT($guile_cv_have_sin6_scope_id) |
| 1055 | if test $guile_cv_have_sin6_scope_id = yes; then |
| 1056 | AC_DEFINE([HAVE_SIN6_SCOPE_ID], 1, |
| 1057 | [Define this if your IPv6 has sin6_scope_id in sockaddr_in6 struct.]) |
| 1058 | fi |
| 1059 | |
| 1060 | # struct sockaddr_in6 field sin_len is only present on BSD systems |
| 1061 | AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_len],,, |
| 1062 | [#ifdef HAVE_SYS_TYPES_H |
| 1063 | #include <sys/types.h> |
| 1064 | #endif |
| 1065 | #include <netinet/in.h>]) |
| 1066 | |
| 1067 | AC_MSG_CHECKING(whether localtime caches TZ) |
| 1068 | AC_CACHE_VAL(guile_cv_localtime_cache, |
| 1069 | [if test x$ac_cv_func_tzset = xyes; then |
| 1070 | AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h> |
| 1071 | #if STDC_HEADERS |
| 1072 | # include <stdlib.h> |
| 1073 | #endif |
| 1074 | extern char **environ; |
| 1075 | unset_TZ () |
| 1076 | { |
| 1077 | char **from, **to; |
| 1078 | for (to = from = environ; (*to = *from); from++) |
| 1079 | if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '=')) |
| 1080 | to++; |
| 1081 | } |
| 1082 | char TZ_GMT0[] = "TZ=GMT0"; |
| 1083 | char TZ_PST8[] = "TZ=PST8"; |
| 1084 | main() |
| 1085 | { |
| 1086 | time_t now = time ((time_t *) 0); |
| 1087 | int hour_GMT0, hour_unset; |
| 1088 | if (putenv (TZ_GMT0) != 0) |
| 1089 | exit (1); |
| 1090 | hour_GMT0 = localtime (&now)->tm_hour; |
| 1091 | unset_TZ (); |
| 1092 | hour_unset = localtime (&now)->tm_hour; |
| 1093 | if (putenv (TZ_PST8) != 0) |
| 1094 | exit (1); |
| 1095 | if (localtime (&now)->tm_hour == hour_GMT0) |
| 1096 | exit (1); |
| 1097 | unset_TZ (); |
| 1098 | if (localtime (&now)->tm_hour != hour_unset) |
| 1099 | exit (1); |
| 1100 | exit (0); |
| 1101 | }]])], |
| 1102 | [guile_cv_localtime_cache=no], |
| 1103 | [guile_cv_localtime_cache=yes], |
| 1104 | [# If we have tzset, assume the worst when cross-compiling. |
| 1105 | guile_cv_localtime_cache=yes]) |
| 1106 | else |
| 1107 | # If we lack tzset, report that localtime does not cache TZ, |
| 1108 | # since we can't invalidate the cache if we don't have tzset. |
| 1109 | guile_cv_localtime_cache=no |
| 1110 | fi])dnl |
| 1111 | AC_MSG_RESULT($guile_cv_localtime_cache) |
| 1112 | if test $guile_cv_localtime_cache = yes; then |
| 1113 | AC_DEFINE([LOCALTIME_CACHE], 1, [Define if localtime caches the TZ setting.]) |
| 1114 | fi |
| 1115 | |
| 1116 | if test "$enable_regex" = yes; then |
| 1117 | AC_LIBOBJ([regex-posix]) |
| 1118 | AC_DEFINE([ENABLE_REGEX], 1, [Define when regex support is enabled.]) |
| 1119 | fi |
| 1120 | |
| 1121 | AC_REPLACE_FUNCS([strerror memmove mkstemp]) |
| 1122 | |
| 1123 | # Reasons for testing: |
| 1124 | # asinh, acosh, atanh, trunc - C99 standard, generally not available on |
| 1125 | # older systems |
| 1126 | # sincos - GLIBC extension |
| 1127 | # |
| 1128 | AC_CHECK_FUNCS(asinh acosh atanh copysign finite sincos trunc) |
| 1129 | |
| 1130 | # C99 specifies isinf and isnan as macros. |
| 1131 | # HP-UX provides only macros, no functions. |
| 1132 | # glibc 2.3.2 provides both macros and functions. |
| 1133 | # IRIX 6.5 and Solaris 8 only provide functions. |
| 1134 | # |
| 1135 | # The following tests detect isinf and isnan either as functions or as |
| 1136 | # macros from <math.h>. Plain AC_CHECK_FUNCS is insufficient, it doesn't |
| 1137 | # use <math.h> so doesn't detect on macro-only systems like HP-UX. |
| 1138 | # |
| 1139 | AC_MSG_CHECKING([for isinf]) |
| 1140 | AC_LINK_IFELSE([AC_LANG_SOURCE( |
| 1141 | [[#include <math.h> |
| 1142 | volatile double x = 0.0; |
| 1143 | int main () { return (isinf(x) != 0); }]])], |
| 1144 | [AC_MSG_RESULT([yes]) |
| 1145 | AC_DEFINE([HAVE_ISINF], 1, |
| 1146 | [Define to 1 if you have the `isinf' macro or function.])], |
| 1147 | [AC_MSG_RESULT([no])]) |
| 1148 | AC_MSG_CHECKING([for isnan]) |
| 1149 | AC_LINK_IFELSE([AC_LANG_SOURCE([[ |
| 1150 | #include <math.h> |
| 1151 | volatile double x = 0.0; |
| 1152 | int main () { return (isnan(x) != 0); }]])], |
| 1153 | [AC_MSG_RESULT([yes]) |
| 1154 | AC_DEFINE([HAVE_ISNAN], 1, |
| 1155 | [Define to 1 if you have the `isnan' macro or function.])], |
| 1156 | [AC_MSG_RESULT([no])]) |
| 1157 | |
| 1158 | # Reasons for checking: |
| 1159 | # |
| 1160 | # st_rdev |
| 1161 | # st_blksize |
| 1162 | # st_blocks not in mingw |
| 1163 | # tm_gmtoff BSD+GNU, not in C99 |
| 1164 | # |
| 1165 | # Note AC_STRUCT_ST_BLOCKS is not used here because we don't want the |
| 1166 | # AC_LIBOBJ(fileblocks) replacement which that macro gives. |
| 1167 | # |
| 1168 | AC_CHECK_MEMBERS([struct stat.st_rdev, struct stat.st_blksize, struct stat.st_blocks, struct stat.st_atim, struct stat.st_mtim, struct stat.st_ctim],,, |
| 1169 | [#define _GNU_SOURCE |
| 1170 | AC_INCLUDES_DEFAULT |
| 1171 | ]) |
| 1172 | |
| 1173 | AC_STRUCT_TIMEZONE |
| 1174 | AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,, |
| 1175 | [#include <time.h> |
| 1176 | #ifdef TIME_WITH_SYS_TIME |
| 1177 | # include <sys/time.h> |
| 1178 | # include <time.h> |
| 1179 | #else |
| 1180 | # if HAVE_SYS_TIME_H |
| 1181 | # include <sys/time.h> |
| 1182 | # else |
| 1183 | # include <time.h> |
| 1184 | # endif |
| 1185 | #endif |
| 1186 | ]) |
| 1187 | GUILE_STRUCT_UTIMBUF |
| 1188 | |
| 1189 | |
| 1190 | #-------------------------------------------------------------------- |
| 1191 | # |
| 1192 | # What values do the iconv error handlers have? |
| 1193 | # |
| 1194 | # The only place that we need iconv in our public interfaces is for |
| 1195 | # the error handlers, which are just ints. So we weaken our |
| 1196 | # dependency by looking up those values at configure-time. |
| 1197 | #-------------------------------------------------------------------- |
| 1198 | GUILE_UNISTRING_ICONVEH_VALUES |
| 1199 | |
| 1200 | #-------------------------------------------------------------------- |
| 1201 | # |
| 1202 | # Which way does the stack grow? |
| 1203 | # |
| 1204 | # Following code comes from Autoconf 2.69's internal _AC_LIBOBJ_ALLOCA |
| 1205 | # macro (/usr/share/autoconf/autoconf/functions.m4). Gnulib has |
| 1206 | # very similar code, so in future we could look at using that. |
| 1207 | # |
| 1208 | # An important detail is that the code involves find_stack_direction |
| 1209 | # calling _itself_ - which means that find_stack_direction (or at |
| 1210 | # least the second find_stack_direction() call) cannot be inlined. |
| 1211 | # If the code could be inlined, that might cause the test to give |
| 1212 | # an incorrect answer. |
| 1213 | #-------------------------------------------------------------------- |
| 1214 | |
| 1215 | SCM_I_GSC_STACK_GROWS_UP=0 |
| 1216 | AC_RUN_IFELSE([AC_LANG_SOURCE( |
| 1217 | [AC_INCLUDES_DEFAULT |
| 1218 | int |
| 1219 | find_stack_direction (int *addr, int depth) |
| 1220 | { |
| 1221 | int dir, dummy = 0; |
| 1222 | if (! addr) |
| 1223 | addr = &dummy; |
| 1224 | *addr = addr < &dummy ? 1 : addr == &dummy ? 0 : -1; |
| 1225 | dir = depth ? find_stack_direction (addr, depth - 1) : 0; |
| 1226 | return dir + dummy; |
| 1227 | } |
| 1228 | |
| 1229 | int |
| 1230 | main (int argc, char **argv) |
| 1231 | { |
| 1232 | return find_stack_direction (0, argc + !argv + 20) < 0; |
| 1233 | }])], |
| 1234 | [SCM_I_GSC_STACK_GROWS_UP=1], |
| 1235 | [], |
| 1236 | [AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h)]) |
| 1237 | |
| 1238 | #-------------------------------------------------------------------- |
| 1239 | # |
| 1240 | # Boehm's GC library |
| 1241 | # |
| 1242 | #-------------------------------------------------------------------- |
| 1243 | PKG_CHECK_MODULES([BDW_GC], [bdw-gc >= 7.2]) |
| 1244 | |
| 1245 | save_LIBS="$LIBS" |
| 1246 | LIBS="$BDW_GC_LIBS $LIBS" |
| 1247 | CFLAGS="$BDW_GC_CFLAGS $CFLAGS" |
| 1248 | |
| 1249 | # Functions that might not be defined, depending on configuration. |
| 1250 | AC_CHECK_FUNCS([GC_pthread_exit GC_pthread_cancel GC_pthread_sigmask]) |
| 1251 | |
| 1252 | # Functions from GC 7.3. |
| 1253 | AC_CHECK_FUNCS([GC_move_disappearing_link]) |
| 1254 | |
| 1255 | LIBS="$save_LIBS" |
| 1256 | |
| 1257 | |
| 1258 | AC_CHECK_SIZEOF(float) |
| 1259 | if test "$ac_cv_sizeof_float" -le "$ac_cv_sizeof_long"; then |
| 1260 | AC_DEFINE([SCM_SINGLES], 1, |
| 1261 | [Define this if floats are the same size as longs.]) |
| 1262 | fi |
| 1263 | |
| 1264 | AC_MSG_CHECKING(for struct linger) |
| 1265 | AC_CACHE_VAL(scm_cv_struct_linger, |
| 1266 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 1267 | #include <sys/types.h> |
| 1268 | #include <sys/socket.h>]], |
| 1269 | [[struct linger lgr; lgr.l_linger = 100]])], |
| 1270 | [scm_cv_struct_linger="yes"], |
| 1271 | [scm_cv_struct_linger="no"])) |
| 1272 | AC_MSG_RESULT($scm_cv_struct_linger) |
| 1273 | if test $scm_cv_struct_linger = yes; then |
| 1274 | AC_DEFINE([HAVE_STRUCT_LINGER], 1, |
| 1275 | [Define this if your system defines struct linger, for use with the |
| 1276 | getsockopt and setsockopt system calls.]) |
| 1277 | fi |
| 1278 | |
| 1279 | |
| 1280 | dnl Check for `struct timespec', for the sake of `gen-scmconfig'. When |
| 1281 | dnl building Guile, we always have it, thanks to Gnulib; but scmconfig.h |
| 1282 | dnl must tell whether the system has it. |
| 1283 | dnl |
| 1284 | dnl On MinGW, struct timespec is in <pthread.h>. |
| 1285 | AC_MSG_CHECKING(for struct timespec) |
| 1286 | AC_CACHE_VAL(scm_cv_struct_timespec, |
| 1287 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ |
| 1288 | #include <time.h> |
| 1289 | #if HAVE_PTHREAD_H |
| 1290 | #include <pthread.h> |
| 1291 | #endif]], [[struct timespec t; t.tv_nsec = 100]])], |
| 1292 | [scm_cv_struct_timespec="yes"], |
| 1293 | [scm_cv_struct_timespec="no"])) |
| 1294 | AC_MSG_RESULT($scm_cv_struct_timespec) |
| 1295 | if test $scm_cv_struct_timespec = yes; then |
| 1296 | dnl Don't call it `HAVE_STRUCT_TIMESPEC' because pthread-win32's |
| 1297 | dnl <pthread.h> checks whether that macro is defined. |
| 1298 | AC_DEFINE([HAVE_SYSTEM_STRUCT_TIMESPEC], 1, |
| 1299 | [Define this if your system defines struct timespec via either <time.h> or <pthread.h>.]) |
| 1300 | fi |
| 1301 | |
| 1302 | #-------------------------------------------------------------------- |
| 1303 | # |
| 1304 | # Flags for thread support |
| 1305 | # |
| 1306 | #-------------------------------------------------------------------- |
| 1307 | |
| 1308 | SCM_I_GSC_USE_PTHREAD_THREADS=0 |
| 1309 | SCM_I_GSC_USE_NULL_THREADS=0 |
| 1310 | AC_SUBST([SCM_I_GSC_USE_PTHREAD_THREADS]) |
| 1311 | AC_SUBST([SCM_I_GSC_USE_NULL_THREADS]) |
| 1312 | |
| 1313 | ### What thread package has the user asked for? |
| 1314 | AC_ARG_WITH(threads, [ --with-threads thread interface], |
| 1315 | , with_threads=yes) |
| 1316 | |
| 1317 | AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT, 0) |
| 1318 | AC_SUBST(SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER, 0) |
| 1319 | |
| 1320 | case "$with_threads" in |
| 1321 | "yes" | "pthread" | "pthreads" | "pthread-threads" | "") |
| 1322 | |
| 1323 | build_pthread_support="yes" |
| 1324 | |
| 1325 | ACX_PTHREAD([CC="$PTHREAD_CC" |
| 1326 | LIBS="$PTHREAD_LIBS $LIBS" |
| 1327 | SCM_I_GSC_USE_PTHREAD_THREADS=1 |
| 1328 | with_threads="pthreads"], |
| 1329 | [with_threads="null" |
| 1330 | build_pthread_support="no"]) |
| 1331 | |
| 1332 | old_CFLAGS="$CFLAGS" |
| 1333 | CFLAGS="$PTHREAD_CFLAGS $CFLAGS" |
| 1334 | |
| 1335 | # Reasons for testing: |
| 1336 | # pthread_getattr_np - "np" meaning "non portable" says it |
| 1337 | # all; not present on MacOS X or Solaris 10 |
| 1338 | # pthread_get_stackaddr_np - "np" meaning "non portable" says it |
| 1339 | # all; specific to MacOS X |
| 1340 | # pthread_attr_get_np - "np" meaning "non portable" says it |
| 1341 | # all; specific to FreeBSD |
| 1342 | # pthread_sigmask - not available on mingw |
| 1343 | # |
| 1344 | AC_CHECK_FUNCS(pthread_attr_getstack pthread_getattr_np pthread_get_stackaddr_np pthread_attr_get_np pthread_sigmask) |
| 1345 | |
| 1346 | # On past versions of Solaris, believe 8 through 10 at least, you |
| 1347 | # had to write "pthread_once_t foo = { PTHREAD_ONCE_INIT };". |
| 1348 | # This is contrary to POSIX: |
| 1349 | # http://www.opengroup.org/onlinepubs/000095399/functions/pthread_once.html |
| 1350 | # Check here if this style is required. |
| 1351 | # |
| 1352 | # glibc (2.3.6 at least) works both with or without braces, so the |
| 1353 | # test checks whether it works without. |
| 1354 | # |
| 1355 | |
| 1356 | if test "$GCC" = "yes"; then |
| 1357 | # Since GCC only issues a warning for missing braces, so we need |
| 1358 | # `-Werror' to catch it. |
| 1359 | CFLAGS="-Werror -Wmissing-braces $CFLAGS" |
| 1360 | fi |
| 1361 | |
| 1362 | AC_CACHE_CHECK([whether PTHREAD_ONCE_INIT needs braces], |
| 1363 | guile_cv_need_braces_on_pthread_once_init, |
| 1364 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h> |
| 1365 | pthread_once_t foo = PTHREAD_ONCE_INIT;]])], |
| 1366 | [guile_cv_need_braces_on_pthread_once_init=no], |
| 1367 | [guile_cv_need_braces_on_pthread_once_init=yes])]) |
| 1368 | if test "$guile_cv_need_braces_on_pthread_once_init" = yes; then |
| 1369 | SCM_I_GSC_NEED_BRACES_ON_PTHREAD_ONCE_INIT=1 |
| 1370 | fi |
| 1371 | |
| 1372 | # Same problem with `PTHREAD_MUTEX_INITIALIZER', e.g., on IRIX |
| 1373 | # 6.5.30m with GCC 3.3. |
| 1374 | AC_CACHE_CHECK([whether PTHREAD_MUTEX_INITIALIZER needs braces], |
| 1375 | guile_cv_need_braces_on_pthread_mutex_initializer, |
| 1376 | [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h> |
| 1377 | pthread_mutex_t foo = PTHREAD_MUTEX_INITIALIZER;]])], |
| 1378 | [guile_cv_need_braces_on_pthread_mutex_initializer=no], |
| 1379 | [guile_cv_need_braces_on_pthread_mutex_initializer=yes])]) |
| 1380 | if test "$guile_cv_need_braces_on_pthread_mutex_initializer" = yes; then |
| 1381 | SCM_I_GSC_NEED_BRACES_ON_PTHREAD_MUTEX_INITIALIZER=1 |
| 1382 | fi |
| 1383 | |
| 1384 | CFLAGS="$old_CFLAGS" |
| 1385 | |
| 1386 | # On Solaris, sched_yield lives in -lrt. |
| 1387 | AC_SEARCH_LIBS(sched_yield, rt) |
| 1388 | |
| 1389 | ;; |
| 1390 | esac |
| 1391 | |
| 1392 | case "$with_threads" in |
| 1393 | "pthreads") |
| 1394 | ;; |
| 1395 | "no" | "null") |
| 1396 | SCM_I_GSC_USE_NULL_THREADS=1 |
| 1397 | SCM_I_GSC_HAVE_THREAD_STORAGE_CLASS=0 |
| 1398 | with_threads="null-threads" |
| 1399 | ;; |
| 1400 | * ) |
| 1401 | AC_MSG_ERROR(invalid value for --with-threads: $with_threads) |
| 1402 | ;; |
| 1403 | esac |
| 1404 | |
| 1405 | AC_MSG_CHECKING(what kind of threads to support) |
| 1406 | AC_MSG_RESULT($with_threads) |
| 1407 | |
| 1408 | AM_CONDITIONAL([BUILD_PTHREAD_SUPPORT], |
| 1409 | [test "x$build_pthread_support" = "xyes"]) |
| 1410 | |
| 1411 | |
| 1412 | ## Check whether pthread_attr_getstack works for the main thread |
| 1413 | |
| 1414 | if test "$with_threads" = pthreads; then |
| 1415 | |
| 1416 | AC_MSG_CHECKING([whether pthread_attr_getstack works for the main thread]) |
| 1417 | old_CFLAGS="$CFLAGS" |
| 1418 | CFLAGS="$PTHREAD_CFLAGS $CFLAGS" |
| 1419 | if test "$cross_compiling" = "no"; then |
| 1420 | AC_RUN_IFELSE([AC_LANG_SOURCE([[ |
| 1421 | #if HAVE_PTHREAD_ATTR_GETSTACK |
| 1422 | #include <pthread.h> |
| 1423 | |
| 1424 | int main () |
| 1425 | { |
| 1426 | pthread_attr_t attr; |
| 1427 | void *start, *end; |
| 1428 | size_t size; |
| 1429 | |
| 1430 | pthread_getattr_np (pthread_self (), &attr); |
| 1431 | pthread_attr_getstack (&attr, &start, &size); |
| 1432 | end = (char *)start + size; |
| 1433 | |
| 1434 | if ((void *)&attr < start || (void *)&attr >= end) |
| 1435 | return 1; |
| 1436 | else |
| 1437 | return 0; |
| 1438 | } |
| 1439 | #else |
| 1440 | int main () |
| 1441 | { |
| 1442 | return 1; |
| 1443 | } |
| 1444 | #endif |
| 1445 | ]])], |
| 1446 | [works=yes |
| 1447 | AC_DEFINE([PTHREAD_ATTR_GETSTACK_WORKS], [1], [Define when pthread_att_get_stack works for the main thread])], |
| 1448 | [works=no], |
| 1449 | []) |
| 1450 | else |
| 1451 | works="assuming it doesn't" |
| 1452 | fi |
| 1453 | CFLAGS="$old_CFLAGS" |
| 1454 | AC_MSG_RESULT($works) |
| 1455 | |
| 1456 | GUILE_THREAD_LOCAL_STORAGE |
| 1457 | |
| 1458 | fi # with_threads=pthreads |
| 1459 | |
| 1460 | |
| 1461 | ## Cross building |
| 1462 | if test "$cross_compiling" = "yes"; then |
| 1463 | AC_MSG_CHECKING(cc for build) |
| 1464 | ## /usr/bin/cc still uses wrong assembler |
| 1465 | ## CC_FOR_BUILD="${CC_FOR_BUILD-/usr/bincc}" |
| 1466 | CC_FOR_BUILD="${CC_FOR_BUILD-PATH=/usr/bin:$PATH cc}" |
| 1467 | else |
| 1468 | CC_FOR_BUILD="${CC_FOR_BUILD-$CC}" |
| 1469 | fi |
| 1470 | |
| 1471 | ## AC_MSG_CHECKING("if we are cross compiling") |
| 1472 | ## AC_MSG_RESULT($cross_compiling) |
| 1473 | if test "$cross_compiling" = "yes"; then |
| 1474 | AC_MSG_RESULT($CC_FOR_BUILD) |
| 1475 | fi |
| 1476 | |
| 1477 | ## No need as yet to be more elaborate |
| 1478 | CCLD_FOR_BUILD="$CC_FOR_BUILD" |
| 1479 | |
| 1480 | AC_SUBST(cross_compiling) |
| 1481 | AC_ARG_VAR(CC_FOR_BUILD,[build system C compiler]) |
| 1482 | AC_SUBST(CCLD_FOR_BUILD) |
| 1483 | |
| 1484 | ## libtool erroneously calls CC_FOR_BUILD HOST_CC; |
| 1485 | ## --HOST is the platform that PACKAGE is compiled for. |
| 1486 | HOST_CC="$CC_FOR_BUILD" |
| 1487 | AC_SUBST(HOST_CC) |
| 1488 | |
| 1489 | GUILE_CHECK_GUILE_FOR_BUILD |
| 1490 | |
| 1491 | ## If we're using GCC, ask for aggressive warnings. |
| 1492 | GCC_CFLAGS="" |
| 1493 | case "$GCC" in |
| 1494 | yes ) |
| 1495 | ## We had -Wstrict-prototypes in here for a bit, but Guile does too |
| 1496 | ## much stuff with generic function pointers for that to really be |
| 1497 | ## less than exasperating. |
| 1498 | ## -Wundef was removed because Gnulib prevented it (see |
| 1499 | ## <http://thread.gmane.org/gmane.lisp.guile.bugs/5329>.) |
| 1500 | |
| 1501 | ## Build with `-fno-strict-aliasing' to prevent miscompilation on |
| 1502 | ## some platforms. See |
| 1503 | ## <http://lists.gnu.org/archive/html/guile-devel/2012-01/msg00487.html>. |
| 1504 | |
| 1505 | POTENTIAL_GCC_CFLAGS="-Wall -Wmissing-prototypes \ |
| 1506 | -Wdeclaration-after-statement -Wpointer-arith \ |
| 1507 | -Wswitch-enum -fno-strict-aliasing" |
| 1508 | # Do this here so we don't screw up any of the tests above that might |
| 1509 | # not be "warning free" |
| 1510 | if test "${GUILE_ERROR_ON_WARNING}" = yes |
| 1511 | then |
| 1512 | POTENTIAL_GCC_CFLAGS="${POTENTIAL_GCC_CFLAGS} -Werror" |
| 1513 | enable_compile_warnings=no |
| 1514 | fi |
| 1515 | |
| 1516 | for flag in $POTENTIAL_GCC_CFLAGS |
| 1517 | do |
| 1518 | gl_WARN_ADD([$flag], [GCC_CFLAGS]) |
| 1519 | done |
| 1520 | ;; |
| 1521 | esac |
| 1522 | |
| 1523 | AC_SUBST(GCC_CFLAGS) |
| 1524 | |
| 1525 | # Check for GNU ld's "-z relro". |
| 1526 | GUILE_GNU_LD_RELRO |
| 1527 | |
| 1528 | |
| 1529 | LIBLOBJS="" |
| 1530 | for file in $LIBOBJS; do |
| 1531 | file=`echo "$file" | sed 's,\.[[^.]]*$,.lo,'` |
| 1532 | LIBLOBJS="$LIBLOBJS libguile_${GUILE_EFFECTIVE_VERSION}_la-$file" |
| 1533 | done |
| 1534 | |
| 1535 | ## We also need to create corresponding .doc and .x files |
| 1536 | EXTRA_DOT_DOC_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.doc ,g;s,\.[[^.]]*$,.doc,'`" |
| 1537 | EXTRA_DOT_X_FILES="`echo ${LIB@&t@OBJS} | sed 's,\.[[^.]]* ,.x ,g;s,\.[[^.]]*$,.x,'`" |
| 1538 | |
| 1539 | # GNU Readline bindings. |
| 1540 | GUILE_READLINE |
| 1541 | |
| 1542 | AC_SUBST(GUILE_MAJOR_VERSION) |
| 1543 | AC_SUBST(GUILE_MINOR_VERSION) |
| 1544 | AC_SUBST(GUILE_MICRO_VERSION) |
| 1545 | AC_SUBST(GUILE_EFFECTIVE_VERSION) |
| 1546 | AC_SUBST(GUILE_VERSION) |
| 1547 | |
| 1548 | ####################################################################### |
| 1549 | # library versioning |
| 1550 | |
| 1551 | AC_SUBST(LIBGUILE_INTERFACE_CURRENT) |
| 1552 | AC_SUBST(LIBGUILE_INTERFACE_REVISION) |
| 1553 | AC_SUBST(LIBGUILE_INTERFACE_AGE) |
| 1554 | AC_SUBST(LIBGUILE_INTERFACE) |
| 1555 | |
| 1556 | AC_SUBST(LIBGUILE_I18N_MAJOR) |
| 1557 | AC_SUBST(LIBGUILE_I18N_INTERFACE_CURRENT) |
| 1558 | AC_SUBST(LIBGUILE_I18N_INTERFACE_REVISION) |
| 1559 | AC_SUBST(LIBGUILE_I18N_INTERFACE_AGE) |
| 1560 | AC_SUBST(LIBGUILE_I18N_INTERFACE) |
| 1561 | |
| 1562 | |
| 1563 | ####################################################################### |
| 1564 | |
| 1565 | dnl Tell guile-config what flags guile users should compile and link |
| 1566 | dnl with, keeping only `-I' flags from $CPPFLAGS. |
| 1567 | GUILE_CFLAGS="" |
| 1568 | next_is_includedir=false |
| 1569 | for flag in $CPPFLAGS |
| 1570 | do |
| 1571 | if $next_is_includedir; then |
| 1572 | GUILE_CFLAGS="$GUILE_CFLAGS -I $flag" |
| 1573 | next_is_includedir=false |
| 1574 | else |
| 1575 | case "$flag" in |
| 1576 | -I) next_is_includedir=true;; |
| 1577 | -I*) GUILE_CFLAGS="$GUILE_CFLAGS $flag";; |
| 1578 | *) ;; |
| 1579 | esac |
| 1580 | fi |
| 1581 | done |
| 1582 | |
| 1583 | GUILE_CFLAGS="$GUILE_CFLAGS $PTHREAD_CFLAGS" |
| 1584 | GUILE_LIBS="$LDFLAGS $LIBS" |
| 1585 | |
| 1586 | AC_SUBST(GUILE_LIBS) |
| 1587 | AC_SUBST(GUILE_CFLAGS) |
| 1588 | |
| 1589 | AC_SUBST(AWK) |
| 1590 | AC_SUBST(LIBLOBJS) |
| 1591 | AC_SUBST(EXTRA_DOT_DOC_FILES) |
| 1592 | AC_SUBST(EXTRA_DOT_X_FILES) |
| 1593 | |
| 1594 | dnl See also top_builddir in info node: (libtool)AC_PROG_LIBTOOL |
| 1595 | top_builddir_absolute=`pwd` |
| 1596 | AC_SUBST(top_builddir_absolute) |
| 1597 | top_srcdir_absolute=`(cd $srcdir && pwd)` |
| 1598 | AC_SUBST(top_srcdir_absolute) |
| 1599 | |
| 1600 | dnl `sitedir' goes into libpath.h and the pkg-config file. |
| 1601 | pkgdatadir="$datadir/$PACKAGE_TARNAME" |
| 1602 | sitedir="$pkgdatadir/site/$GUILE_EFFECTIVE_VERSION" |
| 1603 | AC_SUBST([sitedir]) |
| 1604 | |
| 1605 | dnl Name of the `guile' program. |
| 1606 | guile_program_name="`echo guile | "$SED" "$program_transform_name"`" |
| 1607 | AC_SUBST([guile_program_name]) |
| 1608 | |
| 1609 | # Additional SCM_I_GSC definitions are above. |
| 1610 | AC_SUBST([SCM_I_GSC_GUILE_DEBUG]) |
| 1611 | AC_SUBST([SCM_I_GSC_ENABLE_DEPRECATED]) |
| 1612 | AC_SUBST([SCM_I_GSC_STACK_GROWS_UP]) |
| 1613 | AC_SUBST([SCM_I_GSC_C_INLINE]) |
| 1614 | AC_CONFIG_FILES([libguile/gen-scmconfig.h]) |
| 1615 | |
| 1616 | AC_CONFIG_FILES([ |
| 1617 | Makefile |
| 1618 | am/Makefile |
| 1619 | lib/Makefile |
| 1620 | benchmark-suite/Makefile |
| 1621 | gc-benchmarks/Makefile |
| 1622 | doc/Makefile |
| 1623 | doc/r5rs/Makefile |
| 1624 | doc/ref/Makefile |
| 1625 | emacs/Makefile |
| 1626 | examples/Makefile |
| 1627 | libguile/Makefile |
| 1628 | libguile/version.h |
| 1629 | guile-readline/Makefile |
| 1630 | test-suite/Makefile |
| 1631 | test-suite/standalone/Makefile |
| 1632 | test-suite/vm/Makefile |
| 1633 | meta/Makefile |
| 1634 | module/Makefile |
| 1635 | ]) |
| 1636 | |
| 1637 | AC_CONFIG_FILES([meta/guile-2.2.pc]) |
| 1638 | AC_CONFIG_FILES([meta/guile-2.2-uninstalled.pc]) |
| 1639 | |
| 1640 | GUILE_CONFIG_SCRIPT([check-guile]) |
| 1641 | GUILE_CONFIG_SCRIPT([benchmark-guile]) |
| 1642 | GUILE_CONFIG_SCRIPT([meta/guile]) |
| 1643 | GUILE_CONFIG_SCRIPT([meta/uninstalled-env]) |
| 1644 | GUILE_CONFIG_SCRIPT([meta/gdb-uninstalled-guile]) |
| 1645 | GUILE_CONFIG_SCRIPT([meta/guild]) |
| 1646 | GUILE_CONFIG_SCRIPT([libguile/guile-snarf]) |
| 1647 | GUILE_CONFIG_SCRIPT([libguile/guile-snarf-docs]) |
| 1648 | GUILE_CONFIG_SCRIPT([test-suite/standalone/test-use-srfi]) |
| 1649 | GUILE_CONFIG_SCRIPT([test-suite/standalone/test-fast-slot-ref]) |
| 1650 | |
| 1651 | AC_OUTPUT |
| 1652 | |
| 1653 | dnl Local Variables: |
| 1654 | dnl comment-start: "dnl " |
| 1655 | dnl comment-end: "" |
| 1656 | dnl comment-start-skip: "\\bdnl\\b\\s *" |
| 1657 | dnl End: |