lisp/emacs-lisp/lisp-mode.el

   1 ;;; lisp-mode.el --- Lisp mode, and its idiosyncratic commands.
   2
   3 ;; Copyright (C) 1985, 1986 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, languages
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; The base major mode for editing Lisp code (used also for Emacs Lisp).
  28 ;; This mode is documented in the Emacs manual
  29
  30 ;;; Code:
  31
  32 (defvar lisp-mode-syntax-table nil "")
  33 (defvar emacs-lisp-mode-syntax-table nil "")
  34 (defvar lisp-mode-abbrev-table nil "")
  35
  36 (if (not emacs-lisp-mode-syntax-table)
  37     (let ((i 0))
  38       (setq emacs-lisp-mode-syntax-table (make-syntax-table))
  39       (while (< i ?0)
  40         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  41         (setq i (1+ i)))
  42       (setq i (1+ ?9))
  43       (while (< i ?A)
  44         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  45         (setq i (1+ i)))
  46       (setq i (1+ ?Z))
  47       (while (< i ?a)
  48         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  49         (setq i (1+ i)))
  50       (setq i (1+ ?z))
  51       (while (< i 128)
  52         (modify-syntax-entry i "_   " emacs-lisp-mode-syntax-table)
  53         (setq i (1+ i)))
  54       (modify-syntax-entry ?  "    " emacs-lisp-mode-syntax-table)
  55       (modify-syntax-entry ?\t "    " emacs-lisp-mode-syntax-table)
  56       (modify-syntax-entry ?\f "    " emacs-lisp-mode-syntax-table)
  57       (modify-syntax-entry ?\n ">   " emacs-lisp-mode-syntax-table)
  58       ;; Give CR the same syntax as newline, for selective-display.
  59       (modify-syntax-entry ?\^m ">   " emacs-lisp-mode-syntax-table)
  60       (modify-syntax-entry ?\; "<   " emacs-lisp-mode-syntax-table)
  61       (modify-syntax-entry ?` "'   " emacs-lisp-mode-syntax-table)
  62       (modify-syntax-entry ?' "'   " emacs-lisp-mode-syntax-table)
  63       (modify-syntax-entry ?, "'   " emacs-lisp-mode-syntax-table)
  64       ;; Used to be singlequote; changed for flonums.
  65       (modify-syntax-entry ?. "_   " emacs-lisp-mode-syntax-table)
  66       (modify-syntax-entry ?# "'   " emacs-lisp-mode-syntax-table)
  67       (modify-syntax-entry ?\" "\"    " emacs-lisp-mode-syntax-table)
  68       (modify-syntax-entry ?\\ "\\   " emacs-lisp-mode-syntax-table)
  69       (modify-syntax-entry ?\( "()  " emacs-lisp-mode-syntax-table)
  70       (modify-syntax-entry ?\) ")(  " emacs-lisp-mode-syntax-table)
  71       (modify-syntax-entry ?\[ "(]  " emacs-lisp-mode-syntax-table)
  72       (modify-syntax-entry ?\] ")[  " emacs-lisp-mode-syntax-table)))
  73
  74 (if (not lisp-mode-syntax-table)
  75     (progn (setq lisp-mode-syntax-table
  76                  (copy-syntax-table emacs-lisp-mode-syntax-table))
  77            (modify-syntax-entry ?\| "\"   " lisp-mode-syntax-table)
  78            (modify-syntax-entry ?\[ "_   " lisp-mode-syntax-table)
  79            (modify-syntax-entry ?\] "_   " lisp-mode-syntax-table)))
  80
  81 (define-abbrev-table 'lisp-mode-abbrev-table ())
  82
  83 (defvar lisp-imenu-generic-expression
  84       '(
  85         (nil
  86          "^\\s-*(def\\(un\\|subst\\|macro\\|advice\\)\\s-+\\([-A-Za-z0-9+*|:/]+\\)" 2)
  87         ("Variables"
  88          "^\\s-*(def\\(var\\|const\\|custom\\)\\s-+\\([-A-Za-z0-9+*|:/]+\\)" 2)
  89         ("Types"
  90          "^\\s-*(def\\(group\\|type\\|struct\\|class\\|ine-condition\\)\\s-+\\([-A-Za-z0-9+*|:/]+\\)"
  91          2))
  92
  93   "Imenu generic expression for Lisp mode.  See `imenu-generic-expression'.")
  94
  95 (defun lisp-mode-variables (lisp-syntax)
  96   (cond (lisp-syntax
  97           (set-syntax-table lisp-mode-syntax-table)))
  98   (setq local-abbrev-table lisp-mode-abbrev-table)
  99   (make-local-variable 'paragraph-start)
 100   (setq paragraph-start (concat page-delimiter "\\|$" ))
 101   (make-local-variable 'paragraph-separate)
 102   (setq paragraph-separate paragraph-start)
 103   (make-local-variable 'paragraph-ignore-fill-prefix)
 104   (setq paragraph-ignore-fill-prefix t)
 105   (make-local-variable 'fill-paragraph-function)
 106   (setq fill-paragraph-function 'lisp-fill-paragraph)
 107   ;; Adaptive fill mode gets in the way of auto-fill,
 108   ;; and should make no difference for explicit fill
 109   ;; because lisp-fill-paragraph should do the job.
 110   (make-local-variable 'adaptive-fill-mode)
 111   (setq adaptive-fill-mode nil)
 112   (make-local-variable 'indent-line-function)
 113   (setq indent-line-function 'lisp-indent-line)
 114   (make-local-variable 'indent-region-function)
 115   (setq indent-region-function 'lisp-indent-region)
 116   (make-local-variable 'parse-sexp-ignore-comments)
 117   (setq parse-sexp-ignore-comments t)
 118   (make-local-variable 'outline-regexp)
 119   (setq outline-regexp ";;; \\|(....")
 120   (make-local-variable 'comment-start)
 121   (setq comment-start ";")
 122   (make-local-variable 'comment-start-skip)
 123   ;; Look within the line for a ; following an even number of backslashes
 124   ;; after either a non-backslash or the line beginning.
 125   (setq comment-start-skip "\\(\\(^\\|[^\\\\\n]\\)\\(\\\\\\\\\\)*\\);+ *")
 126   (make-local-variable 'comment-column)
 127   (setq comment-column 40)
 128   (make-local-variable 'comment-indent-function)
 129   (setq comment-indent-function 'lisp-comment-indent)
 130   (make-local-variable 'imenu-generic-expression)
 131   (setq imenu-generic-expression lisp-imenu-generic-expression))
 132 \f
 133 (defvar shared-lisp-mode-map ()
 134   "Keymap for commands shared by all sorts of Lisp modes.")
 135
 136 (if shared-lisp-mode-map
 137     ()
 138    (setq shared-lisp-mode-map (make-sparse-keymap))
 139    (define-key shared-lisp-mode-map "\e\C-q" 'indent-sexp)
 140    (define-key shared-lisp-mode-map "\177" 'backward-delete-char-untabify))
 141
 142 (defvar emacs-lisp-mode-map ()
 143   "Keymap for Emacs Lisp mode.
 144 All commands in `shared-lisp-mode-map' are inherited by this map.")
 145
 146 (if emacs-lisp-mode-map
 147     ()
 148   (let ((map (make-sparse-keymap "Emacs-Lisp")))
 149     (setq emacs-lisp-mode-map
 150           (nconc (make-sparse-keymap) shared-lisp-mode-map))
 151     (define-key emacs-lisp-mode-map "\e\t" 'lisp-complete-symbol)
 152     (define-key emacs-lisp-mode-map "\e\C-x" 'eval-defun)
 153     (define-key emacs-lisp-mode-map [menu-bar] (make-sparse-keymap))
 154     (define-key emacs-lisp-mode-map [menu-bar emacs-lisp]
 155       (cons "Emacs-Lisp" map))
 156     (define-key map [edebug-defun]
 157       '("Instrument Function for Debugging" . edebug-defun))
 158     (define-key map [byte-recompile]
 159       '("Byte-recompile Directory..." . byte-recompile-directory))
 160     (define-key map [emacs-byte-compile-and-load]
 161       '("Byte-compile And Load" . emacs-lisp-byte-compile-and-load))
 162     (define-key map [byte-compile]
 163       '("Byte-compile This File" . emacs-lisp-byte-compile))
 164     (define-key map [separator-eval] '("--"))
 165     (define-key map [eval-buffer] '("Evaluate Buffer" . eval-current-buffer))
 166     (define-key map [eval-region] '("Evaluate Region" . eval-region))
 167     (define-key map [eval-sexp] '("Evaluate Last S-expression" . eval-last-sexp))
 168     (define-key map [separator-format] '("--"))
 169     (define-key map [comment-region] '("Comment Out Region" . comment-region))
 170     (define-key map [indent-region] '("Indent Region" . indent-region))
 171     (define-key map [indent-line] '("Indent Line" . lisp-indent-line))
 172     (put 'eval-region 'menu-enable 'mark-active)
 173     (put 'comment-region 'menu-enable 'mark-active)
 174     (put 'indent-region 'menu-enable 'mark-active)))
 175
 176 (defun emacs-lisp-byte-compile ()
 177   "Byte compile the file containing the current buffer."
 178   (interactive)
 179   (if buffer-file-name
 180       (byte-compile-file buffer-file-name)
 181     (error "The buffer must be saved in a file first")))
 182
 183 (defun emacs-lisp-byte-compile-and-load ()
 184   "Byte-compile the current file (if it has changed), then load compiled code."
 185   (interactive)
 186   (or buffer-file-name
 187       (error "The buffer must be saved in a file first"))
 188   (require 'bytecomp)
 189   ;; Recompile if file or buffer has changed since last compilation.
 190   (if (and (buffer-modified-p)
 191            (y-or-n-p (format "save buffer %s first? " (buffer-name))))
 192       (save-buffer))
 193   (let ((compiled-file-name (byte-compile-dest-file buffer-file-name)))
 194     (if (file-newer-than-file-p compiled-file-name buffer-file-name)
 195         (load-file compiled-file-name)
 196       (byte-compile-file buffer-file-name t))))
 197
 198 (defun emacs-lisp-mode ()
 199   "Major mode for editing Lisp code to run in Emacs.
 200 Commands:
 201 Delete converts tabs to spaces as it moves back.
 202 Blank lines separate paragraphs.  Semicolons start comments.
 203 \\{emacs-lisp-mode-map}
 204 Entry to this mode calls the value of `emacs-lisp-mode-hook'
 205 if that value is non-nil."
 206   (interactive)
 207   (kill-all-local-variables)
 208   (use-local-map emacs-lisp-mode-map)
 209   (set-syntax-table emacs-lisp-mode-syntax-table)
 210   (setq major-mode 'emacs-lisp-mode)
 211   (setq mode-name "Emacs-Lisp")
 212   (lisp-mode-variables nil)
 213   (run-hooks 'emacs-lisp-mode-hook))
 214
 215 (defvar lisp-mode-map ()
 216   "Keymap for ordinary Lisp mode.
 217 All commands in `shared-lisp-mode-map' are inherited by this map.")
 218
 219 (if lisp-mode-map
 220     ()
 221   (setq lisp-mode-map
 222         (nconc (make-sparse-keymap) shared-lisp-mode-map))
 223   (define-key lisp-mode-map "\e\C-x" 'lisp-eval-defun)
 224   (define-key lisp-mode-map "\C-c\C-z" 'run-lisp))
 225
 226 (defun lisp-mode ()
 227   "Major mode for editing Lisp code for Lisps other than GNU Emacs Lisp.
 228 Commands:
 229 Delete converts tabs to spaces as it moves back.
 230 Blank lines separate paragraphs.  Semicolons start comments.
 231 \\{lisp-mode-map}
 232 Note that `run-lisp' may be used either to start an inferior Lisp job
 233 or to switch back to an existing one.
 234
 235 Entry to this mode calls the value of `lisp-mode-hook'
 236 if that value is non-nil."
 237   (interactive)
 238   (kill-all-local-variables)
 239   (use-local-map lisp-mode-map)
 240   (setq major-mode 'lisp-mode)
 241   (setq mode-name "Lisp")
 242   (lisp-mode-variables t)
 243   (set-syntax-table lisp-mode-syntax-table)
 244   (run-hooks 'lisp-mode-hook))
 245
 246 ;; This will do unless shell.el is loaded.
 247 (defun lisp-eval-defun nil
 248   "Send the current defun to the Lisp process made by \\[run-lisp]."
 249   (interactive)
 250   (error "Process lisp does not exist"))
 251
 252 (defvar lisp-interaction-mode-map ()
 253   "Keymap for Lisp Interaction moe.
 254 All commands in `shared-lisp-mode-map' are inherited by this map.")
 255
 256 (if lisp-interaction-mode-map
 257     ()
 258   (setq lisp-interaction-mode-map
 259         (nconc (make-sparse-keymap) shared-lisp-mode-map))
 260   (define-key lisp-interaction-mode-map "\e\C-x" 'eval-defun)
 261   (define-key lisp-interaction-mode-map "\e\t" 'lisp-complete-symbol)
 262   (define-key lisp-interaction-mode-map "\n" 'eval-print-last-sexp))
 263
 264 (defun lisp-interaction-mode ()
 265   "Major mode for typing and evaluating Lisp forms.
 266 Like Lisp mode except that \\[eval-print-last-sexp] evals the Lisp expression
 267 before point, and prints its value into the buffer, advancing point.
 268
 269 Commands:
 270 Delete converts tabs to spaces as it moves back.
 271 Paragraphs are separated only by blank lines.
 272 Semicolons start comments.
 273 \\{lisp-interaction-mode-map}
 274 Entry to this mode calls the value of `lisp-interaction-mode-hook'
 275 if that value is non-nil."
 276   (interactive)
 277   (kill-all-local-variables)
 278   (use-local-map lisp-interaction-mode-map)
 279   (setq major-mode 'lisp-interaction-mode)
 280   (setq mode-name "Lisp Interaction")
 281   (set-syntax-table emacs-lisp-mode-syntax-table)
 282   (lisp-mode-variables nil)
 283   (run-hooks 'lisp-interaction-mode-hook))
 284
 285 (defun eval-print-last-sexp ()
 286   "Evaluate sexp before point; print value into current buffer."
 287   (interactive)
 288   (let ((standard-output (current-buffer)))
 289     (terpri)
 290     (eval-last-sexp t)
 291     (terpri)))
 292 \f
 293 (defun eval-last-sexp (eval-last-sexp-arg-internal)
 294   "Evaluate sexp before point; print value in minibuffer.
 295 With argument, print output into current buffer."
 296   (interactive "P")
 297   (let ((standard-output (if eval-last-sexp-arg-internal (current-buffer) t)))
 298     (prin1 (eval (let ((stab (syntax-table))
 299                        (opoint (point))
 300                        ignore-quotes
 301                        expr)
 302                    (unwind-protect
 303                        (save-excursion
 304                          (set-syntax-table emacs-lisp-mode-syntax-table)
 305                          ;; If this sexp appears to be enclosed in `...'
 306                          ;; then ignore the surrounding quotes.
 307                          (setq ignore-quotes
 308                                (or (eq (following-char) ?\')
 309                                    (eq (preceding-char) ?\')))
 310                          (forward-sexp -1)
 311                          (save-restriction
 312                            ;; vladimir@cs.ualberta.ca 30-Jul-1997: skip ` in
 313                            ;; `variable' so that the value is returned, not the
 314                            ;; name
 315                            (if (and ignore-quotes
 316                                     (eq (following-char) ?`))
 317                                (forward-char))
 318                            (narrow-to-region (point-min) opoint)
 319                            (setq expr (read (current-buffer)))
 320                            ;; If it's an (interactive ...) form, it's more
 321                            ;; useful to show how an interactive call would
 322                            ;; use it.
 323                            (and (consp expr)
 324                                 (eq (car expr) 'interactive)
 325                                 (setq expr
 326                                       (list 'call-interactively
 327                                             (list 'quote
 328                                                   (list 'lambda
 329                                                         '(&rest args)
 330                                                         expr
 331                                                         'args)))))
 332                            expr))
 333                      (set-syntax-table stab)))))))
 334
 335 (defun eval-defun (eval-defun-arg-internal)
 336   "Evaluate defun that point is in or before.
 337 Print value in minibuffer.
 338 With argument, insert value in current buffer after the defun."
 339   (interactive "P")
 340   (let ((standard-output (if eval-defun-arg-internal (current-buffer) t))
 341         (form (save-excursion
 342                 (end-of-defun)
 343                 (beginning-of-defun)
 344                 (read (current-buffer)))))
 345     (cond ((and (eq (car form) 'defvar)
 346                 (cdr-safe (cdr-safe form)))
 347            ;; Force variable to be bound.
 348            (setq form (cons 'defconst (cdr form))))
 349           ((and (eq (car form) 'defcustom)
 350                 (default-boundp (nth 1 form)))
 351            ;; Force variable to be bound.
 352            (set-default (nth 1 form) (eval (nth 2 form)))))
 353     (prin1 (eval form))))
 354 \f
 355 (defun lisp-comment-indent ()
 356   (if (looking-at "\\s<\\s<\\s<")
 357       (current-column)
 358     (if (looking-at "\\s<\\s<")
 359         (let ((tem (or (calculate-lisp-indent) (current-column))))
 360           (if (listp tem) (car tem) tem))
 361       (skip-chars-backward " \t")
 362       (max (if (bolp) 0 (1+ (current-column)))
 363            comment-column))))
 364
 365 (defvar lisp-indent-offset nil "")
 366 (defvar lisp-indent-function 'lisp-indent-function "")
 367
 368 (defun lisp-indent-line (&optional whole-exp)
 369   "Indent current line as Lisp code.
 370 With argument, indent any additional lines of the same expression
 371 rigidly along with this one."
 372   (interactive "P")
 373   (let ((indent (calculate-lisp-indent)) shift-amt beg end
 374         (pos (- (point-max) (point))))
 375     (beginning-of-line)
 376     (setq beg (point))
 377     (skip-chars-forward " \t")
 378     (if (or (null indent) (looking-at "\\s<\\s<\\s<"))
 379         ;; Don't alter indentation of a ;;; comment line
 380         ;; or a line that starts in a string.
 381         (goto-char (- (point-max) pos))
 382       (if (and (looking-at "\\s<") (not (looking-at "\\s<\\s<")))
 383           ;; Single-semicolon comment lines should be indented
 384           ;; as comment lines, not as code.
 385           (progn (indent-for-comment) (forward-char -1))
 386         (if (listp indent) (setq indent (car indent)))
 387         (setq shift-amt (- indent (current-column)))
 388         (if (zerop shift-amt)
 389             nil
 390           (delete-region beg (point))
 391           (indent-to indent)))
 392       ;; If initial point was within line's indentation,
 393       ;; position after the indentation.  Else stay at same point in text.
 394       (if (> (- (point-max) pos) (point))
 395           (goto-char (- (point-max) pos)))
 396       ;; If desired, shift remaining lines of expression the same amount.
 397       (and whole-exp (not (zerop shift-amt))
 398            (save-excursion
 399              (goto-char beg)
 400              (forward-sexp 1)
 401              (setq end (point))
 402              (goto-char beg)
 403              (forward-line 1)
 404              (setq beg (point))
 405              (> end beg))
 406            (indent-code-rigidly beg end shift-amt)))))
 407
 408 (defvar calculate-lisp-indent-last-sexp)
 409
 410 (defun calculate-lisp-indent (&optional parse-start)
 411   "Return appropriate indentation for current line as Lisp code.
 412 In usual case returns an integer: the column to indent to.
 413 If the value is nil, that means don't change the indentation
 414 because the line starts inside a string.
 415
 416 The value can also be a list of the form (COLUMN CONTAINING-SEXP-START).
 417 This means that following lines at the same level of indentation
 418 should not necessarily be indented the same as this line.
 419 Then COLUMN is the column to indent to, and CONTAINING-SEXP-START
 420 is the buffer position of the start of the containing expression."
 421   (save-excursion
 422     (beginning-of-line)
 423     (let ((indent-point (point))
 424           state paren-depth
 425           ;; setting this to a number inhibits calling hook
 426           (desired-indent nil)
 427           (retry t)
 428           calculate-lisp-indent-last-sexp containing-sexp)
 429       (if parse-start
 430           (goto-char parse-start)
 431           (beginning-of-defun))
 432       ;; Find outermost containing sexp
 433       (while (< (point) indent-point)
 434         (setq state (parse-partial-sexp (point) indent-point 0)))
 435       ;; Find innermost containing sexp
 436       (while (and retry
 437                   state
 438                   (> (setq paren-depth (elt state 0)) 0))
 439         (setq retry nil)
 440         (setq calculate-lisp-indent-last-sexp (elt state 2))
 441         (setq containing-sexp (elt state 1))
 442         ;; Position following last unclosed open.
 443         (goto-char (1+ containing-sexp))
 444         ;; Is there a complete sexp since then?
 445         (if (and calculate-lisp-indent-last-sexp
 446                  (> calculate-lisp-indent-last-sexp (point)))
 447             ;; Yes, but is there a containing sexp after that?
 448             (let ((peek (parse-partial-sexp calculate-lisp-indent-last-sexp
 449                                             indent-point 0)))
 450               (if (setq retry (car (cdr peek))) (setq state peek)))))
 451       (if retry
 452           nil
 453         ;; Innermost containing sexp found
 454         (goto-char (1+ containing-sexp))
 455         (if (not calculate-lisp-indent-last-sexp)
 456             ;; indent-point immediately follows open paren.
 457             ;; Don't call hook.
 458             (setq desired-indent (current-column))
 459           ;; Find the start of first element of containing sexp.
 460           (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
 461           (cond ((looking-at "\\s(")
 462                  ;; First element of containing sexp is a list.
 463                  ;; Indent under that list.
 464                  )
 465                 ((> (save-excursion (forward-line 1) (point))
 466                     calculate-lisp-indent-last-sexp)
 467                  ;; This is the first line to start within the containing sexp.
 468                  ;; It's almost certainly a function call.
 469                  (if (= (point) calculate-lisp-indent-last-sexp)
 470                      ;; Containing sexp has nothing before this line
 471                      ;; except the first element.  Indent under that element.
 472                      nil
 473                    ;; Skip the first element, find start of second (the first
 474                    ;; argument of the function call) and indent under.
 475                    (progn (forward-sexp 1)
 476                           (parse-partial-sexp (point)
 477                                               calculate-lisp-indent-last-sexp
 478                                               0 t)))
 479                  (backward-prefix-chars))
 480                 (t
 481                  ;; Indent beneath first sexp on same line as
 482                  ;; calculate-lisp-indent-last-sexp.  Again, it's
 483                  ;; almost certainly a function call.
 484                  (goto-char calculate-lisp-indent-last-sexp)
 485                  (beginning-of-line)
 486                  (parse-partial-sexp (point) calculate-lisp-indent-last-sexp
 487                                      0 t)
 488                  (backward-prefix-chars)))))
 489       ;; Point is at the point to indent under unless we are inside a string.
 490       ;; Call indentation hook except when overridden by lisp-indent-offset
 491       ;; or if the desired indentation has already been computed.
 492       (let ((normal-indent (current-column)))
 493         (cond ((elt state 3)
 494                ;; Inside a string, don't change indentation.
 495                nil)
 496               ((and (integerp lisp-indent-offset) containing-sexp)
 497                ;; Indent by constant offset
 498                (goto-char containing-sexp)
 499                (+ (current-column) lisp-indent-offset))
 500               (desired-indent)
 501               ((and (boundp 'lisp-indent-function)
 502                     lisp-indent-function
 503                     (not retry))
 504                (or (funcall lisp-indent-function indent-point state)
 505                    normal-indent))
 506               (t
 507                normal-indent))))))
 508
 509 (defun lisp-indent-function (indent-point state)
 510   (let ((normal-indent (current-column)))
 511     (goto-char (1+ (elt state 1)))
 512     (parse-partial-sexp (point) calculate-lisp-indent-last-sexp 0 t)
 513     (if (and (elt state 2)
 514              (not (looking-at "\\sw\\|\\s_")))
 515         ;; car of form doesn't seem to be a a symbol
 516         (progn
 517           (if (not (> (save-excursion (forward-line 1) (point))
 518                       calculate-lisp-indent-last-sexp))
 519               (progn (goto-char calculate-lisp-indent-last-sexp)
 520                      (beginning-of-line)
 521                      (parse-partial-sexp (point)
 522                                          calculate-lisp-indent-last-sexp 0 t)))
 523           ;; Indent under the list or under the first sexp on the same
 524           ;; line as calculate-lisp-indent-last-sexp.  Note that first
 525           ;; thing on that line has to be complete sexp since we are
 526           ;; inside the innermost containing sexp.
 527           (backward-prefix-chars)
 528           (current-column))
 529       (let ((function (buffer-substring (point)
 530                                         (progn (forward-sexp 1) (point))))
 531             method)
 532         (setq method (or (get (intern-soft function) 'lisp-indent-function)
 533                          (get (intern-soft function) 'lisp-indent-hook)))
 534         (cond ((or (eq method 'defun)
 535                    (and (null method)
 536                         (> (length function) 3)
 537                         (string-match "\\`def" function)))
 538                (lisp-indent-defform state indent-point))
 539               ((integerp method)
 540                (lisp-indent-specform method state
 541                                      indent-point normal-indent))
 542               (method
 543                 (funcall method state indent-point)))))))
 544
 545 (defvar lisp-body-indent 2
 546   "Number of columns to indent the second line of a `(def...)' form.")
 547
 548 (defun lisp-indent-specform (count state indent-point normal-indent)
 549   (let ((containing-form-start (elt state 1))
 550         (i count)
 551         body-indent containing-form-column)
 552     ;; Move to the start of containing form, calculate indentation
 553     ;; to use for non-distinguished forms (> count), and move past the
 554     ;; function symbol.  lisp-indent-function guarantees that there is at
 555     ;; least one word or symbol character following open paren of containing
 556     ;; form.
 557     (goto-char containing-form-start)
 558     (setq containing-form-column (current-column))
 559     (setq body-indent (+ lisp-body-indent containing-form-column))
 560     (forward-char 1)
 561     (forward-sexp 1)
 562     ;; Now find the start of the last form.
 563     (parse-partial-sexp (point) indent-point 1 t)
 564     (while (and (< (point) indent-point)
 565                 (condition-case ()
 566                     (progn
 567                       (setq count (1- count))
 568                       (forward-sexp 1)
 569                       (parse-partial-sexp (point) indent-point 1 t))
 570                   (error nil))))
 571     ;; Point is sitting on first character of last (or count) sexp.
 572     (if (> count 0)
 573         ;; A distinguished form.  If it is the first or second form use double
 574         ;; lisp-body-indent, else normal indent.  With lisp-body-indent bound
 575         ;; to 2 (the default), this just happens to work the same with if as
 576         ;; the older code, but it makes unwind-protect, condition-case,
 577         ;; with-output-to-temp-buffer, et. al. much more tasteful.  The older,
 578         ;; less hacked, behavior can be obtained by replacing below with
 579         ;; (list normal-indent containing-form-start).
 580         (if (<= (- i count) 1)
 581             (list (+ containing-form-column (* 2 lisp-body-indent))
 582                   containing-form-start)
 583             (list normal-indent containing-form-start))
 584       ;; A non-distinguished form.  Use body-indent if there are no
 585       ;; distinguished forms and this is the first undistinguished form,
 586       ;; or if this is the first undistinguished form and the preceding
 587       ;; distinguished form has indentation at least as great as body-indent.
 588       (if (or (and (= i 0) (= count 0))
 589               (and (= count 0) (<= body-indent normal-indent)))
 590           body-indent
 591           normal-indent))))
 592
 593 (defun lisp-indent-defform (state indent-point)
 594   (goto-char (car (cdr state)))
 595   (forward-line 1)
 596   (if (> (point) (car (cdr (cdr state))))
 597       (progn
 598         (goto-char (car (cdr state)))
 599         (+ lisp-body-indent (current-column)))))
 600
 601 \f
 602 ;; (put 'progn 'lisp-indent-function 0), say, causes progn to be indented
 603 ;; like defun if the first form is placed on the next line, otherwise
 604 ;; it is indented like any other form (i.e. forms line up under first).
 605
 606 (put 'lambda 'lisp-indent-function 'defun)
 607 (put 'autoload 'lisp-indent-function 'defun)
 608 (put 'progn 'lisp-indent-function 0)
 609 (put 'prog1 'lisp-indent-function 1)
 610 (put 'prog2 'lisp-indent-function 2)
 611 (put 'save-excursion 'lisp-indent-function 0)
 612 (put 'save-window-excursion 'lisp-indent-function 0)
 613 (put 'save-selected-window 'lisp-indent-function 0)
 614 (put 'save-restriction 'lisp-indent-function 0)
 615 (put 'save-match-data 'lisp-indent-function 0)
 616 (put 'save-current-buffer 'lisp-indent-function 0)
 617 (put 'with-current-buffer 'lisp-indent-function 1)
 618 (put 'combine-after-change-calls 'lisp-indent-function 0)
 619 (put 'with-output-to-string 'lisp-indent-function 0)
 620 (put 'with-temp-file 'lisp-indent-function 1)
 621 (put 'with-temp-buffer 'lisp-indent-function 0)
 622 (put 'let 'lisp-indent-function 1)
 623 (put 'let* 'lisp-indent-function 1)
 624 (put 'while 'lisp-indent-function 1)
 625 (put 'if 'lisp-indent-function 2)
 626 (put 'catch 'lisp-indent-function 1)
 627 (put 'condition-case 'lisp-indent-function 2)
 628 (put 'unwind-protect 'lisp-indent-function 1)
 629 (put 'with-output-to-temp-buffer 'lisp-indent-function 1)
 630 (put 'eval-after-load 'lisp-indent-function 1)
 631
 632 (defun indent-sexp (&optional endpos)
 633   "Indent each line of the list starting just after point.
 634 If optional arg ENDPOS is given, indent each line, stopping when
 635 ENDPOS is encountered."
 636   (interactive)
 637   (let ((indent-stack (list nil))
 638         (next-depth 0)
 639         ;; If ENDPOS is non-nil, use nil as STARTING-POINT
 640         ;; so that calculate-lisp-indent will find the beginning of
 641         ;; the defun we are in.
 642         ;; If ENDPOS is nil, it is safe not to scan before point
 643         ;; since every line we indent is more deeply nested than point is.
 644         (starting-point (if endpos nil (point)))
 645         (last-point (point))
 646         last-depth bol outer-loop-done inner-loop-done state this-indent)
 647     (or endpos
 648         ;; Get error now if we don't have a complete sexp after point.
 649         (save-excursion (forward-sexp 1)))
 650     (save-excursion
 651       (setq outer-loop-done nil)
 652       (while (if endpos (< (point) endpos)
 653                (not outer-loop-done))
 654         (setq last-depth next-depth
 655               inner-loop-done nil)
 656         ;; Parse this line so we can learn the state
 657         ;; to indent the next line.
 658         ;; This inner loop goes through only once
 659         ;; unless a line ends inside a string.
 660         (while (and (not inner-loop-done)
 661                     (not (setq outer-loop-done (eobp))))
 662           (setq state (parse-partial-sexp (point) (progn (end-of-line) (point))
 663                                           nil nil state))
 664           (setq next-depth (car state))
 665           ;; If the line contains a comment other than the sort
 666           ;; that is indented like code,
 667           ;; indent it now with indent-for-comment.
 668           ;; Comments indented like code are right already.
 669           ;; In any case clear the in-comment flag in the state
 670           ;; because parse-partial-sexp never sees the newlines.
 671           (if (car (nthcdr 4 state))
 672               (progn (indent-for-comment)
 673                      (end-of-line)
 674                      (setcar (nthcdr 4 state) nil)))
 675           ;; If this line ends inside a string,
 676           ;; go straight to next line, remaining within the inner loop,
 677           ;; and turn off the \-flag.
 678           (if (car (nthcdr 3 state))
 679               (progn
 680                 (forward-line 1)
 681                 (setcar (nthcdr 5 state) nil))
 682             (setq inner-loop-done t)))
 683         (and endpos
 684              (<= next-depth 0)
 685              (progn
 686                (setq indent-stack (append indent-stack
 687                                           (make-list (- next-depth) nil))
 688                      last-depth (- last-depth next-depth)
 689                      next-depth 0)))
 690         (or outer-loop-done endpos
 691             (setq outer-loop-done (<= next-depth 0)))
 692         (if outer-loop-done
 693             (forward-line 1)
 694           (while (> last-depth next-depth)
 695             (setq indent-stack (cdr indent-stack)
 696                   last-depth (1- last-depth)))
 697           (while (< last-depth next-depth)
 698             (setq indent-stack (cons nil indent-stack)
 699                   last-depth (1+ last-depth)))
 700           ;; Now go to the next line and indent it according
 701           ;; to what we learned from parsing the previous one.
 702           (forward-line 1)
 703           (setq bol (point))
 704           (skip-chars-forward " \t")
 705           ;; But not if the line is blank, or just a comment
 706           ;; (except for double-semi comments; indent them as usual).
 707           (if (or (eobp) (looking-at "\\s<\\|\n"))
 708               nil
 709             (if (and (car indent-stack)
 710                      (>= (car indent-stack) 0))
 711                 (setq this-indent (car indent-stack))
 712               (let ((val (calculate-lisp-indent
 713                           (if (car indent-stack) (- (car indent-stack))
 714                             starting-point))))
 715                 (if (null val)
 716                     (setq this-indent val)
 717                   (if (integerp val)
 718                       (setcar indent-stack
 719                               (setq this-indent val))
 720                     (setcar indent-stack (- (car (cdr val))))
 721                     (setq this-indent (car val))))))
 722             (if (and this-indent (/= (current-column) this-indent))
 723                 (progn (delete-region bol (point))
 724                        (indent-to this-indent)))))
 725         (or outer-loop-done
 726             (setq outer-loop-done (= (point) last-point))
 727             (setq last-point (point)))))))
 728
 729 ;; Indent every line whose first char is between START and END inclusive.
 730 (defun lisp-indent-region (start end)
 731   (save-excursion
 732     (let ((endmark (copy-marker end)))
 733       (goto-char start)
 734       (and (bolp) (not (eolp))
 735            (lisp-indent-line))
 736       (indent-sexp endmark)
 737       (set-marker endmark nil))))
 738 \f
 739 ;;;; Lisp paragraph filling commands.
 740
 741 (defun lisp-fill-paragraph (&optional justify)
 742   "Like \\[fill-paragraph], but handle Emacs Lisp comments.
 743 If any of the current line is a comment, fill the comment or the
 744 paragraph of it that point is in, preserving the comment's indentation
 745 and initial semicolons."
 746   (interactive "P")
 747   (let (
 748         ;; Non-nil if the current line contains a comment.
 749         has-comment
 750
 751         ;; Non-nil if the current line contains code and a comment.
 752         has-code-and-comment
 753
 754         ;; If has-comment, the appropriate fill-prefix for the comment.
 755         comment-fill-prefix
 756         )
 757
 758     ;; Figure out what kind of comment we are looking at.
 759     (save-excursion
 760       (beginning-of-line)
 761       (cond
 762
 763        ;; A line with nothing but a comment on it?
 764        ((looking-at "[ \t]*;[; \t]*")
 765         (setq has-comment t
 766               comment-fill-prefix (buffer-substring (match-beginning 0)
 767                                                     (match-end 0))))
 768
 769        ;; A line with some code, followed by a comment?  Remember that the
 770        ;; semi which starts the comment shouldn't be part of a string or
 771        ;; character.
 772        ((condition-case nil
 773             (save-restriction
 774               (narrow-to-region (point-min)
 775                                 (save-excursion (end-of-line) (point)))
 776               (while (not (looking-at ";\\|$"))
 777                 (skip-chars-forward "^;\n\"\\\\?")
 778                 (cond
 779                  ((eq (char-after (point)) ?\\) (forward-char 2))
 780                  ((memq (char-after (point)) '(?\" ??)) (forward-sexp 1))))
 781               (looking-at ";+[\t ]*"))
 782           (error nil))
 783         (setq has-comment t has-code-and-comment t)
 784         (setq comment-fill-prefix
 785               (concat (make-string (/ (current-column) 8) ?\t)
 786                       (make-string (% (current-column) 8) ?\ )
 787                       (buffer-substring (match-beginning 0) (match-end 0)))))))
 788
 789     (if (not has-comment)
 790         (fill-paragraph justify)
 791
 792       ;; Narrow to include only the comment, and then fill the region.
 793       (save-excursion
 794         (save-restriction
 795           (beginning-of-line)
 796           (narrow-to-region
 797            ;; Find the first line we should include in the region to fill.
 798            (save-excursion
 799              (while (and (zerop (forward-line -1))
 800                          (looking-at "^[ \t]*;")))
 801              ;; We may have gone too far.  Go forward again.
 802              (or (looking-at ".*;")
 803                  (forward-line 1))
 804              (point))
 805            ;; Find the beginning of the first line past the region to fill.
 806            (save-excursion
 807              (while (progn (forward-line 1)
 808                            (looking-at "^[ \t]*;")))
 809              (point)))
 810
 811           ;; Lines with only semicolons on them can be paragraph boundaries.
 812           (let* ((paragraph-start (concat paragraph-start "\\|[ \t;]*$"))
 813                  (paragraph-separate (concat paragraph-start "\\|[ \t;]*$"))
 814                  (paragraph-ignore-fill-prefix nil)
 815                  (fill-prefix comment-fill-prefix)
 816                  (after-line (if has-code-and-comment
 817                                  (save-excursion
 818                                    (forward-line 1) (point))))
 819                  (end (progn
 820                         (forward-paragraph)
 821                         (or (bolp) (newline 1))
 822                         (point)))
 823                  ;; If this comment starts on a line with code,
 824                  ;; include that like in the filling.
 825                  (beg (progn (backward-paragraph)
 826                              (if (eq (point) after-line)
 827                                  (forward-line -1))
 828                              (point))))
 829             (fill-region-as-paragraph beg end
 830                                       justify nil
 831                                       (save-excursion
 832                                         (goto-char beg)
 833                                         (if (looking-at fill-prefix)
 834                                             nil
 835                                           (re-search-forward comment-start-skip)
 836                                           (point))))))))
 837     t))
 838 \f
 839 (defun indent-code-rigidly (start end arg &optional nochange-regexp)
 840   "Indent all lines of code, starting in the region, sideways by ARG columns.
 841 Does not affect lines starting inside comments or strings, assuming that
 842 the start of the region is not inside them.
 843
 844 Called from a program, takes args START, END, COLUMNS and NOCHANGE-REGEXP.
 845 The last is a regexp which, if matched at the beginning of a line,
 846 means don't indent that line."
 847   (interactive "r\np")
 848   (let (state)
 849     (save-excursion
 850       (goto-char end)
 851       (setq end (point-marker))
 852       (goto-char start)
 853       (or (bolp)
 854           (setq state (parse-partial-sexp (point)
 855                                           (progn
 856                                             (forward-line 1) (point))
 857                                           nil nil state)))
 858       (while (< (point) end)
 859         (or (car (nthcdr 3 state))
 860             (and nochange-regexp
 861                  (looking-at nochange-regexp))
 862             ;; If line does not start in string, indent it
 863             (let ((indent (current-indentation)))
 864               (delete-region (point) (progn (skip-chars-forward " \t") (point)))
 865               (or (eolp)
 866                   (indent-to (max 0 (+ indent arg)) 0))))
 867         (setq state (parse-partial-sexp (point)
 868                                         (progn
 869                                           (forward-line 1) (point))
 870                                         nil nil state))))))
 871
 872 (provide 'lisp-mode)
 873
 874 ;;; lisp-mode.el ends here