[bpt/guile.git] / configure.in

dnl   configuration script for Guile
dnl   Process this file with autoconf to produce configure.
dnl
dnl  Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
dnl
dnl  This file is part of GUILE
dnl
dnl  GUILE is free software; you can redistribute it and/or modify it
dnl  under the terms of the GNU General Public License as published by
dnl  the Free Software Foundation; either version 2, or (at your
dnl  option) any later version.
dnl
dnl  GUILE is distributed in the hope that it will be useful, but
dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
dnl  General Public License for more details.
dnl
dnl  You should have received a copy of the GNU General Public License
dnl  along with GUILE; see the file COPYING.  If not, write to the
dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
dnl  Boston, MA 02111-1307, USA.

AC_INIT(Makefile.in)
. $srcdir/GUILE-VERSION
AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
AM_MAINTAINER_MODE
AM_CONFIG_HEADER(libguile/scmconfig.h)

#--------------------------------------------------------------------
#
# Independent Subdirectories
#
#--------------------------------------------------------------------

AC_CONFIG_SUBDIRS(guile-readline)

#--------------------------------------------------------------------
#
# User options
#
#--------------------------------------------------------------------

AC_ARG_ENABLE(guile-debug,
  [  --enable-guile-debug    include internal debugging functions],
  if test "$enable_guile_debug" = y || test "$enable_guile_debug" = yes; then
    AC_DEFINE(GUILE_DEBUG)
  fi)

AC_ARG_ENABLE(debug-freelist,
  [  --enable-debug-freelist    Include garbage collector freelist debugging code],
  if test "$enable_debug_freelist" = y || test "$enable_debug_freelist" = yes; then
    AC_DEFINE(GUILE_DEBUG_FREELIST)
  fi)

AC_ARG_ENABLE(debug-malloc,
  [  --enable-debug-malloc      Include malloc debugging code],
  if test "$enable_debug_malloc" = y || test "$enable_debug_malloc" = yes; then
    AC_DEFINE(GUILE_DEBUG_MALLOC)
  fi)

AC_ARG_ENABLE(arrays,
  [  --disable-arrays        omit array and uniform array support],,
  enable_arrays=yes)

AC_ARG_ENABLE(posix,
  [  --disable-posix         omit posix interfaces],,
  enable_posix=yes)

AC_ARG_ENABLE(networking,
  [  --disable-networking    omit networking interfaces],,
  enable_networking=yes)

AC_ARG_ENABLE(regex,
  [  --disable-regex         omit regular expression interfaces],,
  enable_regex=yes)

dnl The --disable-debug used to control these two.  But now they are
dnl a required part of the distribution.
AC_DEFINE(DEBUG_EXTENSIONS)
AC_DEFINE(READER_EXTENSIONS)

dnl files which are destined for separate modules.

if test "$enable_arrays" = yes; then
   LIBOBJS="$LIBOBJS ramap.o unif.o"
   AC_DEFINE(HAVE_ARRAYS)
fi

if test "$enable_posix" = yes; then
   LIBOBJS="$LIBOBJS filesys.o posix.o"
   AC_DEFINE(HAVE_POSIX)
fi

if test "$enable_networking" = yes; then
   LIBOBJS="$LIBOBJS net_db.o socket.o"
   AC_DEFINE(HAVE_NETWORKING)
fi

if test "$enable_debug_malloc" = yes; then
   LIBOBJS="$LIBOBJS debug-malloc.o"
fi

#--------------------------------------------------------------------

AC_LIBLTDL_CONVENIENCE
AC_CONFIG_SUBDIRS(libltdl)

AC_PROG_CC
AC_PROG_CPP
AC_LIBTOOL_DLOPEN

AC_AIX
AC_ISC_POSIX
AC_MINIX

AM_PROG_CC_STDC
AM_PROG_LIBTOOL

AC_C_CONST
AC_C_INLINE
AC_CHECK_SIZEOF(int)
AC_CHECK_SIZEOF(long)
AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
	       AC_TRY_COMPILE(,
			      [long long a],
			      scm_cv_long_longs=yes,
			      scm_cv_long_longs=no))
if test "$scm_cv_long_longs" = yes; then
  AC_DEFINE(HAVE_LONG_LONGS)
fi

AC_HEADER_STDC
AC_HEADER_DIRENT
AC_HEADER_TIME
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
GUILE_HEADER_LIBC_WITH_UNISTD

AC_TYPE_GETGROUPS
AC_TYPE_SIGNAL
AC_TYPE_MODE_T

AC_CHECK_LIB(m, main)
AC_CHECK_FUNCS(gethostbyname)
if test $ac_cv_func_gethostbyname = no; then
    AC_CHECK_LIB(nsl, gethostbyname)
fi
AC_CHECK_FUNCS(connect)
if test $ac_cv_func_connect = no; then
    AC_CHECK_LIB(socket, connect)
fi

# Check for dynamic linking

use_modules=yes
AC_ARG_WITH(modules,
[  --with-modules[=FILES]  Add support for dynamic modules],
use_modules="$withval")
test -z "$use_modules" && use_modules=yes
DLPREOPEN=
if test "$use_modules" != no; then
  AC_DEFINE(DYNAMIC_LINKING)
  if test "$use_modules" = yes; then
    DLPREOPEN="-dlpreopen force"
  else
    DLPREOPEN="-export-dynamic"
    for module in $use_modules; do
      DLPREOPEN="$DLPREOPEN -dlopen $module"
    done
  fi
