Files
*****

In Emacs, you can find, create, view, save, and otherwise work with files and file directories.  This chapter describes most of the file-related functions of Emacs Lisp, but a few others are described in Buffers, and those related to backups and auto-saving are described in Backups and Auto-Saving.

Many of the file functions take one or more arguments that are file names.  A file name is actually a string.  Most of these functions expand file name arguments by calling expand-file-name, so that ~ is handled correctly, as are relative file names (including ../).  These functions don't recognize environment variable substitutions such as $HOME.  See File Name Expansion.

When file I/O functions signal Lisp errors, they usually use the condition file-error (see Handling Errors).  The error message is in most cases obtained from the operating system, according to locale system-message-locale, and decoded using coding system locale-coding-system (see Locales).

Visiting Files
==============

Visiting a file means reading a file into a buffer.  Once this is done, we say that the buffer is visiting that file, and call the file ``the visited file'' of the buffer.

A file and a buffer are two different things.  A file is information recorded permanently in the computer (unless you delete it).  A buffer, on the other hand, is information inside of Emacs that will vanish at the end of the editing session (or when you kill the buffer).  Usually, a buffer contains information that you have copied from a file; then we say the buffer is visiting that file.  The copy in the buffer is what you modify with editing commands.  Such changes to the buffer do not change the file; therefore, to make the changes permanent, you must save the buffer, which means copying the altered buffer contents back into the file.

In spite of the distinction between files and buffers, people often refer to a file when they mean a buffer and vice-versa.  Indeed, we say, ``I am editing a file,'' rather than, ``I am editing a buffer that I will soon save as a file of the same name.''  Humans do not usually need to make the distinction explicit.  When dealing with a computer program, however, it is good to keep the distinction in mind.

Functions for Visiting Files
----------------------------

This section describes the functions normally used to visit files. For historical reasons, these functions have names starting with find- rather than visit-.  See Buffer File Name, for functions and variables that access the visited file name of a buffer or that find an existing buffer by its visited file name.

In a Lisp program, if you want to look at the contents of a file but not alter it, the fastest way is to use insert-file-contents in a temporary buffer.  Visiting the file is not necessary and takes longer. See Reading from Files.

 -- Command: find-file filename &optional wildcards
     This command selects a buffer visiting the file FILENAME, using an existing buffer if there is one, and otherwise creating a new buffer and reading the file into it.  It also returns that buffer.

     Aside from some technical details, the body of the find-file function is basically equivalent to:

          (switch-to-buffer (find-file-noselect filename nil nil wildcards))

     (See switch-to-buffer in Displaying Buffers.)

     If WILDCARDS is non-nil, which is always true in an interactive call, then find-file expands wildcard characters in FILENAME and visits all the matching files.

     When find-file is called interactively, it prompts for FILENAME in the minibuffer.

 -- Function: find-file-noselect filename &optional nowarn rawfile wildcards
     This function is the guts of all the file-visiting functions.  It returns a buffer visiting the file FILENAME.  You may make the buffer current or display it in a window if you wish, but this function does not do so.

     The function returns an existing buffer if there is one; otherwise it creates a new buffer and reads the file into it.  When find-file-noselect uses an existing buffer, it first verifies that the file has not changed since it was last visited or saved in that buffer.  If the file has changed, this function asks the user whether to reread the changed file.  If the user says yes, any edits previously made in the buffer are lost.

     Reading the file involves decoding the file's contents (see Coding Systems), including end-of-line conversion, and format conversion (see Format Conversion).  If WILDCARDS is non-nil, then find-file-noselect expands wildcard characters in FILENAME and visits all the matching files.

     This function displays warning or advisory messages in various peculiar cases, unless the optional argument NOWARN is non-nil.  For example, if it needs to create a buffer, and there is no file named FILENAME, it displays the message (New file) in the echo area, and leaves the buffer empty.

     The find-file-noselect function normally calls after-find-file after reading the file (see Subroutines of Visiting).  That function sets the buffer major mode, parses local variables, warns the user if there exists an auto-save file more recent than the file just visited, and finishes by running the functions in find-file-hook.

     If the optional argument RAWFILE is non-nil, then after-find-file is not called, and the find-file-not-found-functions are not run in case of failure. What's more, a non-nil RAWFILE value suppresses coding system conversion and format conversion.

     The find-file-noselect function usually returns the buffer that is visiting the file FILENAME.  But, if wildcards are actually used and expanded, it returns a list of buffers that are visiting the various files.

          (find-file-noselect "/etc/fstab")
               => #<buffer fstab>

 -- Command: find-file-other-window filename &optional wildcards
     This command selects a buffer visiting the file FILENAME, but does so in a window other than the selected window.  It may use another existing window or split a window; see Displaying Buffers.

     When this command is called interactively, it prompts for FILENAME.

 -- Command: find-file-read-only filename &optional wildcards
     This command selects a buffer visiting the file FILENAME, like find-file, but it marks the buffer as read-only.  See Read Only Buffers, for related functions and variables.

     When this command is called interactively, it prompts for FILENAME.

 -- Command: view-file filename
     This command visits FILENAME using View mode, returning to the previous buffer when you exit View mode.  View mode is a minor mode that provides commands to skim rapidly through the file, but does not let you modify the text.  Entering View mode runs the normal hook view-mode-hook.  See Hooks.

     When view-file is called interactively, it prompts for FILENAME.

 -- User Option: find-file-wildcards
     If this variable is non-nil, then the various find-file commands check for wildcard characters and visit all the files that match them (when invoked interactively or when their WILDCARDS argument is non-nil).  If this option is nil, then the find-file commands ignore their WILDCARDS argument and never treat wildcard characters specially.

 -- Variable: find-file-hook
     The value of this variable is a list of functions to be called after a file is visited.  The file's local-variables specification (if any) will have been processed before the hooks are run.  The buffer visiting the file is current when the hook functions are run.

     This variable is a normal hook.  See Hooks.

 -- Variable: find-file-not-found-functions
     The value of this variable is a list of functions to be called when find-file or find-file-noselect is passed a nonexistent file name.  find-file-noselect calls these functions as soon as it detects a nonexistent file.  It calls them in the order of the list, until one of them returns non-nil.  buffer-file-name is already set up.

     This is not a normal hook because the values of the functions are used, and in many cases only some of the functions are called.

Subroutines of Visiting
-----------------------

The find-file-noselect function uses two important subroutines which are sometimes useful in user Lisp code: create-file-buffer and after-find-file.  This section explains how to use them.

 -- Function: create-file-buffer filename
     This function creates a suitably named buffer for visiting FILENAME, and returns it.  It uses FILENAME (sans directory) as the name if that name is free; otherwise, it appends a string such as <2> to get an unused name.  See also Creating Buffers.

     Please note: create-file-buffer does not associate the new buffer with a file and does not select the buffer. It also does not use the default major mode.

          (create-file-buffer "foo")
               => #<buffer foo>

          (create-file-buffer "foo")
               => #<buffer foo<2>>

          (create-file-buffer "foo")
               => #<buffer foo<3>>

     This function is used by find-file-noselect. It uses generate-new-buffer (see Creating Buffers).

 -- Function: after-find-file &optional error warn noauto after-find-file-from-revert-buffer nomodes
     This function sets the buffer major mode, and parses local variables (see Auto Major Mode).  It is called by find-file-noselect and by the default revert function (see Reverting).

     If reading the file got an error because the file does not exist, but its directory does exist, the caller should pass a non-nil value for ERROR.  In that case, after-find-file issues a warning: (New file).  For more serious errors, the caller should usually not call after-find-file.

     If WARN is non-nil, then this function issues a warning if an auto-save file exists and is more recent than the visited file.

     If NOAUTO is non-nil, that says not to enable or disable Auto-Save mode.  The mode remains enabled if it was enabled before.

     If AFTER-FIND-FILE-FROM-REVERT-BUFFER is non-nil, that means this call was from revert-buffer.  This has no direct effect, but some mode functions and hook functions check the value of this variable.

     If NOMODES is non-nil, that means don't alter the buffer's major mode, don't process local variables specifications in the file, and don't run find-file-hook.  This feature is used by revert-buffer in some cases.

     The last thing after-find-file does is call all the functions in the list find-file-hook.

Saving Buffers
==============

When you edit a file in Emacs, you are actually working on a buffer that is visiting that file---that is, the contents of the file are copied into the buffer and the copy is what you edit.  Changes to the buffer do not change the file until you save the buffer, which means copying the contents of the buffer into the file.

 -- Command: save-buffer &optional backup-option
     This function saves the contents of the current buffer in its visited file if the buffer has been modified since it was last visited or saved. Otherwise it does nothing.

     save-buffer is responsible for making backup files.  Normally, BACKUP-OPTION is nil, and save-buffer makes a backup file only if this is the first save since visiting the file.  Other values for BACKUP-OPTION request the making of backup files in other circumstances:

       * With an argument of 4 or 64, reflecting 1 or 3 C-u's, the save-buffer function marks this version of the file to be backed up when the buffer is next saved.

       * With an argument of 16 or 64, reflecting 2 or 3 C-u's, the save-buffer function unconditionally backs up the previous version of the file before saving it.

       * With an argument of 0, unconditionally do not make any backup file.

 -- Command: save-some-buffers &optional save-silently-p pred
     This command saves some modified file-visiting buffers.  Normally it asks the user about each buffer.  But if SAVE-SILENTLY-P is non-nil, it saves all the file-visiting buffers without querying the user.

     The optional PRED argument controls which buffers to ask about (or to save silently if SAVE-SILENTLY-P is non-nil). If it is nil, that means to ask only about file-visiting buffers. If it is t, that means also offer to save certain other non-file buffers---those that have a non-nil buffer-local value of buffer-offer-save (see Killing Buffers).  A user who says yes to saving a non-file buffer is asked to specify the file name to use.  The save-buffers-kill-emacs function passes the value t for PRED.

     If PRED is neither t nor nil, then it should be a function of no arguments.  It will be called in each buffer to decide whether to offer to save that buffer.  If it returns a non-nil value in a certain buffer, that means do offer to save that buffer.

 -- Command: write-file filename &optional confirm
     This function writes the current buffer into file FILENAME, makes the buffer visit that file, and marks it not modified.  Then it renames the buffer based on FILENAME, appending a string like <2> if necessary to make a unique buffer name.  It does most of this work by calling set-visited-file-name (see Buffer File Name) and save-buffer.

     If CONFIRM is non-nil, that means to ask for confirmation before overwriting an existing file.  Interactively, confirmation is required, unless the user supplies a prefix argument.

     If FILENAME is an existing directory, or a symbolic link to one, write-file uses the name of the visited file, in directory FILENAME.  If the buffer is not visiting a file, it uses the buffer name instead.

