| 1 | # warnings.m4 serial 7 |
| 2 | dnl Copyright (C) 2008-2013 Free Software Foundation, Inc. |
| 3 | dnl This file is free software; the Free Software Foundation |
| 4 | dnl gives unlimited permission to copy and/or distribute it, |
| 5 | dnl with or without modifications, as long as this notice is preserved. |
| 6 | |
| 7 | dnl From Simon Josefsson |
| 8 | |
| 9 | # gl_AS_VAR_APPEND(VAR, VALUE) |
| 10 | # ---------------------------- |
| 11 | # Provide the functionality of AS_VAR_APPEND if Autoconf does not have it. |
| 12 | m4_ifdef([AS_VAR_APPEND], |
| 13 | [m4_copy([AS_VAR_APPEND], [gl_AS_VAR_APPEND])], |
| 14 | [m4_define([gl_AS_VAR_APPEND], |
| 15 | [AS_VAR_SET([$1], [AS_VAR_GET([$1])$2])])]) |
| 16 | |
| 17 | |
| 18 | # gl_COMPILER_OPTION_IF(OPTION, [IF-SUPPORTED], [IF-NOT-SUPPORTED], |
| 19 | # [PROGRAM = AC_LANG_PROGRAM()]) |
| 20 | # ----------------------------------------------------------------- |
| 21 | # Check if the compiler supports OPTION when compiling PROGRAM. |
| 22 | # |
| 23 | # FIXME: gl_Warn must be used unquoted until we can assume Autoconf |
| 24 | # 2.64 or newer. |
| 25 | AC_DEFUN([gl_COMPILER_OPTION_IF], |
| 26 | [AS_VAR_PUSHDEF([gl_Warn], [gl_cv_warn_[]_AC_LANG_ABBREV[]_$1])dnl |
| 27 | AS_VAR_PUSHDEF([gl_Flags], [_AC_LANG_PREFIX[]FLAGS])dnl |
| 28 | AC_CACHE_CHECK([whether _AC_LANG compiler handles $1], m4_defn([gl_Warn]), [ |
| 29 | gl_save_compiler_FLAGS="$gl_Flags" |
| 30 | gl_AS_VAR_APPEND(m4_defn([gl_Flags]), [" $1"]) |
| 31 | AC_COMPILE_IFELSE([m4_default([$4], [AC_LANG_PROGRAM([])])], |
| 32 | [AS_VAR_SET(gl_Warn, [yes])], |
| 33 | [AS_VAR_SET(gl_Warn, [no])]) |
| 34 | gl_Flags="$gl_save_compiler_FLAGS" |
| 35 | ]) |
| 36 | AS_VAR_IF(gl_Warn, [yes], [$2], [$3]) |
| 37 | AS_VAR_POPDEF([gl_Flags])dnl |
| 38 | AS_VAR_POPDEF([gl_Warn])dnl |
| 39 | ]) |
| 40 | |
| 41 | |
| 42 | # gl_WARN_ADD(OPTION, [VARIABLE = WARN_CFLAGS], |
| 43 | # [PROGRAM = AC_LANG_PROGRAM()]) |
| 44 | # --------------------------------------------- |
| 45 | # Adds parameter to WARN_CFLAGS if the compiler supports it when |
| 46 | # compiling PROGRAM. For example, gl_WARN_ADD([-Wparentheses]). |
| 47 | # |
| 48 | # If VARIABLE is a variable name, AC_SUBST it. |
| 49 | AC_DEFUN([gl_WARN_ADD], |
| 50 | [gl_COMPILER_OPTION_IF([$1], |
| 51 | [gl_AS_VAR_APPEND(m4_if([$2], [], [[WARN_CFLAGS]], [[$2]]), [" $1"])], |
| 52 | [], |
| 53 | [$3]) |
| 54 | m4_ifval([$2], |
| 55 | [AS_LITERAL_IF([$2], [AC_SUBST([$2])])], |
| 56 | [AC_SUBST([WARN_CFLAGS])])dnl |
| 57 | ]) |
| 58 | |
| 59 | # Local Variables: |
| 60 | # mode: autoconf |
| 61 | # End: |