fi
AC_SUBST(INCLTDL)
AC_SUBST(LIBLTDL)
AC_SUBST(DLPREOPEN)

AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep atexit on_exit)

### Some systems don't declare some functions.  On such systems, we
### need to at least provide our own K&R-style declarations.

### GUILE_FUNC_DECLARED(function, headerfile)

### Check for a declaration of FUNCTION in HEADERFILE; if it is
### not there, #define MISSING_FUNCTION_DECL.
AC_DEFUN(GUILE_FUNC_DECLARED, [
  AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
    AC_EGREP_HEADER($1, $2,
		    guile_cv_func_$1_declared=yes, 
		    guile_cv_func_$1_declared=no))
  if test [x$guile_cv_func_]$1[_declared] = xno; then
    AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
  fi
])

GUILE_FUNC_DECLARED(strptime, time.h)
GUILE_FUNC_DECLARED(bzero, string.h)
GUILE_FUNC_DECLARED(sleep, unistd.h)
GUILE_FUNC_DECLARED(usleep, unistd.h)

### On some systems usleep has no return value.  If it does have one,
### we'd like to return it; otherwise, we'll fake it.
AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
  [AC_EGREP_HEADER(changequote(<, >)<void[ 	]+usleep>changequote([, ]),
                   /usr/include/unistd.h,
		   [guile_cv_func_usleep_return_type=void],
		   [guile_cv_func_usleep_return_type=int])])
case "$guile_cv_func_usleep_return_type" in
  "void" )
    AC_DEFINE(USLEEP_RETURNS_VOID)
  ;;
esac

dnl <GNU-WIN32 hacks>

AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
if test -n "$have_sys_un_h" ; then
AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
fi

AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)

dnl I don't know what this prefixing of cygwin32_ is for.
dnl scmconfig.h wasn't updated with the test results.
dnl so use AC_CHECK_FUNCS for now.

dnl how about:
dnl save confdefs.h
dnl if test $ac_cv_cigwin = yes; then
dnl   modify confdefs.h
dnl fi
dnl AC_CHECK_FUNCS...
dnl restore confdefs.h

dnl cp confdefs.h confdefs.h.bak
dnl for func in gethostent sethostent endhostent getnetent setnetent endnetent getprotoent setprotoent endprotoent getservent setservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof hstrerror; do
dnl cp confdefs.h.bak confdefs.h
dnl cat >> confdefs.h << EOF 
dnl #ifdef __CYGWIN32__
dnl #define $func cygwin32_$func
dnl #endif
dnl EOF
dnl AC_CHECK_FUNC($func)
dnl done
dnl cp confdefs.h.bak confdefs.h

AC_CHECK_FUNCS(sethostent   gethostent   endhostent   dnl
               setnetent    getnetent    endnetent    dnl
               setprotoent  getprotoent  endprotoent  dnl
               setservent   getservent   endservent   dnl
               getnetbyaddr getnetbyname dnl
	       inet_lnaof inet_makeaddr inet_netof hstrerror)

dnl </GNU-WIN32 hacks>

AC_MSG_CHECKING(whether localtime caches TZ)
AC_CACHE_VAL(guile_cv_localtime_cache,
[if test x$ac_cv_func_tzset = xyes; then
AC_TRY_RUN([#include <time.h>
#if STDC_HEADERS
# include <stdlib.h>
#endif
extern char **environ;
unset_TZ ()
{
  char **from, **to;
  for (to = from = environ; (*to = *from); from++)
    if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
      to++;
}
char TZ_GMT0[] = "TZ=GMT0";
char TZ_PST8[] = "TZ=PST8";
main()
{
  time_t now = time ((time_t *) 0);
  int hour_GMT0, hour_unset;
  if (putenv (TZ_GMT0) != 0)
    exit (1);
  hour_GMT0 = localtime (&now)->tm_hour;
  unset_TZ ();
  hour_unset = localtime (&now)->tm_hour;
  if (putenv (TZ_PST8) != 0)
    exit (1);
  if (localtime (&now)->tm_hour == hour_GMT0)
    exit (1);
  unset_TZ ();
  if (localtime (&now)->tm_hour != hour_unset)
    exit (1);
  exit (0);
}], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
[# If we have tzset, assume the worst when cross-compiling.
guile_cv_localtime_cache=yes])
else
        # If we lack tzset, report that localtime does not cache TZ,
        # since we can't invalidate the cache if we don't have tzset.
        guile_cv_localtime_cache=no
fi])dnl
AC_MSG_RESULT($guile_cv_localtime_cache)
if test $guile_cv_localtime_cache = yes; then
  AC_DEFINE(LOCALTIME_CACHE)
fi

dnl Test whether system calls are restartable by default on the
dnl current system.  If they are not, we put a loop around every system
dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
dnl change from the default behaviour.  On the other hand, if signals
dnl are restartable then the loop is not installed and when libguile
dnl initialises it also resets the behaviour of each signal to cause a
dnl restart (in case a different runtime had a different default
dnl behaviour for some reason: e.g., different versions of linux seem
dnl to behave differently.)

AC_SYS_RESTARTABLE_SYSCALLS

if test "$enable_regex" = yes; then
   if test "$ac_cv_header_regex_h" = yes ||
      test "$ac_cv_header_rxposix_h" = yes ||
      test "$ac_cv_header_rx_rxposix_h" = yes; then
     GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
     [AC_CHECK_LIB(rx, main)
      GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
     )
     dnl The following should not be necessary, but for some reason
     dnl autoheader misses it if we don't include it!
     if test "$ac_cv_func_regcomp_norx" = yes ||
        test "$ac_cv_func_regcomp_rx" = yes; then
       AC_DEFINE(HAVE_REGCOMP)
     fi
   fi
