lisp/time.el

   1 ;;; time.el --- display time, load and mail indicator in mode line of Emacs.
   2
   3 ;; Copyright (C) 1985, 86, 87, 93, 94, 96, 2000 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Facilities to display current time/date and a new-mail indicator
  27 ;; in the Emacs mode line.  The single entry point is `display-time'.
  28
  29 ;;; Code:
  30
  31 (defgroup display-time nil
  32   "Display time and load in mode line of Emacs."
  33   :group 'modeline
  34   :group 'mail)
  35
  36
  37 ;;;###autoload
  38 (defcustom display-time-mode nil
  39   "Toggle display of time, load level, and mail flag in mode lines.
  40 Setting this variable directly does not take effect;
  41 use either \\[customize] or the function `display-time-mode'."
  42   :set (lambda (symbol value)
  43          (display-time-mode (or value 0)))
  44   :initialize 'custom-initialize-default
  45   :type 'boolean
  46   :group 'display-time
  47   :require 'time
  48   :version "20.3")
  49
  50
  51 (defcustom display-time-mail-file nil
  52   "*File name of mail inbox file, for indicating existence of new mail.
  53 Non-nil and not a string means don't check for mail.  nil means use
  54 default, which is system-dependent, and is the same as used by Rmail."
  55   :type '(choice (const :tag "(None)" none)
  56                  (const :tag "Default" nil)
  57                  (file :format "%v"))
  58   :group 'display-time)
  59
  60 ;;;###autoload
  61 (defcustom display-time-day-and-date nil "\
  62 *Non-nil means \\[display-time] should display day and date as well as time."
  63   :type 'boolean
  64   :group 'display-time)
  65
  66 (defvar display-time-timer nil)
  67
  68 (defcustom display-time-interval 60
  69   "*Seconds between updates of time in the mode line."
  70   :type 'integer
  71   :group 'display-time)
  72
  73 (defcustom display-time-24hr-format nil
  74   "*Non-nil indicates time should be displayed as hh:mm, 0 <= hh <= 23.
  75 Nil means 1 <= hh <= 12, and an AM/PM suffix is used."
  76   :type 'boolean
  77   :group 'display-time)
  78
  79 (defvar display-time-string nil)
  80
  81 (defcustom display-time-hook nil
  82   "*List of functions to be called when the time is updated on the mode line."
  83   :type 'hook
  84   :group 'display-time)
  85
  86 (defvar display-time-server-down-time nil
  87    "Time when mail file's file system was recorded to be down.
  88 If that file system seems to be up, the value is nil.")
  89
  90 ;;;###autoload
  91 (defun display-time ()
  92   "Enable display of time, load level, and mail flag in mode lines.
  93 This display updates automatically every minute.
  94 If `display-time-day-and-date' is non-nil, the current day and date
  95 are displayed as well.
  96 This runs the normal hook `display-time-hook' after each update."
  97   (interactive)
  98   (display-time-mode 1))
  99
 100 ;;;###autoload
 101 (defun display-time-mode (arg)
 102   "Toggle display of time, load level, and mail flag in mode lines.
 103 With a numeric arg, enable this display if arg is positive.
 104
 105 When this display is enabled, it updates automatically every minute.
 106 If `display-time-day-and-date' is non-nil, the current day and date
 107 are displayed as well.
 108 This runs the normal hook `display-time-hook' after each update."
 109   (interactive "P")
 110   (let ((on (if (null arg)
 111                 (not display-time-timer)
 112               (> (prefix-numeric-value arg) 0))))
 113     (setq display-time-mode on)
 114     (and display-time-timer (cancel-timer display-time-timer))
 115     (setq display-time-timer nil)
 116     (setq display-time-string "")
 117     (or global-mode-string (setq global-mode-string '("")))
 118     (if on
 119         (progn
 120           (or (memq 'display-time-string global-mode-string)
 121               (setq global-mode-string
 122                     (append global-mode-string '(display-time-string))))
 123           ;; Set up the time timer.
 124           (setq display-time-timer
 125                 (run-at-time t display-time-interval
 126                              'display-time-event-handler))
 127           ;; Make the time appear right away.
 128           (display-time-update)
 129           ;; When you get new mail, clear "Mail" from the mode line.
 130           (add-hook 'rmail-after-get-new-mail-hook
 131                     'display-time-event-handler))
 132       (remove-hook 'rmail-after-get-new-mail-hook
 133                    'display-time-event-handler))))
 134
 135 (defcustom display-time-mail-face 'mode-line
 136   "Face to use for `display-time-mail-string'.
 137 If `display-time-use-mail-icon' is non-nil, the image's background
 138 colour is the background of this face.  Set this to a face other than
 139 `mode-line' to make the mail indicator stand out on a suitable
 140 display."
 141   :group 'faces
 142   :group 'display-time
 143   :type 'face)
 144
 145 (defvar display-time-mail-icon
 146   (find-image '((:type xbm :file "letter.xbm" :ascent 100)))
 147   "Image specification to offer as the mail indicator on a graphic
 148 display.  See `display-time-use-mail-icon' and
 149 `display-time-mail-face'.")
 150
 151 (defcustom display-time-use-mail-icon nil
 152   "Non-nil means use an icon as the mail indicator on a graphic display.
 153 Otherwise use the string \"Mail\".  The icon may consume less of the
 154 mode line.  It is specified by `display-time-mail-icon'."
 155   :group 'display-time
 156   :type 'boolean)
 157
 158 (defcustom display-time-format nil
 159   "*A string specifying the format for displaying the time in the mode line.
 160 See the function `format-time-string' for an explanation of
 161 how to write this string.  If this is nil, the defaults
 162 depend on `display-time-day-and-date' and `display-time-24hr-format'."
 163   :type '(choice (const :tag "Default" nil)
 164                  string)
 165   :group 'display-time)
 166
 167 (defcustom display-time-string-forms
 168   '((if (and (not display-time-format) display-time-day-and-date)
 169         (format-time-string "%a %b %e " now)
 170       "")
 171     (format-time-string (or display-time-format
 172                             (if display-time-24hr-format "%H:%M" "%-I:%M%p"))
 173                         now)
 174     load
 175     (if mail
 176         ;; Build the string every time to act on customization.
 177         (concat " "
 178                 (propertize
 179                  "Mail"
 180                  'display `(when (and display-time-use-mail-icon
 181                                       (display-graphic-p))
 182                              ,@display-time-mail-icon
 183                              ,@(list :background (face-attribute
 184                                                   display-time-mail-face
 185                                                   :background)))
 186                  'help-echo "mouse-2: Read mail"
 187                  'local-map (make-mode-line-mouse2-map read-mail-command)))
 188       ""))
 189   "*A list of expressions governing display of the time in the mode line.
 190 For most purposes, you can control the time format using `display-time-format'
 191 which is a more standard interface.
 192
 193 This expression is a list of expressions that can involve the keywords
 194 `load', `day', `month', and `year', `12-hours', `24-hours', `minutes',
 195 `seconds', all numbers in string form, and `monthname', `dayname', `am-pm',
 196 and `time-zone' all alphabetic strings, and `mail' a true/nil value.
 197
 198 For example, the form
 199
 200   '((substring year -2) \"/\" month \"/\" day
 201     \" \" 24-hours \":\" minutes \":\" seconds
 202     (if time-zone \" (\") time-zone (if time-zone \")\")
 203     (if mail \" Mail\" \"\"))
 204
 205 would give mode line times like `94/12/30 21:07:48 (UTC)'."
 206   :type 'sexp
 207   :group 'display-time)
 208
 209 (defun display-time-event-handler ()
 210   (display-time-update)
 211   ;; Do redisplay right now, if no input pending.
 212   (sit-for 0)
 213   (let* ((current (current-time))
 214          (timer display-time-timer)
 215          ;; Compute the time when this timer will run again, next.
 216          (next-time (timer-relative-time
 217                      (list (aref timer 1) (aref timer 2) (aref timer 3))
 218                      (* 5 (aref timer 4)) 0)))
 219     ;; If the activation time is far in the past,
 220     ;; skip executions until we reach a time in the future.
 221     ;; This avoids a long pause if Emacs has been suspended for hours.
 222     (or (> (nth 0 next-time) (nth 0 current))
 223         (and (= (nth 0 next-time) (nth 0 current))
 224              (> (nth 1 next-time) (nth 1 current)))
 225         (and (= (nth 0 next-time) (nth 0 current))
 226              (= (nth 1 next-time) (nth 1 current))
 227              (> (nth 2 next-time) (nth 2 current)))
 228         (progn
 229           (timer-set-time timer (timer-next-integral-multiple-of-time
 230                                  current display-time-interval)
 231                           display-time-interval)
 232           (timer-activate timer)))))
 233
 234 ;; Update the display-time info for the mode line
 235 ;; but don't redisplay right now.  This is used for
 236 ;; things like Rmail `g' that want to force an update
 237 ;; which can wait for the next redisplay.
 238 (defun display-time-update ()
 239   (let* ((now (current-time))
 240          (time (current-time-string now))
 241          (load (condition-case ()
 242                    (if (zerop (car (load-average))) ""
 243                      ;; The load average number is mysterious, so
 244                      ;; propvide some help.
 245                      (let ((str (format " %03d" (car (load-average)))))
 246                        (propertize
 247                         (concat (substring str 0 -2) "." (substring str -2))
 248                         'help-echo "System load average")))
 249                  (error "")))
 250          (mail-spool-file (or display-time-mail-file
 251                               (getenv "MAIL")
 252                               (concat rmail-spool-directory
 253                                       (user-login-name))))
 254          (mail (and (stringp mail-spool-file)
 255                     (or (null display-time-server-down-time)
 256                         ;; If have been down for 20 min, try again.
 257                         (> (- (nth 1 now) display-time-server-down-time)
 258                            1200)
 259                         (and (< (nth 1 now) display-time-server-down-time)
 260                              (> (- (nth 1 now) display-time-server-down-time)
 261                                 -64336)))
 262                     (let ((start-time (current-time)))
 263                       (prog1
 264                           (display-time-file-nonempty-p mail-spool-file)
 265                         (if (> (- (nth 1 (current-time)) (nth 1 start-time))
 266                                20)
 267                             ;; Record that mail file is not accessible.
 268                             (setq display-time-server-down-time
 269                                   (nth 1 (current-time)))
 270                           ;; Record that mail file is accessible.
 271                           (setq display-time-server-down-time nil))))))
 272          (24-hours (substring time 11 13))
 273          (hour (string-to-int 24-hours))
 274          (12-hours (int-to-string (1+ (% (+ hour 11) 12))))
 275          (am-pm (if (>= hour 12) "pm" "am"))
 276          (minutes (substring time 14 16))
 277          (seconds (substring time 17 19))
 278          (time-zone (car (cdr (current-time-zone now))))
 279          (day (substring time 8 10))
 280          (year (substring time 20 24))
 281          (monthname (substring time 4 7))
 282          (month
 283           (cdr
 284            (assoc
 285             monthname
 286             '(("Jan" . "1") ("Feb" . "2") ("Mar" . "3") ("Apr" . "4")
 287               ("May" . "5") ("Jun" . "6") ("Jul" . "7") ("Aug" . "8")
 288               ("Sep" . "9") ("Oct" . "10") ("Nov" . "11") ("Dec" . "12")))))
 289          (dayname (substring time 0 3)))
 290     (setq display-time-string
 291           (mapconcat 'eval display-time-string-forms ""))
 292     ;; This is inside the let binding, but we are not going to document
 293     ;; what variables are available.
 294     (run-hooks 'display-time-hook))
 295   (force-mode-line-update))
 296
 297 (defun display-time-file-nonempty-p (file)
 298   (and (file-exists-p file)
 299        (< 0 (nth 7 (file-attributes (file-chase-links file))))))
 300
 301 (if display-time-mode
 302     (display-time-mode t))
 303
 304 (provide 'time)
 305
 306 ;;; time.el ends here