Saving a buffer runs several hooks.  It also performs format conversion (see Format Conversion).

 -- Variable: write-file-functions
     The value of this variable is a list of functions to be called before writing out a buffer to its visited file.  If one of them returns non-nil, the file is considered already written and the rest of the functions are not called, nor is the usual code for writing the file executed.

     If a function in write-file-functions returns non-nil, it is responsible for making a backup file (if that is appropriate). To do so, execute the following code:

          (or buffer-backed-up (backup-buffer))

     You might wish to save the file modes value returned by backup-buffer and use that (if non-nil) to set the mode bits of the file that you write.  This is what save-buffer normally does. See Making Backup Files.

     The hook functions in write-file-functions are also responsible for encoding the data (if desired): they must choose a suitable coding system and end-of-line conversion (see Lisp and Coding Systems), perform the encoding (see Explicit Encoding), and set last-coding-system-used to the coding system that was used (see Encoding and I/O).

     If you set this hook locally in a buffer, it is assumed to be associated with the file or the way the contents of the buffer were obtained.  Thus the variable is marked as a permanent local, so that changing the major mode does not alter a buffer-local value.  On the other hand, calling set-visited-file-name will reset it. If this is not what you want, you might like to use write-contents-functions instead.

     Even though this is not a normal hook, you can use add-hook and remove-hook to manipulate the list.  See Hooks.

 -- Variable: write-contents-functions
     This works just like write-file-functions, but it is intended for hooks that pertain to the buffer's contents, not to the particular visited file or its location.  Such hooks are usually set up by major modes, as buffer-local bindings for this variable.  This variable automatically becomes buffer-local whenever it is set; switching to a new major mode always resets this variable, but calling set-visited-file-name does not.

     If any of the functions in this hook returns non-nil, the file is considered already written and the rest are not called and neither are the functions in write-file-functions.

 -- User Option: before-save-hook
     This normal hook runs before a buffer is saved in its visited file, regardless of whether that is done normally or by one of the hooks described above.  For instance, the copyright.el program uses this hook to make sure the file you are saving has the current year in its copyright notice.

 -- User Option: after-save-hook
     This normal hook runs after a buffer has been saved in its visited file. One use of this hook is in Fast Lock mode; it uses this hook to save the highlighting information in a cache file.

 -- User Option: file-precious-flag
     If this variable is non-nil, then save-buffer protects against I/O errors while saving by writing the new file to a temporary name instead of the name it is supposed to have, and then renaming it to the intended name after it is clear there are no errors.  This procedure prevents problems such as a lack of disk space from resulting in an invalid file.

     As a side effect, backups are necessarily made by copying.  See Rename or Copy.  Yet, at the same time, saving a precious file always breaks all hard links between the file you save and other file names.

     Some modes give this variable a non-nil buffer-local value in particular buffers.

 -- User Option: require-final-newline
     This variable determines whether files may be written out that do not end with a newline.  If the value of the variable is t, then save-buffer silently adds a newline at the end of the file whenever the buffer being saved does not already end in one. If the value of the variable is non-nil, but not t, then save-buffer asks the user whether to add a newline each time the case arises.

     If the value of the variable is nil, then save-buffer doesn't add newlines at all.  nil is the default value, but a few major modes set it to t in particular buffers.

See also the function set-visited-file-name (see Buffer File Name).

Reading from Files
==================

You can copy a file from the disk and insert it into a buffer using the insert-file-contents function.  Don't use the user-level command insert-file in a Lisp program, as that sets the mark.

 -- Function: insert-file-contents filename &optional visit beg end replace
     This function inserts the contents of file FILENAME into the current buffer after point.  It returns a list of the absolute file name and the length of the data inserted.  An error is signaled if FILENAME is not the name of a file that can be read.

     The function insert-file-contents checks the file contents against the defined file formats, and converts the file contents if appropriate and also calls the functions in the list after-insert-file-functions.  See Format Conversion. Normally, one of the functions in the after-insert-file-functions list determines the coding system (see Coding Systems) used for decoding the file's contents, including end-of-line conversion.

     If VISIT is non-nil, this function additionally marks the buffer as unmodified and sets up various fields in the buffer so that it is visiting the file FILENAME: these include the buffer's visited file name and its last save file modtime.  This feature is used by find-file-noselect and you probably should not use it yourself.

     If BEG and END are non-nil, they should be integers specifying the portion of the file to insert.  In this case, VISIT must be nil.  For example,

          (insert-file-contents filename nil 0 500)

     inserts the first 500 characters of a file.

     If the argument REPLACE is non-nil, it means to replace the contents of the buffer (actually, just the accessible portion) with the contents of the file.  This is better than simply deleting the buffer contents and inserting the whole file, because (1) it preserves some marker positions and (2) it puts less data in the undo list.

     It is possible to read a special file (such as a FIFO or an I/O device) with insert-file-contents, as long as REPLACE and VISIT are nil.

 -- Function: insert-file-contents-literally filename &optional visit beg end replace
     This function works like insert-file-contents except that it does not do format decoding (see Format Conversion), does not do character code conversion (see Coding Systems), does not run find-file-hook, does not perform automatic uncompression, and so on.

If you want to pass a file name to another process so that another program can read the file, use the function file-local-copy; see Magic File Names.

Writing to Files
================

You can write the contents of a buffer, or part of a buffer, directly to a file on disk using the append-to-file and write-region functions.  Don't use these functions to write to files that are being visited; that could cause confusion in the mechanisms for visiting.

 -- Command: append-to-file start end filename
     This function appends the contents of the region delimited by START and END in the current buffer to the end of file FILENAME.  If that file does not exist, it is created.  This function returns nil.

     An error is signaled if FILENAME specifies a nonwritable file, or a nonexistent file in a directory where files cannot be created.

     When called from Lisp, this function is completely equivalent to:

          (write-region start end filename t)

 -- Command: write-region start end filename &optional append visit lockname mustbenew
     This function writes the region delimited by START and END in the current buffer into the file specified by FILENAME.

     If START is nil, then the command writes the entire buffer contents (not just the accessible portion) to the file and ignores END.

     If START is a string, then write-region writes or appends that string, rather than text from the buffer.  END is ignored in this case.

     If APPEND is non-nil, then the specified text is appended to the existing file contents (if any).  If APPEND is an integer, write-region seeks to that byte offset from the start of the file and writes the data from there.

     If MUSTBENEW is non-nil, then write-region asks for confirmation if FILENAME names an existing file.  If MUSTBENEW is the symbol excl, then write-region does not ask for confirmation, but instead it signals an error file-already-exists if the file already exists.

     The test for an existing file, when MUSTBENEW is excl, uses a special system feature.  At least for files on a local disk, there is no chance that some other program could create a file of the same name before Emacs does, without Emacs's noticing.

     If VISIT is t, then Emacs establishes an association between the buffer and the file: the buffer is then visiting that file. It also sets the last file modification time for the current buffer to FILENAME's modtime, and marks the buffer as not modified.  This feature is used by save-buffer, but you probably should not use it yourself.

     If VISIT is a string, it specifies the file name to visit.  This way, you can write the data to one file (FILENAME) while recording the buffer as visiting another file (VISIT).  The argument VISIT is used in the echo area message and also for file locking; VISIT is stored in buffer-file-name.  This feature is used to implement file-precious-flag; don't use it yourself unless you really know what you're doing.

     The optional argument LOCKNAME, if non-nil, specifies the file name to use for purposes of locking and unlocking, overriding FILENAME and VISIT for that purpose.

     The function write-region converts the data which it writes to the appropriate file formats specified by buffer-file-format and also calls the functions in the list write-region-annotate-functions. See Format Conversion.

     Normally, write-region displays the message Wrote FILENAME in the echo area.  If VISIT is neither t nor nil nor a string, then this message is inhibited.  This feature is useful for programs that use files for internal purposes, files that the user does not need to know about.

 -- Macro: with-temp-file file body...
     The with-temp-file macro evaluates the BODY forms with a temporary buffer as the current buffer; then, at the end, it writes the buffer contents into file FILE.  It kills the temporary buffer when finished, restoring the buffer that was current before the with-temp-file form.  Then it returns the value of the last form in BODY.

     The current buffer is restored even in case of an abnormal exit via throw or error (see Nonlocal Exits).

     See also with-temp-buffer in The Current Buffer.

File Locks
==========

When two users edit the same file at the same time, they are likely to interfere with each other.  Emacs tries to prevent this situation from arising by recording a file lock when a file is being modified.  (File locks are not implemented on Microsoft systems.) Emacs can then detect the first attempt to modify a buffer visiting a file that is locked by another Emacs job, and ask the user what to do. The file lock is really a file, a symbolic link with a special name, stored in the same directory as the file you are editing.

When you access files using NFS, there may be a small probability that you and another user will both lock the same file ``simultaneously.'' If this happens, it is possible for the two users to make changes simultaneously, but Emacs will still warn the user who saves second. Also, the detection of modification of a buffer visiting a file changed on disk catches some cases of simultaneous editing; see Modification Time.

 -- Function: file-locked-p filename
     This function returns nil if the file FILENAME is not locked.  It returns t if it is locked by this Emacs process, and it returns the name of the user who has locked it if it is locked by some other job.

          (file-locked-p "foo")
               => nil

 -- Function: lock-buffer &optional filename
     This function locks the file FILENAME, if the current buffer is modified.  The argument FILENAME defaults to the current buffer's visited file.  Nothing is done if the current buffer is not visiting a file, or is not modified, or if the system does not support locking.

 -- Function: unlock-buffer
     This function unlocks the file being visited in the current buffer, if the buffer is modified.  If the buffer is not modified, then the file should not be locked, so this function does nothing.  It also does nothing if the current buffer is not visiting a file, or if the system does not support locking.