fi

AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)

# When testing for the presence of alloca, we need to add alloca.o
# explicitly to LIBOBJS to make sure that it is translated to
# `alloca.lo' for libtool later on.  This can and should be done more cleanly.
AC_FUNC_ALLOCA
if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi

AC_STRUCT_ST_RDEV
AC_STRUCT_ST_BLKSIZE

# We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
# LIBOBJS, which we don't need.  This seems more direct. 
AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
[AC_TRY_COMPILE([#include <sys/types.h>
#include <sys/stat.h>], [struct stat s; s.st_blocks;],
ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
if test $ac_cv_struct_st_blocks = yes; then
  AC_DEFINE(HAVE_ST_BLOCKS)
fi

AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
  [AC_TRY_CPP([#include <sys/stat.h>
               #ifndef S_ISLNK
               #error no S_ISLNK
               #endif],
               ac_cv_macro_S_ISLNK=yes,
               ac_cv_macro_S_ISLNK=no)])
if test $ac_cv_macro_S_ISLNK = yes; then
  AC_DEFINE(HAVE_S_ISLNK)
fi

AC_STRUCT_TIMEZONE
GUILE_STRUCT_UTIMBUF

#--------------------------------------------------------------------
#
# Which way does the stack grow?
#
#--------------------------------------------------------------------

AC_TRY_RUN(aux (l) unsigned long l;
	     { int x; exit (l >= ((unsigned long)&x)); }
	   main () { int q; aux((unsigned long)&q); }, 
	   AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))

AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
    [AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
		[guile_cv_type_float_fits_long=yes],
		[guile_cv_type_float_fits_long=no],
		[guile_cv_type_float_fits_long=guess-yes])])
case $guile_cv_type_float_fits_long in
  "yes" )
    AC_DEFINE(SCM_SINGLES)
  ;;
  "guess-yes" )
    AC_DEFINE(SCM_SINGLES)
    AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
    AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
  ;;
esac


AC_MSG_CHECKING(for struct linger)
AC_CACHE_VAL(scm_cv_struct_linger,
	AC_TRY_COMPILE([
#include <sys/types.h>
#include <sys/socket.h>],
			[struct linger lgr;  lgr.l_linger = 100],
			scm_cv_struct_linger="yes",
			scm_cv_struct_linger="no"))
AC_MSG_RESULT($scm_cv_struct_linger)
if test $scm_cv_struct_linger = yes; then
	AC_DEFINE(HAVE_STRUCT_LINGER)
fi


AC_MSG_CHECKING(for struct timespec)
AC_CACHE_VAL(scm_cv_struct_timespec,
	AC_TRY_COMPILE([
#include <time.h>],
			[struct timespec t;  t.tv_nsec = 100],
			scm_cv_struct_timespec="yes",
			scm_cv_struct_timespec="no"))
AC_MSG_RESULT($scm_cv_struct_timespec)
if test $scm_cv_struct_timespec = yes; then
	AC_DEFINE(HAVE_STRUCT_TIMESPEC)
fi

#--------------------------------------------------------------------
#
# Flags for thread support
#
#--------------------------------------------------------------------

### What thread package has the user asked for?
AC_ARG_WITH(threads, [  --with-threads          thread interface],
            , with_threads=no)

### Turn $with_threads into either the name of a threads package, like
### `qt', or `no', meaning that threads should not be supported.
AC_MSG_CHECKING(whether to support threads)
case "$with_threads" in
  "yes" | "qt" | "coop" | "")
    with_threads=qt
  ;;
  "no" )
  ;;
  * )
    AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
  ;;
esac
AC_MSG_RESULT($with_threads)

## Make sure the threads package we've chosen is actually supported on
## the present platform.
case "${with_threads}" in
  "qt" )
    ## This configures the QuickThreads package, and sets or clears
    ## the THREAD_PACKAGE variable if qthreads don't configure
    ## correctly.
    QTHREADS_CONFIGURE
   ;;
esac

## If we're using threads, bring in some other parts of Guile which
## work with them.
if test "${THREAD_PACKAGE}" != "" ; then
  AC_DEFINE(USE_THREADS, 1)

  ## Include the Guile thread interface in the library...
  LIBOBJS="$LIBOBJS threads.o"

  ## ... and tell it which package to talk to.
  case "${THREAD_PACKAGE}" in
    "QT" )
      AC_DEFINE(USE_COOP_THREADS, 1)
    ;;
    * )
      AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
    ;;
  esac

  ## Bring in scm_internal_select, if appropriate.
  if test $ac_cv_func_gettimeofday = yes &&
     test $ac_cv_func_select = yes; then
    AC_DEFINE(GUILE_ISELECT, 1)
  fi

  ## Workaround for linuxthreads (currently disabled)
  if test $host_os = linux-gnu; then
    AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
    AC_CHECK_LIB(pthread, main)
  fi
fi

## If we're using GCC, ask for aggressive warnings.
case "$GCC" in
  yes )
    ## We had -Wstrict-prototypes in here for a bit, but Guile does too
    ## much stuff with generic function pointers for that to really be
    ## less than exasperating.
    ## -Wpointer-arith was here too, but something changed in gcc/glibc
    ## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
    CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
esac

AC_PROG_AWK

