lisp/progmodes/compile.el

   1 ;;; compile.el --- run compiler as inferior of Emacs, parse error messages
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2001, 2002, 2003, 2004, 2005, 2006, 2007  Free Software Foundation, Inc.
   5
   6 ;; Authors: Roland McGrath <roland@gnu.org>,
   7 ;;          Daniel Pfeiffer <occitan@esperanto.org>
   8 ;; Maintainer: FSF
   9 ;; Keywords: tools, processes
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides the compile facilities documented in the Emacs user's
  31 ;; manual.
  32
  33 ;; This mode uses some complex data-structures:
  34
  35 ;;   LOC (or location) is a list of (COLUMN LINE FILE-STRUCTURE)
  36
  37 ;; COLUMN and LINE are numbers parsed from an error message.  COLUMN and maybe
  38 ;; LINE will be nil for a message that doesn't contain them.  Then the
  39 ;; location refers to a indented beginning of line or beginning of file.
  40 ;; Once any location in some file has been jumped to, the list is extended to
  41 ;; (COLUMN LINE FILE-STRUCTURE MARKER . VISITED) for all LOCs pertaining to
  42 ;; that file.
  43 ;; MARKER initially points to LINE and COLUMN in a buffer visiting that file.
  44 ;; Being a marker it sticks to some text, when the buffer grows or shrinks
  45 ;; before that point.  VISITED is t if we have jumped there, else nil.
  46
  47 ;;   FILE-STRUCTURE is a list of
  48 ;;   ((FILENAME . DIRECTORY) FORMATS (LINE LOC ...) ...)
  49
  50 ;; FILENAME is a string parsed from an error message.  DIRECTORY is a string
  51 ;; obtained by following directory change messages.  DIRECTORY will be nil for
  52 ;; an absolute filename.  FORMATS is a list of formats to apply to FILENAME if
  53 ;; a file of that name can't be found.
  54 ;; The rest of the list is an alist of elements with LINE as key.  The keys
  55 ;; are either nil or line numbers.  If present, nil comes first, followed by
  56 ;; the numbers in decreasing order.  The LOCs for each line are again an alist
  57 ;; ordered the same way.  Note that the whole file structure is referenced in
  58 ;; every LOC.
  59
  60 ;;   MESSAGE is a list of (LOC TYPE END-LOC)
  61
  62 ;; TYPE is 0 for info or 1 for warning if the message matcher identified it as
  63 ;; such, 2 otherwise (for a real error).  END-LOC is a LOC pointing to the
  64 ;; other end, if the parsed message contained a range.  If the end of the
  65 ;; range didn't specify a COLUMN, it defaults to -1, meaning end of line.
  66 ;; These are the value of the `message' text-properties in the compilation
  67 ;; buffer.
  68
  69 ;;; Code:
  70
  71 (eval-when-compile (require 'cl))
  72
  73 (defvar font-lock-extra-managed-props)
  74 (defvar font-lock-keywords)
  75 (defvar font-lock-maximum-size)
  76 (defvar font-lock-support-mode)
  77
  78
  79 (defgroup compilation nil
  80   "Run compiler as inferior of Emacs, parse error messages."
  81   :group 'tools
  82   :group 'processes)
  83
  84
  85 ;;;###autoload
  86 (defcustom compilation-mode-hook nil
  87   "*List of hook functions run by `compilation-mode' (see `run-mode-hooks')."
  88   :type 'hook
  89   :group 'compilation)
  90
  91 ;;;###autoload
  92 (defcustom compilation-window-height nil
  93   "*Number of lines in a compilation window.  If nil, use Emacs default."
  94   :type '(choice (const :tag "Default" nil)
  95                  integer)
  96   :group 'compilation)
  97
  98 (defvar compilation-first-column 1
  99   "*This is how compilers number the first column, usually 1 or 0.")
 100
 101 (defvar compilation-parse-errors-filename-function nil
 102   "Function to call to post-process filenames while parsing error messages.
 103 It takes one arg FILENAME which is the name of a file as found
 104 in the compilation output, and should return a transformed file name.")
 105
 106 ;;;###autoload
 107 (defvar compilation-process-setup-function nil
 108   "*Function to call to customize the compilation process.
 109 This function is called immediately before the compilation process is
 110 started.  It can be used to set any variables or functions that are used
 111 while processing the output of the compilation process.  The function
 112 is called with variables `compilation-buffer' and `compilation-window'
 113 bound to the compilation buffer and window, respectively.")
 114
 115 ;;;###autoload
 116 (defvar compilation-buffer-name-function nil
 117   "Function to compute the name of a compilation buffer.
 118 The function receives one argument, the name of the major mode of the
 119 compilation buffer.  It should return a string.
 120 nil means compute the name with `(concat \"*\" (downcase major-mode) \"*\")'.")
 121
 122 ;;;###autoload
 123 (defvar compilation-finish-function nil
 124   "Function to call when a compilation process finishes.
 125 It is called with two arguments: the compilation buffer, and a string
 126 describing how the process finished.")
 127
 128 (make-obsolete-variable 'compilation-finish-function
 129   "Use `compilation-finish-functions', but it works a little differently."
 130   "22.1")
 131
 132 ;;;###autoload
 133 (defvar compilation-finish-functions nil
 134   "Functions to call when a compilation process finishes.
 135 Each function is called with two arguments: the compilation buffer,
 136 and a string describing how the process finished.")
 137
 138 (defvar compilation-in-progress nil
 139   "List of compilation processes now running.")
 140 (or (assq 'compilation-in-progress minor-mode-alist)
 141     (setq minor-mode-alist (cons '(compilation-in-progress " Compiling")
 142                                  minor-mode-alist)))
 143
 144 (defvar compilation-error "error"
 145   "Stem of message to print when no matches are found.")
 146
 147 (defvar compilation-arguments nil
 148   "Arguments that were given to `compilation-start'.")
 149
 150 (defvar compilation-num-errors-found)
 151
 152 (defconst compilation-error-regexp-alist-alist
 153   '((absoft
 154      "^\\(?:[Ee]rror on \\|[Ww]arning on\\( \\)\\)?[Ll]ine[ \t]+\\([0-9]+\\)[ \t]+\
 155 of[ \t]+\"?\\([a-zA-Z]?:?[^\":\n]+\\)\"?:" 3 2 nil (1))
 156
 157     (ada
 158      "\\(warning: .*\\)? at \\([^ \n]+\\):\\([0-9]+\\)$" 2 3 nil (1))
 159
 160     (aix
 161      " in line \\([0-9]+\\) of file \\([^ \n]+[^. \n]\\)\\.? " 2 1)
 162
 163     (ant
 164      "^[ \t]*\\[[^] \n]+\\][ \t]*\\([^: \n]+\\):\\([0-9]+\\):\\(?:\\([0-9]+\\):[0-9]+:[0-9]+:\\)?\
 165 \\( warning\\)?" 1 2 3 (4))
 166
 167     (bash
 168      "^\\([^: \n\t]+\\): line \\([0-9]+\\):" 1 2)
 169
 170     (borland
 171      "^\\(?:Error\\|Warnin\\(g\\)\\) \\(?:[FEW][0-9]+ \\)?\
 172 \\([a-zA-Z]?:?[^:( \t\n]+\\)\
 173  \\([0-9]+\\)\\(?:[) \t]\\|:[^0-9\n]\\)" 2 3 nil (1))
 174
 175     (caml
 176      "^ *File \\(\"?\\)\\([^,\" \n\t<>]+\\)\\1, lines? \\([0-9]+\\)-?\\([0-9]+\\)?\\(?:$\\|,\
 177 \\(?: characters? \\([0-9]+\\)-?\\([0-9]+\\)?:\\)?\\([ \n]Warning:\\)?\\)"
 178      2 (3 . 4) (5 . 6) (7))
 179
 180     (comma
 181      "^\"\\([^,\" \n\t]+\\)\", line \\([0-9]+\\)\
 182 \\(?:[(. pos]+\\([0-9]+\\))?\\)?[:.,; (-]\\( warning:\\|[-0-9 ]*(W)\\)?" 1 2 3 (4))
 183
 184     (edg-1
 185      "^\\([^ \n]+\\)(\\([0-9]+\\)): \\(?:error\\|warnin\\(g\\)\\|remar\\(k\\)\\)"
 186      1 2 nil (3 . 4))
 187     (edg-2
 188      "at line \\([0-9]+\\) of \"\\([^ \n]+\\)\"$"
 189      2 1 nil 0)
 190
 191     (epc
 192      "^Error [0-9]+ at (\\([0-9]+\\):\\([^)\n]+\\))" 2 1)
 193
 194     (ftnchek
 195      "\\(^Warning .*\\)? line[ \n]\\([0-9]+\\)[ \n]\\(?:col \\([0-9]+\\)[ \n]\\)?file \\([^ :;\n]+\\)"
 196      4 2 3 (1))
 197
 198     (iar
 199      "^\"\\(.*\\)\",\\([0-9]+\\)\\s-+\\(?:Error\\|Warnin\\(g\\)\\)\\[[0-9]+\\]:"
 200      1 2 nil (3))
 201
 202     (ibm
 203      "^\\([^( \n\t]+\\)(\\([0-9]+\\):\\([0-9]+\\)) :\
 204  \\(?:warnin\\(g\\)\\|informationa\\(l\\)\\)?" 1 2 3 (4 . 5))
 205
 206     ;; fixme: should be `mips'
 207     (irix
 208      "^[-[:alnum:]_/ ]+: \\(?:\\(?:[sS]evere\\|[eE]rror\\|[wW]arnin\\(g\\)\\|[iI]nf\\(o\\)\\)[0-9 ]*: \\)?\
 209 \\([^,\" \n\t]+\\)\\(?:, line\\|:\\) \\([0-9]+\\):" 3 4 nil (1 . 2))
 210
 211     (java
 212      "^\\(?:[ \t]+at \\|==[0-9]+== +\\(?:at\\|b\\(y\\)\\)\\).+(\\([^()\n]+\\):\\([0-9]+\\))$" 2 3 nil (1))
 213
 214     (jikes-file
 215      "^\\(?:Found\\|Issued\\) .* compiling \"\\(.+\\)\":$" 1 nil nil 0)
 216     (jikes-line
 217      "^ *\\([0-9]+\\)\\.[ \t]+.*\n +\\(<-*>\n\\*\\*\\* \\(?:Error\\|Warnin\\(g\\)\\)\\)"
 218      nil 1 nil 2 0
 219      (2 (compilation-face '(3))))
 220
 221     (gnu
 222      ;; I have no idea what this first line is supposed to match, but it
 223      ;; makes things ambiguous with output such as "foo:344:50:blabla" since
 224      ;; the "foo" part can match this first line (in which case the file
 225      ;; name as "344").  To avoid this, the second line disallows filenames
 226      ;; exclusively composed of digits.  --Stef
 227      ;; Similarly, we get lots of false positives with messages including
 228      ;; times of the form "HH:MM:SS" where MM is taken as a line number, so
 229      ;; the last line tries to rule out message where the info after the
 230      ;; line number starts with "SS".  --Stef
 231      "^\\(?:[[:alpha:]][-[:alnum:].]+: ?\\)?\
 232 \\([0-9]*[^0-9\n]\\(?:[^\n ]\\| [^-\n]\\)*?\\): ?\
 233 \\([0-9]+\\)\\(?:\\([.:]\\)\\([0-9]+\\)\\)?\
 234 \\(?:-\\([0-9]+\\)?\\(?:\\3\\([0-9]+\\)\\)?\\)?:\
 235 \\(?: *\\(\\(?:Future\\|Runtime\\)?[Ww]arning\\|W:\\)\\|\
 236  *\\([Ii]nfo\\(?:\\>\\|rmationa?l?\\)\\|I:\\|instantiated from\\)\\|\
 237 \[0-9]?\\(?:[^0-9\n]\\|$\\)\\|[0-9][0-9][0-9]\\)"
 238      1 (2 . 5) (4 . 6) (7 . 8))
 239
 240     ;; The `gnu' style above can incorrectly match gcc's "In file
 241     ;; included from" message, so we process that first. -- cyd
 242     (gcc-include
 243      "^\\(?:In file included\\|                \\) from \
 244 \\(.+\\):\\([0-9]+\\)\\(?:\\(:\\)\\|\\(,\\)\\)?" 1 2 nil (3 . 4))
 245
 246     (lcc
 247      "^\\(?:E\\|\\(W\\)\\), \\([^(\n]+\\)(\\([0-9]+\\),[ \t]*\\([0-9]+\\)"
 248      2 3 4 (1))
 249
 250     (makepp
 251      "^makepp\\(?:\\(?:: warning\\(:\\).*?\\|\\(: Scanning\\|: [LR]e?l?oading makefile\\|: Imported\\|log:.*?\\) \\|: .*?\\)\
 252 `\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]\\)"
 253      4 5 nil (1 . 2) 3
 254      ("`\\(\\(\\S +?\\)\\(?::\\([0-9]+\\)\\)?\\)['(]" nil nil
 255       (2 compilation-info-face)
 256       (3 compilation-line-face nil t)
 257       (1 (compilation-error-properties 2 3 nil nil nil 0 nil)
 258          append)))
 259
 260     ;; Should be lint-1, lint-2 (SysV lint)
 261     (mips-1
 262      " (\\([0-9]+\\)) in \\([^ \n]+\\)" 2 1)
 263     (mips-2
 264      " in \\([^()\n ]+\\)(\\([0-9]+\\))$" 1 2)
 265
 266     (msft
 267      "^\\([0-9]+>\\)?\\(\\(?:[a-zA-Z]:\\)?[^:(\t\n]+\\)(\\([0-9]+\\)) \
 268 : \\(?:error\\|warnin\\(g\\)\\) C[0-9]+:" 2 3 nil (4))
 269
 270     (oracle
 271      "^\\(?:Semantic error\\|Error\\|PCC-[0-9]+:\\).* line \\([0-9]+\\)\
 272 \\(?:\\(?:,\\| at\\)? column \\([0-9]+\\)\\)?\
 273 \\(?:,\\| in\\| of\\)? file \\(.*?\\):?$"
 274      3 1 2)
 275
 276     (perl
 277      " at \\([^ \n]+\\) line \\([0-9]+\\)\\(?:[,.]\\|$\\)" 1 2)
 278
 279     (rxp
 280      "^\\(?:Error\\|Warnin\\(g\\)\\):.*\n.* line \\([0-9]+\\) char\
 281  \\([0-9]+\\) of file://\\(.+\\)"
 282      4 2 3 (1))
 283
 284     (sparc-pascal-file
 285      "^\\w\\w\\w \\w\\w\\w +[0-3]?[0-9] +[0-2][0-9]:[0-5][0-9]:[0-5][0-9]\
 286  [12][09][0-9][0-9] +\\(.*\\):$"
 287      1 nil nil 0)
 288     (sparc-pascal-line
 289      "^\\(\\(?:E\\|\\(w\\)\\) +[0-9]+\\) line \\([0-9]+\\) -  "
 290      nil 3 nil (2) nil (1 (compilation-face '(2))))
 291     (sparc-pascal-example
 292      "^ +\\([0-9]+\\) +.*\n\\(\\(?:e\\|\\(w\\)\\) [0-9]+\\)-+"
 293      nil 1 nil (3) nil (2 (compilation-face '(3))))
 294
 295     (sun
 296      ": \\(?:ERROR\\|WARNIN\\(G\\)\\|REMAR\\(K\\)\\) \\(?:[[:alnum:] ]+, \\)?\
 297 File = \\(.+\\), Line = \\([0-9]+\\)\\(?:, Column = \\([0-9]+\\)\\)?"
 298      3 4 5 (1 . 2))
 299
 300     (sun-ada
 301      "^\\([^, \n\t]+\\), line \\([0-9]+\\), char \\([0-9]+\\)[:., \(-]" 1 2 3)
 302
 303     (4bsd
 304      "\\(?:^\\|::  \\|\\S ( \\)\\(/[^ \n\t()]+\\)(\\([0-9]+\\))\
 305 \\(?:: \\(warning:\\)?\\|$\\| ),\\)" 1 2 nil (3))
 306
 307     (gcov-file
 308      "^ *-: *\\(0\\):Source:\\(.+\\)$"
 309      2 1 nil 0 nil
 310      (1 compilation-line-face prepend) (2 compilation-info-face prepend))
 311     (gcov-header
 312      "^ *-: *\\(0\\):\\(?:Object\\|Graph\\|Data\\|Runs\\|Programs\\):.+$"
 313      nil 1 nil 0 nil
 314      (1 compilation-line-face prepend))
 315     ;; Underlines over all lines of gcov output are too uncomfortable to read.
 316     ;; However, hyperlinks embedded in the lines are useful.
 317     ;; So I put default face on the lines; and then put
 318     ;; compilation-*-face by manually to eliminate the underlines.
 319     ;; The hyperlinks are still effective.
 320     (gcov-nomark
 321      "^ *-: *\\([1-9]\\|[0-9]\\{2,\\}\\):.*$"
 322      nil 1 nil 0 nil
 323      (0 'default t)
 324      (1 compilation-line-face prepend))
 325     (gcov-called-line
 326      "^ *\\([0-9]+\\): *\\([0-9]+\\):.*$"
 327      nil 2 nil 0 nil
 328      (0 'default t)
 329      (1 compilation-info-face prepend) (2 compilation-line-face prepend))
 330     (gcov-never-called
 331      "^ *\\(#####\\): *\\([0-9]+\\):.*$"
 332      nil 2 nil 2 nil
 333      (0 'default t)
 334      (1 compilation-error-face prepend) (2 compilation-line-face prepend))
 335     )
 336   "Alist of values for `compilation-error-regexp-alist'.")
 337
 338 (defcustom compilation-error-regexp-alist
 339   (mapcar 'car compilation-error-regexp-alist-alist)
 340   "Alist that specifies how to match errors in compiler output.
 341 On GNU and Unix, any string is a valid filename, so these
 342 matchers must make some common sense assumptions, which catch
 343 normal cases.  A shorter list will be lighter on resource usage.
 344
 345 Instead of an alist element, you can use a symbol, which is
 346 looked up in `compilation-error-regexp-alist-alist'.  You can see
 347 the predefined symbols and their effects in the file
 348 `etc/compilation.txt' (linked below if you are customizing this).
 349
 350 Each elt has the form (REGEXP FILE [LINE COLUMN TYPE HYPERLINK
 351 HIGHLIGHT...]).  If REGEXP matches, the FILE'th subexpression
 352 gives the file name, and the LINE'th subexpression gives the line
 353 number.  The COLUMN'th subexpression gives the column number on
 354 that line.
 355
 356 If FILE, LINE or COLUMN are nil or that index didn't match, that
 357 information is not present on the matched line.  In that case the
 358 file name is assumed to be the same as the previous one in the
 359 buffer, line number defaults to 1 and column defaults to
 360 beginning of line's indentation.
 361
 362 FILE can also have the form (FILE FORMAT...), where the FORMATs
 363 \(e.g. \"%s.c\") will be applied in turn to the recognized file
 364 name, until a file of that name is found.  Or FILE can also be a
 365 function that returns (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
 366 In the former case, FILENAME may be relative or absolute.
 367
 368 LINE can also be of the form (LINE . END-LINE) meaning a range
 369 of lines.  COLUMN can also be of the form (COLUMN . END-COLUMN)
 370 meaning a range of columns starting on LINE and ending on
 371 END-LINE, if that matched.
 372
 373 TYPE is 2 or nil for a real error or 1 for warning or 0 for info.
 374 TYPE can also be of the form (WARNING . INFO).  In that case this
 375 will be equivalent to 1 if the WARNING'th subexpression matched
 376 or else equivalent to 0 if the INFO'th subexpression matched.
 377 See `compilation-error-face', `compilation-warning-face',
 378 `compilation-info-face' and `compilation-skip-threshold'.
 379
 380 What matched the HYPERLINK'th subexpression has `mouse-face' and
 381 `compilation-message-face' applied.  If this is nil, the text
 382 matched by the whole REGEXP becomes the hyperlink.
 383
 384 Additional HIGHLIGHTs as described under `font-lock-keywords' can
 385 be added."
 386   :type `(set :menu-tag "Pick"
 387               ,@(mapcar (lambda (elt)
 388                           (list 'const (car elt)))
 389                         compilation-error-regexp-alist-alist))
 390   :link `(file-link :tag "example file"
 391                     ,(expand-file-name "compilation.txt" data-directory))
 392   :group 'compilation)
 393
 394 ;;;###autoload(put 'compilation-directory 'safe-local-variable 'stringp)
 395 (defvar compilation-directory nil
 396   "Directory to restore to when doing `recompile'.")
 397
 398 (defvar compilation-directory-matcher
 399   '("\\(?:Entering\\|Leavin\\(g\\)\\) directory `\\(.+\\)'$" (2 . 1))
 400   "A list for tracking when directories are entered or left.
 401 If nil, do not track directories, e.g. if all file names are absolute.  The
 402 first element is the REGEXP matching these messages.  It can match any number
 403 of variants, e.g. different languages.  The remaining elements are all of the
 404 form (DIR .  LEAVE).  If for any one of these the DIR'th subexpression
 405 matches, that is a directory name.  If LEAVE is nil or the corresponding
 406 LEAVE'th subexpression doesn't match, this message is about going into another
 407 directory.  If it does match anything, this message is about going back to the
 408 directory we were in before the last entering message.  If you change this,
 409 you may also want to change `compilation-page-delimiter'.")
 410
 411 (defvar compilation-page-delimiter
 412   "^\\(?:\f\\|.*\\(?:Entering\\|Leaving\\) directory `.+'\n\\)+"
 413   "Value of `page-delimiter' in Compilation mode.")
 414
 415 (defvar compilation-mode-font-lock-keywords
 416    '(;; configure output lines.
 417      ("^[Cc]hecking \\(?:[Ff]or \\|[Ii]f \\|[Ww]hether \\(?:to \\)?\\)?\\(.+\\)\\.\\.\\. *\\(?:(cached) *\\)?\\(\\(yes\\(?: .+\\)?\\)\\|no\\|\\(.*\\)\\)$"
 418       (1 font-lock-variable-name-face)
 419       (2 (compilation-face '(4 . 3))))
 420      ;; Command output lines.  Recognize `make[n]:' lines too.
 421      ("^\\([[:alnum:]_/.+-]+\\)\\(\\[\\([0-9]+\\)\\]\\)?[ \t]*:"
 422       (1 font-lock-function-name-face) (3 compilation-line-face nil t))
 423      (" --?o\\(?:utfile\\|utput\\)?[= ]?\\(\\S +\\)" . 1)
 424      ("^Compilation \\(finished\\).*"
 425       (0 '(face nil message nil help-echo nil mouse-face nil) t)
 426       (1 compilation-info-face))
 427      ("^Compilation \\(exited abnormally\\|interrupt\\|killed\\|terminated\\|segmentation fault\\)\\(?:.*with code \\([0-9]+\\)\\)?.*"
 428       (0 '(face nil message nil help-echo nil mouse-face nil) t)
 429       (1 compilation-error-face)
 430       (2 compilation-error-face nil t)))
 431    "Additional things to highlight in Compilation mode.
 432 This gets tacked on the end of the generated expressions.")
 433
 434 (defvar compilation-highlight-regexp t
 435   "Regexp matching part of visited source lines to highlight temporarily.
 436 Highlight entire line if t; don't highlight source lines if nil.")
 437
 438 (defvar compilation-highlight-overlay nil
 439   "Overlay used to temporarily highlight compilation matches.")
 440
 441 (defcustom compilation-error-screen-columns t
 442   "*If non-nil, column numbers in error messages are screen columns.
 443 Otherwise they are interpreted as character positions, with
 444 each character occupying one column.
 445 The default is to use screen columns, which requires that the compilation
 446 program and Emacs agree about the display width of the characters,
 447 especially the TAB character."
 448   :type 'boolean
 449   :group 'compilation
 450   :version "20.4")
 451
 452 (defcustom compilation-read-command t
 453   "*Non-nil means \\[compile] reads the compilation command to use.
 454 Otherwise, \\[compile] just uses the value of `compile-command'."
 455   :type 'boolean
 456   :group 'compilation)
 457
 458 ;;;###autoload
 459 (defcustom compilation-ask-about-save t
 460   "*Non-nil means \\[compile] asks which buffers to save before compiling.
 461 Otherwise, it saves all modified buffers without asking."
 462   :type 'boolean
 463   :group 'compilation)
 464
 465 ;;;###autoload
 466 (defcustom compilation-search-path '(nil)
 467   "*List of directories to search for source files named in error messages.
 468 Elements should be directory names, not file names of directories.
 469 nil as an element means to try the default directory."
 470   :type '(repeat (choice (const :tag "Default" nil)
 471                          (string :tag "Directory")))
 472   :group 'compilation)
 473
 474 ;;;###autoload
 475 (defcustom compile-command "make -k "
 476   "*Last shell command used to do a compilation; default for next compilation.
 477
 478 Sometimes it is useful for files to supply local values for this variable.
 479 You might also use mode hooks to specify it in certain modes, like this:
 480
 481     (add-hook 'c-mode-hook
 482        (lambda ()
 483          (unless (or (file-exists-p \"makefile\")
 484                      (file-exists-p \"Makefile\"))
 485            (set (make-local-variable 'compile-command)
 486                 (concat \"make -k \"
 487                         (file-name-sans-extension buffer-file-name))))))"
 488   :type 'string
 489   :group 'compilation)
 490 ;;;###autoload(put 'compile-command 'safe-local-variable 'stringp)
 491
 492 ;;;###autoload
 493 (defcustom compilation-disable-input nil
 494   "*If non-nil, send end-of-file as compilation process input.
 495 This only affects platforms that support asynchronous processes (see
 496 `start-process'); synchronous compilation processes never accept input."
 497   :type 'boolean
 498   :group 'compilation
 499   :version "22.1")
 500
 501 ;; A weak per-compilation-buffer hash indexed by (FILENAME . DIRECTORY).  Each
 502 ;; value is a FILE-STRUCTURE as described above, with the car eq to the hash
 503 ;; key.  This holds the tree seen from root, for storing new nodes.
 504 (defvar compilation-locs ())
 505
 506 (defvar compilation-debug nil
 507   "*Set this to t before creating a *compilation* buffer.
 508 Then every error line will have a debug text property with the matcher that
 509 fit this line and the match data.  Use `describe-text-properties'.")
 510
 511 (defvar compilation-exit-message-function nil "\
 512 If non-nil, called when a compilation process dies to return a status message.
 513 This should be a function of three arguments: process status, exit status,
 514 and exit message; it returns a cons (MESSAGE . MODELINE) of the strings to
 515 write into the compilation buffer, and to put in its mode line.")
 516
 517 (defvar compilation-environment nil
 518   "*List of environment variables for compilation to inherit.
 519 Each element should be a string of the form ENVVARNAME=VALUE.
 520 This list is temporarily prepended to `process-environment' prior to
 521 starting the compilation process.")
 522
 523 ;; History of compile commands.
 524 (defvar compile-history nil)
 525
 526 (defface compilation-error
 527   '((t :inherit font-lock-warning-face))
 528   "Face used to highlight compiler errors."
 529   :group 'compilation
 530   :version "22.1")
 531
 532 (defface compilation-warning
 533   '((((class color) (min-colors 16)) (:foreground "Orange" :weight bold))
 534     (((class color)) (:foreground "cyan" :weight bold))
 535     (t (:weight bold)))
 536   "Face used to highlight compiler warnings."
 537   :group 'compilation
 538   :version "22.1")
 539
 540 (defface compilation-info
 541   '((((class color) (min-colors 16) (background light))
 542      (:foreground "Green3" :weight bold))
 543     (((class color) (min-colors 88) (background dark))
 544      (:foreground "Green1" :weight bold))
 545     (((class color) (min-colors 16) (background dark))
 546      (:foreground "Green" :weight bold))
 547     (((class color)) (:foreground "green" :weight bold))
 548     (t (:weight bold)))
 549   "Face used to highlight compiler information."
 550   :group 'compilation
 551   :version "22.1")
 552
 553 (defface compilation-line-number
 554   '((t :inherit font-lock-variable-name-face))
 555   "Face for displaying line numbers in compiler messages."
 556   :group 'compilation
 557   :version "22.1")
 558
 559 (defface compilation-column-number
 560   '((t :inherit font-lock-type-face))
 561   "Face for displaying column numbers in compiler messages."
 562   :group 'compilation
 563   :version "22.1")
 564
 565 (defcustom compilation-message-face 'underline
 566   "Face name to use for whole messages.
 567 Faces `compilation-error-face', `compilation-warning-face',
 568 `compilation-info-face', `compilation-line-face' and
 569 `compilation-column-face' get prepended to this, when applicable."
 570   :type 'face
 571   :group 'compilation
 572   :version "22.1")
 573
 574 (defvar compilation-error-face 'compilation-error
 575   "Face name to use for file name in error messages.")
 576
 577 (defvar compilation-warning-face 'compilation-warning
 578   "Face name to use for file name in warning messages.")
 579
 580 (defvar compilation-info-face 'compilation-info
 581   "Face name to use for file name in informational messages.")
 582
 583 (defvar compilation-line-face 'compilation-line-number
 584   "Face name to use for line numbers in compiler messages.")
 585
 586 (defvar compilation-column-face 'compilation-column-number
 587   "Face name to use for column numbers in compiler messages.")
 588
 589 ;; same faces as dired uses
 590 (defvar compilation-enter-directory-face 'font-lock-function-name-face
 591   "Face name to use for entering directory messages.")
 592
 593 (defvar compilation-leave-directory-face 'font-lock-type-face
 594   "Face name to use for leaving directory messages.")
 595
 596
 597
 598 ;; Used for compatibility with the old compile.el.
 599 (defvaralias 'compilation-last-buffer 'next-error-last-buffer)
 600 (defvar compilation-parsing-end (make-marker))
 601 (defvar compilation-parse-errors-function nil)
 602 (defvar compilation-error-list nil)
 603 (defvar compilation-old-error-list nil)
 604
 605 (defun compilation-face (type)
 606   (or (and (car type) (match-end (car type)) compilation-warning-face)
 607       (and (cdr type) (match-end (cdr type)) compilation-info-face)
 608       compilation-error-face))
 609
 610 ;; Internal function for calculating the text properties of a directory
 611 ;; change message.  The directory property is important, because it is
 612 ;; the stack of nested enter-messages.  Relative filenames on the following
 613 ;; lines are relative to the top of the stack.
 614 (defun compilation-directory-properties (idx leave)
 615   (if leave (setq leave (match-end leave)))
 616   ;; find previous stack, and push onto it, or if `leave' pop it
 617   (let ((dir (previous-single-property-change (point) 'directory)))
 618     (setq dir (if dir (or (get-text-property (1- dir) 'directory)
 619                           (get-text-property dir 'directory))))
 620     `(face ,(if leave
 621                 compilation-leave-directory-face
 622               compilation-enter-directory-face)
 623       directory ,(if leave
 624                      (or (cdr dir)
 625                          '(nil))        ; nil only isn't a property-change
 626                    (cons (match-string-no-properties idx) dir))
 627       mouse-face highlight
 628       keymap compilation-button-map
 629       help-echo "mouse-2: visit destination directory")))
 630
 631 ;; Data type `reverse-ordered-alist' retriever.  This function retrieves the
 632 ;; KEY element from the ALIST, creating it in the right position if not already
 633 ;; present. ALIST structure is
 634 ;; '(ANCHOR (KEY1 ...) (KEY2 ...)... (KEYn ALIST ...))
 635 ;; ANCHOR is ignored, but necessary so that elements can be inserted.  KEY1
 636 ;; may be nil.  The other KEYs are ordered backwards so that growing line
 637 ;; numbers can be inserted in front and searching can abort after half the
 638 ;; list on average.
 639 (eval-when-compile                  ;Don't keep it at runtime if not needed.
 640 (defmacro compilation-assq (key alist)
 641   `(let* ((l1 ,alist)
 642           (l2 (cdr l1)))
 643      (car (if (if (null ,key)
 644                   (if l2 (null (caar l2)))
 645                 (while (if l2 (if (caar l2) (< ,key (caar l2)) t))
 646                   (setq l1 l2
 647                         l2 (cdr l1)))
 648                 (if l2 (eq ,key (caar l2))))
 649               l2
 650             (setcdr l1 (cons (list ,key) l2)))))))
 651
 652
 653 ;; This function is the central driver, called when font-locking to gather
 654 ;; all information needed to later jump to corresponding source code.
 655 ;; Return a property list with all meta information on this error location.
 656
 657 (defun compilation-error-properties (file line end-line col end-col type fmt)
 658   (unless (< (next-single-property-change (match-beginning 0) 'directory nil (point))
 659              (point))
 660     (if file
 661         (if (functionp file)
 662             (setq file (funcall file))
 663           (let (dir)
 664             (setq file (match-string-no-properties file))
 665             (unless (file-name-absolute-p file)
 666               (setq dir (previous-single-property-change (point) 'directory)
 667                     dir (if dir (or (get-text-property (1- dir) 'directory)
 668                                     (get-text-property dir 'directory)))))
 669             (setq file (cons file (car dir)))))
 670       ;; This message didn't mention one, get it from previous
 671       (let ((prev-pos
 672              ;; Find the previous message.
 673              (previous-single-property-change (point) 'message)))
 674         (if prev-pos
 675             ;; Get the file structure that belongs to it.
 676             (let* ((prev
 677                     (or (get-text-property (1- prev-pos) 'message)
 678                         (get-text-property prev-pos 'message)))
 679                    (prev-struct
 680                     (car (nth 2 (car prev)))))
 681               ;; Construct FILE . DIR from that.
 682               (if prev-struct
 683                   (setq file (cons (car prev-struct)
 684                                    (cadr prev-struct))))))
 685         (unless file
 686           (setq file '("*unknown*")))))
 687     ;; All of these fields are optional, get them only if we have an index, and
 688     ;; it matched some part of the message.
 689     (and line
 690          (setq line (match-string-no-properties line))
 691          (setq line (string-to-number line)))
 692     (and end-line
 693          (setq end-line (match-string-no-properties end-line))
 694          (setq end-line (string-to-number end-line)))
 695     (if col
 696         (if (functionp col)
 697             (setq col (funcall col))
 698           (and
 699            (setq col (match-string-no-properties col))
 700            (setq col (- (string-to-number col) compilation-first-column)))))
 701     (if (and end-col (functionp end-col))
 702         (setq end-col (funcall end-col))
 703       (if (and end-col (setq end-col (match-string-no-properties end-col)))
 704           (setq end-col (- (string-to-number end-col) compilation-first-column -1))
 705         (if end-line (setq end-col -1))))
 706     (if (consp type)                    ; not a static type, check what it is.
 707         (setq type (or (and (car type) (match-end (car type)) 1)
 708                        (and (cdr type) (match-end (cdr type)) 0)
 709                        2)))
 710     (compilation-internal-error-properties file line end-line col end-col type fmt)))
 711
 712 (defun compilation-move-to-column (col screen)
 713   "Go to column COL on the current line.
 714 If SCREEN is non-nil, columns are screen columns, otherwise, they are
 715 just char-counts."
 716   (if screen
 717       (move-to-column col)
 718     (goto-char (min (+ (line-beginning-position) col) (line-end-position)))))
 719
 720 (defun compilation-internal-error-properties (file line end-line col end-col type fmts)
 721   "Get the meta-info that will be added as text-properties.
 722 LINE, END-LINE, COL, END-COL are integers or nil.
 723 TYPE can be 0, 1, or 2, meaning error, warning, or just info.
 724 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME) or nil.
 725 FMTS is a list of format specs for transforming the file name.
 726  (See `compilation-error-regexp-alist'.)"
 727   (unless file (setq file '("*unknown*")))
 728   (let* ((file-struct (compilation-get-file-structure file fmts))
 729          ;; Get first already existing marker (if any has one, all have one).
 730          ;; Do this first, as the compilation-assq`s may create new nodes.
 731          (marker-line (car (cddr file-struct))) ; a line structure
 732          (marker (nth 3 (cadr marker-line)))    ; its marker
 733          (compilation-error-screen-columns compilation-error-screen-columns)
 734          end-marker loc end-loc)
 735     (if (not (and marker (marker-buffer marker)))
 736         (setq marker nil)               ; no valid marker for this file
 737       (setq loc (or line 1))            ; normalize no linenumber to line 1
 738       (catch 'marker                    ; find nearest loc, at least one exists
 739         (dolist (x (nthcdr 3 file-struct))      ; loop over remaining lines
 740           (if (> (car x) loc)           ; still bigger
 741               (setq marker-line x)
 742             (if (> (- (or (car marker-line) 1) loc)
 743                    (- loc (car x)))     ; current line is nearer
 744                 (setq marker-line x))
 745             (throw 'marker t))))
 746       (setq marker (nth 3 (cadr marker-line))
 747             marker-line (or (car marker-line) 1))
 748       (with-current-buffer (marker-buffer marker)
 749         (save-excursion
 750           (save-restriction
 751             (widen)
 752             (goto-char (marker-position marker))
 753             (when (or end-col end-line)
 754               (beginning-of-line (- (or end-line line) marker-line -1))
 755               (if (or (null end-col) (< end-col 0))
 756                   (end-of-line)
 757                 (compilation-move-to-column
 758                  end-col compilation-error-screen-columns))
 759               (setq end-marker (list (point-marker))))
 760             (beginning-of-line (if end-line
 761                                    (- line end-line -1)
 762                                  (- loc marker-line -1)))
 763             (if col
 764                 (compilation-move-to-column
 765                  col compilation-error-screen-columns)
 766               (forward-to-indentation 0))
 767             (setq marker (list (point-marker)))))))
 768
 769     (setq loc (compilation-assq line (cdr file-struct)))
 770     (if end-line
 771         (setq end-loc (compilation-assq end-line (cdr file-struct))
 772               end-loc (compilation-assq end-col end-loc))
 773       (if end-col                       ; use same line element
 774           (setq end-loc (compilation-assq end-col loc))))
 775     (setq loc (compilation-assq col loc))
 776     ;; If they are new, make the loc(s) reference the file they point to.
 777     (or (cdr loc) (setcdr loc `(,line ,file-struct ,@marker)))
 778     (if end-loc
 779         (or (cdr end-loc)
 780             (setcdr end-loc `(,(or end-line line) ,file-struct ,@end-marker))))
 781
 782     ;; Must start with face
 783     `(face ,compilation-message-face
 784            message (,loc ,type ,end-loc)
 785            ,@(if compilation-debug
 786                  `(debug (,(assoc (with-no-warnings matcher) font-lock-keywords)
 787                           ,@(match-data))))
 788            help-echo ,(if col
 789                           "mouse-2: visit this file, line and column"
 790                         (if line
 791                             "mouse-2: visit this file and line"
 792                           "mouse-2: visit this file"))
 793            keymap compilation-button-map
 794            mouse-face highlight)))
 795
 796 (defun compilation-mode-font-lock-keywords ()
 797   "Return expressions to highlight in Compilation mode."
 798   (if compilation-parse-errors-function
 799       ;; An old package!  Try the compatibility code.
 800       '((compilation-compat-parse-errors))
 801     (append
 802      ;; make directory tracking
 803      (if compilation-directory-matcher
 804          `((,(car compilation-directory-matcher)
 805             ,@(mapcar (lambda (elt)
 806                         `(,(car elt)
 807                           (compilation-directory-properties
 808                            ,(car elt) ,(cdr elt))
 809                           t t))
 810                       (cdr compilation-directory-matcher)))))
 811
 812      ;; Compiler warning/error lines.
 813      (mapcar
 814       (lambda (item)
 815         (if (symbolp item)
 816             (setq item (cdr (assq item
 817                                   compilation-error-regexp-alist-alist))))
 818         (let ((file (nth 1 item))
 819               (line (nth 2 item))
 820               (col (nth 3 item))
 821               (type (nth 4 item))
 822               end-line end-col fmt)
 823           (if (consp file)      (setq fmt (cdr file)      file (car file)))
 824           (if (consp line)      (setq end-line (cdr line) line (car line)))
 825           (if (consp col)       (setq end-col (cdr col)   col (car col)))
 826
 827           (if (functionp line)
 828               ;; The old compile.el had here an undocumented hook that
 829               ;; allowed `line' to be a function that computed the actual
 830               ;; error location.  Let's do our best.
 831               `(,(car item)
 832                 (0 (save-match-data
 833                      (compilation-compat-error-properties
 834                       (funcall ',line (cons (match-string ,file)
 835                                             (cons default-directory
 836                                                   ',(nthcdr 4 item)))
 837                                ,(if col `(match-string ,col))))))
 838                 (,file compilation-error-face t))
 839
 840             (unless (or (null (nth 5 item)) (integerp (nth 5 item)))
 841               (error "HYPERLINK should be an integer: %s" (nth 5 item)))
 842
 843             `(,(nth 0 item)
 844
 845               ,@(when (integerp file)
 846                   `((,file ,(if (consp type)
 847                                 `(compilation-face ',type)
 848                               (aref [compilation-info-face
 849                                      compilation-warning-face
 850                                      compilation-error-face]
 851                                     (or type 2))))))
 852
 853               ,@(when line
 854                   `((,line compilation-line-face nil t)))
 855               ,@(when end-line
 856                   `((,end-line compilation-line-face nil t)))
 857
 858               ,@(when (integerp col)
 859                   `((,col compilation-column-face nil t)))
 860               ,@(when (integerp end-col)
 861                   `((,end-col compilation-column-face nil t)))
 862
 863               ,@(nthcdr 6 item)
 864               (,(or (nth 5 item) 0)
 865                (compilation-error-properties ',file ,line ,end-line
 866                                              ,col ,end-col ',(or type 2)
 867                                              ',fmt)
 868                append)))))              ; for compilation-message-face
 869       compilation-error-regexp-alist)
 870
 871      compilation-mode-font-lock-keywords)))
 872
 873 \f
 874 ;;;###autoload
 875 (defun compile (command &optional comint)
 876   "Compile the program including the current buffer.  Default: run `make'.
 877 Runs COMMAND, a shell command, in a separate process asynchronously
 878 with output going to the buffer `*compilation*'.
 879
 880 You can then use the command \\[next-error] to find the next error message
 881 and move to the source code that caused it.
 882
 883 If optional second arg COMINT is t the buffer will be in Comint mode with
 884 `compilation-shell-minor-mode'.
 885
 886 Interactively, prompts for the command if `compilation-read-command' is
 887 non-nil; otherwise uses `compile-command'.  With prefix arg, always prompts.
 888 Additionally, with universal prefix arg, compilation buffer will be in
 889 comint mode, i.e. interactive.
 890
 891 To run more than one compilation at once, start one and rename
 892 the \`*compilation*' buffer to some other name with
 893 \\[rename-buffer].  Then start the next one.  On most systems,
 894 termination of the main compilation process kills its
 895 subprocesses.
 896
 897 The name used for the buffer is actually whatever is returned by
 898 the function in `compilation-buffer-name-function', so you can set that
 899 to a function that generates a unique name."
 900   (interactive
 901    (list
 902     (let ((command (eval compile-command)))
 903       (if (or compilation-read-command current-prefix-arg)
 904           (read-from-minibuffer "Compile command: "
 905                                 command nil nil
 906                                 (if (equal (car compile-history) command)
 907                                     '(compile-history . 1)
 908                                   'compile-history))
 909         command))
 910     (consp current-prefix-arg)))
 911   (unless (equal command (eval compile-command))
 912     (setq compile-command command))
 913   (save-some-buffers (not compilation-ask-about-save) nil)
 914   (setq compilation-directory default-directory)
 915   (compilation-start command comint))
 916
 917 ;; run compile with the default command line
 918 (defun recompile ()
 919   "Re-compile the program including the current buffer.
 920 If this is run in a Compilation mode buffer, re-use the arguments from the
 921 original use.  Otherwise, recompile using `compile-command'."
 922   (interactive)
 923   (save-some-buffers (not compilation-ask-about-save) nil)
 924   (let ((default-directory
 925           (or (and (not (eq major-mode (nth 1 compilation-arguments)))
 926                    compilation-directory)
 927               default-directory)))
 928     (apply 'compilation-start (or compilation-arguments
 929                                   `(,(eval compile-command))))))
 930
 931 (defcustom compilation-scroll-output nil
 932   "*Non-nil to scroll the *compilation* buffer window as output appears.
 933
 934 Setting it causes the Compilation mode commands to put point at the
 935 end of their output window so that the end of the output is always
 936 visible rather than the beginning."
 937   :type 'boolean
 938   :version "20.3"
 939   :group 'compilation)
 940
 941
 942 (defun compilation-buffer-name (mode-name mode-command name-function)
 943   "Return the name of a compilation buffer to use.
 944 If NAME-FUNCTION is non-nil, call it with one argument MODE-NAME
 945 to determine the buffer name.
 946 Likewise if `compilation-buffer-name-function' is non-nil.
 947 If current buffer is the mode MODE-COMMAND,
 948 return the name of the current buffer, so that it gets reused.
 949 Otherwise, construct a buffer name from MODE-NAME."
 950   (cond (name-function
 951          (funcall name-function mode-name))
 952         (compilation-buffer-name-function
 953          (funcall compilation-buffer-name-function mode-name))
 954         ((and (eq mode-command major-mode)
 955               (eq major-mode (nth 1 compilation-arguments)))
 956          (buffer-name))
 957         (t
 958          (concat "*" (downcase mode-name) "*"))))
 959
 960 ;; This is a rough emulation of the old hack, until the transition to new
 961 ;; compile is complete.
 962 (defun compile-internal (command error-message
 963                                  &optional name-of-mode parser
 964                                  error-regexp-alist name-function
 965                                  enter-regexp-alist leave-regexp-alist
 966                                  file-regexp-alist nomessage-regexp-alist
 967                                  no-async highlight-regexp local-map)
 968   (if parser
 969       (error "Compile now works very differently, see `compilation-error-regexp-alist'"))
 970   (let ((compilation-error-regexp-alist
 971          (append file-regexp-alist (or error-regexp-alist
 972                                        compilation-error-regexp-alist)))
 973         (compilation-error (replace-regexp-in-string "^No more \\(.+\\)s\\.?"
 974                                                      "\\1" error-message)))
 975     (compilation-start command nil name-function highlight-regexp)))
 976 (make-obsolete 'compile-internal 'compilation-start)
 977
 978 ;;;###autoload
 979 (defun compilation-start (command &optional mode name-function highlight-regexp)
 980   "Run compilation command COMMAND (low level interface).
 981 If COMMAND starts with a cd command, that becomes the `default-directory'.
 982 The rest of the arguments are optional; for them, nil means use the default.
 983
 984 MODE is the major mode to set in the compilation buffer.  Mode
 985 may also be t meaning use `compilation-shell-minor-mode' under `comint-mode'.
 986 If NAME-FUNCTION is non-nil, call it with one argument (the mode name)
 987 to determine the buffer name.
 988
 989 If HIGHLIGHT-REGEXP is non-nil, `next-error' will temporarily highlight
 990 the matching section of the visited source line; the default is to use the
 991 global value of `compilation-highlight-regexp'.
 992
 993 Returns the compilation buffer created."
 994   (or mode (setq mode 'compilation-mode))
 995   (let* ((name-of-mode
 996           (if (eq mode t)
 997               (prog1 "compilation" (require 'comint))
 998             (replace-regexp-in-string "-mode$" "" (symbol-name mode))))
 999          (thisdir default-directory)
1000          outwin outbuf)
1001     (with-current-buffer
1002         (setq outbuf
1003               (get-buffer-create
1004                (compilation-buffer-name name-of-mode mode name-function)))
1005       (let ((comp-proc (get-buffer-process (current-buffer))))
1006         (if comp-proc
1007             (if (or (not (eq (process-status comp-proc) 'run))
1008                     (yes-or-no-p
1009                      (format "A %s process is running; kill it? "
1010                              name-of-mode)))
1011                 (condition-case ()
1012                     (progn
1013                       (interrupt-process comp-proc)
1014                       (sit-for 1)
1015                       (delete-process comp-proc))
1016                   (error nil))
1017               (error "Cannot have two processes in `%s' at once"
1018                      (buffer-name)))))
1019       (buffer-disable-undo (current-buffer))
1020       ;; first transfer directory from where M-x compile was called
1021       (setq default-directory thisdir)
1022       ;; Make compilation buffer read-only.  The filter can still write it.
1023       ;; Clear out the compilation buffer.
1024       (let ((inhibit-read-only t)
1025             (default-directory thisdir))
1026         ;; Then evaluate a cd command if any, but don't perform it yet, else start-command
1027         ;; would do it again through the shell: (cd "..") AND sh -c "cd ..; make"
1028         (cd (if (string-match "^\\s *cd\\(?:\\s +\\(\\S +?\\)\\)?\\s *[;&\n]" command)
1029                 (if (match-end 1)
1030                     (substitute-env-vars (match-string 1 command))
1031                   "~")
1032               default-directory))
1033         (erase-buffer)
1034         ;; Select the desired mode.
1035         (if (not (eq mode t))
1036             (funcall mode)
1037           (setq buffer-read-only nil)
1038           (with-no-warnings (comint-mode))
1039           (compilation-shell-minor-mode))
1040         (if highlight-regexp
1041             (set (make-local-variable 'compilation-highlight-regexp)
1042                  highlight-regexp))
1043         ;; Output a mode setter, for saving and later reloading this buffer.
1044         (insert "-*- mode: " name-of-mode
1045                 "; default-directory: " (prin1-to-string default-directory)
1046                 " -*-\n"
1047                 (format "%s started at %s\n\n"
1048                         mode-name
1049                         (substring (current-time-string) 0 19))
1050                 command "\n")
1051         (setq thisdir default-directory))
1052       (set-buffer-modified-p nil))
1053     ;; If we're already in the compilation buffer, go to the end
1054     ;; of the buffer, so point will track the compilation output.
1055     (if (eq outbuf (current-buffer))
1056         (goto-char (point-max)))
1057     ;; Pop up the compilation buffer.
1058     (setq outwin (display-buffer outbuf nil t))
1059     (with-current-buffer outbuf
1060       (let ((process-environment
1061              (append
1062               compilation-environment
1063               (if (if (boundp 'system-uses-terminfo) ; `if' for compiler warning
1064                       system-uses-terminfo)
1065                   (list "TERM=dumb" "TERMCAP="
1066                         (format "COLUMNS=%d" (window-width)))
1067                 (list "TERM=emacs"
1068                       (format "TERMCAP=emacs:co#%d:tc=unknown:"
1069                               (window-width))))
1070               ;; Set the EMACS variable, but
1071               ;; don't override users' setting of $EMACS.
1072               (unless (getenv "EMACS")
1073                 (list "EMACS=t"))
1074               (list "INSIDE_EMACS=t")
1075               (copy-sequence process-environment))))
1076         (set (make-local-variable 'compilation-arguments)
1077              (list command mode name-function highlight-regexp))
1078         (set (make-local-variable 'revert-buffer-function)
1079              'compilation-revert-buffer)
1080         (set-window-start outwin (point-min))
1081         (or (eq outwin (selected-window))
1082             (set-window-point outwin (if compilation-scroll-output
1083                                          (point)
1084                                        (point-min))))
1085         ;; The setup function is called before compilation-set-window-height
1086         ;; so it can set the compilation-window-height buffer locally.
1087         (if compilation-process-setup-function
1088             (funcall compilation-process-setup-function))
1089         (compilation-set-window-height outwin)
1090         ;; Start the compilation.
1091         (if (fboundp 'start-process)
1092             (let ((proc (if (eq mode t)
1093                             (get-buffer-process
1094                              (with-no-warnings
1095                               (comint-exec outbuf (downcase mode-name)
1096                                            shell-file-name nil `("-c" ,command))))
1097                           (start-process-shell-command (downcase mode-name)
1098                                                        outbuf command))))
1099               ;; Make the buffer's mode line show process state.
1100               (setq mode-line-process '(":%s"))
1101               (set-process-sentinel proc 'compilation-sentinel)
1102               (set-process-filter proc 'compilation-filter)
1103               (set-marker (process-mark proc) (point) outbuf)
1104               (when compilation-disable-input
1105                 (condition-case nil
1106                     (process-send-eof proc)
1107                   ;; The process may have exited already.
1108                   (error nil)))
1109               (setq compilation-in-progress
1110                     (cons proc compilation-in-progress)))
1111           ;; No asynchronous processes available.
1112           (message "Executing `%s'..." command)
1113           ;; Fake modeline display as if `start-process' were run.
1114           (setq mode-line-process ":run")
1115           (force-mode-line-update)
1116           (sit-for 0)                   ; Force redisplay
1117           (let* ((buffer-read-only nil) ; call-process needs to modify outbuf
1118                  (status (call-process shell-file-name nil outbuf nil "-c"
1119                                        command)))
1120             (cond ((numberp status)
1121                    (compilation-handle-exit 'exit status
1122                                             (if (zerop status)
1123                                                 "finished\n"
1124                                               (format "\
1125 exited abnormally with code %d\n"
1126                                                       status))))
1127                   ((stringp status)
1128                    (compilation-handle-exit 'signal status
1129                                             (concat status "\n")))
1130                   (t
1131                    (compilation-handle-exit 'bizarre status status))))
1132           ;; Without async subprocesses, the buffer is not yet
1133           ;; fontified, so fontify it now.
1134           (let ((font-lock-verbose nil)) ; shut up font-lock messages
1135             (font-lock-fontify-buffer))
1136           (set-buffer-modified-p nil)
1137           (message "Executing `%s'...done" command)))
1138       ;; Now finally cd to where the shell started make/grep/...
1139       (setq default-directory thisdir))
1140     (if (buffer-local-value 'compilation-scroll-output outbuf)
1141         (save-selected-window
1142           (select-window outwin)
1143           (goto-char (point-max))))
1144     ;; Make it so the next C-x ` will use this buffer.
1145     (setq next-error-last-buffer outbuf)))
1146
1147 (defun compilation-set-window-height (window)
1148   "Set the height of WINDOW according to `compilation-window-height'."
1149   (let ((height (buffer-local-value 'compilation-window-height (window-buffer window))))
1150     (and height
1151          (= (window-width window) (frame-width (window-frame window)))
1152          ;; If window is alone in its frame, aside from a minibuffer,
1153          ;; don't change its height.
1154          (not (eq window (frame-root-window (window-frame window))))
1155          ;; Stef said that doing the saves in this order is safer:
1156          (save-excursion
1157            (save-selected-window
1158              (select-window window)
1159              (enlarge-window (- height (window-height))))))))
1160
1161 (defvar compilation-menu-map
1162   (let ((map (make-sparse-keymap "Errors")))
1163     (define-key map [stop-subjob]
1164       '("Stop Compilation" . kill-compilation))
1165     (define-key map [compilation-mode-separator2]
1166       '("----" . nil))
1167     (define-key map [compilation-first-error]
1168       '("First Error" . first-error))
1169     (define-key map [compilation-previous-error]
1170       '("Previous Error" . previous-error))
1171     (define-key map [compilation-next-error]
1172       '("Next Error" . next-error))
1173     map))
1174
1175 (defvar compilation-minor-mode-map
1176   (let ((map (make-sparse-keymap)))
1177     (define-key map [mouse-2] 'compile-goto-error)
1178     (define-key map [follow-link] 'mouse-face)
1179     (define-key map "\C-c\C-c" 'compile-goto-error)
1180     (define-key map "\C-m" 'compile-goto-error)
1181     (define-key map "\C-c\C-k" 'kill-compilation)
1182     (define-key map "\M-n" 'compilation-next-error)
1183     (define-key map "\M-p" 'compilation-previous-error)
1184     (define-key map "\M-{" 'compilation-previous-file)
1185     (define-key map "\M-}" 'compilation-next-file)
1186     ;; Set up the menu-bar
1187     (define-key map [menu-bar compilation]
1188       (cons "Errors" compilation-menu-map))
1189     map)
1190   "Keymap for `compilation-minor-mode'.")
1191
1192 (defvar compilation-shell-minor-mode-map
1193   (let ((map (make-sparse-keymap)))
1194     (define-key map "\M-\C-m" 'compile-goto-error)
1195     (define-key map "\M-\C-n" 'compilation-next-error)
1196     (define-key map "\M-\C-p" 'compilation-previous-error)
1197     (define-key map "\M-{" 'compilation-previous-file)
1198     (define-key map "\M-}" 'compilation-next-file)
1199     ;; Set up the menu-bar
1200     (define-key map [menu-bar compilation]
1201       (cons "Errors" compilation-menu-map))
1202     map)
1203   "Keymap for `compilation-shell-minor-mode'.")
1204
1205 (defvar compilation-button-map
1206   (let ((map (make-sparse-keymap)))
1207     (define-key map [mouse-2] 'compile-goto-error)
1208     (define-key map [follow-link] 'mouse-face)
1209     (define-key map "\C-m" 'compile-goto-error)
1210     map)
1211   "Keymap for compilation-message buttons.")
1212 (fset 'compilation-button-map compilation-button-map)
1213
1214 (defvar compilation-mode-map
1215   (let ((map (make-sparse-keymap)))
1216     ;; Don't inherit from compilation-minor-mode-map,
1217     ;; because that introduces a menu bar item we don't want.
1218     ;; That confuses C-down-mouse-3.
1219     (define-key map [mouse-2] 'compile-goto-error)
1220     (define-key map [follow-link] 'mouse-face)
1221     (define-key map "\C-c\C-c" 'compile-goto-error)
1222     (define-key map "\C-m" 'compile-goto-error)
1223     (define-key map "\C-c\C-k" 'kill-compilation)
1224     (define-key map "\M-n" 'compilation-next-error)
1225     (define-key map "\M-p" 'compilation-previous-error)
1226     (define-key map "\M-{" 'compilation-previous-file)
1227     (define-key map "\M-}" 'compilation-next-file)
1228     (define-key map "\t" 'compilation-next-error)
1229     (define-key map [backtab] 'compilation-previous-error)
1230
1231     (define-key map " " 'scroll-up)
1232     (define-key map "\^?" 'scroll-down)
1233     (define-key map "\C-c\C-f" 'next-error-follow-minor-mode)
1234
1235     ;; Set up the menu-bar
1236     (let ((submap (make-sparse-keymap "Compile")))
1237       (define-key map [menu-bar compilation]
1238         (cons "Compile" submap))
1239       (set-keymap-parent submap compilation-menu-map))
1240     (define-key map [menu-bar compilation compilation-separator2]
1241       '("----" . nil))
1242     (define-key map [menu-bar compilation compilation-grep]
1243       '("Search Files (grep)..." . grep))
1244     (define-key map [menu-bar compilation compilation-recompile]
1245       '("Recompile" . recompile))
1246     (define-key map [menu-bar compilation compilation-compile]
1247       '("Compile..." . compile))
1248     map)
1249   "Keymap for compilation log buffers.
1250 `compilation-minor-mode-map' is a parent of this.")
1251
1252 (put 'compilation-mode 'mode-class 'special)
1253
1254 (defvar compilation-skip-to-next-location t
1255   "*If non-nil, skip multiple error messages for the same source location.")
1256
1257 (defcustom compilation-skip-threshold 1
1258   "*Compilation motion commands skip less important messages.
1259 The value can be either 2 -- skip anything less than error, 1 --
1260 skip anything less than warning or 0 -- don't skip any messages.
1261 Note that all messages not positively identified as warning or
1262 info, are considered errors."
1263   :type '(choice (const :tag "Warnings and info" 2)
1264                  (const :tag "Info" 1)
1265                  (const :tag "None" 0))
1266   :group 'compilation
1267   :version "22.1")
1268
1269 (defcustom compilation-skip-visited nil
1270   "*Compilation motion commands skip visited messages if this is t.
1271 Visited messages are ones for which the file, line and column have been jumped
1272 to from the current content in the current compilation buffer, even if it was
1273 from a different message."
1274   :type 'boolean
1275   :group 'compilation
1276   :version "22.1")
1277
1278 ;;;###autoload
1279 (defun compilation-mode (&optional name-of-mode)
1280   "Major mode for compilation log buffers.
1281 \\<compilation-mode-map>To visit the source for a line-numbered error,
1282 move point to the error message line and type \\[compile-goto-error].
1283 To kill the compilation, type \\[kill-compilation].
1284
1285 Runs `compilation-mode-hook' with `run-mode-hooks' (which see).
1286
1287 \\{compilation-mode-map}"
1288   (interactive)
1289   (kill-all-local-variables)
1290   (use-local-map compilation-mode-map)
1291   (setq major-mode 'compilation-mode
1292         mode-name (or name-of-mode "Compilation"))
1293   (set (make-local-variable 'page-delimiter)
1294        compilation-page-delimiter)
1295   (compilation-setup)
1296   (setq buffer-read-only t)
1297   (run-mode-hooks 'compilation-mode-hook))
1298
1299 (defmacro define-compilation-mode (mode name doc &rest body)
1300   "This is like `define-derived-mode' without the PARENT argument.
1301 The parent is always `compilation-mode' and the customizable `compilation-...'
1302 variables are also set from the name of the mode you have chosen,
1303 by replacing the first word, e.g `compilation-scroll-output' from
1304 `grep-scroll-output' if that variable exists."
1305   (let ((mode-name (replace-regexp-in-string "-mode\\'" "" (symbol-name mode))))
1306     `(define-derived-mode ,mode compilation-mode ,name
1307        ,doc
1308        ,@(mapcar (lambda (v)
1309                    (setq v (cons v
1310                                  (intern-soft (replace-regexp-in-string
1311                                                "^compilation" mode-name
1312                                                (symbol-name v)))))
1313                    (and (cdr v)
1314                         (or (boundp (cdr v))
1315                             (if (boundp 'byte-compile-bound-variables)
1316                                 (memq (cdr v) byte-compile-bound-variables)))
1317                         `(set (make-local-variable ',(car v)) ,(cdr v))))
1318                  '(compilation-buffer-name-function
1319                    compilation-directory-matcher
1320                    compilation-error
1321                    compilation-error-regexp-alist
1322                    compilation-error-regexp-alist-alist
1323                    compilation-error-screen-columns
1324                    compilation-finish-function
1325                    compilation-finish-functions
1326                    compilation-first-column
1327                    compilation-mode-font-lock-keywords
1328                    compilation-page-delimiter
1329                    compilation-parse-errors-filename-function
1330                    compilation-process-setup-function
1331                    compilation-scroll-output
1332                    compilation-search-path
1333                    compilation-skip-threshold
1334                    compilation-window-height))
1335        ,@body)))
1336
1337 (defun compilation-revert-buffer (ignore-auto noconfirm)
1338   (if buffer-file-name
1339       (let (revert-buffer-function)
1340         (revert-buffer ignore-auto noconfirm))
1341     (if (or noconfirm (yes-or-no-p (format "Restart compilation? ")))
1342         (apply 'compilation-start compilation-arguments))))
1343
1344 (defvar compilation-current-error nil
1345   "Marker to the location from where the next error will be found.
1346 The global commands next/previous/first-error/goto-error use this.")
1347
1348 (defvar compilation-messages-start nil
1349   "Buffer position of the beginning of the compilation messages.
1350 If nil, use the beginning of buffer.")
1351
1352 ;; A function name can't be a hook, must be something with a value.
1353 (defconst compilation-turn-on-font-lock 'turn-on-font-lock)
1354
1355 (defun compilation-setup (&optional minor)
1356   "Prepare the buffer for the compilation parsing commands to work.
1357 Optional argument MINOR indicates this is called from
1358 `compilation-minor-mode'."
1359   (make-local-variable 'compilation-current-error)
1360   (make-local-variable 'compilation-messages-start)
1361   (make-local-variable 'compilation-error-screen-columns)
1362   (make-local-variable 'overlay-arrow-position)
1363   (set (make-local-variable 'overlay-arrow-string) "")
1364   (setq next-error-overlay-arrow-position nil)
1365   (add-hook 'kill-buffer-hook
1366             (lambda () (setq next-error-overlay-arrow-position nil)) nil t)
1367   ;; Note that compilation-next-error-function is for interfacing
1368   ;; with the next-error function in simple.el, and it's only
1369   ;; coincidentally named similarly to compilation-next-error.
1370   (setq next-error-function 'compilation-next-error-function)
1371   (set (make-local-variable 'font-lock-extra-managed-props)
1372        '(directory message help-echo mouse-face debug))
1373   (set (make-local-variable 'compilation-locs)
1374        (make-hash-table :test 'equal :weakness 'value))
1375   ;; lazy-lock would never find the message unless it's scrolled to.
1376   ;; jit-lock might fontify some things too late.
1377   (set (make-local-variable 'font-lock-support-mode) nil)
1378   (set (make-local-variable 'font-lock-maximum-size) nil)
1379   (if minor
1380       (let ((fld font-lock-defaults))
1381         (font-lock-add-keywords nil (compilation-mode-font-lock-keywords))
1382         (if font-lock-mode
1383             (if fld
1384                 (font-lock-fontify-buffer)
1385               (font-lock-change-mode)
1386               (turn-on-font-lock))
1387           (turn-on-font-lock)))
1388     (setq font-lock-defaults '(compilation-mode-font-lock-keywords t))
1389     ;; maybe defer font-lock till after derived mode is set up
1390     (run-mode-hooks 'compilation-turn-on-font-lock)))
1391
1392 ;;;###autoload
1393 (define-minor-mode compilation-shell-minor-mode
1394   "Toggle compilation shell minor mode.
1395 With arg, turn compilation mode on if and only if arg is positive.
1396 In this minor mode, all the error-parsing commands of the
1397 Compilation major mode are available but bound to keys that don't
1398 collide with Shell mode.  See `compilation-mode'.
1399 Turning the mode on runs the normal hook `compilation-shell-minor-mode-hook'."
1400   nil " Shell-Compile"
1401   :group 'compilation
1402   (if compilation-shell-minor-mode
1403       (compilation-setup t)
1404     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1405     (font-lock-fontify-buffer)))
1406
1407 ;;;###autoload
1408 (define-minor-mode compilation-minor-mode
1409   "Toggle compilation minor mode.
1410 With arg, turn compilation mode on if and only if arg is positive.
1411 In this minor mode, all the error-parsing commands of the
1412 Compilation major mode are available.  See `compilation-mode'.
1413 Turning the mode on runs the normal hook `compilation-minor-mode-hook'."
1414   nil " Compilation"
1415   :group 'compilation
1416   (if compilation-minor-mode
1417       (compilation-setup t)
1418     (font-lock-remove-keywords nil (compilation-mode-font-lock-keywords))
1419     (font-lock-fontify-buffer)))
1420
1421 (defun compilation-handle-exit (process-status exit-status msg)
1422   "Write MSG in the current buffer and hack its mode-line-process."
1423   (let ((inhibit-read-only t)
1424         (status (if compilation-exit-message-function
1425                     (funcall compilation-exit-message-function
1426                              process-status exit-status msg)
1427                   (cons msg exit-status)))
1428         (omax (point-max))
1429         (opoint (point)))
1430     ;; Record where we put the message, so we can ignore it later on.
1431     (goto-char omax)
1432     (insert ?\n mode-name " " (car status))
1433     (if (and (numberp compilation-window-height)
1434              (zerop compilation-window-height))
1435         (message "%s" (cdr status)))
1436     (if (bolp)
1437         (forward-char -1))
1438     (insert " at " (substring (current-time-string) 0 19))
1439     (goto-char (point-max))
1440     ;; Prevent that message from being recognized as a compilation error.
1441     (add-text-properties omax (point)
1442                          (append '(compilation-handle-exit t) nil))
1443     (setq mode-line-process (format ":%s [%s]" process-status (cdr status)))
1444     ;; Force mode line redisplay soon.
1445     (force-mode-line-update)
1446     (if (and opoint (< opoint omax))
1447         (goto-char opoint))
1448     (with-no-warnings
1449       (if compilation-finish-function
1450           (funcall compilation-finish-function (current-buffer) msg)))
1451     (let ((functions compilation-finish-functions))
1452       (while functions
1453         (funcall (car functions) (current-buffer) msg)
1454         (setq functions (cdr functions))))))
1455
1456 ;; Called when compilation process changes state.
1457 (defun compilation-sentinel (proc msg)
1458   "Sentinel for compilation buffers."
1459   (if (memq (process-status proc) '(exit signal))
1460       (let ((buffer (process-buffer proc)))
1461         (if (null (buffer-name buffer))
1462             ;; buffer killed
1463             (set-process-buffer proc nil)
1464           (with-current-buffer buffer
1465             ;; Write something in the compilation buffer
1466             ;; and hack its mode line.
1467             (compilation-handle-exit (process-status proc)
1468                                      (process-exit-status proc)
1469                                      msg)
1470             ;; Since the buffer and mode line will show that the
1471             ;; process is dead, we can delete it now.  Otherwise it
1472             ;; will stay around until M-x list-processes.
1473             (delete-process proc)))
1474         (setq compilation-in-progress (delq proc compilation-in-progress)))))
1475
1476 (defun compilation-filter (proc string)
1477   "Process filter for compilation buffers.
1478 Just inserts the text, but uses `insert-before-markers'."
1479   (if (buffer-name (process-buffer proc))
1480       (with-current-buffer (process-buffer proc)
1481         (let ((inhibit-read-only t))
1482           (save-excursion
1483             (goto-char (process-mark proc))
1484             (insert-before-markers string)
1485             (run-hooks 'compilation-filter-hook))))))
1486
1487 ;;; test if a buffer is a compilation buffer, assuming we're in the buffer
1488 (defsubst compilation-buffer-internal-p ()
1489   "Test if inside a compilation buffer."
1490   (local-variable-p 'compilation-locs))
1491
1492 ;;; test if a buffer is a compilation buffer, using compilation-buffer-internal-p
1493 (defsubst compilation-buffer-p (buffer)
1494   "Test if BUFFER is a compilation buffer."
1495   (with-current-buffer buffer
1496     (compilation-buffer-internal-p)))
1497
1498 (defmacro compilation-loop (< property-change 1+ error limit)
1499   `(let (opt)
1500      (while (,< n 0)
1501        (setq opt pt)
1502        (or (setq pt (,property-change pt 'message))
1503            ;; Handle the case where where the first error message is
1504            ;; at the start of the buffer, and n < 0.
1505            (if (or (eq (get-text-property ,limit 'message)
1506                        (get-text-property opt 'message))
1507                    (eq pt opt))
1508                (error ,error compilation-error)
1509              (setq pt ,limit)))
1510        ;; prop 'message usually has 2 changes, on and off, so
1511        ;; re-search if off
1512        (or (setq msg (get-text-property pt 'message))
1513            (if (setq pt (,property-change pt 'message nil ,limit))
1514                (setq msg (get-text-property pt 'message)))
1515            (error ,error compilation-error))
1516        (or (< (cadr msg) compilation-skip-threshold)
1517            (if different-file
1518                (eq (prog1 last (setq last (nth 2 (car msg))))
1519                    last))
1520            (if compilation-skip-visited
1521                (nthcdr 4 (car msg)))
1522            (if compilation-skip-to-next-location
1523                (eq (car msg) loc))
1524            ;; count this message only if none of the above are true
1525            (setq n (,1+ n))))))
1526
1527 (defun compilation-next-error (n &optional different-file pt)
1528   "Move point to the next error in the compilation buffer.
1529 Prefix arg N says how many error messages to move forwards (or
1530 backwards, if negative).
1531 Does NOT find the source line like \\[next-error]."
1532   (interactive "p")
1533   (or (compilation-buffer-p (current-buffer))
1534       (error "Not in a compilation buffer"))
1535   (or pt (setq pt (point)))
1536   (let* ((msg (get-text-property pt 'message))
1537          (loc (car msg))
1538          last)
1539     (if (zerop n)
1540         (unless (or msg                 ; find message near here
1541                     (setq msg (get-text-property (max (1- pt) (point-min))
1542                                                  'message)))
1543           (setq pt (previous-single-property-change pt 'message nil
1544                                                     (line-beginning-position)))
1545           (unless (setq msg (get-text-property (max (1- pt) (point-min)) 'message))
1546             (setq pt (next-single-property-change pt 'message nil
1547                                                   (line-end-position)))
1548             (or (setq msg (get-text-property pt 'message))
1549                 (setq pt (point)))))
1550       (setq last (nth 2 (car msg)))
1551       (if (>= n 0)
1552           (compilation-loop > next-single-property-change 1-
1553                             (if (get-buffer-process (current-buffer))
1554                                 "No more %ss yet"
1555                               "Moved past last %s")
1556                             (point-max))
1557         ;; Don't move "back" to message at or before point.
1558         ;; Pass an explicit (point-min) to make sure pt is non-nil.
1559         (setq pt (previous-single-property-change pt 'message nil (point-min)))
1560         (compilation-loop < previous-single-property-change 1+
1561                           "Moved back before first %s" (point-min))))
1562     (goto-char pt)
1563     (or msg
1564         (error "No %s here" compilation-error))))
1565
1566 (defun compilation-previous-error (n)
1567   "Move point to the previous error in the compilation buffer.
1568 Prefix arg N says how many error messages to move backwards (or
1569 forwards, if negative).
1570 Does NOT find the source line like \\[previous-error]."
1571   (interactive "p")
1572   (compilation-next-error (- n)))
1573
1574 (defun compilation-next-file (n)
1575   "Move point to the next error for a different file than the current one.
1576 Prefix arg N says how many files to move forwards (or backwards, if negative)."
1577   (interactive "p")
1578   (compilation-next-error n t))
1579
1580 (defun compilation-previous-file (n)
1581   "Move point to the previous error for a different file than the current one.
1582 Prefix arg N says how many files to move backwards (or forwards, if negative)."
1583   (interactive "p")
1584   (compilation-next-file (- n)))
1585
1586 (defun kill-compilation ()
1587   "Kill the process made by the \\[compile] or \\[grep] commands."
1588   (interactive)
1589   (let ((buffer (compilation-find-buffer)))
1590     (if (get-buffer-process buffer)
1591         (interrupt-process (get-buffer-process buffer))
1592       (error "The %s process is not running" (downcase mode-name)))))
1593
1594 (defalias 'compile-mouse-goto-error 'compile-goto-error)
1595
1596 (defun compile-goto-error (&optional event)
1597   "Visit the source for the error message at point.
1598 Use this command in a compilation log buffer.  Sets the mark at point there."
1599   (interactive (list last-input-event))
1600   (if event (posn-set-point (event-end event)))
1601   (or (compilation-buffer-p (current-buffer))
1602       (error "Not in a compilation buffer"))
1603   (if (get-text-property (point) 'directory)
1604       (dired-other-window (car (get-text-property (point) 'directory)))
1605     (push-mark)
1606     (setq compilation-current-error (point))
1607     (next-error-internal)))
1608
1609 ;; Return a compilation buffer.
1610 ;; If the current buffer is a compilation buffer, return it.
1611 ;; Otherwise, look for a compilation buffer and signal an error
1612 ;; if there are none.
1613 (defun compilation-find-buffer (&optional avoid-current)
1614   (next-error-find-buffer avoid-current 'compilation-buffer-internal-p))
1615
1616 ;;;###autoload
1617 (defun compilation-next-error-function (n &optional reset)
1618   "Advance to the next error message and visit the file where the error was.
1619 This is the value of `next-error-function' in Compilation buffers."
1620   (interactive "p")
1621   (when reset
1622     (setq compilation-current-error nil))
1623   (let* ((columns compilation-error-screen-columns) ; buffer's local value
1624          (last 1)
1625          (loc (compilation-next-error (or n 1) nil
1626                                       (or compilation-current-error
1627                                           compilation-messages-start
1628                                           (point-min))))
1629          (end-loc (nth 2 loc))
1630          (marker (point-marker)))
1631     (setq compilation-current-error (point-marker)
1632           overlay-arrow-position
1633             (if (bolp)
1634                 compilation-current-error
1635               (copy-marker (line-beginning-position)))
1636           loc (car loc))
1637     ;; If loc contains no marker, no error in that file has been visited.  If
1638     ;; the marker is invalid the buffer has been killed.  So, recalculate all
1639     ;; markers for that file.
1640     (unless (and (nth 3 loc) (marker-buffer (nth 3 loc)))
1641       (with-current-buffer (compilation-find-file marker (caar (nth 2 loc))
1642                                                   (cadr (car (nth 2 loc))))
1643         (save-restriction
1644           (widen)
1645           (goto-char (point-min))
1646           ;; Treat file's found lines in forward order, 1 by 1.
1647           (dolist (line (reverse (cddr (nth 2 loc))))
1648             (when (car line)            ; else this is a filename w/o a line#
1649               (beginning-of-line (- (car line) last -1))
1650               (setq last (car line)))
1651             ;; Treat line's found columns and store/update a marker for each.
1652             (dolist (col (cdr line))
1653               (if (car col)
1654                   (if (eq (car col) -1) ; special case for range end
1655                       (end-of-line)
1656                     (compilation-move-to-column (car col) columns))
1657                 (beginning-of-line)
1658                 (skip-chars-forward " \t"))
1659               (if (nth 3 col)
1660                   (set-marker (nth 3 col) (point))
1661                 (setcdr (nthcdr 2 col) `(,(point-marker)))))))))
1662     (compilation-goto-locus marker (nth 3 loc) (nth 3 end-loc))
1663     (setcdr (nthcdr 3 loc) t)))         ; Set this one as visited.
1664
1665 (defvar compilation-gcpro nil
1666   "Internal variable used to keep some values from being GC'd.")
1667 (make-variable-buffer-local 'compilation-gcpro)
1668
1669 (defun compilation-fake-loc (marker file &optional line col)
1670   "Preassociate MARKER with FILE.
1671 FILE should be ABSOLUTE-FILENAME or (RELATIVE-FILENAME . DIRNAME).
1672 This is useful when you compile temporary files, but want
1673 automatic translation of the messages to the real buffer from
1674 which the temporary file came.  This only works if done before a
1675 message about FILE appears!
1676
1677 Optional args LINE and COL default to 1 and beginning of
1678 indentation respectively.  The marker is expected to reflect
1679 this.  In the simplest case the marker points to the first line
1680 of the region that was saved to the temp file.
1681
1682 If you concatenate several regions into the temp file (e.g. a
1683 header with variable assignments and a code region), you must
1684 call this several times, once each for the last line of one
1685 region and the first line of the next region."
1686   (or (consp file) (setq file (list file)))
1687   (setq file (compilation-get-file-structure file))
1688   ;; Between the current call to compilation-fake-loc and the first occurrence
1689   ;; of an error message referring to `file', the data is only kept is the
1690   ;; weak hash-table compilation-locs, so we need to prevent this entry
1691   ;; in compilation-locs from being GC'd away.  --Stef
1692   (push file compilation-gcpro)
1693   (let ((loc (compilation-assq (or line 1) (cdr file))))
1694     (setq loc (compilation-assq col loc))
1695     (if (cdr loc)
1696         (setcdr (cddr loc) (list marker))
1697       (setcdr loc (list line file marker)))
1698     loc))
1699
1700 (defcustom compilation-context-lines nil
1701   "Display this many lines of leading context before the current message.
1702 If nil and the left fringe is displayed, don't scroll the
1703 compilation output window; an arrow in the left fringe points to
1704 the current message.  If nil and there is no left fringe, the message
1705 displays at the top of the window; there is no arrow."
1706   :type '(choice integer (const :tag "No window scrolling" nil))
1707   :group 'compilation
1708   :version "22.1")
1709
1710 (defsubst compilation-set-window (w mk)
1711   "Align the compilation output window W with marker MK near top."
1712   (if (integerp compilation-context-lines)
1713       (set-window-start w (save-excursion
1714                             (goto-char mk)
1715                             (beginning-of-line
1716                              (- 1 compilation-context-lines))
1717                             (point)))
1718     ;; If there is no left fringe.
1719     (if (equal (car (window-fringes)) 0)
1720         (set-window-start w (save-excursion
1721                               (goto-char mk)
1722                             (beginning-of-line 1)
1723                             (point)))))
1724     (set-window-point w mk))
1725
1726 (defvar next-error-highlight-timer)
1727
1728 (defun compilation-goto-locus (msg mk end-mk)
1729   "Jump to an error corresponding to MSG at MK.
1730 All arguments are markers.  If END-MK is non-nil, mark is set there
1731 and overlay is highlighted between MK and END-MK."
1732   ;; Show compilation buffer in other window, scrolled to this error.
1733   (let* ((from-compilation-buffer (eq (window-buffer (selected-window))
1734                                       (marker-buffer msg)))
1735          ;; Use an existing window if it is in a visible frame.
1736          (pre-existing (get-buffer-window (marker-buffer msg) 0))
1737          (w (if (and from-compilation-buffer pre-existing)
1738                 ;; Calling display-buffer here may end up (partly) hiding
1739                 ;; the error location if the two buffers are in two
1740                 ;; different frames.  So don't do it if it's not necessary.
1741                 pre-existing
1742               (let ((display-buffer-reuse-frames t)
1743                     (pop-up-windows t))
1744                 ;; Pop up a window.
1745                 (display-buffer (marker-buffer msg)))))
1746          (highlight-regexp (with-current-buffer (marker-buffer msg)
1747                              ;; also do this while we change buffer
1748                              (compilation-set-window w msg)
1749                              compilation-highlight-regexp)))
1750     ;; Ideally, the window-size should be passed to `display-buffer' (via
1751     ;; something like special-display-buffer) so it's only used when
1752     ;; creating a new window.
1753     (unless pre-existing (compilation-set-window-height w))
1754
1755     (if from-compilation-buffer
1756         ;; If the compilation buffer window was selected,
1757         ;; keep the compilation buffer in this window;
1758         ;; display the source in another window.
1759         (let ((pop-up-windows t))
1760           (pop-to-buffer (marker-buffer mk) 'other-window))
1761       (if (window-dedicated-p (selected-window))
1762           (pop-to-buffer (marker-buffer mk))
1763         (switch-to-buffer (marker-buffer mk))))
1764     ;; If narrowing gets in the way of going to the right place, widen.
1765     (unless (eq (goto-char mk) (point))
1766       (widen)
1767       (goto-char mk))
1768     (if end-mk
1769         (push-mark end-mk t)
1770       (if mark-active (setq mark-active)))
1771     ;; If hideshow got in the way of
1772     ;; seeing the right place, open permanently.
1773     (dolist (ov (overlays-at (point)))
1774       (when (eq 'hs (overlay-get ov 'invisible))
1775         (delete-overlay ov)
1776         (goto-char mk)))
1777
1778     (when highlight-regexp
1779       (if (timerp next-error-highlight-timer)
1780           (cancel-timer next-error-highlight-timer))
1781       (unless compilation-highlight-overlay
1782         (setq compilation-highlight-overlay
1783               (make-overlay (point-min) (point-min)))
1784         (overlay-put compilation-highlight-overlay 'face 'next-error))
1785       (with-current-buffer (marker-buffer mk)
1786         (save-excursion
1787           (if end-mk (goto-char end-mk) (end-of-line))
1788           (let ((end (point)))
1789             (if mk (goto-char mk) (beginning-of-line))
1790             (if (and (stringp highlight-regexp)
1791                      (re-search-forward highlight-regexp end t))
1792                 (progn
1793                   (goto-char (match-beginning 0))
1794                   (move-overlay compilation-highlight-overlay
1795                                 (match-beginning 0) (match-end 0)
1796                                 (current-buffer)))
1797               (move-overlay compilation-highlight-overlay
1798                             (point) end (current-buffer)))
1799             (if (or (eq next-error-highlight t)
1800                     (numberp next-error-highlight))
1801                 ;; We want highlighting: delete overlay on next input.
1802                 (add-hook 'pre-command-hook
1803                           'compilation-goto-locus-delete-o)
1804               ;; We don't want highlighting: delete overlay now.
1805               (delete-overlay compilation-highlight-overlay))
1806             ;; We want highlighting for a limited time:
1807             ;; set up a timer to delete it.
1808             (when (numberp next-error-highlight)
1809               (setq next-error-highlight-timer
1810                     (run-at-time next-error-highlight nil
1811                                  'compilation-goto-locus-delete-o)))))))
1812     (when (and (eq next-error-highlight 'fringe-arrow))
1813       ;; We want a fringe arrow (instead of highlighting).
1814       (setq next-error-overlay-arrow-position
1815             (copy-marker (line-beginning-position))))))
1816
1817 (defun compilation-goto-locus-delete-o ()
1818   (delete-overlay compilation-highlight-overlay)
1819   ;; Get rid of timer and hook that would try to do this again.
1820   (if (timerp next-error-highlight-timer)
1821       (cancel-timer next-error-highlight-timer))
1822   (remove-hook 'pre-command-hook
1823                'compilation-goto-locus-delete-o))
1824 \f
1825 (defun compilation-find-file (marker filename directory &rest formats)
1826   "Find a buffer for file FILENAME.
1827 Search the directories in `compilation-search-path'.
1828 A nil in `compilation-search-path' means to try the
1829 \"current\" directory, which is passed in DIRECTORY.
1830 If DIRECTORY. is relative, it is combined with `default-directory'.
1831 If DIRECTORY. is nil, that means use `default-directory'.
1832 If FILENAME is not found at all, ask the user where to find it.
1833 Pop up the buffer containing MARKER and scroll to MARKER if we ask the user."
1834   (or formats (setq formats '("%s")))
1835   (let ((dirs compilation-search-path)
1836         (spec-dir (if directory
1837                       (expand-file-name directory)
1838                     default-directory))
1839         buffer thisdir fmts name)
1840     (if (file-name-absolute-p filename)
1841         ;; The file name is absolute.  Use its explicit directory as
1842         ;; the first in the search path, and strip it from FILENAME.
1843         (setq filename (abbreviate-file-name (expand-file-name filename))
1844               dirs (cons (file-name-directory filename) dirs)
1845               filename (file-name-nondirectory filename)))
1846     ;; Now search the path.
1847     (while (and dirs (null buffer))
1848       (setq thisdir (or (car dirs) spec-dir)
1849             fmts formats)
1850       ;; For each directory, try each format string.
1851       (while (and fmts (null buffer))
1852         (setq name (expand-file-name (format (car fmts) filename) thisdir)
1853               buffer (and (file-exists-p name)
1854                           (find-file-noselect name))
1855               fmts (cdr fmts)))
1856       (setq dirs (cdr dirs)))
1857     (while (null buffer)    ;Repeat until the user selects an existing file.
1858       ;; The file doesn't exist.  Ask the user where to find it.
1859       (save-excursion            ;This save-excursion is probably not right.
1860         (let ((pop-up-windows t))
1861           (compilation-set-window (display-buffer (marker-buffer marker))
1862                                   marker)
1863           (let* ((name (read-file-name
1864                         (format "Find this %s in (default %s): "
1865                                 compilation-error filename)
1866                         spec-dir filename t nil))
1867                  (origname name))
1868             (cond
1869              ((not (file-exists-p name))
1870               (message "Cannot find file `%s'" name)
1871               (ding) (sit-for 2))
1872              ((and (file-directory-p name)
1873                    (not (file-exists-p
1874                          (setq name (expand-file-name filename name)))))
1875               (message "No `%s' in directory %s" filename origname)
1876               (ding) (sit-for 2))
1877              (t
1878               (setq buffer (find-file-noselect name))))))))
1879     ;; Make intangible overlays tangible.
1880     ;; This is weird: it's not even clear which is the current buffer,
1881     ;; so the code below can't be expected to DTRT here.  -- Stef
1882     (dolist (ov (overlays-in (point-min) (point-max)))
1883       (when (overlay-get ov 'intangible)
1884         (overlay-put ov 'intangible nil)))
1885     buffer))
1886
1887 (defun compilation-get-file-structure (file &optional fmt)
1888   "Retrieve FILE's file-structure or create a new one.
1889 FILE should be (FILENAME) or (RELATIVE-FILENAME . DIRNAME).
1890 In the former case, FILENAME may be relative or absolute.
1891
1892 The file-structure looks like this:
1893   (list (list FILENAME [DIR-FROM-PREV-MSG]) FMT LINE-STRUCT...)
1894 "
1895   (or (gethash file compilation-locs)
1896       ;; File was not previously encountered, at least not in the form passed.
1897       ;; Let's normalize it and look again.
1898       (let ((filename (car file))
1899             ;; Get the specified directory from FILE.
1900             (spec-directory (if (cdr file)
1901                                 (file-truename (cdr file)))))
1902
1903         ;; Check for a comint-file-name-prefix and prepend it if appropriate.
1904         ;; (This is very useful for compilation-minor-mode in an rlogin-mode
1905         ;; buffer.)
1906         (when (and (boundp 'comint-file-name-prefix)
1907                    (not (equal comint-file-name-prefix "")))
1908           (if (file-name-absolute-p filename)
1909               (setq filename
1910                     (concat comint-file-name-prefix filename))
1911             (if spec-directory
1912                 (setq spec-directory
1913                       (file-truename
1914                        (concat comint-file-name-prefix spec-directory))))))
1915
1916         ;; If compilation-parse-errors-filename-function is
1917         ;; defined, use it to process the filename.
1918         (when compilation-parse-errors-filename-function
1919           (setq filename
1920                 (funcall compilation-parse-errors-filename-function
1921                          filename)))
1922
1923         ;; Some compilers (e.g. Sun's java compiler, reportedly) produce bogus
1924         ;; file names like "./bar//foo.c" for file "bar/foo.c";
1925         ;; expand-file-name will collapse these into "/foo.c" and fail to find
1926         ;; the appropriate file.  So we look for doubled slashes in the file
1927         ;; name and fix them.
1928         (setq filename (command-line-normalize-file-name filename))
1929
1930         ;; Store it for the possibly unnormalized name
1931         (puthash file
1932                  ;; Retrieve or create file-structure for normalized name
1933                  (or (gethash (list filename) compilation-locs)
1934                      (puthash (list filename)
1935                               (list (list filename spec-directory) fmt)
1936                               compilation-locs))
1937                  compilation-locs))))
1938
1939 (add-to-list 'debug-ignored-errors "^No more [-a-z ]+s yet$")
1940
1941 ;;; Compatibility with the old compile.el.
1942
1943 (defun compile-buffer-substring (n) (if n (match-string n)))
1944
1945 (defun compilation-compat-error-properties (err)
1946   "Map old-style error ERR to new-style message."
1947   ;; Old-style structure is (MARKER (FILE DIR) LINE COL) or
1948   ;; (MARKER . MARKER).
1949   (let ((dst (cdr err)))
1950     (if (markerp dst)
1951         ;; Must start with a face, for font-lock.
1952         `(face nil
1953           message ,(list (list nil nil nil dst) 2)
1954           help-echo "mouse-2: visit the source location"
1955           keymap compilation-button-map
1956           mouse-face highlight)
1957       ;; Too difficult to do it by hand: dispatch to the normal code.
1958       (let* ((file (pop dst))
1959              (line (pop dst))
1960              (col (pop dst))
1961              (filename (pop file))
1962              (dirname (pop file))
1963              (fmt (pop file)))
1964         (compilation-internal-error-properties
1965          (cons filename dirname) line nil col nil 2 fmt)))))
1966
1967 (defun compilation-compat-parse-errors (limit)
1968   (when compilation-parse-errors-function
1969     ;; FIXME: We should remove the rest of the compilation keywords
1970     ;; but we can't do that from here because font-lock is using
1971     ;; the value right now.  --stef
1972     (save-excursion
1973       (setq compilation-error-list nil)
1974       ;; Reset compilation-parsing-end each time because font-lock
1975       ;; might force us the re-parse many times (typically because
1976       ;; some code adds some text-property to the output that we
1977       ;; already parsed).  You might say "why reparse", well:
1978       ;; because font-lock has just removed the `message' property so
1979       ;; have to do it all over again.
1980       (if compilation-parsing-end
1981           (set-marker compilation-parsing-end (point))
1982         (setq compilation-parsing-end (point-marker)))
1983       (condition-case nil
1984           ;; Ignore any error: we're calling this function earlier than
1985           ;; in the old compile.el so things might not all be setup yet.
1986           (funcall compilation-parse-errors-function limit nil)
1987         (error nil))
1988       (dolist (err (if (listp compilation-error-list) compilation-error-list))
1989         (let* ((src (car err))
1990                (dst (cdr err))
1991                (loc (cond ((markerp dst) (list nil nil nil dst))
1992                           ((consp dst)
1993                            (list (nth 2 dst) (nth 1 dst)
1994                                  (cons (cdar dst) (caar dst)))))))
1995           (when loc
1996             (goto-char src)
1997             ;; (put-text-property src (line-end-position) 'font-lock-face 'font-lock-warning-face)
1998             (put-text-property src (line-end-position)
1999                                'message (list loc 2)))))))
2000   (goto-char limit)
2001   nil)
2002
2003 ;; Beware: this is not only compatiblity code.  New code stil uses it.  --Stef
2004 (defun compilation-forget-errors ()
2005   ;; In case we hit the same file/line specs, we want to recompute a new
2006   ;; marker for them, so flush our cache.
2007   (setq compilation-locs (make-hash-table :test 'equal :weakness 'value))
2008   (setq compilation-gcpro nil)
2009   ;; FIXME: the old code reset the directory-stack, so maybe we should
2010   ;; put a `directory change' marker of some sort, but where?  -stef
2011   ;;
2012   ;; FIXME: The old code moved compilation-current-error (which was
2013   ;; virtually represented by a mix of compilation-parsing-end and
2014   ;; compilation-error-list) to point-min, but that was only meaningful for
2015   ;; the internal uses of compilation-forget-errors: all calls from external
2016   ;; packages seem to be followed by a move of compilation-parsing-end to
2017   ;; something equivalent to point-max.  So we speculatively move
2018   ;; compilation-current-error to point-max (since the external package
2019   ;; won't know that it should do it).  --stef
2020   (setq compilation-current-error nil)
2021   (let* ((proc (get-buffer-process (current-buffer)))
2022          (mark (if proc (process-mark proc)))
2023          (pos (or mark (point-max))))
2024     (setq compilation-messages-start
2025           ;; In the future, ignore the text already present in the buffer.
2026           ;; Since many process filter functions insert before markers,
2027           ;; we need to put ours just before the insertion point rather
2028           ;; than at the insertion point.  If that's not possible, then
2029           ;; don't use a marker.  --Stef
2030           (if (> pos (point-min)) (copy-marker (1- pos)) pos))))
2031
2032 ;;;###autoload
2033 (add-to-list 'auto-mode-alist '("\\.gcov\\'" . compilation-mode))
2034
2035 (provide 'compile)
2036
2037 ;; arch-tag: 12465727-7382-4f72-b234-79855a00dd8c
2038 ;;; compile.el ends here