File locking is not supported on some systems.  On systems that do not support it, the functions lock-buffer, unlock-buffer and file-locked-p do nothing and return nil.

 -- Function: ask-user-about-lock file other-user
     This function is called when the user tries to modify FILE, but it is locked by another user named OTHER-USER.  The default definition of this function asks the user to say what to do.  The value this function returns determines what Emacs does next:

       * A value of t says to grab the lock on the file.  Then this user may edit the file and OTHER-USER loses the lock.

       * A value of nil says to ignore the lock and let this user edit the file anyway.

       * This function may instead signal a file-locked error, in which case the change that the user was about to make does not take place.

          The error message for this error looks like this:

               error--> File is locked: FILE OTHER-USER

          where file is the name of the file and OTHER-USER is the name of the user who has locked the file.

     If you wish, you can replace the ask-user-about-lock function with your own version that makes the decision in another way.  The code for its usual definition is in userlock.el.

Information about Files
=======================

The functions described in this section all operate on strings that designate file names.  With a few exceptions, all the functions have names that begin with the word file.  These functions all return information about actual files or directories, so their arguments must all exist as actual files or directories unless otherwise noted.

Testing Accessibility
---------------------

These functions test for permission to access a file in specific ways.  Unless explicitly stated otherwise, they recursively follow symbolic links for their file name arguments, at all levels (at the level of the file itself and at all levels of parent directories).

 -- Function: file-exists-p filename
     This function returns t if a file named FILENAME appears to exist.  This does not mean you can necessarily read the file, only that you can find out its attributes.  (On Unix and GNU/Linux, this is true if the file exists and you have execute permission on the containing directories, regardless of the protection of the file itself.)

     If the file does not exist, or if fascist access control policies prevent you from finding the attributes of the file, this function returns nil.

     Directories are files, so file-exists-p returns t when given a directory name.  However, symbolic links are treated specially; file-exists-p returns t for a symbolic link name only if the target file exists.

 -- Function: file-readable-p filename
     This function returns t if a file named FILENAME exists and you can read it.  It returns nil otherwise.

          (file-readable-p "files.texi")
               => t

          (file-exists-p "/usr/spool/mqueue")
               => t

          (file-readable-p "/usr/spool/mqueue")
               => nil

 -- Function: file-executable-p filename
     This function returns t if a file named FILENAME exists and you can execute it.  It returns nil otherwise.  On Unix and GNU/Linux, if the file is a directory, execute permission means you can check the existence and attributes of files inside the directory, and open those files if their modes permit.

 -- Function: file-writable-p filename
     This function returns t if the file FILENAME can be written or created by you, and nil otherwise.  A file is writable if the file exists and you can write it.  It is creatable if it does not exist, but the specified directory does exist and you can write in that directory.

     In the third example below, foo is not writable because the parent directory does not exist, even though the user could create such a directory.

          (file-writable-p "~/foo")
               => t

          (file-writable-p "/foo")
               => nil

          (file-writable-p "~/no-such-dir/foo")
               => nil

 -- Function: file-accessible-directory-p dirname
     This function returns t if you have permission to open existing files in the directory whose name as a file is DIRNAME; otherwise (or if there is no such directory), it returns nil. The value of DIRNAME may be either a directory name (such as /foo/) or the file name of a file which is a directory (such as /foo, without the final slash).

     Example: after the following,

          (file-accessible-directory-p "/foo")
               => nil

     we can deduce that any attempt to read a file in /foo/ will give an error.

 -- Function: access-file filename string
     This function opens file FILENAME for reading, then closes it and returns nil.  However, if the open fails, it signals an error using STRING as the error message text.

 -- Function: file-ownership-preserved-p filename
     This function returns t if deleting the file FILENAME and then creating it anew would keep the file's owner unchanged.  It also returns t for nonexistent files.

     If FILENAME is a symbolic link, then, unlike the other functions discussed here, file-ownership-preserved-p does not replace FILENAME with its target.  However, it does recursively follow symbolic links at all levels of parent directories.

 -- Function: file-newer-than-file-p filename1 filename2
     This function returns t if the file FILENAME1 is newer than file FILENAME2.  If FILENAME1 does not exist, it returns nil.  If FILENAME1 does exist, but FILENAME2 does not, it returns t.

     In the following example, assume that the file aug-19 was written on the 19th, aug-20 was written on the 20th, and the file no-file doesn't exist at all.

          (file-newer-than-file-p "aug-19" "aug-20")
               => nil

          (file-newer-than-file-p "aug-20" "aug-19")
               => t

          (file-newer-than-file-p "aug-19" "no-file")
               => t

          (file-newer-than-file-p "no-file" "aug-19")
               => nil

     You can use file-attributes to get a file's last modification time as a list of two numbers.  See File Attributes.

Distinguishing Kinds of Files
-----------------------------

This section describes how to distinguish various kinds of files, such as directories, symbolic links, and ordinary files.

 -- Function: file-symlink-p filename
     If the file FILENAME is a symbolic link, the file-symlink-p function returns the (non-recursive) link target as a string.  (Determining the file name that the link points to from the target is nontrivial.)  First, this function recursively follows symbolic links at all levels of parent directories.

     If the file FILENAME is not a symbolic link (or there is no such file), file-symlink-p returns nil.

          (file-symlink-p "foo")
               => nil

          (file-symlink-p "sym-link")
               => "foo"

          (file-symlink-p "sym-link2")
               => "sym-link"

          (file-symlink-p "/bin")
               => "/pub/bin"

The next two functions recursively follow symbolic links at all levels for FILENAME.

 -- Function: file-directory-p filename
     This function returns t if FILENAME is the name of an existing directory, nil otherwise.

          (file-directory-p "~rms")
               => t

          (file-directory-p "~rms/lewis/files.texi")
               => nil

          (file-directory-p "~rms/lewis/no-such-file")
               => nil

          (file-directory-p "$HOME")
               => nil

          (file-directory-p
           (substitute-in-file-name "$HOME"))
               => t

 -- Function: file-regular-p filename
     This function returns t if the file FILENAME exists and is a regular file (not a directory, named pipe, terminal, or other I/O device).

Truenames
---------

The truename of a file is the name that you get by following symbolic links at all levels until none remain, then simplifying away . and .. appearing as name components.  This results in a sort of canonical name for the file.  A file does not always have a unique truename; the number of distinct truenames a file has is equal to the number of hard links to the file.  However, truenames are useful because they eliminate symbolic links as a cause of name variation.

 -- Function: file-truename filename
     The function file-truename returns the truename of the file FILENAME.  The argument must be an absolute file name.

     This function does not expand environment variables.  Only substitute-in-file-name does that.  See Definition of substitute-in-file-name.

     If you may need to follow symbolic links preceding .. appearing as a name component, you should make sure to call file-truename without prior direct or indirect calls to expand-file-name, as otherwise the file name component immediately preceding .. will be ``simplified away'' before file-truename is called.  To eliminate the need for a call to expand-file-name, file-truename handles ~ in the same way that expand-file-name does.  See Functions that Expand Filenames.

 -- Function: file-chase-links filename &optional limit
     This function follows symbolic links, starting with FILENAME, until it finds a file name which is not the name of a symbolic link. Then it returns that file name.  This function does not follow symbolic links at the level of parent directories.

     If you specify a number for LIMIT, then after chasing through that many links, the function just returns what it has even if that is still a symbolic link.

To illustrate the difference between file-chase-links and file-truename, suppose that /usr/foo is a symbolic link to the directory /home/foo, and /home/foo/hello is an ordinary file (or at least, not a symbolic link) or nonexistent.  Then we would have:

     (file-chase-links "/usr/foo/hello")
          ;; This does not follow the links in the parent directories.
          => "/usr/foo/hello"
     (file-truename "/usr/foo/hello")
          ;; Assuming that /home is not a symbolic link.
          => "/home/foo/hello"

See Buffer File Name, for related information.

Other Information about Files
-----------------------------

This section describes the functions for getting detailed information about a file, other than its contents.  This information includes the mode bits that control access permission, the owner and group numbers, the number of names, the inode number, the size, and the times of access and modification.

 -- Function: file-modes filename
     This function returns the mode bits of FILENAME, as an integer. The mode bits are also called the file permissions, and they specify access control in the usual Unix fashion.  If the low-order bit is 1, then the file is executable by all users, if the second-lowest-order bit is 1, then the file is writable by all users, etc.

     The highest value returnable is 4095 (7777 octal), meaning that everyone has read, write, and execute permission, that the SUID bit is set for both others and group, and that the sticky bit is set.

     If FILENAME does not exist, file-modes returns nil.

     This function recursively follows symbolic links at all levels.

          (file-modes "~/junk/diffs")
               => 492               ; Decimal integer.

          (format "%o" 492)
               => "754"             ; Convert to octal.

          (set-file-modes "~/junk/diffs" 438)
               => nil

          (format "%o" 438)
               => "666"             ; Convert to octal.

          % ls -l diffs
            -rw-rw-rw-  1 lewis 0 3063 Oct 30 16:00 diffs