## If we're creating a shared library (using libtool!), then we'll
## need to generate a list of .lo files corresponding to the .o files
## given in LIBOBJS.  We'll call it LIBLOBJS.
LIBLOBJS="`echo ${LIBOBJS} | sed 's/\.o/.lo/g'`"

AC_SUBST(GUILE_MAJOR_VERSION)
AC_SUBST(GUILE_MINOR_VERSION)
AC_SUBST(GUILE_VERSION)

dnl Tell guile-config what flags guile users should link against.
GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
AC_SUBST(GUILE_LIBS)

AC_SUBST(AWK)
AC_SUBST(LIBLOBJS)

AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check libguile/guile-snarf.awk libguile/versiondat.h ice-9/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check])

dnl Local Variables:
dnl comment-start: "dnl "
dnl comment-end: ""
dnl comment-start-skip: "\\bdnl\\b\\s *"
dnl End:
Commit	Line	Data
777b022a JB	1	dnl configuration script for Guile
777b022a JB	2	dnl Process this file with autoconf to produce configure.
50848747	3	dnl
7534dfdc	4	dnl Copyright (C) 1998, 1999, 2000 Free Software Foundation, Inc.
50848747 JB	5	dnl
	6	dnl This file is part of GUILE
	7	dnl
	8	dnl GUILE is free software; you can redistribute it and/or modify it
	9	dnl under the terms of the GNU General Public License as published by
	10	dnl the Free Software Foundation; either version 2, or (at your
	11	dnl option) any later version.
	12	dnl
	13	dnl GUILE is distributed in the hope that it will be useful, but
	14	dnl WITHOUT ANY WARRANTY; without even the implied warranty of
	15	dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
	16	dnl General Public License for more details.
	17	dnl
	18	dnl You should have received a copy of the GNU General Public License
	19	dnl along with GUILE; see the file COPYING. If not, write to the
	20	dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
	21	dnl Boston, MA 02111-1307, USA.
	22
0f2d19dd	23	AC_INIT(Makefile.in)
2d26def0	24	. $srcdir/GUILE-VERSION
3a629497	25	AM_INIT_AUTOMAKE($PACKAGE, $VERSION, no-define)
15ae1bee	26	AM_MAINTAINER_MODE
3a629497	27	AM_CONFIG_HEADER(libguile/scmconfig.h)
2d26def0	28
3a629497	29	#--------------------------------------------------------------------
0e8a8468 MV	30	#
	31	# Independent Subdirectories
	32	#
	33	#--------------------------------------------------------------------
	34
	35	AC_CONFIG_SUBDIRS(guile-readline)
	36
	37	#--------------------------------------------------------------------
3a629497 JB	38	#
	39	# User options
	40	#
	41	#--------------------------------------------------------------------
86789f9b	42
3a629497	43	AC_ARG_ENABLE(guile-debug,
52cfc69b	44	[ --enable-guile-debug include internal debugging functions],
7a11a87c MD	45	if test "$enable_guile_debug" = y \|\| test "$enable_guile_debug" = yes; then
	46	AC_DEFINE(GUILE_DEBUG)
	47	fi)
	48
52b3923a GB	49	AC_ARG_ENABLE(debug-freelist,
	50	[ --enable-debug-freelist Include garbage collector freelist debugging code],
	51	if test "$enable_debug_freelist" = y \|\| test "$enable_debug_freelist" = yes; then
fca7547b	52	AC_DEFINE(GUILE_DEBUG_FREELIST)
52b3923a GB	53	fi)
52b3923a GB	54
cf890744 MD	55	AC_ARG_ENABLE(debug-malloc,
	56	[ --enable-debug-malloc Include malloc debugging code],
	57	if test "$enable_debug_malloc" = y \|\| test "$enable_debug_malloc" = yes; then
	58	AC_DEFINE(GUILE_DEBUG_MALLOC)
	59	fi)
	60
afe5177e GH	61	AC_ARG_ENABLE(arrays,
	62	[ --disable-arrays omit array and uniform array support],,
	63	enable_arrays=yes)
	64
52cfc69b GH	65	AC_ARG_ENABLE(posix,
	66	[ --disable-posix omit posix interfaces],,
	67	enable_posix=yes)
	68
	69	AC_ARG_ENABLE(networking,
dc914156	70	[ --disable-networking omit networking interfaces],,
52cfc69b GH	71	enable_networking=yes)
	72
	73	AC_ARG_ENABLE(regex,
	74	[ --disable-regex omit regular expression interfaces],,
	75	enable_regex=yes)
	76
c176b92b JB	77	dnl The --disable-debug used to control these two. But now they are
	78	dnl a required part of the distribution.
	79	AC_DEFINE(DEBUG_EXTENSIONS)
	80	AC_DEFINE(READER_EXTENSIONS)
	81
52cfc69b GH	82	dnl files which are destined for separate modules.
52cfc69b GH	83
afe5177e GH	84	if test "$enable_arrays" = yes; then
	85	LIBOBJS="$LIBOBJS ramap.o unif.o"
	86	AC_DEFINE(HAVE_ARRAYS)
	87	fi
	88
52cfc69b GH	89	if test "$enable_posix" = yes; then
	90	LIBOBJS="$LIBOBJS filesys.o posix.o"
	91	AC_DEFINE(HAVE_POSIX)
	92	fi
	93
	94	if test "$enable_networking" = yes; then
	95	LIBOBJS="$LIBOBJS net_db.o socket.o"
	96	AC_DEFINE(HAVE_NETWORKING)
	97	fi
	98
