[bpt/guile.git] / module / ice-9 / eval.scm

;;; -*- mode: scheme; coding: utf-8; -*-

;;;; Copyright (C) 2009, 2010, 2011
;;;; Free Software Foundation, Inc.
;;;;
;;;; This library is free software; you can redistribute it and/or
;;;; modify it under the terms of the GNU Lesser General Public
;;;; License as published by the Free Software Foundation; either
;;;; version 3 of the License, or (at your option) any later version.
;;;; 
;;;; This library is distributed in the hope that it will be useful,
;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;;; Lesser General Public License for more details.
;;;; 
;;;; You should have received a copy of the GNU Lesser General Public
;;;; License along with this library; if not, write to the Free Software
;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
;;;;

\f

;;; Commentary:

;;; Scheme eval, written in Scheme.
;;;
;;; Expressions are first expanded, by the syntax expander (i.e.
;;; psyntax), then memoized into internal forms. The evaluator itself
;;; only operates on the internal forms ("memoized expressions").
;;;
;;; Environments are represented as linked lists of the form (VAL ... .
;;; MOD). If MOD is #f, it means the environment was captured before
;;; modules were booted. If MOD is the literal value '(), we are
;;; evaluating at the top level, and so should track changes to the
;;; current module.
;;;
;;; Evaluate this in Emacs to make code indentation work right:
;;;
;;;    (put 'memoized-expression-case 'scheme-indent-function 1)
;;;

;;; Code:

\f