If the FILENAME argument to the next two functions is a symbolic link, then these function do not replace it with its target. However, they both recursively follow symbolic links at all levels of parent directories.

 -- Function: file-nlinks filename
     This functions returns the number of names (i.e., hard links) that file FILENAME has.  If the file does not exist, then this function returns nil.  Note that symbolic links have no effect on this function, because they are not considered to be names of the files they link to.

          % ls -l foo*
          -rw-rw-rw-  2 rms       4 Aug 19 01:27 foo
          -rw-rw-rw-  2 rms       4 Aug 19 01:27 foo1

          (file-nlinks "foo")
               => 2

          (file-nlinks "doesnt-exist")
               => nil

 -- Function: file-attributes filename &optional id-format
     This function returns a list of attributes of file FILENAME.  If the specified file cannot be opened, it returns nil. The optional parameter ID-FORMAT specifies the preferred format of attributes UID and GID (see below)---the valid values are 'string and 'integer.  The latter is the default, but we plan to change that, so you should specify a non-nil value for ID-FORMAT if you use the returned UID or GID.

     The elements of the list, in order, are:

      0. t for a directory, a string for a symbolic link (the name linked to), or nil for a text file.

      1. The number of names the file has.  Alternate names, also known as hard links, can be created by using the add-name-to-file function (see Changing Files).

      2. The file's UID, normally as a string.  However, if it does not correspond to a named user, the value is an integer or a floating point number.

      3. The file's GID, likewise.

      4. The time of last access, as a list of two integers. The first integer has the high-order 16 bits of time, the second has the low 16 bits.  (This is similar to the value of current-time; see Time of Day.)

      5. The time of last modification as a list of two integers (as above).

      6. The time of last status change as a list of two integers (as above).

      7. The size of the file in bytes.  If the size is too large to fit in a Lisp integer, this is a floating point number.

      8. The file's modes, as a string of ten letters or dashes, as in ls -l.

      9. t if the file's GID would change if file were deleted and recreated; nil otherwise.

      10. The file's inode number.  If possible, this is an integer.  If the inode number is too large to be represented as an integer in Emacs Lisp, then the value has the form (HIGH . LOW), where LOW holds the low 16 bits.

      11. The file system number of the file system that the file is in. Depending on the magnitude of the value, this can be either an integer or a cons cell, in the same manner as the inode number.  This element and the file's inode number together give enough information to distinguish any two files on the system---no two files can have the same values for both of these numbers.

     For example, here are the file attributes for files.texi:

          (file-attributes "files.texi" 'string)
               =>  (nil 1 "lh" "users"
                    (8489 20284)
                    (8489 20284)
                    (8489 20285)
                    14906 "-rw-rw-rw-"
                    nil 129500 -32252)

     and here is how the result is interpreted:

     nil
          is neither a directory nor a symbolic link.

     1
          has only one name (the name files.texi in the current default directory).

     "lh"
          is owned by the user with name "lh".

     "users"
          is in the group with name "users".

     (8489 20284)
          was last accessed on Aug 19 00:09.

     (8489 20284)
          was last modified on Aug 19 00:09.

     (8489 20285)
          last had its inode changed on Aug 19 00:09.

     14906
          is 14906 bytes long.  (It may not contain 14906 characters, though, if some of the bytes belong to multibyte sequences.)

     "-rw-rw-rw-"
          has a mode of read and write access for the owner, group, and world.

     nil
          would retain the same GID if it were recreated.

     129500
          has an inode number of 129500.

     -32252
          is on file system number -32252.

How to Locate Files in Standard Places
--------------------------------------

This section explains how to search for a file in a list of directories (a path).  One example is when you need to look for a program's executable file, e.g., to find out whether a given program is installed on the user's system.  Another example is the search for Lisp libraries (see Library Search).  Such searches generally need to try various possible file name extensions, in addition to various possible directories.  Emacs provides a function for such a generalized search for a file.

 -- Function: locate-file filename path &optional suffixes predicate
     This function searches for a file whose name is FILENAME in a list of directories given by PATH, trying the suffixes in SUFFIXES.  If it finds such a file, it returns the full absolute file name of the file (see Relative File Names); otherwise it returns nil.

     The optional argument SUFFIXES gives the list of file-name suffixes to append to FILENAME when searching. locate-file tries each possible directory with each of these suffixes.  If SUFFIXES is nil, or (""), then there are no suffixes, and FILENAME is used only as-is.  Typical values of SUFFIXES are exec-suffixes (see exec-suffixes), load-suffixes, load-file-rep-suffixes and the return value of the function get-load-suffixes (see Load Suffixes).

     Typical values for PATH are exec-path (see exec-path) when looking for executable programs or load-path (see load-path) when looking for Lisp files.  If FILENAME is absolute, PATH has no effect, but the suffixes in SUFFIXES are still tried.

     The optional argument PREDICATE, if non-nil, specifies the predicate function to use for testing whether a candidate file is suitable.  The predicate function is passed the candidate file name as its single argument.  If PREDICATE is nil or unspecified, locate-file uses file-readable-p as the default predicate.  Useful non-default predicates include file-executable-p, file-directory-p, and other predicates described in Kinds of Files.

     For compatibility, PREDICATE can also be one of the symbols executable, readable, writable, exists, or a list of one or more of these symbols.

 -- Function: executable-find program
     This function searches for the executable file of the named PROGRAM and returns the full absolute name of the executable, including its file-name extensions, if any.  It returns nil if the file is not found.  The functions searches in all the directories in exec-path and tries all the file-name extensions in exec-suffixes.

Changing File Names and Attributes
==================================

The functions in this section rename, copy, delete, link, and set the modes of files.

In the functions that have an argument NEWNAME, if a file by the name of NEWNAME already exists, the actions taken depend on the value of the argument OK-IF-ALREADY-EXISTS:

  * Signal a file-already-exists error if OK-IF-ALREADY-EXISTS is nil.

  * Request confirmation if OK-IF-ALREADY-EXISTS is a number.

  * Replace the old file without confirmation if OK-IF-ALREADY-EXISTS is any other value.

The next four commands all recursively follow symbolic links at all levels of parent directories for their first argument, but, if that argument is itself a symbolic link, then only copy-file replaces it with its (recursive) target.

 -- Command: add-name-to-file oldname newname &optional ok-if-already-exists
     This function gives the file named OLDNAME the additional name NEWNAME.  This means that NEWNAME becomes a new ``hard link'' to OLDNAME.

     In the first part of the following example, we list two files, foo and foo3.

          % ls -li fo*
          81908 -rw-rw-rw-  1 rms       29 Aug 18 20:32 foo
          84302 -rw-rw-rw-  1 rms       24 Aug 18 20:31 foo3

     Now we create a hard link, by calling add-name-to-file, then list the files again.  This shows two names for one file, foo and foo2.

          (add-name-to-file "foo" "foo2")
               => nil

          % ls -li fo*
          81908 -rw-rw-rw-  2 rms       29 Aug 18 20:32 foo
          81908 -rw-rw-rw-  2 rms       29 Aug 18 20:32 foo2
          84302 -rw-rw-rw-  1 rms       24 Aug 18 20:31 foo3

     Finally, we evaluate the following:

          (add-name-to-file "foo" "foo3" t)

     and list the files again.  Now there are three names for one file: foo, foo2, and foo3.  The old contents of foo3 are lost.

          (add-name-to-file "foo1" "foo3")
               => nil

          % ls -li fo*
          81908 -rw-rw-rw-  3 rms       29 Aug 18 20:32 foo
          81908 -rw-rw-rw-  3 rms       29 Aug 18 20:32 foo2
          81908 -rw-rw-rw-  3 rms       29 Aug 18 20:32 foo3

     This function is meaningless on operating systems where multiple names for one file are not allowed.  Some systems implement multiple names by copying the file instead.

     See also file-nlinks in File Attributes.

 -- Command: rename-file filename newname &optional ok-if-already-exists
     This command renames the file FILENAME as NEWNAME.

     If FILENAME has additional names aside from FILENAME, it continues to have those names.  In fact, adding the name NEWNAME with add-name-to-file and then deleting FILENAME has the same effect as renaming, aside from momentary intermediate states.

 -- Command: copy-file oldname newname &optional ok-if-exists time preserve-uid-gid
     This command copies the file OLDNAME to NEWNAME.  An error is signaled if OLDNAME does not exist.  If NEWNAME names a directory, it copies OLDNAME into that directory, preserving its final name component.

     If TIME is non-nil, then this function gives the new file the same last-modified time that the old one has.  (This works on only some operating systems.)  If setting the time gets an error, copy-file signals a file-date-error error.  In an interactive call, a prefix argument specifies a non-nil value for TIME.

     This function copies the file modes, too.

     If argument PRESERVE-UID-GID is nil, we let the operating system decide the user and group ownership of the new file (this is usually set to the user running Emacs).  If PRESERVE-UID-GID is non-nil, we attempt to copy the user and group ownership of the file.  This works only on some operating systems, and only if you have the correct permissions to do so.

 -- Command: make-symbolic-link filename newname &optional ok-if-exists
     This command makes a symbolic link to FILENAME, named NEWNAME.  This is like the shell command ln -s FILENAME NEWNAME.

     This function is not available on systems that don't support symbolic links.

 -- Command: delete-file filename
     This command deletes the file FILENAME, like the shell command rm FILENAME.  If the file has multiple names, it continues to exist under the other names.

     A suitable kind of file-error error is signaled if the file does not exist, or is not deletable.  (On Unix and GNU/Linux, a file is deletable if its directory is writable.)

     If FILENAME is a symbolic link, delete-file does not replace it with its target, but it does follow symbolic links at all levels of parent directories.

     See also delete-directory in Create/Delete Dirs.

 -- Function: define-logical-name varname string
     This function defines the logical name VARNAME to have the value STRING.  It is available only on VMS.

 -- Function: set-file-modes filename mode
     This function sets mode bits of FILENAME to MODE (which must be an integer).  Only the low 12 bits of MODE are used. This function recursively follows symbolic links at all levels for FILENAME.

 -- Function: set-default-file-modes mode
     This function sets the default file protection for new files created by Emacs and its subprocesses.  Every file created with Emacs initially has this protection, or a subset of it (write-region will not give a file execute permission even if the default file protection allows execute permission).  On Unix and GNU/Linux, the default protection is the bitwise complement of the ``umask'' value.

     The argument MODE must be an integer.  On most systems, only the low 9 bits of MODE are meaningful.  You can use the Lisp construct for octal character codes to enter MODE; for example,

          (set-default-file-modes ?\644)

     Saving a modified version of an existing file does not count as creating the file; it preserves the existing file's mode, whatever that is.  So the default file protection has no effect.

 -- Function: default-file-modes
     This function returns the current default protection value.

 -- Function: set-file-times filename &optional time
     This function sets the access and modification times of FILENAME to TIME.  The return value is t if the times are successfully set, otherwise it is nil.  TIME defaults to the current time and must be in the format returned by current-time (see Time of Day).

On MS-DOS, there is no such thing as an ``executable'' file mode bit. So Emacs considers a file executable if its name ends in one of the standard executable extensions, such as .com, .bat, .exe, and some others.  Files that begin with the Unix-standard #! signature, such as shell and Perl scripts, are also considered as executable files.  This is reflected in the values returned by file-modes and file-attributes.  Directories are also reported with executable bit set, for compatibility with Unix.

File Names
==========

Files are generally referred to by their names, in Emacs as elsewhere. File names in Emacs are represented as strings.  The functions that operate on a file all expect a file name argument.

In addition to operating on files themselves, Emacs Lisp programs often need to operate on file names; i.e., to take them apart and to use part of a name to construct related file names.  This section describes how to manipulate file names.

The functions in this section do not actually access files, so they can operate on file names that do not refer to an existing file or directory.

On MS-DOS and MS-Windows, these functions (like the function that actually operate on files) accept MS-DOS or MS-Windows file-name syntax, where backslashes separate the components, as well as Unix syntax; but they always return Unix syntax.  On VMS, these functions (and the ones that operate on files) understand both VMS file-name syntax and Unix syntax.  This enables Lisp programs to specify file names in Unix syntax and work properly on all systems without change.

File Name Components
--------------------

The operating system groups files into directories.  To specify a file, you must specify the directory and the file's name within that directory.  Therefore, Emacs considers a file name as having two main parts: the directory name part, and the nondirectory part (or file name within the directory).  Either part may be empty. Concatenating these two parts reproduces the original file name.

On most systems, the directory part is everything up to and including the last slash (backslash is also allowed in input on MS-DOS or MS-Windows); the nondirectory part is the rest.  The rules in VMS syntax are complicated.

For some purposes, the nondirectory part is further subdivided into the name proper and the version number.  On most systems, only backup files have version numbers in their names.  On VMS, every file has a version number, but most of the time the file name actually used in Emacs omits the version number, so that version numbers in Emacs are found mostly in directory lists.

 -- Function: file-name-directory filename
     This function returns the directory part of FILENAME, as a directory name (see Directory Names), or nil if FILENAME does not include a directory part.

     On GNU and Unix systems, a string returned by this function always ends in a slash.  On MS-DOS it can also end in a colon.  On VMS, it returns a string ending in one of the three characters :, ], or >.

          (file-name-directory "lewis/foo")  ; Unix example
               => "lewis/"

          (file-name-directory "foo")        ; Unix example
               => nil

          (file-name-directory "[X]FOO.TMP") ; VMS example
               => "[X]"

 -- Function: file-name-nondirectory filename
     This function returns the nondirectory part of FILENAME.

          (file-name-nondirectory "lewis/foo")
               => "foo"

          (file-name-nondirectory "foo")
               => "foo"

          (file-name-nondirectory "lewis/")
               => ""

          ;; The following example is accurate only on VMS.
          (file-name-nondirectory "[X]FOO.TMP")
               => "FOO.TMP"

 -- Function: file-name-sans-versions filename &optional keep-backup-version
     This function returns FILENAME with any file version numbers, backup version numbers, or trailing tildes discarded.

     If KEEP-BACKUP-VERSION is non-nil, then true file version numbers understood as such by the file system are discarded from the return value, but backup version numbers are kept.

          (file-name-sans-versions "~rms/foo.~1~")
               => "~rms/foo"

          (file-name-sans-versions "~rms/foo~")
               => "~rms/foo"

          (file-name-sans-versions "~rms/foo")
               => "~rms/foo"

          ;; The following example applies to VMS only.
          (file-name-sans-versions "foo;23")
               => "foo"

 -- Function: file-name-extension filename &optional period
     This function returns FILENAME's final ``extension,'' if any, after applying file-name-sans-versions to remove any version/backup part.  The extension, in a file name, is the part that starts with the last . in the last name component (minus any version/backup part).

     This function returns nil for extensionless file names such as foo.  It returns "" for null extensions, as in foo..  If the last component of a file name begins with a ., that .  doesn't count as the beginning of an extension.  Thus, .emacs's ``extension'' is nil, not .emacs.

     If PERIOD is non-nil, then the returned value includes the period that delimits the extension, and if FILENAME has no extension, the value is "".

 -- Function: file-name-sans-extension filename
     This function returns FILENAME minus its extension, if any.  The version/backup part, if present, is only removed if the file has an extension.  For example,

          (file-name-sans-extension "foo.lose.c")
               => "foo.lose"
          (file-name-sans-extension "big.hack/foo")
               => "big.hack/foo"
          (file-name-sans-extension "/my/home/.emacs")
               => "/my/home/.emacs"
          (file-name-sans-extension "/my/home/.emacs.el")
               => "/my/home/.emacs"
          (file-name-sans-extension "~/foo.el.~3~")
               => "~/foo"
          (file-name-sans-extension "~/foo.~3~")
               => "~/foo.~3~"

     Note that the .~3~ in the two last examples is the backup part, not an extension.