cf890744 MD	99	if test "$enable_debug_malloc" = yes; then
	100	LIBOBJS="$LIBOBJS debug-malloc.o"
	101	fi
	102
3a629497 JB	103	#--------------------------------------------------------------------
3a629497 JB	104
b7f27d64 MV	105	AC_LIBLTDL_CONVENIENCE
	106	AC_CONFIG_SUBDIRS(libltdl)
	107
3a629497 JB	108	AC_PROG_CC
3a629497 JB	109	AC_PROG_CPP
b7f27d64	110	AC_LIBTOOL_DLOPEN
3a629497 JB	111
	112	AC_AIX
	113	AC_ISC_POSIX
	114	AC_MINIX
	115
e40ffcb6	116	AM_PROG_CC_STDC
9da7f717	117	AM_PROG_LIBTOOL
e40ffcb6	118
3a629497	119	AC_C_CONST
5e9345c3	120	AC_C_INLINE
9dec9737 MD	121	AC_CHECK_SIZEOF(int)
	122	AC_CHECK_SIZEOF(long)
	123	AC_CACHE_CHECK([for long longs], scm_cv_long_longs,
	124	AC_TRY_COMPILE(,
	125	[long long a],
	126	scm_cv_long_longs=yes,
	127	scm_cv_long_longs=no))
	128	if test "$scm_cv_long_longs" = yes; then
	129	AC_DEFINE(HAVE_LONG_LONGS)
	130	fi
3a629497 JB	131
	132	AC_HEADER_STDC
	133	AC_HEADER_DIRENT
	134	AC_HEADER_TIME
	135	AC_HEADER_SYS_WAIT
2adc1dd3	136	AC_CHECK_HEADERS(io.h libc.h limits.h malloc.h memory.h string.h regex.h rxposix.h rx/rxposix.h sys/ioctl.h sys/select.h sys/time.h sys/timeb.h sys/times.h sys/types.h sys/utime.h time.h unistd.h utime.h)
3a629497 JB	137	GUILE_HEADER_LIBC_WITH_UNISTD
	138
	139	AC_TYPE_GETGROUPS
	140	AC_TYPE_SIGNAL
	141	AC_TYPE_MODE_T
	142
5852c051	143	AC_CHECK_LIB(m, main)
4c787b52	144	AC_CHECK_FUNCS(gethostbyname)
5852c051 JB	145	if test $ac_cv_func_gethostbyname = no; then
	146	AC_CHECK_LIB(nsl, gethostbyname)
	147	fi
4c787b52	148	AC_CHECK_FUNCS(connect)
5852c051 JB	149	if test $ac_cv_func_connect = no; then
	150	AC_CHECK_LIB(socket, connect)
	151	fi
5ee74cec	152
b7f27d64	153	# Check for dynamic linking
5852c051	154
b7f27d64 MV	155	use_modules=yes
	156	AC_ARG_WITH(modules,
	157	[ --with-modules[=FILES] Add support for dynamic modules],
	158	use_modules="$withval")
	159	test -z "$use_modules" && use_modules=yes
	160	DLPREOPEN=
	161	if test "$use_modules" != no; then
a4995389	162	AC_DEFINE(DYNAMIC_LINKING)
b7f27d64 MV	163	if test "$use_modules" = yes; then
	164	DLPREOPEN="-dlpreopen force"
	165	else
	166	DLPREOPEN="-export-dynamic"
	167	for module in $use_modules; do
	168	DLPREOPEN="$DLPREOPEN -dlopen $module"
	169	done
	170	fi
a4995389	171	fi
b7f27d64 MV	172	AC_SUBST(INCLTDL)
	173	AC_SUBST(LIBLTDL)
	174	AC_SUBST(DLPREOPEN)
5852c051	175
d831b039	176	AC_CHECK_FUNCS(ctermid ftime fchown getcwd geteuid gettimeofday lstat mkdir mknod nice readlink rename rmdir select setegid seteuid setlocale setpgid setsid sigaction siginterrupt strftime strptime symlink sync tcgetpgrp tcsetpgrp times uname waitpid bzero strdup system usleep atexit on_exit)
64e121dc	177
777b022a JB	178	### Some systems don't declare some functions. On such systems, we
	179	### need to at least provide our own K&R-style declarations.
	180
	181	### GUILE_FUNC_DECLARED(function, headerfile)
	182
	183	### Check for a declaration of FUNCTION in HEADERFILE; if it is
	184	### not there, #define MISSING_FUNCTION_DECL.
	185	AC_DEFUN(GUILE_FUNC_DECLARED, [
fc342a63	186	AC_CACHE_CHECK(for $1 declaration, guile_cv_func_$1_declared,
777b022a	187	AC_EGREP_HEADER($1, $2,
fc342a63 JB	188	guile_cv_func_$1_declared=yes,
	189	guile_cv_func_$1_declared=no))
	190	if test [x$guile_cv_func_]$1[_declared] = xno; then
777b022a JB	191	AC_DEFINE([MISSING_]translit($1, [a-z], [A-Z])[_DECL])
	192	fi
	193	])
	194
	195	GUILE_FUNC_DECLARED(strptime, time.h)
	196	GUILE_FUNC_DECLARED(bzero, string.h)
