lisp/vc/log-view.el

   1 ;;; log-view.el --- Major mode for browsing RCS/CVS/SCCS log output -*- lexical-binding: t -*-
   2
   3 ;; Copyright (C) 1999-2012  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
   6 ;; Keywords: rcs, sccs, cvs, log, vc, tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; Major mode to browse revision log histories.
  26 ;; Currently supports the format output by:
  27 ;;  RCS, SCCS, CVS, Subversion, and DaRCS.
  28
  29 ;; Examples of log output:
  30
  31 ;;;; RCS/CVS:
  32
  33 ;; ----------------------------
  34 ;; revision 1.35        locked by: turlutut
  35 ;; date: 2005-03-22 18:48:38 +0000;  author: monnier;  state: Exp;  lines: +6 -8
  36 ;; (gnus-display-time-event-handler):
  37 ;; Check display-time-timer at runtime rather than only at load time
  38 ;; in case display-time-mode is turned off in the mean time.
  39 ;; ----------------------------
  40 ;; revision 1.34
  41 ;; date: 2005-02-09 15:50:38 +0000;  author: kfstorm;  state: Exp;  lines: +7 -7
  42 ;; branches:  1.34.2;
  43 ;; Change release version from 21.4 to 22.1 throughout.
  44 ;; Change development version from 21.3.50 to 22.0.50.
  45
  46 ;;;; SCCS:
  47
  48 ;;;; Subversion:
  49
  50 ;; ------------------------------------------------------------------------
  51 ;; r4622 | ckuethe | 2007-12-23 18:18:01 -0500 (Sun, 23 Dec 2007) | 2 lines
  52 ;;
  53 ;; uBlox AEK-4T in binary mode. Added to unstable because it breaks gpsfake
  54 ;;
  55 ;; ------------------------------------------------------------------------
  56 ;; r4621 | ckuethe | 2007-12-23 16:48:11 -0500 (Sun, 23 Dec 2007) | 3 lines
  57 ;;
  58 ;; Add a note about requiring usbfs to use the garmin gps18 (usb)
  59 ;; Mention firmware testing the AC12 with firmware BQ00 and BQ04
  60 ;;
  61 ;; ------------------------------------------------------------------------
  62 ;; r4620 | ckuethe | 2007-12-23 15:52:34 -0500 (Sun, 23 Dec 2007) | 1 line
  63 ;;
  64 ;; add link to latest hardware reference
  65 ;; ------------------------------------------------------------------------
  66 ;; r4619 | ckuethe | 2007-12-23 14:37:31 -0500 (Sun, 23 Dec 2007) | 1 line
  67 ;;
  68 ;; there is now a regression test for AC12 without raw data output
  69
  70 ;;;; Darcs:
  71
  72 ;; Changes to darcsum.el:
  73 ;;
  74 ;; Mon Nov 28 15:19:38 GMT 2005  Dave Love <fx@gnu.org>
  75 ;;   * Abstract process startup into darcsum-start-process.  Use TERM=dumb.
  76 ;;   TERM=dumb avoids escape characters, at least, for any old darcs that
  77 ;;   doesn't understand DARCS_DONT_COLOR & al.
  78 ;;
  79 ;; Thu Nov 24 15:20:45 GMT 2005  Dave Love <fx@gnu.org>
  80 ;;   * darcsum-mode-related changes.
  81 ;;   Don't call font-lock-mode (unnecessary) or use-local-map (redundant).
  82 ;;   Use mode-class 'special.  Add :group.
  83 ;;   Add trailing-whitespace option to mode hook and fix
  84 ;;   darcsum-display-changeset not to use trailing whitespace.
  85
  86 ;;;; Mercurial
  87
  88 ;; changeset:   11:8ff1a4166444
  89 ;; tag:         tip
  90 ;; user:        Eric S. Raymond <esr@thyrsus.com>
  91 ;; date:        Wed Dec 26 12:18:58 2007 -0500
  92 ;; summary:     Explain keywords.  Add markup fixes.
  93 ;;
  94 ;; changeset:   10:20abc7ab09c3
  95 ;; user:        Eric S. Raymond <esr@thyrsus.com>
  96 ;; date:        Wed Dec 26 11:37:28 2007 -0500
  97 ;; summary:     Typo fixes.
  98 ;;
  99 ;; changeset:   9:ada9f4da88aa
 100 ;; user:        Eric S. Raymond <esr@thyrsus.com>
 101 ;; date:        Wed Dec 26 11:23:00 2007 -0500
 102 ;; summary:     Add RCS example session.
 103
 104 ;;; Todo:
 105
 106 ;; - add ability to modify a log-entry (via cvs-mode-admin ;-)
 107 ;; - remove references to cvs-*
 108 ;; - make it easier to add support for new backends without changing the code.
 109
 110 ;;; Code:
 111
 112 (eval-when-compile (require 'cl))
 113 (require 'pcvs-util)
 114 (autoload 'vc-find-revision "vc")
 115 (autoload 'vc-diff-internal "vc")
 116
 117 (defvar cvs-minor-wrap-function)
 118 (defvar cvs-force-command)
 119
 120 (defgroup log-view nil
 121   "Major mode for browsing log output of RCS/CVS/SCCS."
 122   :group 'pcl-cvs
 123   :prefix "log-view-")
 124
 125 (easy-mmode-defmap log-view-mode-map
 126   '(
 127     ;; FIXME: (copy-keymap special-mode-map) instead
 128     ("z" . kill-this-buffer)
 129     ("q" . quit-window)
 130     ("g" . revert-buffer)
 131     ("\C-m" . log-view-toggle-entry-display)
 132
 133     ("m" . log-view-toggle-mark-entry)
 134     ("e" . log-view-modify-change-comment)
 135     ("d" . log-view-diff)
 136     ("=" . log-view-diff)
 137     ("D" . log-view-diff-changeset)
 138     ("a" . log-view-annotate-version)
 139     ("f" . log-view-find-revision)
 140     ("n" . log-view-msg-next)
 141     ("p" . log-view-msg-prev)
 142     ("\t" . log-view-msg-next)
 143     ([backtab] . log-view-msg-prev)
 144     ("N" . log-view-file-next)
 145     ("P" . log-view-file-prev)
 146     ("\M-n" . log-view-file-next)
 147     ("\M-p" . log-view-file-prev))
 148   "Log-View's keymap."
 149   :group 'log-view)
 150
 151 (easy-menu-define log-view-mode-menu log-view-mode-map
 152   "Log-View Display Menu"
 153   `("Log-View"
 154     ;; XXX Do we need menu entries for these?
 155     ;; ["Quit"  quit-window]
 156     ;; ["Kill This Buffer"  kill-this-buffer]
 157     ["Mark Log Entry for Diff"  set-mark-command
 158      :help ""]
 159     ["Diff Revisions"  log-view-diff
 160      :help "Get the diff between two revisions"]
 161     ["Changeset Diff"  log-view-diff-changeset
 162      :help "Get the changeset diff between two revisions"]
 163     ["Visit Version"  log-view-find-revision
 164      :help "Visit the version at point"]
 165     ["Annotate Version"  log-view-annotate-version
 166      :help "Annotate the version at point"]
 167     ["Modify Log Comment" log-view-modify-change-comment
 168      :help "Edit the change comment displayed at point"]
 169     ["Toggle Details at Point" log-view-toggle-entry-display
 170      :active log-view-expanded-log-entry-function]
 171     "-----"
 172     ["Next Log Entry"  log-view-msg-next
 173      :help "Go to the next count'th log message"]
 174     ["Previous Log Entry"  log-view-msg-prev
 175      :help "Go to the previous count'th log message"]
 176     ["Next File"  log-view-file-next
 177      :help "Go to the next count'th file"]
 178     ["Previous File"  log-view-file-prev
 179      :help "Go to the previous count'th file"]))
 180
 181 (defvar log-view-mode-hook nil
 182   "Hook run at the end of `log-view-mode'.")
 183
 184 (defvar log-view-expanded-log-entry-function nil
 185   "Function returning the detailed description of a Log View entry.
 186 It is called by the command `log-view-toggle-entry-display' with
 187 one arg, the revision tag (a string), and should return a string.
 188 If it is nil, `log-view-toggle-entry-display' does nothing.")
 189
 190 (defface log-view-file
 191   '((((class color) (background light))
 192      (:background "grey70" :weight bold))
 193     (t (:weight bold)))
 194   "Face for the file header line in `log-view-mode'."
 195   :group 'log-view)
 196 (define-obsolete-face-alias 'log-view-file-face 'log-view-file "22.1")
 197 (defvar log-view-file-face 'log-view-file)
 198
 199 (defface log-view-message
 200   '((((class color) (background light))
 201      (:background "grey85"))
 202     (t (:weight bold)))
 203   "Face for the message header line in `log-view-mode'."
 204   :group 'log-view)
 205 ;; backward-compatibility alias
 206 (define-obsolete-face-alias 'log-view-message-face 'log-view-message "22.1")
 207 (defvar log-view-message-face 'log-view-message)
 208
 209 (defvar log-view-file-re
 210   (concat "^\\(?:Working file: \\(?1:.+\\)"                ;RCS and CVS.
 211           ;; Subversion has no such thing??
 212           "\\|\\(?:SCCS/s\\.\\|Changes to \\)\\(?1:.+\\):" ;SCCS and Darcs.
 213           "\\)\n")                    ;Include the \n for font-lock reasons.
 214   "Regexp matching the text identifying the file.
 215 The match group number 1 should match the file name itself.")
 216
 217 (defvar log-view-per-file-logs t
 218   "Set if to t if the logs are shown one file at a time.")
 219
 220 (defvar log-view-message-re
 221   (concat "^\\(?:revision \\(?1:[.0-9]+\\)\\(?:\t.*\\)?" ; RCS and CVS.
 222           "\\|r\\(?1:[0-9]+\\) | .* | .*"                ; Subversion.
 223           "\\|D \\(?1:[.0-9]+\\) .*"                     ; SCCS.
 224           ;; Darcs doesn't have revision names.  VC-darcs uses patch names
 225           ;; instead.  Darcs patch names are hashcodes, which do not appear
 226           ;; in the log output :-(, but darcs accepts any prefix of the log
 227           ;; message as a patch name, so we match the first line of the log
 228           ;; message.
 229           ;; First loosely match the date format.
 230           (concat "\\|[^ \n].*[^0-9\n][0-9][0-9]:[0-9][0-9][^0-9\n].*[^ \n]"
 231                   ;;Email of user and finally Msg, used as revision name.
 232                   "  .*@.*\n\\(?:  \\* \\(?1:.*\\)\\)?")
 233           "\\)$")
 234   "Regexp matching the text identifying a revision.
 235 The match group number 1 should match the revision number itself.")
 236
 237 (defvar log-view-font-lock-keywords
 238   ;; We use `eval' so as to use the buffer-local value of log-view-file-re
 239   ;; and log-view-message-re, if applicable.
 240   '((eval . `(,log-view-file-re
 241               (1 (if (boundp 'cvs-filename-face) cvs-filename-face))
 242               (0 log-view-file-face append)))
 243     (eval . `(,log-view-message-re . log-view-message-face))))
 244
 245 (defconst log-view-font-lock-defaults
 246   '(log-view-font-lock-keywords t nil nil nil))
 247
 248 (defvar log-view-vc-fileset nil
 249   "Set this to the fileset corresponding to the current log.")
 250
 251 (defvar log-view-vc-backend nil
 252   "Set this to the VC backend that created the current log.")
 253
 254 ;;;;
 255 ;;;; Actual code
 256 ;;;;
 257
 258 ;;;###autoload
 259 (define-derived-mode log-view-mode special-mode "Log-View"
 260   "Major mode for browsing CVS log output."
 261   (setq buffer-read-only t)
 262   (set (make-local-variable 'font-lock-defaults) log-view-font-lock-defaults)
 263   (set (make-local-variable 'beginning-of-defun-function)
 264        'log-view-beginning-of-defun)
 265   (set (make-local-variable 'end-of-defun-function)
 266        'log-view-end-of-defun)
 267   (set (make-local-variable 'cvs-minor-wrap-function) 'log-view-minor-wrap)
 268   (hack-dir-local-variables-non-file-buffer))
 269
 270 ;;;;
 271 ;;;; Navigation
 272 ;;;;
 273
 274 ;; define log-view-{msg,file}-{next,prev}
 275 (easy-mmode-define-navigation log-view-msg log-view-message-re "log message")
 276 (easy-mmode-define-navigation log-view-file log-view-file-re "file")
 277
 278 (defun log-view-goto-rev (rev)
 279   (goto-char (point-min))
 280   (ignore-errors
 281     (while (not (equal rev (log-view-current-tag)))
 282       (log-view-msg-next))
 283     t))
 284
 285 ;;;;
 286 ;;;; Linkage to PCL-CVS (mostly copied from cvs-status.el)
 287 ;;;;
 288
 289 (defconst log-view-dir-re "^cvs[.ex]* [a-z]+: Logging \\(.+\\)$")
 290
 291 (defun log-view-current-file ()
 292   (save-excursion
 293     (forward-line 1)
 294     (or (re-search-backward log-view-file-re nil t)
 295         (re-search-forward log-view-file-re nil t)
 296         (error "Unable to determine the current file"))
 297     (let* ((file (match-string 1))
 298            (cvsdir (and (re-search-backward log-view-dir-re nil t)
 299                         (match-string 1)))
 300            (pcldir (and (boundp 'cvs-pcl-cvs-dirchange-re)
 301                         (re-search-backward cvs-pcl-cvs-dirchange-re nil t)
 302                         (match-string 1)))
 303            (dir ""))
 304       (let ((default-directory ""))
 305         (when pcldir (setq dir (expand-file-name pcldir dir)))
 306         (when cvsdir (setq dir (expand-file-name cvsdir dir))))
 307       (expand-file-name file dir))))
 308
 309 (defun log-view-current-entry (&optional pos move)
 310   "Return the position and revision tag of the Log View entry at POS.
 311 This is a list (BEG TAG), where BEG is a buffer position and TAG
 312 is a string.  If POS is nil or omitted, it defaults to point.
 313 If there is no entry at POS, return nil.
 314
 315 If optional arg MOVE is non-nil, move point to BEG if found.
 316 Otherwise, don't move point."
 317   (let ((looping t)
 318         result)
 319     (save-excursion
 320       (when pos (goto-char pos))
 321       (forward-line 1)
 322       (while looping
 323         (setq pos (re-search-backward log-view-message-re nil 'move)
 324               looping (and pos (log-view-inside-comment-p (point)))))
 325       (when pos
 326         (setq result
 327               (list pos (match-string-no-properties 1)))))
 328     (and move result (goto-char pos))
 329     result))
 330
 331 (defun log-view-inside-comment-p (pos)
 332   "Return non-nil if POS lies inside an expanded log entry."
 333   (eq (get-text-property pos 'log-view-comment) t))
 334
 335 (defun log-view-current-tag (&optional pos)
 336   "Return the revision tag (a string) of the Log View entry at POS.
 337 if POS is omitted or nil, it defaults to point."
 338   (cadr (log-view-current-entry pos)))
 339
 340 (defun log-view-toggle-mark-entry ()
 341   "Toggle the marked state for the log entry at point.
 342 Individual log entries can be marked and unmarked. The marked
 343 entries are denoted by changing their background color.
 344 `log-view-get-marked' returns the list of tags for the marked
 345 log entries."
 346   (interactive)
 347   (save-excursion
 348     (let* ((entry (log-view-current-entry nil t))
 349            (beg (car entry))
 350            found)
 351       (when entry
 352         ;; Look to see if the current entry is marked.
 353         (setq found (get-char-property beg 'log-view-self))
 354         (if found
 355             (delete-overlay found)
 356           ;; Create an overlay covering this entry and change its color.
 357           (let* ((end (if (get-text-property beg 'log-view-entry-expanded)
 358                           (next-single-property-change beg 'log-view-comment)
 359                         (log-view-end-of-defun)
 360                         (point)))
 361                  (ov (make-overlay beg end)))
 362             (overlay-put ov 'face 'log-view-file)
 363             ;; This is used to check if the overlay is present.
 364             (overlay-put ov 'log-view-self ov)
 365             (overlay-put ov 'log-view-marked (nth 1 entry))))))))
 366
 367 (defun log-view-get-marked ()
 368   "Return the list of tags for the marked log entries."
 369   (save-excursion
 370     (let ((pos (point-min))
 371           marked-list ov)
 372       (while (setq pos (next-single-property-change pos 'face))
 373         (when (setq ov (get-char-property pos 'log-view-self))
 374           (push (overlay-get ov 'log-view-marked) marked-list)
 375           (setq pos (overlay-end ov))))
 376       marked-list)))
 377
 378 (defun log-view-toggle-entry-display ()
 379   "If possible, expand the current Log View entry.
 380 This calls `log-view-expanded-log-entry-function' to do the work."
 381   (interactive)
 382   ;; Don't do anything unless `log-view-expanded-log-entry-function'
 383   ;; is defined in this mode.
 384   (when (functionp log-view-expanded-log-entry-function)
 385     (let* ((opoint (point))
 386            (entry (log-view-current-entry nil t))
 387            (beg (car entry))
 388            (buffer-read-only nil))
 389       (when entry
 390         (if (get-text-property beg 'log-view-entry-expanded)
 391             ;; If the entry is expanded, collapse it.
 392             (let ((pos (next-single-property-change beg 'log-view-comment)))
 393               (unless (and pos (log-view-inside-comment-p pos))
 394                 (error "Broken markup in `log-view-toggle-entry-display'"))
 395               (delete-region pos
 396                              (next-single-property-change pos 'log-view-comment))
 397               (put-text-property beg (1+ beg) 'log-view-entry-expanded nil)
 398               (if (< opoint pos)
 399                   (goto-char opoint)))
 400           ;; Otherwise, expand the entry.
 401           (let ((long-entry (funcall log-view-expanded-log-entry-function
 402                                      (nth 1 entry))))
 403             (when long-entry
 404               (put-text-property beg (1+ beg) 'log-view-entry-expanded t)
 405               (log-view-end-of-defun)
 406               (setq beg (point))
 407               (insert long-entry "\n")
 408               (add-text-properties
 409                beg (point)
 410                '(font-lock-face font-lock-comment-face log-view-comment t))
 411               (goto-char opoint))))))))
 412
 413 (defun log-view-beginning-of-defun (&optional arg)
 414   "Move backward to the beginning of a Log View entry.
 415 With ARG, do it that many times.  Negative ARG means move forward
 416 to the beginning of the ARGth following entry.
 417
 418 This is Log View mode's default `beginning-of-defun-function'.
 419 It assumes that a log entry starts with a line matching
 420 `log-view-message-re'."
 421   (if (or (null arg) (zerop arg))
 422       (setq arg 1))
 423   (if (< arg 0)
 424       (dotimes (_n (- arg))
 425         (log-view-end-of-defun))
 426     (catch 'beginning-of-buffer
 427       (dotimes (_n arg)
 428         (or (log-view-current-entry nil t)
 429             (throw 'beginning-of-buffer nil)))
 430       (point))))
 431
 432 (defun log-view-end-of-defun ()
 433   "Move forward to the next Log View entry."
 434   (let ((looping t))
 435     (if (looking-at log-view-message-re)
 436         (goto-char (match-end 0)))
 437     (while looping
 438       (cond
 439        ((re-search-forward log-view-message-re nil 'move)
 440         (unless (log-view-inside-comment-p (point))
 441           (setq looping nil)
 442           (goto-char (match-beginning 0))))
 443        ;; Don't advance past the end buttons inserted by
 444        ;; `vc-print-log-setup-buttons'.
 445        ((looking-back "Show 2X entries    Show unlimited entries")
 446         (setq looping nil)
 447         (forward-line -1))))))
 448
 449 (defvar cvs-minor-current-files)
 450 (defvar cvs-branch-prefix)
 451 (defvar cvs-secondary-branch-prefix)
 452
 453 (defun log-view-minor-wrap (buf f)
 454   (let ((data (with-current-buffer buf
 455                 (let* ((beg (point))
 456                        (end (if mark-active (mark) (point)))
 457                        (fr (log-view-current-tag beg))
 458                        (to (log-view-current-tag end)))
 459                   (when (string-equal fr to)
 460                     (save-excursion
 461                       (goto-char end)
 462                       (log-view-msg-next)
 463                       (setq to (log-view-current-tag))))
 464                   (cons
 465                    ;; The first revision has to be the one at point, for
 466                    ;; operations that only take one revision
 467                    ;; (e.g. cvs-mode-edit).
 468                    (cons (log-view-current-file) fr)
 469                    (cons (log-view-current-file) to))))))
 470     (let ((cvs-branch-prefix (cdar data))
 471           (cvs-secondary-branch-prefix (and (cdar data) (cddr data)))
 472           (cvs-minor-current-files
 473            (cons (caar data)
 474                  (when (and (cadr data) (not (equal (caar data) (cadr data))))
 475                    (list (cadr data)))))
 476           ;; FIXME:  I need to force because the fileinfos are UNKNOWN
 477           (cvs-force-command "/F"))
 478       (funcall f))))
 479
 480 (defun log-view-find-revision (pos)
 481   "Visit the version at point."
 482   (interactive "d")
 483   (unless log-view-per-file-logs
 484     (when (> (length log-view-vc-fileset) 1)
 485       (error "Multiple files shown in this buffer, cannot use this command here")))
 486   (save-excursion
 487     (goto-char pos)
 488     (switch-to-buffer (vc-find-revision (if log-view-per-file-logs
 489                                             (log-view-current-file)
 490                                           (car log-view-vc-fileset))
 491                                         (log-view-current-tag)))))
 492
 493
 494 (defun log-view-extract-comment ()
 495   "Parse comment from around the current point in the log."
 496   (save-excursion
 497     (let (st en (backend (vc-backend (log-view-current-file))))
 498       (log-view-end-of-defun)
 499       (cond ((eq backend 'SVN)
 500              (forward-line -1)))
 501       (setq en (point))
 502       (log-view-beginning-of-defun)
 503       (cond ((memq backend '(SCCS RCS CVS MCVS SVN))
 504              (forward-line 2))
 505             ((eq backend 'Hg)
 506              (forward-line 4)
 507              (re-search-forward "summary: *" nil t)))
 508       (setq st (point))
 509       (buffer-substring st en))))
 510
 511 (declare-function vc-modify-change-comment "vc" (files rev oldcomment))
 512
 513 (defun log-view-modify-change-comment ()
 514   "Edit the change comment displayed at point."
 515   (interactive)
 516   (vc-modify-change-comment (list (if log-view-per-file-logs
 517                                       (log-view-current-file)
 518                                     (car log-view-vc-fileset)))
 519                             (log-view-current-tag)
 520                             (log-view-extract-comment)))
 521
 522 (defun log-view-annotate-version (pos)
 523   "Annotate the version at point."
 524   (interactive "d")
 525   (unless log-view-per-file-logs
 526     (when (> (length log-view-vc-fileset) 1)
 527       (error "Multiple files shown in this buffer, cannot use this command here")))
 528   (save-excursion
 529     (goto-char pos)
 530     (vc-annotate (if log-view-per-file-logs
 531                      (log-view-current-file)
 532                    (car log-view-vc-fileset))
 533                  (log-view-current-tag))))
 534
 535 ;;
 536 ;; diff
 537 ;;
 538
 539 (defun log-view-diff (beg end)
 540   "Get the diff between two revisions.
 541 If the mark is not active or the mark is on the revision at point,
 542 get the diff between the revision at point and its previous revision.
 543 Otherwise, get the diff between the revisions where the region starts
 544 and ends.
 545 Contrary to `log-view-diff-changeset', it will only show the part of the
 546 changeset that affected the currently considered file(s)."
 547   (interactive
 548    (list (if mark-active (region-beginning) (point))
 549          (if mark-active (region-end) (point))))
 550   (let ((fr (log-view-current-tag beg))
 551         (to (log-view-current-tag end)))
 552     (when (string-equal fr to)
 553       (save-excursion
 554         (goto-char end)
 555         (log-view-msg-next)
 556         (setq to (log-view-current-tag))))
 557     (vc-diff-internal
 558      t (list log-view-vc-backend
 559              (if log-view-per-file-logs
 560                  (list (log-view-current-file))
 561                log-view-vc-fileset))
 562      to fr)))
 563
 564 (defun log-view-diff-changeset (beg end)
 565   "Get the diff between two revisions.
 566 If the mark is not active or the mark is on the revision at point,
 567 get the diff between the revision at point and its previous revision.
 568 Otherwise, get the diff between the revisions where the region starts
 569 and ends.
 570 Contrary to `log-view-diff', it will show the whole changeset including
 571 the changes that affected other files than the currently considered file(s)."
 572   (interactive
 573    (list (if mark-active (region-beginning) (point))
 574          (if mark-active (region-end) (point))))
 575   (when (eq (vc-call-backend log-view-vc-backend 'revision-granularity) 'file)
 576     (error "The %s backend does not support changeset diffs" log-view-vc-backend))
 577   (let ((fr (log-view-current-tag beg))
 578         (to (log-view-current-tag end)))
 579     (when (string-equal fr to)
 580       ;; TO and FR are the same, look at the previous revision.
 581       (setq to (vc-call-backend log-view-vc-backend 'previous-revision nil fr)))
 582     (vc-diff-internal
 583      t
 584      ;; We want to see the diff for all the files in the changeset, so
 585      ;; pass NIL for the file list.  The value passed here should
 586      ;; follow what `vc-deduce-fileset' returns.
 587      (list log-view-vc-backend nil)
 588      to fr)))
 589
 590 (provide 'log-view)
 591
 592 ;;; log-view.el ends here