Absolute and Relative File Names
--------------------------------

All the directories in the file system form a tree starting at the root directory.  A file name can specify all the directory names starting from the root of the tree; then it is called an absolute file name.  Or it can specify the position of the file in the tree relative to a default directory; then it is called a relative file name.  On Unix and GNU/Linux, an absolute file name starts with a slash or a tilde (~), and a relative one does not.  On MS-DOS and MS-Windows, an absolute file name starts with a slash or a backslash, or with a drive specification X:/, where X is the drive letter.  The rules on VMS are complicated.

 -- Function: file-name-absolute-p filename
     This function returns t if file FILENAME is an absolute file name, nil otherwise.  On VMS, this function understands both Unix syntax and VMS syntax.

          (file-name-absolute-p "~rms/foo")
               => t

          (file-name-absolute-p "rms/foo")
               => nil

          (file-name-absolute-p "/user/rms/foo")
               => t

Given a possibly relative file name, you can convert it to an absolute name using expand-file-name (see File Name Expansion).  This function converts absolute file names to relative names:

 -- Function: file-relative-name filename &optional directory
     This function tries to return a relative name that is equivalent to FILENAME, assuming the result will be interpreted relative to DIRECTORY (an absolute directory name or directory file name). If DIRECTORY is omitted or nil, it defaults to the current buffer's default directory.

     On some operating systems, an absolute file name begins with a device name.  On such systems, FILENAME has no relative equivalent based on DIRECTORY if they start with two different device names.  In this case, file-relative-name returns FILENAME in absolute form.

          (file-relative-name "/foo/bar" "/foo/")
               => "bar"
          (file-relative-name "/foo/bar" "/hack/")
               => "../foo/bar"

Directory Names
---------------

A directory name is the name of a directory.  A directory is actually a kind of file, so it has a file name, which is related to the directory name but not identical to it.  (This is not quite the same as the usual Unix terminology.)  These two different names for the same entity are related by a syntactic transformation.  On GNU and Unix systems, this is simple: a directory name ends in a slash, whereas the directory's name as a file lacks that slash.  On MS-DOS and VMS, the relationship is more complicated.

The difference between a directory name and its name as a file is subtle but crucial.  When an Emacs variable or function argument is described as being a directory name, a file name of a directory is not acceptable.  When file-name-directory returns a string, that is always a directory name.

The following two functions convert between directory names and file names.  They do nothing special with environment variable substitutions such as $HOME, and the constructs ~, . and ...

 -- Function: file-name-as-directory filename
     This function returns a string representing FILENAME in a form that the operating system will interpret as the name of a directory.  On most systems, this means appending a slash to the string (if it does not already end in one).  On VMS, the function converts a string of the form [X]Y.DIR.1 to the form [X.Y].

          (file-name-as-directory "~rms/lewis")
               => "~rms/lewis/"

 -- Function: directory-file-name dirname
     This function returns a string representing DIRNAME in a form that the operating system will interpret as the name of a file.  On most systems, this means removing the final slash (or backslash) from the string.  On VMS, the function converts a string of the form [X.Y] to [X]Y.DIR.1.

          (directory-file-name "~lewis/")
               => "~lewis"

Given a directory name, you can combine it with a relative file name using concat:

     (concat DIRNAME RELFILE)

Be sure to verify that the file name is relative before doing that. If you use an absolute file name, the results could be syntactically invalid or refer to the wrong file.

If you want to use a directory file name in making such a combination, you must first convert it to a directory name using file-name-as-directory:

     (concat (file-name-as-directory DIRFILE) RELFILE)

Don't try concatenating a slash by hand, as in

     ;;; Wrong!
     (concat DIRFILE "/" RELFILE)

because this is not portable.  Always use file-name-as-directory.

Directory name abbreviations are useful for directories that are normally accessed through symbolic links.  Sometimes the users recognize primarily the link's name as ``the name'' of the directory, and find it annoying to see the directory's ``real'' name.  If you define the link name as an abbreviation for the ``real'' name, Emacs shows users the abbreviation instead.

 -- Variable: directory-abbrev-alist
     The variable directory-abbrev-alist contains an alist of abbreviations to use for file directories.  Each element has the form (FROM . TO), and says to replace FROM with TO when it appears in a directory name.  The FROM string is actually a regular expression; it should always start with ^. The TO string should be an ordinary absolute directory name.  Do not use ~ to stand for a home directory in that string.  The function abbreviate-file-name performs these substitutions.

     You can set this variable in site-init.el to describe the abbreviations appropriate for your site.

     Here's an example, from a system on which file system /home/fsf and so on are normally accessed through symbolic links named /fsf and so on.

          (("^/home/fsf" . "/fsf")
           ("^/home/gp" . "/gp")
           ("^/home/gd" . "/gd"))

To convert a directory name to its abbreviation, use this function:

 -- Function: abbreviate-file-name filename
     This function applies abbreviations from directory-abbrev-alist to its argument, and substitutes ~ for the user's home directory.  You can use it for directory names and for file names, because it recognizes abbreviations even as part of the name.

Functions that Expand Filenames
-------------------------------