c31bfb85	197	GUILE_FUNC_DECLARED(sleep, unistd.h)
777b022a	198	GUILE_FUNC_DECLARED(usleep, unistd.h)
e1a191a8	199
da753252 JB	200	### On some systems usleep has no return value. If it does have one,
da753252 JB	201	### we'd like to return it; otherwise, we'll fake it.
fc342a63	202	AC_CACHE_CHECK([return type of usleep], guile_cv_func_usleep_return_type,
c43f86c1	203	[AC_EGREP_HEADER(changequote(<, >)<void[ ]+usleep>changequote([, ]),
fc342a63 JB	204	/usr/include/unistd.h,
	205	[guile_cv_func_usleep_return_type=void],
	206	[guile_cv_func_usleep_return_type=int])])
	207	case "$guile_cv_func_usleep_return_type" in
	208	"void" )
	209	AC_DEFINE(USLEEP_RETURNS_VOID)
	210	;;
	211	esac
	212
da88f0cb JB	213	dnl <GNU-WIN32 hacks>
	214
	215	AC_CHECK_HEADER(sys/un.h, have_sys_un_h=1)
	216	if test -n "$have_sys_un_h" ; then
	217	AC_DEFINE(HAVE_UNIX_DOMAIN_SOCKETS)
	218	fi
	219
	220	AC_CHECK_FUNCS(socketpair getgroups setpwent pause tzset)
	221
f4e5b810 GH	222	dnl I don't know what this prefixing of cygwin32_ is for.
	223	dnl scmconfig.h wasn't updated with the test results.
	224	dnl so use AC_CHECK_FUNCS for now.
	225
	226	dnl how about:
	227	dnl save confdefs.h
	228	dnl if test $ac_cv_cigwin = yes; then
	229	dnl modify confdefs.h
	230	dnl fi
	231	dnl AC_CHECK_FUNCS...
	232	dnl restore confdefs.h
	233
	234	dnl cp confdefs.h confdefs.h.bak
5c11cc9d	235	dnl for func in gethostent sethostent endhostent getnetent setnetent endnetent getprotoent setprotoent endprotoent getservent setservent endservent getnetbyaddr getnetbyname inet_lnaof inet_makeaddr inet_netof hstrerror; do
f4e5b810 GH	236	dnl cp confdefs.h.bak confdefs.h
	237	dnl cat >> confdefs.h << EOF
	238	dnl #ifdef __CYGWIN32__
	239	dnl #define $func cygwin32_$func
	240	dnl #endif
	241	dnl EOF
	242	dnl AC_CHECK_FUNC($func)
	243	dnl done
	244	dnl cp confdefs.h.bak confdefs.h
	245
219a5a5b JB	246	AC_CHECK_FUNCS(sethostent gethostent endhostent dnl
	247	setnetent getnetent endnetent dnl
	248	setprotoent getprotoent endprotoent dnl
	249	setservent getservent endservent dnl
5c11cc9d GH	250	getnetbyaddr getnetbyname dnl
5c11cc9d GH	251	inet_lnaof inet_makeaddr inet_netof hstrerror)
da88f0cb JB	252
	253	dnl </GNU-WIN32 hacks>
	254
38c1d3c4 GH	255	AC_MSG_CHECKING(whether localtime caches TZ)
	256	AC_CACHE_VAL(guile_cv_localtime_cache,
	257	[if test x$ac_cv_func_tzset = xyes; then
	258	AC_TRY_RUN([#include <time.h>
	259	#if STDC_HEADERS
	260	# include <stdlib.h>
	261	#endif
	262	extern char **environ;
	263	unset_TZ ()
	264	{
	265	char from, to;
	266	for (to = from = environ; (to = from); from++)
	267	if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
	268	to++;
	269	}
	270	char TZ_GMT0[] = "TZ=GMT0";
	271	char TZ_PST8[] = "TZ=PST8";
	272	main()
	273	{
	274	time_t now = time ((time_t *) 0);
	275	int hour_GMT0, hour_unset;
	276	if (putenv (TZ_GMT0) != 0)
	277	exit (1);
	278	hour_GMT0 = localtime (&now)->tm_hour;
	279	unset_TZ ();
	280	hour_unset = localtime (&now)->tm_hour;
	281	if (putenv (TZ_PST8) != 0)
	282	exit (1);
	283	if (localtime (&now)->tm_hour == hour_GMT0)
	284	exit (1);
	285	unset_TZ ();
	286	if (localtime (&now)->tm_hour != hour_unset)
	287	exit (1);
	288	exit (0);
	289	}], guile_cv_localtime_cache=no, guile_cv_localtime_cache=yes,
	290	[# If we have tzset, assume the worst when cross-compiling.
	291	guile_cv_localtime_cache=yes])
	292	else
	293	# If we lack tzset, report that localtime does not cache TZ,
	294	# since we can't invalidate the cache if we don't have tzset.
	295	guile_cv_localtime_cache=no
	296	fi])dnl
	297	AC_MSG_RESULT($guile_cv_localtime_cache)
	298	if test $guile_cv_localtime_cache = yes; then
	299	AC_DEFINE(LOCALTIME_CACHE)
	300	fi
	301
7ee92fce GH	302	dnl Test whether system calls are restartable by default on the
	303	dnl current system. If they are not, we put a loop around every system
	304	dnl call to check for EINTR (see SCM_SYSCALL) and do not attempt to
	305	dnl change from the default behaviour. On the other hand, if signals
	306	dnl are restartable then the loop is not installed and when libguile
	307	dnl initialises it also resets the behaviour of each signal to cause a
	308	dnl restart (in case a different runtime had a different default
	309	dnl behaviour for some reason: e.g., different versions of linux seem
	310	dnl to behave differently.)
	311