(eval-when (compile)
  (define-syntax capture-env
    (syntax-rules ()
      ((_ (exp ...))
       (let ((env (exp ...)))
         (capture-env env)))
      ((_ env)
       (if (null? env)
           (current-module)
           (if (not env)
               ;; the and current-module checks that modules are booted,
               ;; and thus the-root-module is defined
               (and (current-module) the-root-module)
               env)))))

  ;; Fast case for procedures with fixed arities.
  (define-syntax make-fixed-closure
    (lambda (x)
      (define *max-static-argument-count* 8)
      (define (make-formals n)
        (map (lambda (i)
               (datum->syntax
                x 
                (string->symbol
                 (string (integer->char (+ (char->integer #\a) i))))))
             (iota n)))
      (syntax-case x ()
        ((_ eval nreq body env) (not (identifier? #'env))
         #'(let ((e env))
             (make-fixed-closure eval nreq body e)))
        ((_ eval nreq body env)
         #`(case nreq
             #,@(map (lambda (nreq)
                       (let ((formals (make-formals nreq)))
                         #`((#,nreq)
                            (lambda (#,@formals)
                              (eval body
                                    (cons* #,@(reverse formals) env))))))
                     (iota *max-static-argument-count*))
             (else
              #,(let ((formals (make-formals *max-static-argument-count*)))
                  #`(lambda (#,@formals . more)
                      (let lp ((new-env (cons* #,@(reverse formals) env))
                               (nreq (- nreq #,*max-static-argument-count*))
                               (args more))
                        (if (zero? nreq)
                            (eval body
                                  (if (null? args)
                                      new-env
                                      (scm-error 'wrong-number-of-args
                                                 "eval" "Wrong number of arguments"
                                                 '() #f)))
                            (if (null? args)
                                (scm-error 'wrong-number-of-args
                                           "eval" "Wrong number of arguments"
                                           '() #f)
                                (lp (cons (car args) new-env)
                                    (1- nreq)
                                    (cdr args)))))))))))))

  (define-syntax call
    (lambda (x)
      (define *max-static-call-count* 4)
      (syntax-case x ()
        ((_ eval proc nargs args env) (identifier? #'env)
         #`(case nargs
             #,@(map (lambda (nargs)
                       #`((#,nargs)
                          (proc
                           #,@(map
                               (lambda (n)
                                 (let lp ((n n) (args #'args))
                                   (if (zero? n)
                                       #`(eval (car #,args) env)
                                       (lp (1- n) #`(cdr #,args)))))
                               (iota nargs)))))
                     (iota *max-static-call-count*))
             (else
              (apply proc
                     #,@(map
                         (lambda (n)
                           (let lp ((n n) (args #'args))
                             (if (zero? n)
                                 #`(eval (car #,args) env)
                                 (lp (1- n) #`(cdr #,args)))))
                         (iota *max-static-call-count*))
                     (let lp ((exps #,(let lp ((n *max-static-call-count*)
                                               (args #'args))
                                        (if (zero? n)
                                            args
                                            (lp (1- n) #`(cdr #,args)))))
                              (args '()))
                       (if (null? exps)
                           (reverse args)
                           (lp (cdr exps)
                               (cons (eval (car exps) env) args)))))))))))

  ;; This macro could be more straightforward if the compiler had better
  ;; copy propagation. As it is we do some copy propagation by hand.
  (define-syntax mx-bind
    (lambda (x)
      (syntax-case x ()
        ((_ data () body)
         #'body)
        ((_ data (a . b) body) (and (identifier? #'a) (identifier? #'b))
         #'(let ((a (car data))
                 (b (cdr data)))
             body))
        ((_ data (a . b) body) (identifier? #'a)
         #'(let ((a (car data))
                 (xb (cdr data)))
             (mx-bind xb b body)))
        ((_ data (a . b) body) 
         #'(let ((xa (car data))
                 (xb (cdr data)))
             (mx-bind xa a (mx-bind xb b body))))
        ((_ data v body) (identifier? #'v)
         #'(let ((v data))
             body)))))
  
  ;; The resulting nested if statements will be an O(n) dispatch. Once
  ;; we compile `case' effectively, this situation will improve.
  (define-syntax mx-match
    (lambda (x)
      (syntax-case x (quote)
        ((_ mx data tag)
         #'(error "what" mx))
        ((_ mx data tag (('type pat) body) c* ...)
         #`(if (eqv? tag #,(or (memoized-typecode (syntax->datum #'type))
                               (error "not a typecode" #'type)))
               (mx-bind data pat body)
               (mx-match mx data tag c* ...))))))

  (define-syntax memoized-expression-case
    (lambda (x)
      (syntax-case x ()
        ((_ mx c ...)
         #'(let ((tag (memoized-expression-typecode mx))
                 (data (memoized-expression-data mx)))
             (mx-match mx data tag c ...)))))))


;;;
;;; On 18 Feb 2010, I did a profile of how often the various memoized expression
;;; types occur when getting to a prompt on a fresh build. Here are the numbers
;;; I got:
;;;
;;;      lexical-ref: 32933054
;;;             call: 20281547
;;;     toplevel-ref: 13228724
;;;               if: 9156156
;;;            quote: 6610137
;;;              let: 2619707
;;;           lambda: 1010921
;;;            begin: 948945
;;;      lexical-set: 509862
;;; call-with-values: 139668
;;;            apply: 49402
;;;       module-ref: 14468
;;;           define: 1259
;;;     toplevel-set: 328
;;;          dynwind: 162
;;;      with-fluids: 0
;;;          call/cc: 0
;;;       module-set: 0
;;;
;;; So until we compile `case' into a computed goto, we'll order the clauses in
;;; `eval' in this order, to put the most frequent cases first.
;;;

(define primitive-eval
  (let ()
    ;; We pre-generate procedures with fixed arities, up to some number of
    ;; arguments; see make-fixed-closure above.

    ;; A unique marker for unbound keywords.
    (define unbound-arg (list 'unbound-arg))

    ;; Procedures with rest, optional, or keyword arguments, potentially with
    ;; multiple arities, as with case-lambda.
    (define (make-general-closure env body nreq rest? nopt kw inits alt)
      (define alt-proc
        (and alt
             (let* ((body (car alt))
                    (nreq (cadr alt))
                    (rest (if (null? (cddr alt)) #f (caddr alt)))
                    (tail (and (pair? (cddr alt)) (pair? (cdddr alt)) (cdddr alt)))
                    (nopt (if tail (car tail) 0))
                    (kw (and tail (cadr tail)))
                    (inits (if tail (caddr tail) '()))
                    (alt (and tail (cadddr tail))))
               (make-general-closure env body nreq rest nopt kw inits alt))))
      (define (set-procedure-arity! proc)
        (let lp ((alt alt) (nreq nreq) (nopt nopt) (rest? rest?))
          (if (not alt)
              (begin
                (set-procedure-property! proc 'arglist
                                         (list nreq
                                               nopt
                                               (if kw (cdr kw) '())
                                               (and kw (car kw))
                                               (and rest? '_)))
                (set-procedure-minimum-arity! proc nreq nopt rest?))
              (let* ((nreq* (cadr alt))
                     (rest?* (if (null? (cddr alt)) #f (caddr alt)))
                     (tail (and (pair? (cddr alt)) (pair? (cdddr alt)) (cdddr alt)))
                     (nopt* (if tail (car tail) 0))
                     (alt* (and tail (cadddr tail))))
                (if (or (< nreq* nreq)
                        (and (= nreq* nreq)
                             (if rest?
                                 (and rest?* (> nopt* nopt))
                                 (or rest?* (> nopt* nopt)))))
                    (lp alt* nreq* nopt* rest?*)
                    (lp alt* nreq nopt rest?)))))
        proc)
      (set-procedure-arity!
       (lambda %args
         (let lp ((env env)
                  (nreq* nreq)
                  (args %args))
           (if (> nreq* 0)
               ;; First, bind required arguments.
               (if (null? args)
                   (if alt
                       (apply alt-proc %args)
                       (scm-error 'wrong-number-of-args
                                  "eval" "Wrong number of arguments"
                                  '() #f))
                   (lp (cons (car args) env)
                       (1- nreq*)
                       (cdr args)))
               ;; Move on to optional arguments.
               (if (not kw)
                   ;; Without keywords, bind optionals from arguments.
                   (let lp ((env env)
                            (nopt nopt)
                            (args args)
                            (inits inits))
                     (if (zero? nopt)
                         (if rest?
                             (eval body (cons args env))
                             (if (null? args)
                                 (eval body env)
                                 (if alt
                                     (apply alt-proc %args)
                                     (scm-error 'wrong-number-of-args
                                                "eval" "Wrong number of arguments"
                                                '() #f))))
                         (if (null? args)
                             (lp (cons (eval (car inits) env) env)
                                 (1- nopt) args (cdr inits))
                             (lp (cons (car args) env)
                                 (1- nopt) (cdr args) (cdr inits)))))
                   ;; With keywords, we stop binding optionals at the first
                   ;; keyword.
                   (let lp ((env env)
                            (nopt* nopt)
                            (args args)
                            (inits inits))
                     (if (> nopt* 0)
                         (if (or (null? args) (keyword? (car args)))
                             (lp (cons (eval (car inits) env) env)
                                 (1- nopt*) args (cdr inits))
                             (lp (cons (car args) env)
                                 (1- nopt*) (cdr args) (cdr inits)))
                         ;; Finished with optionals.
                         (let* ((aok (car kw))
                                (kw (cdr kw))
                                (kw-base (+ nopt nreq (if rest? 1 0)))
                                (imax (let lp ((imax (1- kw-base)) (kw kw))
                                        (if (null? kw)
                                            imax
                                            (lp (max (cdar kw) imax)
                                                (cdr kw)))))
                                ;; Fill in kwargs  with "undefined" vals.
                                (env (let lp ((i kw-base)
                                              ;; Also, here we bind the rest
                                              ;; arg, if any.
                                              (env (if rest? (cons args env) env)))
                                       (if (<= i imax)
                                           (lp (1+ i) (cons unbound-arg env))
                                           env))))
                           ;; Now scan args for keywords.
                           (let lp ((args args))
                             (if (and (pair? args) (pair? (cdr args))
                                      (keyword? (car args)))
                                 (let ((kw-pair (assq (car args) kw))
                                       (v (cadr args)))
                                   (if kw-pair
                                       ;; Found a known keyword; set its value.
                                       (list-set! env (- imax (cdr kw-pair)) v)
                                       ;; Unknown keyword.
                                       (if (not aok)
                                           (scm-error 'keyword-argument-error
                                                      "eval" "Unrecognized keyword"
                                                      '() #f)))
                                   (lp (cddr args)))
                                 (if (pair? args)
                                     (if rest?
                                         ;; Be lenient parsing rest args.
                                         (lp (cdr args))
                                         (scm-error 'keyword-argument-error
                                                    "eval" "Invalid keyword"
                                                    '() #f))
                                     ;; Finished parsing keywords. Fill in
                                     ;; uninitialized kwargs by evalling init
                                     ;; expressions in their appropriate
                                     ;; environment.
                                     (let lp ((i (- imax kw-base))
                                              (inits inits))
                                       (if (pair? inits)
                                           (let ((tail (list-tail env i)))
                                             (if (eq? (car tail) unbound-arg)
                                                 (set-car! tail
                                                           (eval (car inits)
                                                                 (cdr tail))))
                                             (lp (1- i) (cdr inits)))
                                           ;; Finally, eval the body.
                                           (eval body env)))))))))))))))

    ;; The "engine". EXP is a memoized expression.
    (define (eval exp env)
      (memoized-expression-case exp
        (('lexical-ref n)
         (list-ref env n))
        
        (('call (f nargs . args))
         (let ((proc (eval f env)))
           (call eval proc nargs args env)))
        
        (('toplevel-ref var-or-sym)
         (variable-ref
          (if (variable? var-or-sym)
              var-or-sym
              (memoize-variable-access! exp
                                        (capture-env (if (pair? env)
                                                         (cdr (last-pair env))
                                                         env))))))

        (('if (test consequent . alternate))
         (if (eval test env)
             (eval consequent env)
             (eval alternate env)))
      
        (('quote x)
         x)

        (('let (inits . body))
         (let lp ((inits inits) (new-env (capture-env env)))
           (if (null? inits)
               (eval body new-env)
               (lp (cdr inits)
                   (cons (eval (car inits) env) new-env)))))
      
        (('lambda (body nreq . tail))
         (if (null? tail)
             (make-fixed-closure eval nreq body (capture-env env))
             (if (null? (cdr tail))
                 (make-general-closure (capture-env env) body nreq (car tail)
                                       0 #f '() #f)
                 (apply make-general-closure (capture-env env) body nreq tail))))

        (('seq (head . tail))
         (begin
           (eval head env)
           (eval tail env)))
        
        (('lexical-set! (n . x))
         (let ((val (eval x env)))
           (list-set! env n val)))
        
        (('call-with-values (producer . consumer))
         (call-with-values (eval producer env)
           (eval consumer env)))

        (('apply (f args))
         (apply (eval f env) (eval args env)))

        (('module-ref var-or-spec)
         (variable-ref
          (if (variable? var-or-spec)
              var-or-spec
              (memoize-variable-access! exp #f))))

        (('define (name . x))
         (let ((x (eval x env)))
           (if (and (procedure? x) (not (procedure-property x 'name)))
               (set-procedure-property! x 'name name))
           (define! name x)
           (if #f #f)))
      
        (('toplevel-set! (var-or-sym . x))
         (variable-set!
          (if (variable? var-or-sym)
              var-or-sym
              (memoize-variable-access! exp
                                        (capture-env (if (pair? env)
                                                         (cdr (last-pair env))
                                                         env))))
          (eval x env)))
      
        (('dynwind (in exp . out))
         (dynamic-wind (eval in env)
                       (lambda () (eval exp env))
                       (eval out env)))
        
        (('with-fluids (fluids vals . exp))
         (let* ((fluids (map (lambda (x) (eval x env)) fluids))
                (vals (map (lambda (x) (eval x env)) vals)))
           (let lp ((fluids fluids) (vals vals))
             (if (null? fluids)
                 (eval exp env)
                 (with-fluids (((car fluids) (car vals)))
                   (lp (cdr fluids) (cdr vals)))))))
        
        (('prompt (tag exp . handler))
         (@prompt (eval tag env)
                  (eval exp env)
                  (eval handler env)))
        
        (('call/cc proc)
         (call/cc (eval proc env)))

        (('module-set! (x . var-or-spec))
         (variable-set!
          (if (variable? var-or-spec)
              var-or-spec
              (memoize-variable-access! exp #f))
          (eval x env)))))
  
    ;; primitive-eval
    (lambda (exp)
      "Evaluate @var{exp} in the current module."
      (eval 
       (memoize-expression 
        (if (macroexpanded? exp)
            exp
            ((module-transformer (current-module)) exp)))
       '()))))
Commit	Line	Data
5161a3c0 AW	1	;;; -- mode: scheme; coding: utf-8; --
5161a3c0 AW	2
6fc3eae4	3	;;;; Copyright (C) 2009, 2010, 2011
5161a3c0 AW	4	;;;; Free Software Foundation, Inc.
	5	;;;;
	6	;;;; This library is free software; you can redistribute it and/or
	7	;;;; modify it under the terms of the GNU Lesser General Public
	8	;;;; License as published by the Free Software Foundation; either
	9	;;;; version 3 of the License, or (at your option) any later version.
	10	;;;;
	11	;;;; This library is distributed in the hope that it will be useful,
	12	;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
	13	;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
	14	;;;; Lesser General Public License for more details.
	15	;;;;
	16	;;;; You should have received a copy of the GNU Lesser General Public
	17	;;;; License along with this library; if not, write to the Free Software
	18	;;;; Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
	19	;;;;
	20
	21	\f
	22
	23	;;; Commentary:
	24
b2b554ef AW	25	;;; Scheme eval, written in Scheme.
	26	;;;
	27	;;; Expressions are first expanded, by the syntax expander (i.e.
	28	;;; psyntax), then memoized into internal forms. The evaluator itself
	29	;;; only operates on the internal forms ("memoized expressions").
	30	;;;
	31	;;; Environments are represented as linked lists of the form (VAL ... .
	32	;;; MOD). If MOD is #f, it means the environment was captured before
	33	;;; modules were booted. If MOD is the literal value '(), we are
	34	;;; evaluating at the top level, and so should track changes to the
	35	;;; current module.
	36	;;;
	37	;;; Evaluate this in Emacs to make code indentation work right:
	38	;;;
	39	;;; (put 'memoized-expression-case 'scheme-indent-function 1)
5161a3c0 AW	40	;;;
	41
	42	;;; Code:
	43
	44	\f
	45
5161a3c0 AW	46	(eval-when (compile)
	47	(define-syntax capture-env
	48	(syntax-rules ()
bb0c8157 AW	49	((_ (exp ...))
	50	(let ((env (exp ...)))
	51	(capture-env env)))
5161a3c0 AW	52	((_ env)
	53	(if (null? env)
	54	(current-module)
	55	(if (not env)
b2b554ef AW	56	;; the and current-module checks that modules are booted,
b2b554ef AW	57	;; and thus the-root-module is defined
5f161164	58	(and (current-module) the-root-module)
5161a3c0 AW	59	env)))))
5161a3c0 AW	60
d8a071fc AW	61	;; Fast case for procedures with fixed arities.
d8a071fc AW	62	(define-syntax make-fixed-closure
4abb824c	63	(lambda (x)
9331f91c	64	(define max-static-argument-count 8)
4abb824c AW	65	(define (make-formals n)
	66	(map (lambda (i)
	67	(datum->syntax
	68	x
	69	(string->symbol
	70	(string (integer->char (+ (char->integer #\a) i))))))
	71	(iota n)))
	72	(syntax-case x ()
d8a071fc	73	((_ eval nreq body env) (not (identifier? #'env))
4abb824c	74	#'(let ((e env))
d8a071fc AW	75	(make-fixed-closure eval nreq body e)))
d8a071fc AW	76	((_ eval nreq body env)
4abb824c AW	77	#`(case nreq
	78	#,@(map (lambda (nreq)
	79	(let ((formals (make-formals nreq)))
	80	#`((#,nreq)
d8a071fc AW	81	(lambda (#,@formals)
	82	(eval body
	83	(cons* #,@(reverse formals) env))))))
4abb824c AW	84	(iota max-static-argument-count))
	85	(else
	86	#,(let ((formals (make-formals max-static-argument-count)))
	87	#`(lambda (#,@formals . more)
	88	(let lp ((new-env (cons* #,@(reverse formals) env))
	89	(nreq (- nreq #,max-static-argument-count))
	90	(args more))
	91	(if (zero? nreq)
	92	(eval body
d8a071fc AW	93	(if (null? args)
	94	new-env
	95	(scm-error 'wrong-number-of-args
	96	"eval" "Wrong number of arguments"
	97	'() #f)))
4abb824c AW	98	(if (null? args)
	99	(scm-error 'wrong-number-of-args
	100	"eval" "Wrong number of arguments"
	101	'() #f)
	102	(lp (cons (car args) new-env)
	103	(1- nreq)
	104	(cdr args)))))))))))))
	105
9331f91c AW	106	(define-syntax call
	107	(lambda (x)
	108	(define max-static-call-count 4)
	109	(syntax-case x ()
	110	((_ eval proc nargs args env) (identifier? #'env)
	111	#`(case nargs
	112	#,@(map (lambda (nargs)
	113	#`((#,nargs)
	114	(proc
	115	#,@(map
	116	(lambda (n)
	117	(let lp ((n n) (args #'args))
	118	(if (zero? n)
	119	#`(eval (car #,args) env)
	120	(lp (1- n) #`(cdr #,args)))))
	121	(iota nargs)))))
	122	(iota max-static-call-count))
	123	(else
	124	(apply proc
	125	#,@(map
	126	(lambda (n)
	127	(let lp ((n n) (args #'args))
	128	(if (zero? n)
	129	#`(eval (car #,args) env)
	130	(lp (1- n) #`(cdr #,args)))))
	131	(iota max-static-call-count))
	132	(let lp ((exps #,(let lp ((n max-static-call-count)
	133	(args #'args))
	134	(if (zero? n)
	135	args
	136	(lp (1- n) #`(cdr #,args)))))
	137	(args '()))
	138	(if (null? exps)
	139	(reverse args)
	140	(lp (cdr exps)
	141	(cons (eval (car exps) env) args)))))))))))
	142
b2b554ef AW	143	;; This macro could be more straightforward if the compiler had better
b2b554ef AW	144	;; copy propagation. As it is we do some copy propagation by hand.
5161a3c0 AW	145	(define-syntax mx-bind
	146	(lambda (x)
	147	(syntax-case x ()
	148	((_ data () body)
	149	#'body)
	150	((_ data (a . b) body) (and (identifier? #'a) (identifier? #'b))
	151	#'(let ((a (car data))
	152	(b (cdr data)))
	153	body))
	154	((_ data (a . b) body) (identifier? #'a)
	155	#'(let ((a (car data))
	156	(xb (cdr data)))
	157	(mx-bind xb b body)))
	158	((_ data (a . b) body)
	159	#'(let ((xa (car data))
	160	(xb (cdr data)))
	161	(mx-bind xa a (mx-bind xb b body))))
	162	((_ data v body) (identifier? #'v)
	163	#'(let ((v data))
	164	body)))))
	165
b2b554ef AW	166	;; The resulting nested if statements will be an O(n) dispatch. Once
b2b554ef AW	167	;; we compile `case' effectively, this situation will improve.
5161a3c0 AW	168	(define-syntax mx-match
	169	(lambda (x)
	170	(syntax-case x (quote)
	171	((_ mx data tag)
	172	#'(error "what" mx))
	173	((_ mx data tag (('type pat) body) c* ...)
	174	#`(if (eqv? tag #,(or (memoized-typecode (syntax->datum #'type))
	175	(error "not a typecode" #'type)))
	176	(mx-bind data pat body)
	177	(mx-match mx data tag c* ...))))))
	178
	179	(define-syntax memoized-expression-case
	180	(lambda (x)
	181	(syntax-case x ()
	182	((_ mx c ...)
	183	#'(let ((tag (memoized-expression-typecode mx))
	184	(data (memoized-expression-data mx)))
	185	(mx-match mx data tag c ...)))))))
	186
	187
21ec0bd9 AW	188	;;;
	189	;;; On 18 Feb 2010, I did a profile of how often the various memoized expression
	190	;;; types occur when getting to a prompt on a fresh build. Here are the numbers
	191	;;; I got:
	192	;;;
	193	;;; lexical-ref: 32933054
	194	;;; call: 20281547
	195	;;; toplevel-ref: 13228724
	196	;;; if: 9156156
	197	;;; quote: 6610137
	198	;;; let: 2619707
	199	;;; lambda: 1010921
	200	;;; begin: 948945
	201	;;; lexical-set: 509862
	202	;;; call-with-values: 139668
	203	;;; apply: 49402
	204	;;; module-ref: 14468
	205	;;; define: 1259
	206	;;; toplevel-set: 328
	207	;;; dynwind: 162
	208	;;; with-fluids: 0
	209	;;; call/cc: 0
	210	;;; module-set: 0
	211	;;;
	212	;;; So until we compile `case' into a computed goto, we'll order the clauses in
	213	;;; `eval' in this order, to put the most frequent cases first.
	214	;;;
	215
5161a3c0 AW	216	(define primitive-eval
5161a3c0 AW	217	(let ()
d8a071fc AW	218	;; We pre-generate procedures with fixed arities, up to some number of
	219	;; arguments; see make-fixed-closure above.
	220
	221	;; A unique marker for unbound keywords.
	222	(define unbound-arg (list 'unbound-arg))
	223
7572ee52 AW	224	;; Procedures with rest, optional, or keyword arguments, potentially with
7572ee52 AW	225	;; multiple arities, as with case-lambda.
d8a071fc	226	(define (make-general-closure env body nreq rest? nopt kw inits alt)
7572ee52 AW	227	(define alt-proc
7572ee52 AW	228	(and alt
dc3e203e AW	229	(let* ((body (car alt))
	230	(nreq (cadr alt))
	231	(rest (if (null? (cddr alt)) #f (caddr alt)))
	232	(tail (and (pair? (cddr alt)) (pair? (cdddr alt)) (cdddr alt)))
	233	(nopt (if tail (car tail) 0))
	234	(kw (and tail (cadr tail)))
	235	(inits (if tail (caddr tail) '()))
	236	(alt (and tail (cadddr tail))))
	237	(make-general-closure env body nreq rest nopt kw inits alt))))
f3cf9421 AW	238	(define (set-procedure-arity! proc)
	239	(let lp ((alt alt) (nreq nreq) (nopt nopt) (rest? rest?))
	240	(if (not alt)
fc835b1b AW	241	(begin
	242	(set-procedure-property! proc 'arglist
	243	(list nreq
	244	nopt
	245	(if kw (cdr kw) '())
	246	(and kw (car kw))
	247	(and rest? '_)))
	248	(set-procedure-minimum-arity! proc nreq nopt rest?))
f3cf9421 AW	249	(let* ((nreq* (cadr alt))
	250	(rest?* (if (null? (cddr alt)) #f (caddr alt)))
	251	(tail (and (pair? (cddr alt)) (pair? (cdddr alt)) (cdddr alt)))
	252	(nopt* (if tail (car tail) 0))
	253	(alt* (and tail (cadddr tail))))
	254	(if (or (< nreq* nreq)
	255	(and (= nreq* nreq)
	256	(if rest?
	257	(and rest?* (> nopt* nopt))
	258	(or rest?* (> nopt* nopt)))))
	259	(lp alt* nreq* nopt* rest?*)
	260	(lp alt* nreq nopt rest?)))))
	261	proc)
	262	(set-procedure-arity!
	263	(lambda %args
	264	(let lp ((env env)
	265	(nreq* nreq)
	266	(args %args))
	267	(if (> nreq* 0)
	268	;; First, bind required arguments.
	269	(if (null? args)
	270	(if alt
	271	(apply alt-proc %args)
	272	(scm-error 'wrong-number-of-args
	273	"eval" "Wrong number of arguments"
	274	'() #f))
	275	(lp (cons (car args) env)
	276	(1- nreq*)
	277	(cdr args)))
	278	;; Move on to optional arguments.
	279	(if (not kw)
	280	;; Without keywords, bind optionals from arguments.
	281	(let lp ((env env)
	282	(nopt nopt)
	283	(args args)
	284	(inits inits))
	285	(if (zero? nopt)
	286	(if rest?
	287	(eval body (cons args env))
	288	(if (null? args)
	289	(eval body env)
	290	(if alt
	291	(apply alt-proc %args)
	292	(scm-error 'wrong-number-of-args
	293	"eval" "Wrong number of arguments"
	294	'() #f))))
	295	(if (null? args)
	296	(lp (cons (eval (car inits) env) env)
	297	(1- nopt) args (cdr inits))
	298	(lp (cons (car args) env)
	299	(1- nopt) (cdr args) (cdr inits)))))
	300	;; With keywords, we stop binding optionals at the first
	301	;; keyword.
	302	(let lp ((env env)
	303	(nopt* nopt)
	304	(args args)
	305	(inits inits))
	306	(if (> nopt* 0)
	307	(if (or (null? args) (keyword? (car args)))
	308	(lp (cons (eval (car inits) env) env)
	309	(1- nopt*) args (cdr inits))
	310	(lp (cons (car args) env)
	311	(1- nopt*) (cdr args) (cdr inits)))
	312	;; Finished with optionals.
313	(let* ((aok (car kw))
314	(kw (cdr kw))
315	(kw-base (+ nopt nreq (if rest? 1 0)))
316	(imax (let lp ((imax (1- kw-base)) (kw kw))
317	(if (null? kw)
318	imax
319	(lp (max (cdar kw) imax)
320	(cdr kw)))))
321	;; Fill in kwargs with "undefined" vals.
322	(env (let lp ((i kw-base)
323	;; Also, here we bind the rest
324	;; arg, if any.
325	(env (if rest? (cons args env) env)))
326	(if (<= i imax)
327	(lp (1+ i) (cons unbound-arg env))
328	env))))
329	;; Now scan args for keywords.
330	(let lp ((args args))
331	(if (and (pair? args) (pair? (cdr args))
332	(keyword? (car args)))
333	(let ((kw-pair (assq (car args) kw))
334	(v (cadr args)))
335	(if kw-pair
336	;; Found a known keyword; set its value.
337	(list-set! env (- imax (cdr kw-pair)) v)
338	;; Unknown keyword.
339	(if (not aok)
340	(scm-error 'keyword-argument-error
341	"eval" "Unrecognized keyword"
342	'() #f)))
343	(lp (cddr args)))
344	(if (pair? args)
345	(if rest?
346	;; Be lenient parsing rest args.
347	(lp (cdr args))
348	(scm-error 'keyword-argument-error
349	"eval" "Invalid keyword"
350	'() #f))
351	;; Finished parsing keywords. Fill in
352	;; uninitialized kwargs by evalling init
353	;; expressions in their appropriate
354	;; environment.
355	(let lp ((i (- imax kw-base))
356	(inits inits))
357	(if (pair? inits)
358	(let ((tail (list-tail env i)))
359	(if (eq? (car tail) unbound-arg)
360	(set-car! tail
361	(eval (car inits)
362	(cdr tail))))
363	(lp (1- i) (cdr inits)))
364	;; Finally, eval the body.
365	(eval body env)))))))))))))))
d8a071fc	366
b2b554ef	367	;; The "engine". EXP is a memoized expression.
5161a3c0 AW	368	(define (eval exp env)
5161a3c0 AW	369	(memoized-expression-case exp
21ec0bd9	370	(('lexical-ref n)
bb0c8157 AW	371	(list-ref env n))
bb0c8157 AW	372
21ec0bd9 AW	373	(('call (f nargs . args))
	374	(let ((proc (eval f env)))
	375	(call eval proc nargs args env)))
	376
	377	(('toplevel-ref var-or-sym)
	378	(variable-ref
	379	(if (variable? var-or-sym)
	380	var-or-sym
bb0c8157 AW	381	(memoize-variable-access! exp
	382	(capture-env (if (pair? env)
	383	(cdr (last-pair env))
	384	env))))))
21ec0bd9	385
5161a3c0 AW	386	(('if (test consequent . alternate))
	387	(if (eval test env)
	388	(eval consequent env)
	389	(eval alternate env)))
	390
21ec0bd9 AW	391	(('quote x)
	392	x)
	393
5161a3c0 AW	394	(('let (inits . body))
	395	(let lp ((inits inits) (new-env (capture-env env)))
	396	(if (null? inits)
	397	(eval body new-env)
	398	(lp (cdr inits)
	399	(cons (eval (car inits) env) new-env)))))
	400
8f9c5b58	401	(('lambda (body nreq . tail))
d8a071fc AW	402	(if (null? tail)
	403	(make-fixed-closure eval nreq body (capture-env env))
	404	(if (null? (cdr tail))
	405	(make-general-closure (capture-env env) body nreq (car tail)
	406	0 #f '() #f)
	407	(apply make-general-closure (capture-env env) body nreq tail))))
	408
6fc3eae4 AW	409	(('seq (head . tail))
	410	(begin
	411	(eval head env)
	412	(eval tail env)))
	413
5161a3c0 AW	414	(('lexical-set! (n . x))
5161a3c0 AW	415	(let ((val (eval x env)))
bb0c8157	416	(list-set! env n val)))
5161a3c0	417
21ec0bd9 AW	418	(('call-with-values (producer . consumer))
	419	(call-with-values (eval producer env)
	420	(eval consumer env)))
	421
	422	(('apply (f args))
	423	(apply (eval f env) (eval args env)))
	424
	425	(('module-ref var-or-spec)
5161a3c0	426	(variable-ref
21ec0bd9 AW	427	(if (variable? var-or-spec)
	428	var-or-spec
	429	(memoize-variable-access! exp #f))))
5161a3c0	430
21ec0bd9	431	(('define (name . x))
ee15aa46 AW	432	(let ((x (eval x env)))
	433	(if (and (procedure? x) (not (procedure-property x 'name)))
	434	(set-procedure-property! x 'name name))
adb8054c MW	435	(define! name x)
adb8054c MW	436	(if #f #f)))
21ec0bd9	437
5161a3c0 AW	438	(('toplevel-set! (var-or-sym . x))
	439	(variable-set!
	440	(if (variable? var-or-sym)
	441	var-or-sym
bb0c8157 AW	442	(memoize-variable-access! exp
	443	(capture-env (if (pair? env)
	444	(cdr (last-pair env))
	445	env))))
5161a3c0 AW	446	(eval x env)))
5161a3c0 AW	447
21ec0bd9 AW	448	(('dynwind (in exp . out))
	449	(dynamic-wind (eval in env)
	450	(lambda () (eval exp env))
	451	(eval out env)))
	452
bb0229b5 AW	453	(('with-fluids (fluids vals . exp))
	454	(let* ((fluids (map (lambda (x) (eval x env)) fluids))
	455	(vals (map (lambda (x) (eval x env)) vals)))
1371fe9b AW	456	(let lp ((fluids fluids) (vals vals))
	457	(if (null? fluids)
	458	(eval exp env)
	459	(with-fluids (((car fluids) (car vals)))
	460	(lp (cdr fluids) (cdr vals)))))))
bb0229b5	461
747022e4 AW	462	(('prompt (tag exp . handler))
	463	(@prompt (eval tag env)
	464	(eval exp env)
	465	(eval handler env)))
	466
21ec0bd9 AW	467	(('call/cc proc)
21ec0bd9 AW	468	(call/cc (eval proc env)))
5161a3c0 AW	469
	470	(('module-set! (x . var-or-spec))
	471	(variable-set!
	472	(if (variable? var-or-spec)
	473	var-or-spec
	474	(memoize-variable-access! exp #f))
	475	(eval x env)))))
	476
b2b554ef	477	;; primitive-eval
5161a3c0	478	(lambda (exp)
b2b554ef	479	"Evaluate @var{exp} in the current module."
5161a3c0	480	(eval
a310a1d1 AW	481	(memoize-expression
	482	(if (macroexpanded? exp)
	483	exp
	484	((module-transformer (current-module)) exp)))
5161a3c0	485	'()))))