Expansion of a file name means converting a relative file name to an absolute one.  Since this is done relative to a default directory, you must specify the default directory name as well as the file name to be expanded.  Expansion also simplifies file names by eliminating redundancies such as ./ and NAME/../.

 -- Function: expand-file-name filename &optional directory
     This function converts FILENAME to an absolute file name.  If DIRECTORY is supplied, it is the default directory to start with if FILENAME is relative.  (The value of DIRECTORY should itself be an absolute directory name or directory file name; it may start with ~.)  Otherwise, the current buffer's value of default-directory is used.  For example:

          (expand-file-name "foo")
               => "/xcssun/users/rms/lewis/foo"

          (expand-file-name "../foo")
               => "/xcssun/users/rms/foo"

          (expand-file-name "foo" "/usr/spool/")
               => "/usr/spool/foo"

          (expand-file-name "$HOME/foo")
               => "/xcssun/users/rms/lewis/$HOME/foo"

     If the part of the combined file name before the first slash is ~, it expands to the value of the HOME environment variable (usually your home directory).  If the part before the first slash is ~USER and if USER is a valid login name, it expands to USER's home directory.

     Filenames containing . or .. are simplified to their canonical form:

          (expand-file-name "bar/../foo")
               => "/xcssun/users/rms/lewis/foo"

     In some cases, a leading .. component can remain in the output:

          (expand-file-name "../home" "/")
               => "/../home"

     This is for the sake of filesystems that have the concept of a ``superroot'' above the root directory /.  On other filesystems, /../ is interpreted exactly the same as /.

     Note that expand-file-name does not expand environment variables; only substitute-in-file-name does that.

     Note also that expand-file-name does not follow symbolic links at any level.  This results in a difference between the way file-truename and expand-file-name treat ... Assuming that /tmp/bar is a symbolic link to the directory /tmp/foo/bar we get:

          (file-truename "/tmp/bar/../myfile")
               => "/tmp/foo/myfile"

          (expand-file-name "/tmp/bar/../myfile")
               => "/tmp/myfile"

     If you may need to follow symbolic links preceding .., you should make sure to call file-truename without prior direct or indirect calls to expand-file-name.  See Truenames.

 -- Variable: default-directory
     The value of this buffer-local variable is the default directory for the current buffer.  It should be an absolute directory name; it may start with ~.  This variable is buffer-local in every buffer.

     expand-file-name uses the default directory when its second argument is nil.

     Aside from VMS, the value is always a string ending with a slash.

          default-directory
               => "/user/lewis/manual/"

 -- Function: substitute-in-file-name filename
     This function replaces environment variable references in FILENAME with the environment variable values.  Following standard Unix shell syntax, $ is the prefix to substitute an environment variable value.  If the input contains $$, that is converted to $; this gives the user a way to ``quote'' a $.

     The environment variable name is the series of alphanumeric characters (including underscores) that follow the $.  If the character following the $ is a {, then the variable name is everything up to the matching }.

     Calling substitute-in-file-name on output produced by substitute-in-file-name tends to give incorrect results.  For instance, use of $$ to quote a single $ won't work properly, and $ in an environment variable's value could lead to repeated substitution.  Therefore, programs that call this function and put the output where it will be passed to this function need to double all $ characters to prevent subsequent incorrect results.

     Here we assume that the environment variable HOME, which holds the user's home directory name, has value /xcssun/users/rms.

          (substitute-in-file-name "$HOME/foo")
               => "/xcssun/users/rms/foo"

     After substitution, if a ~ or a / appears immediately after another /, the function discards everything before it (up through the immediately preceding /).

          (substitute-in-file-name "bar/~/foo")
               => "~/foo"

          (substitute-in-file-name "/usr/local/$HOME/foo")
               => "/xcssun/users/rms/foo"
               ;; /usr/local/ has been discarded.

     On VMS, $ substitution is not done, so this function does nothing on VMS except discard superfluous initial components as shown above.

Generating Unique File Names
----------------------------

Some programs need to write temporary files.  Here is the usual way to construct a name for such a file:

     (make-temp-file NAME-OF-APPLICATION)

The job of make-temp-file is to prevent two different users or two different jobs from trying to use the exact same file name.

 -- Function: make-temp-file prefix &optional dir-flag suffix
     This function creates a temporary file and returns its name.  Emacs creates the temporary file's name by adding to PREFIX some random characters that are different in each Emacs job.  The result is guaranteed to be a newly created empty file.  On MS-DOS, this function can truncate the STRING prefix to fit into the 8+3 file-name limits.  If PREFIX is a relative file name, it is expanded against temporary-file-directory.

          (make-temp-file "foo")
               => "/tmp/foo232J6v"

     When make-temp-file returns, the file has been created and is empty.  At that point, you should write the intended contents into the file.

     If DIR-FLAG is non-nil, make-temp-file creates an empty directory instead of an empty file.  It returns the file name, not the directory name, of that directory.  See Directory Names.

     If SUFFIX is non-nil, make-temp-file adds it at the end of the file name.

     To prevent conflicts among different libraries running in the same Emacs, each Lisp program that uses make-temp-file should have its own PREFIX.  The number added to the end of PREFIX distinguishes between the same application running in different Emacs jobs.  Additional added characters permit a large number of distinct names even in one Emacs job.

The default directory for temporary files is controlled by the variable temporary-file-directory.  This variable gives the user a uniform way to specify the directory for all temporary files.  Some programs use small-temporary-file-directory instead, if that is non-nil.  To use it, you should expand the prefix against the proper directory before calling make-temp-file.

In older Emacs versions where make-temp-file does not exist, you should use make-temp-name instead:

     (make-temp-name
      (expand-file-name NAME-OF-APPLICATION
                        temporary-file-directory))

 -- Function: make-temp-name string
     This function generates a string that can be used as a unique file name.  The name starts with STRING, and has several random characters appended to it, which are different in each Emacs job.  It is like make-temp-file except that it just constructs a name, and does not create a file.  Another difference is that STRING should be an absolute file name.  On MS-DOS, this function can truncate the STRING prefix to fit into the 8+3 file-name limits.

 -- Variable: temporary-file-directory
     This variable specifies the directory name for creating temporary files. Its value should be a directory name (see Directory Names), but it is good for Lisp programs to cope if the value is a directory's file name instead.  Using the value as the second argument to expand-file-name is a good way to achieve that.

     The default value is determined in a reasonable way for your operating system; it is based on the TMPDIR, TMP and TEMP environment variables, with a fall-back to a system-dependent name if none of these variables is defined.

     Even if you do not use make-temp-file to create the temporary file, you should still use this variable to decide which directory to put the file in.  However, if you expect the file to be small, you should use small-temporary-file-directory first if that is non-nil.

 -- Variable: small-temporary-file-directory
     This variable specifies the directory name for creating certain temporary files, which are likely to be small.

     If you want to write a temporary file which is likely to be small, you should compute the directory like this:

          (make-temp-file
            (expand-file-name PREFIX
                              (or small-temporary-file-directory
                                  temporary-file-directory)))

File Name Completion
--------------------

This section describes low-level subroutines for completing a file name.  For higher level functions, see Reading File Names.

 -- Function: file-name-all-completions partial-filename directory
     This function returns a list of all possible completions for a file whose name starts with PARTIAL-FILENAME in directory DIRECTORY.  The order of the completions is the order of the files in the directory, which is unpredictable and conveys no useful information.

     The argument PARTIAL-FILENAME must be a file name containing no directory part and no slash (or backslash on some systems).  The current buffer's default directory is prepended to DIRECTORY, if DIRECTORY is not absolute.

     In the following example, suppose that ~rms/lewis is the current default directory, and has five files whose names begin with f: foo, file~, file.c, file.c.~1~, and file.c.~2~.

          (file-name-all-completions "f" "")
               => ("foo" "file~" "file.c.~2~"
                          "file.c.~1~" "file.c")

          (file-name-all-completions "fo" "")
               => ("foo")

 -- Function: file-name-completion filename directory &optional predicate
     This function completes the file name FILENAME in directory DIRECTORY.  It returns the longest prefix common to all file names in directory DIRECTORY that start with FILENAME.  If PREDICATE is non-nil then it ignores possible completions that don't satisfy PREDICATE, after calling that function with one argument, the expanded absolute file name.

     If only one match exists and FILENAME matches it exactly, the function returns t.  The function returns nil if directory DIRECTORY contains no name starting with FILENAME.

     In the following example, suppose that the current default directory has five files whose names begin with f: foo, file~, file.c, file.c.~1~, and file.c.~2~.

          (file-name-completion "fi" "")
               => "file"

          (file-name-completion "file.c.~1" "")
               => "file.c.~1~"

          (file-name-completion "file.c.~1~" "")
               => t

          (file-name-completion "file.c.~3" "")
               => nil

 -- User Option: completion-ignored-extensions
     file-name-completion usually ignores file names that end in any string in this list.  It does not ignore them when all the possible completions end in one of these suffixes.  This variable has no effect on file-name-all-completions.

     A typical value might look like this:

          completion-ignored-extensions
               => (".o" ".elc" "~" ".dvi")

     If an element of completion-ignored-extensions ends in a slash /, it signals a directory.  The elements which do not end in a slash will never match a directory; thus, the above value will not filter out a directory named foo.elc.

Standard File Names
-------------------

Most of the file names used in Lisp programs are entered by the user. But occasionally a Lisp program needs to specify a standard file name for a particular use---typically, to hold customization information about each user.  For example, abbrev definitions are stored (by default) in the file ~/.abbrev_defs; the completion package stores completions in the file ~/.completions.  These are two of the many standard file names used by parts of Emacs for certain purposes.

Various operating systems have their own conventions for valid file names and for which file names to use for user profile data.  A Lisp program which reads a file using a standard file name ought to use, on each type of system, a file name suitable for that system.  The function convert-standard-filename makes this easy to do.

 -- Function: convert-standard-filename filename
     This function alters the file name FILENAME to fit the conventions of the operating system in use, and returns the result as a new string.