08b8c694	312	AC_SYS_RESTARTABLE_SYSCALLS
e1a191a8	313
52cfc69b GH	314	if test "$enable_regex" = yes; then
	315	if test "$ac_cv_header_regex_h" = yes \|\|
	316	test "$ac_cv_header_rxposix_h" = yes \|\|
	317	test "$ac_cv_header_rx_rxposix_h" = yes; then
	318	GUILE_NAMED_CHECK_FUNC(regcomp, norx, [LIBOBJS="regex-posix.o $LIBOBJS"],
	319	[AC_CHECK_LIB(rx, main)
	320	GUILE_NAMED_CHECK_FUNC(regcomp, rx, [LIBOBJS="regex-posix.o $LIBOBJS"])]
	321	)
	322	dnl The following should not be necessary, but for some reason
	323	dnl autoheader misses it if we don't include it!
	324	if test "$ac_cv_func_regcomp_norx" = yes \|\|
	325	test "$ac_cv_func_regcomp_rx" = yes; then
	326	AC_DEFINE(HAVE_REGCOMP)
	327	fi
	328	fi
da88f0cb	329	fi
8e1bfcd0	330
dbbbec40	331	AC_REPLACE_FUNCS(inet_aton putenv strerror memmove)
3a629497	332
4a5fa91c TP	333	# When testing for the presence of alloca, we need to add alloca.o
	334	# explicitly to LIBOBJS to make sure that it is translated to
	335	# `alloca.lo' for libtool later on. This can and should be done more cleanly.
3a629497	336	AC_FUNC_ALLOCA
4a5fa91c	337	if test "$ALLOCA" = "alloca.o"; then LIBOBJS="alloca.o $LIBOBJS"; fi
3a629497 JB	338
	339	AC_STRUCT_ST_RDEV
	340	AC_STRUCT_ST_BLKSIZE
075edbde JB	341
	342	# We could use AC_STRUCT_ST_BLOCKS here, but that adds fileblocks.o to
	343	# LIBOBJS, which we don't need. This seems more direct.
	344	AC_CACHE_CHECK([for st_blocks in struct stat], ac_cv_struct_st_blocks,
	345	[AC_TRY_COMPILE([#include <sys/types.h>
	346	#include <sys/stat.h>], [struct stat s; s.st_blocks;],
	347	ac_cv_struct_st_blocks=yes, ac_cv_struct_st_blocks=no)])
	348	if test $ac_cv_struct_st_blocks = yes; then
	349	AC_DEFINE(HAVE_ST_BLOCKS)
	350	fi
	351
fd02f2ad MD	352	AC_CACHE_CHECK([for S_ISLNK in sys/stat.h], ac_cv_macro_S_ISLNK,
	353	[AC_TRY_CPP([#include <sys/stat.h>
	354	#ifndef S_ISLNK
	355	#error no S_ISLNK
	356	#endif],
	357	ac_cv_macro_S_ISLNK=yes,
	358	ac_cv_macro_S_ISLNK=no)])
	359	if test $ac_cv_macro_S_ISLNK = yes; then
	360	AC_DEFINE(HAVE_S_ISLNK)
	361	fi
	362
3a629497 JB	363	AC_STRUCT_TIMEZONE
	364	GUILE_STRUCT_UTIMBUF
	365
3a629497 JB	366	#--------------------------------------------------------------------
	367	#
	368	# Which way does the stack grow?
	369	#
	370	#--------------------------------------------------------------------
	371
	372	AC_TRY_RUN(aux (l) unsigned long l;
	373	{ int x; exit (l >= ((unsigned long)&x)); }
	374	main () { int q; aux((unsigned long)&q); },
	375	AC_DEFINE(SCM_STACK_GROWS_UP),,AC_MSG_WARN(Guessing that stack grows down -- see scmconfig.h.in))
	376
3a171311 JB	377	AC_CACHE_CHECK([whether floats fit in longs], guile_cv_type_float_fits_long,
	378	[AC_TRY_RUN([main () { exit (sizeof(float) > sizeof(long)); }],
	379	[guile_cv_type_float_fits_long=yes],
	380	[guile_cv_type_float_fits_long=no],
	381	[guile_cv_type_float_fits_long=guess-yes])])
	382	case $guile_cv_type_float_fits_long in
	383	"yes" )
	384	AC_DEFINE(SCM_SINGLES)
	385	;;
	386	"guess-yes" )
	387	AC_DEFINE(SCM_SINGLES)
	388	AC_MSG_WARN([guessing that sizeof(long) == sizeof(float)])
	389	AC_MSG_WARN([see SCM_SINGLES in scmconfig.h.in])
	390	;;
	391	esac