The recommended way to specify a standard file name in a Lisp program is to choose a name which fits the conventions of GNU and Unix systems, usually with a nondirectory part that starts with a period, and pass it to convert-standard-filename instead of using it directly.  Here is an example from the completion package:

     (defvar save-completions-file-name
             (convert-standard-filename "~/.completions")
       "*The file name to save completions to.")

On GNU and Unix systems, and on some other systems as well, convert-standard-filename returns its argument unchanged.  On some other systems, it alters the name to fit the system's conventions.

For example, on MS-DOS the alterations made by this function include converting a leading .  to _, converting a _ in the middle of the name to . if there is no other ., inserting a . after eight characters if there is none, and truncating to three characters after the ..  (It makes other changes as well.) Thus, .abbrev_defs becomes _abbrev.def, and .completions becomes _complet.ion.

Contents of Directories
=======================

A directory is a kind of file that contains other files entered under various names.  Directories are a feature of the file system.

Emacs can list the names of the files in a directory as a Lisp list, or display the names in a buffer using the ls shell command.  In the latter case, it can optionally display information about each file, depending on the options passed to the ls command.

 -- Function: directory-files directory &optional full-name match-regexp nosort
     This function returns a list of the names of the files in the directory DIRECTORY.  By default, the list is in alphabetical order.

     If FULL-NAME is non-nil, the function returns the files' absolute file names.  Otherwise, it returns the names relative to the specified directory.

     If MATCH-REGEXP is non-nil, this function returns only those file names that contain a match for that regular expression---the other file names are excluded from the list.  On case-insensitive filesystems, the regular expression matching is case-insensitive.

     If NOSORT is non-nil, directory-files does not sort the list, so you get the file names in no particular order.  Use this if you want the utmost possible speed and don't care what order the files are processed in.  If the order of processing is visible to the user, then the user will probably be happier if you do sort the names.

          (directory-files "~lewis")
               => ("#foo#" "#foo.el#" "." ".."
                   "dired-mods.el" "files.texi"
                   "files.texi.~1~")

     An error is signaled if DIRECTORY is not the name of a directory that can be read.

 -- Function: directory-files-and-attributes directory &optional full-name match-regexp nosort id-format
     This is similar to directory-files in deciding which files to report on and how to report their names.  However, instead of returning a list of file names, it returns for each file a list (FILENAME . ATTRIBUTES), where ATTRIBUTES is what file-attributes would return for that file. The optional argument ID-FORMAT has the same meaning as the corresponding argument to file-attributes (see Definition of file-attributes).

 -- Function: file-name-all-versions file dirname
     This function returns a list of all versions of the file named FILE in directory DIRNAME.  It is only available on VMS.

 -- Function: file-expand-wildcards pattern &optional full
     This function expands the wildcard pattern PATTERN, returning a list of file names that match it.

     If PATTERN is written as an absolute file name, the values are absolute also.

     If PATTERN is written as a relative file name, it is interpreted relative to the current default directory.  The file names returned are normally also relative to the current default directory.  However, if FULL is non-nil, they are absolute.

 -- Function: insert-directory file switches &optional wildcard full-directory-p
     This function inserts (in the current buffer) a directory listing for directory FILE, formatted with ls according to SWITCHES.  It leaves point after the inserted text. SWITCHES may be a string of options, or a list of strings representing individual options.

     The argument FILE may be either a directory name or a file specification including wildcard characters.  If WILDCARD is non-nil, that means treat FILE as a file specification with wildcards.

     If FULL-DIRECTORY-P is non-nil, that means the directory listing is expected to show the full contents of a directory.  You should specify t when FILE is a directory and switches do not contain -d.  (The -d option to ls says to describe a directory itself as a file, rather than showing its contents.)

     On most systems, this function works by running a directory listing program whose name is in the variable insert-directory-program. If WILDCARD is non-nil, it also runs the shell specified by shell-file-name, to expand the wildcards.

     MS-DOS and MS-Windows systems usually lack the standard Unix program ls, so this function emulates the standard Unix program ls with Lisp code.

     As a technical detail, when SWITCHES contains the long --dired option, insert-directory treats it specially, for the sake of dired.  However, the normally equivalent short -D option is just passed on to insert-directory-program, as any other option.

 -- Variable: insert-directory-program
     This variable's value is the program to run to generate a directory listing for the function insert-directory.  It is ignored on systems which generate the listing with Lisp code.

Creating and Deleting Directories
=================================

Most Emacs Lisp file-manipulation functions get errors when used on files that are directories.  For example, you cannot delete a directory with delete-file.  These special functions exist to create and delete directories.

 -- Function: make-directory dirname &optional parents
     This function creates a directory named DIRNAME. If PARENTS is non-nil, as is always the case in an interactive call, that means to create the parent directories first, if they don't already exist.

 -- Function: delete-directory dirname
     This function deletes the directory named DIRNAME.  The function delete-file does not work for files that are directories; you must use delete-directory for them.  If the directory contains any files, delete-directory signals an error.

     This function only follows symbolic links at the level of parent directories.

Making Certain File Names ``Magic''
===================================

You can implement special handling for certain file names.  This is called making those names magic.  The principal use for this feature is in implementing remote file names (see Remote Files (The GNU Emacs Manual)).

To define a kind of magic file name, you must supply a regular expression to define the class of names (all those that match the regular expression), plus a handler that implements all the primitive Emacs file operations for file names that do match.

The variable file-name-handler-alist holds a list of handlers, together with regular expressions that determine when to apply each handler.  Each element has this form:

     (REGEXP . HANDLER)

All the Emacs primitives for file access and file name transformation check the given file name against file-name-handler-alist.  If the file name matches REGEXP, the primitives handle that file by calling HANDLER.

The first argument given to HANDLER is the name of the primitive, as a symbol; the remaining arguments are the arguments that were passed to that primitive.  (The first of these arguments is most often the file name itself.)  For example, if you do this:

     (file-exists-p FILENAME)

and FILENAME has handler HANDLER, then HANDLER is called like this:

     (funcall HANDLER 'file-exists-p FILENAME)

When a function takes two or more arguments that must be file names, it checks each of those names for a handler.  For example, if you do this:

     (expand-file-name FILENAME DIRNAME)

then it checks for a handler for FILENAME and then for a handler for DIRNAME.  In either case, the HANDLER is called like this:

     (funcall HANDLER 'expand-file-name FILENAME DIRNAME)

The HANDLER then needs to figure out whether to handle FILENAME or DIRNAME.

If the specified file name matches more than one handler, the one whose match starts last in the file name gets precedence.  This rule is chosen so that handlers for jobs such as uncompression are handled first, before handlers for jobs such as remote file access.

Here are the operations that a magic file name handler gets to handle:

access-file, add-name-to-file, byte-compiler-base-file-name,

copy-file, delete-directory, delete-file, diff-latest-backup-file, directory-file-name, directory-files, directory-files-and-attributes, dired-compress-file, dired-uncache,

expand-file-name, file-accessible-directory-p, file-attributes, file-directory-p, file-executable-p, file-exists-p, file-local-copy, file-remote-p, file-modes, file-name-all-completions, file-name-as-directory, file-name-completion, file-name-directory, file-name-nondirectory, file-name-sans-versions, file-newer-than-file-p, file-ownership-preserved-p, file-readable-p, file-regular-p, file-symlink-p, file-truename, file-writable-p, find-backup-file-name, find-file-noselect,

get-file-buffer, insert-directory, insert-file-contents,

load, make-auto-save-file-name, make-directory, make-directory-internal, make-symbolic-link,

process-file, rename-file, set-file-modes, set-file-times, set-visited-file-modtime, shell-command, start-file-process, substitute-in-file-name,

unhandled-file-name-directory, vc-registered, verify-visited-file-modtime,

write-region.

Handlers for insert-file-contents typically need to clear the buffer's modified flag, with (set-buffer-modified-p nil), if the VISIT argument is non-nil.  This also has the effect of unlocking the buffer if it is locked.

The handler function must handle all of the above operations, and possibly others to be added in the future.  It need not implement all these operations itself---when it has nothing special to do for a certain operation, it can reinvoke the primitive, to handle the operation ``in the usual way.''  It should always reinvoke the primitive for an operation it does not recognize.  Here's one way to do this:

     (defun my-file-handler (operation &rest args)
       ;; First check for the specific operations
       ;; that we have special handling for.
       (cond ((eq operation 'insert-file-contents) ...)
             ((eq operation 'write-region) ...)
             ...
             ;; Handle any operation we don't know about.
             (t (let ((inhibit-file-name-handlers
                       (cons 'my-file-handler
                             (and (eq inhibit-file-name-operation operation)
                                  inhibit-file-name-handlers)))
                      (inhibit-file-name-operation operation))
                  (apply operation args)))))

When a handler function decides to call the ordinary Emacs primitive for the operation at hand, it needs to prevent the primitive from calling the same handler once again, thus leading to an infinite recursion.  The example above shows how to do this, with the variables inhibit-file-name-handlers and inhibit-file-name-operation.  Be careful to use them exactly as shown above; the details are crucial for proper behavior in the case of multiple handlers, and for operations that have two file names that may each have handlers.

Handlers that don't really do anything special for actual access to the file---such as the ones that implement completion of host names for remote file names---should have a non-nil safe-magic property.  For instance, Emacs normally ``protects'' directory names it finds in PATH from becoming magic, if they look like magic file names, by prefixing them with /:.  But if the handler that would be used for them has a non-nil safe-magic property, the /: is not added.

A file name handler can have an operations property to declare which operations it handles in a nontrivial way.  If this property has a non-nil value, it should be a list of operations; then only those operations will call the handler.  This avoids inefficiency, but its main purpose is for autoloaded handler functions, so that they won't be loaded except when they have real work to do.

Simply deferring all operations to the usual primitives does not work.  For instance, if the file name handler applies to file-exists-p, then it must handle load itself, because the usual load code won't work properly in that case.  However, if the handler uses the operations property to say it doesn't handle file-exists-p, then it need not handle load nontrivially.

 -- Variable: inhibit-file-name-handlers
     This variable holds a list of handlers whose use is presently inhibited for a certain operation.

 -- Variable: inhibit-file-name-operation
     The operation for which certain handlers are presently inhibited.

 -- Function: find-file-name-handler file operation
     This function returns the handler function for file name FILE, or nil if there is none.  The argument OPERATION should be the operation to be performed on the file---the value you will pass to the handler as its first argument when you call it.  If OPERATION equals inhibit-file-name-operation, or if it is not found in the operations property of the handler, this function returns nil.

 -- Function: file-local-copy filename
     This function copies file FILENAME to an ordinary non-magic file on the local machine, if it isn't on the local machine already.  Magic file names should handle the file-local-copy operation if they refer to files on other machines.  A magic file name that is used for other purposes than remote file access should not handle file-local-copy; then this function will treat the file as local.

     If FILENAME is local, whether magic or not, this function does nothing and returns nil.  Otherwise it returns the file name of the local copy file.

 -- Function: file-remote-p filename &optional connected
     This function tests whether FILENAME is a remote file.  If FILENAME is local (not remote), the return value is nil. If FILENAME is indeed remote, the return value is a string that identifies the remote system.

     This identifier string can include a host name and a user name, as well as characters designating the method used to access the remote system.  For example, the remote identifier string for the filename /sudo::/some/file is /sudo:root@localhost:.

     If file-remote-p returns the same identifier for two different filenames, that means they are stored on the same file system and can be accessed locally with respect to each other.  This means, for example, that it is possible to start a remote process accessing both files at the same time.  Implementors of file handlers need to ensure this principle is valid.

     The optional parameter CONNECTED, when passed non-nil, triggers an additional check whether the remote system has been connected already.  The function returns then nil if there is no corresponding open connection, even if FILENAME is remote. This can be used to avoid unnecessary connection attempts.

 -- Function: unhandled-file-name-directory filename
     This function returns the name of a directory that is not magic.  It uses the directory part of FILENAME if that is not magic.  For a magic file name, it invokes the file name handler, which therefore decides what value to return.

     This is useful for running a subprocess; every subprocess must have a non-magic directory to serve as its current directory, and this function is a good way to come up with one.

File Format Conversion
======================

Emacs performs several steps to convert the data in a buffer (text, text properties, and possibly other information) to and from a representation suitable for storing into a file.  This section describes the fundamental functions that perform this format conversion, namely insert-file-contents for reading a file into a buffer, and write-region for writing a buffer into a file.

Overview
--------

The function insert-file-contents:

  * initially, inserts bytes from the file into the buffer;

  * decodes bytes to characters as appropriate;

  * processes formats as defined by entries in format-alist; and

  * calls functions in after-insert-file-functions.

The function write-region:

  * initially, calls functions in write-region-annotate-functions;

  * processes formats as defined by entries in format-alist;

  * encodes characters to bytes as appropriate; and

  * modifies the file with the bytes.

This shows the symmetry of the lowest-level operations; reading and writing handle things in opposite order.  The rest of this section describes the two facilities surrounding the three variables named above, as well as some related functions.  Coding Systems, for details on character encoding and decoding.

Round-Trip Specification
------------------------

The most general of the two facilities is controlled by the variable format-alist, a list of file format specifications, which describe textual representations used in files for the data in an Emacs buffer.  The descriptions for reading and writing are paired, which is why we call this ``round-trip'' specification (see Format Conversion Piecemeal, for non-paired specification).

 -- Variable: format-alist
     This list contains one format definition for each defined file format. Each format definition is a list of this form:

          (NAME DOC-STRING REGEXP FROM-FN TO-FN MODIFY MODE-FN)

Here is what the elements in a format definition mean:

name
     The name of this format.

doc-string
     A documentation string for the format.

regexp
     A regular expression which is used to recognize files represented in this format.

from-fn
     A shell command or function to decode data in this format (to convert file data into the usual Emacs data representation).

     A shell command is represented as a string; Emacs runs the command as a filter to perform the conversion.

     If FROM-FN is a function, it is called with two arguments, BEGIN and END, which specify the part of the buffer it should convert. It should convert the text by editing it in place.  Since this can change the length of the text, FROM-FN should return the modified end position.

     One responsibility of FROM-FN is to make sure that the beginning of the file no longer matches REGEXP.  Otherwise it is likely to get called again.

to-fn
     A shell command or function to encode data in this format---that is, to convert the usual Emacs data representation into this format.

     If TO-FN is a string, it is a shell command; Emacs runs the command as a filter to perform the conversion.

     If TO-FN is a function, it is called with three arguments: BEGIN and END, which specify the part of the buffer it should convert, and BUFFER, which specifies which buffer.  There are two ways it can do the conversion:

       * By editing the buffer in place.  In this case, TO-FN should return the end-position of the range of text, as modified.

       * By returning a list of annotations.  This is a list of elements of the form (POSITION . STRING), where POSITION is an integer specifying the relative position in the text to be written, and STRING is the annotation to add there.  The list must be sorted in order of position when TO-FN returns it.

          When write-region actually writes the text from the buffer to the file, it intermixes the specified annotations at the corresponding positions.  All this takes place without modifying the buffer.

modify
     A flag, t if the encoding function modifies the buffer, and nil if it works by returning a list of annotations.

mode-fn
     A minor-mode function to call after visiting a file converted from this format.  The function is called with one argument, the integer 1; that tells a minor-mode function to enable the mode.

The function insert-file-contents automatically recognizes file formats when it reads the specified file.  It checks the text of the beginning of the file against the regular expressions of the format definitions, and if it finds a match, it calls the decoding function for that format.  Then it checks all the known formats over again. It keeps checking them until none of them is applicable.

Visiting a file, with find-file-noselect or the commands that use it, performs conversion likewise (because it calls insert-file-contents); it also calls the mode function for each format that it decodes.  It stores a list of the format names in the buffer-local variable buffer-file-format.

 -- Variable: buffer-file-format
     This variable states the format of the visited file.  More precisely, this is a list of the file format names that were decoded in the course of visiting the current buffer's file.  It is always buffer-local in all buffers.

When write-region writes data into a file, it first calls the encoding functions for the formats listed in buffer-file-format, in the order of appearance in the list.

 -- Command: format-write-file file format &optional confirm
     This command writes the current buffer contents into the file FILE in format FORMAT, and makes that format the default for future saves of the buffer.  The argument FORMAT is a list of format names.  Except for the FORMAT argument, this command is similar to write-file.  In particular, CONFIRM has the same meaning and interactive treatment as the corresponding argument to write-file.  See Definition of write-file.

 -- Command: format-find-file file format
     This command finds the file FILE, converting it according to format FORMAT.  It also makes FORMAT the default if the buffer is saved later.

     The argument FORMAT is a list of format names.  If FORMAT is nil, no conversion takes place.  Interactively, typing just RET for FORMAT specifies nil.

 -- Command: format-insert-file file format &optional beg end
     This command inserts the contents of file FILE, converting it according to format FORMAT.  If BEG and END are non-nil, they specify which part of the file to read, as in insert-file-contents (see Reading from Files).

     The return value is like what insert-file-contents returns: a list of the absolute file name and the length of the data inserted (after conversion).

     The argument FORMAT is a list of format names.  If FORMAT is nil, no conversion takes place.  Interactively, typing just RET for FORMAT specifies nil.

 -- Variable: buffer-auto-save-file-format
     This variable specifies the format to use for auto-saving.  Its value is a list of format names, just like the value of buffer-file-format; however, it is used instead of buffer-file-format for writing auto-save files.  If the value is t, the default, auto-saving uses the same format as a regular save in the same buffer.  This variable is always buffer-local in all buffers.

Piecemeal Specification
-----------------------

In contrast to the round-trip specification described in the previous subsection (see Format Conversion Round-Trip), you can use the variables after-insert-file-functions and write-region-annotate-functions to separately control the respective reading and writing conversions.

Conversion starts with one representation and produces another representation.  When there is only one conversion to do, there is no conflict about what to start with.  However, when there are multiple conversions involved, conflict may arise when two conversions need to start with the same data.

This situation is best understood in the context of converting text properties during write-region.  For example, the character at position 42 in a buffer is X with a text property foo.  If the conversion for foo is done by inserting into the buffer, say, FOO:, then that changes the character at position 42 from X to F.  The next conversion will start with the wrong data straight away.

To avoid conflict, cooperative conversions do not modify the buffer, but instead specify annotations, a list of elements of the form (POSITION . STRING), sorted in order of increasing POSITION.

If there is more than one conversion, write-region merges their annotations destructively into one sorted list.  Later, when the text from the buffer is actually written to the file, it intermixes the specified annotations at the corresponding positions.  All this takes place without modifying the buffer.

In contrast, when reading, the annotations intermixed with the text are handled immediately.  insert-file-contents sets point to the beginning of some text to be converted, then calls the conversion functions with the length of that text.  These functions should always return with point at the beginning of the inserted text.  This approach makes sense for reading because annotations removed by the first converter can't be mistakenly processed by a later converter.

Each conversion function should scan for the annotations it recognizes, remove the annotation, modify the buffer text (to set a text property, for example), and return the updated length of the text, as it stands after those changes.  The value returned by one function becomes the argument to the next function.

 -- Variable: write-region-annotate-functions
     A list of functions for write-region to call.  Each function in the list is called with two arguments: the start and end of the region to be written.  These functions should not alter the contents of the buffer.  Instead, they should return annotations.

     As a special case, if a function returns with a different buffer current, Emacs takes it to mean the current buffer contains altered text to be output, and discards all previous annotations because they should have been dealt with by this function.

 -- Variable: after-insert-file-functions
     Each function in this list is called by insert-file-contents with one argument, the number of characters inserted, and with point at the beginning of the inserted text.  Each function should leave point unchanged, and return the new character count describing the inserted text as modified by the function.

We invite users to write Lisp programs to store and retrieve text properties in files, using these hooks, and thus to experiment with various data formats and find good ones.  Eventually we hope users will produce good, general extensions we can install in Emacs.

We suggest not trying to handle arbitrary Lisp objects as text property names or values---because a program that general is probably difficult to write, and slow.  Instead, choose a set of possible data types that are reasonably flexible, and not too hard to encode.