3a629497	392
3a629497 JB	393
	394	AC_MSG_CHECKING(for struct linger)
	395	AC_CACHE_VAL(scm_cv_struct_linger,
	396	AC_TRY_COMPILE([
	397	#include <sys/types.h>
	398	#include <sys/socket.h>],
	399	[struct linger lgr; lgr.l_linger = 100],
	400	scm_cv_struct_linger="yes",
	401	scm_cv_struct_linger="no"))
	402	AC_MSG_RESULT($scm_cv_struct_linger)
	403	if test $scm_cv_struct_linger = yes; then
	404	AC_DEFINE(HAVE_STRUCT_LINGER)
	405	fi
3a629497	406
7534dfdc MD	407
	408	AC_MSG_CHECKING(for struct timespec)
	409	AC_CACHE_VAL(scm_cv_struct_timespec,
	410	AC_TRY_COMPILE([
	411	#include <time.h>],
	412	[struct timespec t; t.tv_nsec = 100],
	413	scm_cv_struct_timespec="yes",
	414	scm_cv_struct_timespec="no"))
	415	AC_MSG_RESULT($scm_cv_struct_timespec)
	416	if test $scm_cv_struct_timespec = yes; then
	417	AC_DEFINE(HAVE_STRUCT_TIMESPEC)
	418	fi
	419
3a629497 JB	420	#--------------------------------------------------------------------
	421	#
	422	# Flags for thread support
	423	#
	424	#--------------------------------------------------------------------
	425
539c89a1 JB	426	### What thread package has the user asked for?
	427	AC_ARG_WITH(threads, [ --with-threads thread interface],
	428	, with_threads=no)
	429
	430	### Turn $with_threads into either the name of a threads package, like
	431	### `qt', or `no', meaning that threads should not be supported.
e0f54bcc	432	AC_MSG_CHECKING(whether to support threads)
539c89a1 JB	433	case "$with_threads" in
	434	"yes" \| "qt" \| "coop" \| "")
	435	with_threads=qt
	436	;;
	437	"no" )
	438	;;
	439	* )
	440	AC_MSG_ERROR(invalid value for --with-threads: $with_threads)
	441	;;
	442	esac
e0f54bcc	443	AC_MSG_RESULT($with_threads)
3a629497	444
539c89a1 JB	445	## Make sure the threads package we've chosen is actually supported on
	446	## the present platform.
	447	case "${with_threads}" in
	448	"qt" )
	449	## This configures the QuickThreads package, and sets or clears
	450	## the THREAD_PACKAGE variable if qthreads don't configure
	451	## correctly.
	452	QTHREADS_CONFIGURE
	453	;;
	454	esac
3a629497	455
539c89a1 JB	456	## If we're using threads, bring in some other parts of Guile which
	457	## work with them.
	458	if test "${THREAD_PACKAGE}" != "" ; then
	459	AC_DEFINE(USE_THREADS, 1)
3a629497	460
539c89a1 JB	461	## Include the Guile thread interface in the library...
539c89a1 JB	462	LIBOBJS="$LIBOBJS threads.o"
933a7411	463
539c89a1 JB	464	## ... and tell it which package to talk to.
	465	case "${THREAD_PACKAGE}" in
	466	"QT" )
	467	AC_DEFINE(USE_COOP_THREADS, 1)
	468	;;
	469	* )
	470	AC_MSG_ERROR(invalid value for THREAD_PACKAGE: ${THREAD_PACKAGE})
	471	;;
	472	esac
	473
	474	## Bring in scm_internal_select, if appropriate.
	475	if test $ac_cv_func_gettimeofday = yes &&
	476	test $ac_cv_func_select = yes; then
539c89a1 JB	477	AC_DEFINE(GUILE_ISELECT, 1)
539c89a1 JB	478	fi
ed65453e MD	479
ed65453e MD	480	## Workaround for linuxthreads (currently disabled)
e4d2166f MD	481	if test $host_os = linux-gnu; then
	482	AC_DEFINE(GUILE_PTHREAD_COMPAT, 1)
	483	AC_CHECK_LIB(pthread, main)
	484	fi
933a7411 MD	485	fi
933a7411 MD	486
3a629497 JB	487	## If we're using GCC, ask for aggressive warnings.
3a629497 JB	488	case "$GCC" in
99be3450	489	yes )
0a1b8b15 JB	490	## We had -Wstrict-prototypes in here for a bit, but Guile does too
	491	## much stuff with generic function pointers for that to really be
	492	## less than exasperating.
aee8ca3f GH	493	## -Wpointer-arith was here too, but something changed in gcc/glibc
	494	## and it became equally exasperating (gcc 2.95 and/or glibc 2.1.2).
	495	CFLAGS="$CFLAGS -Wall -Wmissing-prototypes" ;;
3a629497 JB	496	esac
	497
	498	AC_PROG_AWK
	499
	500	## If we're creating a shared library (using libtool!), then we'll
	501	## need to generate a list of .lo files corresponding to the .o files
	502	## given in LIBOBJS. We'll call it LIBLOBJS.
	503	LIBLOBJS="`echo ${LIBOBJS} \| sed 's/\.o/.lo/g'`"
	504
7c86ae05 JB	505	AC_SUBST(GUILE_MAJOR_VERSION)
	506	AC_SUBST(GUILE_MINOR_VERSION)
	507	AC_SUBST(GUILE_VERSION)
539c89a1	508
bcc695e3	509	dnl Tell guile-config what flags guile users should link against.
539c89a1	510	GUILE_LIBS="$LDFLAGS $THREAD_LIBS_INSTALLED $LIBS"
daa4f38c	511	AC_SUBST(GUILE_LIBS)
7c86ae05	512
3a629497 JB	513	AC_SUBST(AWK)
	514	AC_SUBST(LIBLOBJS)
	515
951afd33	516	AC_OUTPUT([Makefile libguile/Makefile libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check libguile/guile-snarf.awk libguile/versiondat.h ice-9/Makefile qt/Makefile qt/qt.h qt/md/Makefile qt/time/Makefile guile-config/Makefile doc/Makefile], [chmod +x libguile/guile-snarf libguile/guile-doc-snarf libguile/guile-func-name-check])
0f2d19dd	517
3a629497 JB	518	dnl Local Variables:
	519	dnl comment-start: "dnl "
	520	dnl comment-end: ""
	521	dnl comment-start-skip: "\\bdnl\\b\\s *"
d67c13f6	522	dnl End: