lisp/gnus/nnspool.el

   1 ;;; nnspool.el --- spool access for GNU Emacs
   2
   3 ;; Copyright (C) 1988, 1989, 1990, 1993, 1994, 1995, 1996, 1997, 1998,
   4 ;;   2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011
   5 ;;   Free Software Foundation, Inc.
   6
   7 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   8 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   9 ;; Keywords: news
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (require 'nnheader)
  31 (require 'nntp)
  32 (require 'nnoo)
  33 (eval-when-compile (require 'cl))
  34
  35 (nnoo-declare nnspool)
  36
  37 (defvoo nnspool-inews-program news-inews-program
  38   "Program to post news.
  39 This is most commonly `inews' or `injnews'.")
  40
  41 (defvoo nnspool-inews-switches '("-h" "-S")
  42   "Switches for nnspool-request-post to pass to `inews' for posting news.
  43 If you are using Cnews, you probably should set this variable to nil.")
  44
  45 (defvoo nnspool-spool-directory
  46     (file-name-as-directory (if (boundp 'news-directory)
  47                                 (symbol-value 'news-directory)
  48                               news-path))
  49   "Local news spool directory.")
  50
  51 (defvoo nnspool-nov-directory (concat nnspool-spool-directory "over.view/")
  52   "Local news nov directory.")
  53
  54 (defvoo nnspool-lib-dir
  55     (if (file-exists-p "/usr/lib/news/active")
  56         "/usr/lib/news/"
  57       "/var/lib/news/")
  58   "Where the local news library files are stored.")
  59
  60 (defvoo nnspool-active-file (concat nnspool-lib-dir "active")
  61   "Local news active file.")
  62
  63 (defvoo nnspool-newsgroups-file (concat nnspool-lib-dir "newsgroups")
  64   "Local news newsgroups file.")
  65
  66 (defvoo nnspool-distributions-file (concat nnspool-lib-dir "distribs.pat")
  67   "Local news distributions file.")
  68
  69 (defvoo nnspool-history-file (concat nnspool-lib-dir "history")
  70   "Local news history file.")
  71
  72 (defvoo nnspool-active-times-file (concat nnspool-lib-dir "active.times")
  73   "Local news active date file.")
  74
  75 (defvoo nnspool-large-newsgroup 50
  76   "The number of articles which indicates a large newsgroup.
  77 If the number of articles is greater than the value, verbose
  78 messages will be shown to indicate the current status.")
  79
  80 (defvoo nnspool-nov-is-evil nil
  81   "Non-nil means that nnspool will never return NOV lines instead of headers.")
  82
  83 (defconst nnspool-sift-nov-with-sed nil
  84   "If non-nil, use sed to get the relevant portion from the overview file.
  85 If nil, nnspool will load the entire file into a buffer and process it
  86 there.")
  87
  88 (defvoo nnspool-rejected-article-hook nil
  89   "*A hook that will be run when an article has been rejected by the server.")
  90
  91 (defvoo nnspool-file-coding-system nnheader-file-coding-system
  92   "Coding system for nnspool.")
  93
  94 \f
  95
  96 (defconst nnspool-version "nnspool 2.0"
  97   "Version numbers of this version of NNSPOOL.")
  98
  99 (defvoo nnspool-current-directory nil
 100   "Current news group directory.")
 101
 102 (defvoo nnspool-current-group nil)
 103 (defvoo nnspool-status-string "")
 104
 105 \f
 106 ;;; Interface functions.
 107
 108 (nnoo-define-basics nnspool)
 109
 110 (deffoo nnspool-retrieve-headers (articles &optional group server fetch-old)
 111   "Retrieve the headers of ARTICLES."
 112   (save-excursion
 113     (set-buffer nntp-server-buffer)
 114     (erase-buffer)
 115     (when (nnspool-possibly-change-directory group)
 116       (let* ((number (length articles))
 117              (count 0)
 118              (default-directory nnspool-current-directory)
 119              (do-message (and (numberp nnspool-large-newsgroup)
 120                               (> number nnspool-large-newsgroup)))
 121              (nnheader-file-coding-system nnspool-file-coding-system)
 122              file beg article ag)
 123         (if (and (numberp (car articles))
 124                  (nnspool-retrieve-headers-with-nov articles fetch-old))
 125             ;; We successfully retrieved the NOV headers.
 126             'nov
 127           ;; No NOV headers here, so we do it the hard way.
 128           (while (setq article (pop articles))
 129             (if (stringp article)
 130                 ;; This is a Message-ID.
 131                 (setq ag (nnspool-find-id article)
 132                       file (and ag (nnspool-article-pathname
 133                                     (car ag) (cdr ag)))
 134                       article (cdr ag))
 135               ;; This is an article in the current group.
 136               (setq file (int-to-string article)))
 137             ;; Insert the head of the article.
 138             (when (and file
 139                        (file-exists-p file))
 140               (insert "221 ")
 141               (princ article (current-buffer))
 142               (insert " Article retrieved.\n")
 143               (setq beg (point))
 144               (inline (nnheader-insert-head file))
 145               (goto-char beg)
 146               (if (search-forward "\n\n" nil t)
 147                   (progn
 148                     (forward-char -1)
 149                     (insert ".\n"))
 150                 (goto-char (point-max))
 151                 (if (bolp)
 152                     (insert ".\n")
 153                   (insert "\n.\n")))
 154               (delete-region (point) (point-max)))
 155
 156             (and do-message
 157                  (zerop (% (incf count) 20))
 158                  (nnheader-message 5 "nnspool: Receiving headers... %d%%"
 159                                    (/ (* count 100) number))))
 160
 161           (when do-message
 162             (nnheader-message 5 "nnspool: Receiving headers...done"))
 163
 164           ;; Fold continuation lines.
 165           (nnheader-fold-continuation-lines)
 166           'headers)))))
 167
 168 (deffoo nnspool-open-server (server &optional defs)
 169   (nnoo-change-server 'nnspool server defs)
 170   (cond
 171    ((not (file-exists-p nnspool-spool-directory))
 172     (nnspool-close-server)
 173     (nnheader-report 'nnspool "Spool directory doesn't exist: %s"
 174                      nnspool-spool-directory))
 175    ((not (file-directory-p
 176           (directory-file-name
 177            (file-truename nnspool-spool-directory))))
 178     (nnspool-close-server)
 179     (nnheader-report 'nnspool "Not a directory: %s" nnspool-spool-directory))
 180    ((not (file-exists-p nnspool-active-file))
 181     (nnheader-report 'nnspool "The active file doesn't exist: %s"
 182                      nnspool-active-file))
 183    (t
 184     (nnheader-report 'nnspool "Opened server %s using directory %s"
 185                      server nnspool-spool-directory)
 186     t)))
 187
 188 (deffoo nnspool-request-article (id &optional group server buffer)
 189   "Select article by message ID (or number)."
 190   (nnspool-possibly-change-directory group)
 191   (let ((nntp-server-buffer (or buffer nntp-server-buffer))
 192         file ag)
 193     (if (stringp id)
 194         ;; This is a Message-ID.
 195         (when (setq ag (nnspool-find-id id))
 196           (setq file (nnspool-article-pathname (car ag) (cdr ag))))
 197       (setq file (nnspool-article-pathname nnspool-current-group id)))
 198     (and file
 199          (file-exists-p file)
 200          (not (file-directory-p file))
 201          (save-excursion (nnspool-find-file file))
 202          ;; We return the article number and group name.
 203          (if (numberp id)
 204              (cons nnspool-current-group id)
 205            ag))))
 206
 207 (deffoo nnspool-request-body (id &optional group server)
 208   "Select article body by message ID (or number)."
 209   (nnspool-possibly-change-directory group)
 210   (let ((res (nnspool-request-article id)))
 211     (when res
 212       (save-excursion
 213         (set-buffer nntp-server-buffer)
 214         (goto-char (point-min))
 215         (when (search-forward "\n\n" nil t)
 216           (delete-region (point-min) (point)))
 217         res))))
 218
 219 (deffoo nnspool-request-head (id &optional group server)
 220   "Select article head by message ID (or number)."
 221   (nnspool-possibly-change-directory group)
 222   (let ((res (nnspool-request-article id)))
 223     (when res
 224       (save-excursion
 225         (set-buffer nntp-server-buffer)
 226         (goto-char (point-min))
 227         (when (search-forward "\n\n" nil t)
 228           (delete-region (1- (point)) (point-max)))
 229         (nnheader-fold-continuation-lines)))
 230     res))
 231
 232 (deffoo nnspool-request-group (group &optional server dont-check)
 233   "Select news GROUP."
 234   (let ((pathname (nnspool-article-pathname group))
 235         dir)
 236     (if (not (file-directory-p pathname))
 237         (nnheader-report
 238          'nnspool "Invalid group name (no such directory): %s" group)
 239       (setq nnspool-current-directory pathname)
 240       (nnheader-report 'nnspool "Selected group %s" group)
 241       (if dont-check
 242           (progn
 243             (nnheader-report 'nnspool "Selected group %s" group)
 244             t)
 245         ;; Yes, completely empty spool directories *are* possible.
 246         ;; Fix by Sudish Joseph <joseph@cis.ohio-state.edu>
 247         (when (setq dir (directory-files pathname nil "^[0-9]+$" t))
 248           (setq dir (sort (mapcar 'string-to-number dir) '<)))
 249         (if dir
 250             (nnheader-insert
 251              "211 %d %d %d %s\n" (length dir) (car dir)
 252              (car (last dir)) group)
 253           (nnheader-report 'nnspool "Empty group %s" group)
 254           (nnheader-insert "211 0 0 0 %s\n" group))))))
 255
 256 (deffoo nnspool-request-type (group &optional article)
 257   'news)
 258
 259 (deffoo nnspool-close-group (group &optional server)
 260   t)
 261
 262 (deffoo nnspool-request-list (&optional server)
 263   "List active newsgroups."
 264   (save-excursion
 265     (or (nnspool-find-file nnspool-active-file)
 266         (nnheader-report 'nnspool (nnheader-file-error nnspool-active-file)))))
 267
 268 (deffoo nnspool-request-list-newsgroups (&optional server)
 269   "List newsgroups (defined in NNTP2)."
 270   (save-excursion
 271     (or (nnspool-find-file nnspool-newsgroups-file)
 272         (nnheader-report 'nnspool (nnheader-file-error
 273                                    nnspool-newsgroups-file)))))
 274
 275 (deffoo nnspool-request-list-distributions (&optional server)
 276   "List distributions (defined in NNTP2)."
 277   (save-excursion
 278     (or (nnspool-find-file nnspool-distributions-file)
 279         (nnheader-report 'nnspool (nnheader-file-error
 280                                    nnspool-distributions-file)))))
 281
 282 ;; Suggested by Hallvard B Furuseth <h.b.furuseth@usit.uio.no>.
 283 (deffoo nnspool-request-newgroups (date &optional server)
 284   "List groups created after DATE."
 285   (if (nnspool-find-file nnspool-active-times-file)
 286       (save-excursion
 287         ;; Find the last valid line.
 288         (goto-char (point-max))
 289         (while (and (not (looking-at
 290                           "\\([^ ]+\\) +\\([0-9]+\\)[0-9][0-9][0-9] "))
 291                     (zerop (forward-line -1))))
 292         ;; We require nnheader which requires gnus-util.
 293         (let ((seconds (gnus-float-time (date-to-time date)))
 294               groups)
 295           ;; Go through lines and add the latest groups to a list.
 296           (while (and (looking-at "\\([^ ]+\\) +[0-9]+ ")
 297                       (progn
 298                         ;; We insert a .0 to make the list reader
 299                         ;; interpret the number as a float.  It is far
 300                         ;; too big to be stored in a lisp integer.
 301                         (goto-char (1- (match-end 0)))
 302                         (insert ".0")
 303                         (> (progn
 304                              (goto-char (match-end 1))
 305                              (read (current-buffer)))
 306                            seconds))
 307                       (push (buffer-substring
 308                              (match-beginning 1) (match-end 1))
 309                             groups)
 310                       (zerop (forward-line -1))))
 311           (erase-buffer)
 312           (dolist (group groups)
 313             (insert group " 0 0 y\n")))
 314         t)
 315     nil))
 316
 317 (deffoo nnspool-request-post (&optional server)
 318   "Post a new news in current buffer."
 319   (save-excursion
 320     (let* ((process-connection-type nil) ; t bugs out on Solaris
 321            (inews-buffer (generate-new-buffer " *nnspool post*"))
 322            (proc
 323             (condition-case err
 324                 (apply 'start-process "*nnspool inews*" inews-buffer
 325                        nnspool-inews-program nnspool-inews-switches)
 326               (error
 327                (nnheader-report 'nnspool "inews error: %S" err)))))
 328       (if (not proc)
 329           ;; The inews program failed.
 330           ()
 331         (nnheader-report 'nnspool "")
 332         (set-process-sentinel proc 'nnspool-inews-sentinel)
 333         (mm-with-unibyte-current-buffer
 334           (process-send-region proc (point-min) (point-max)))
 335         ;; We slap a condition-case around this, because the process may
 336         ;; have exited already...
 337         (ignore-errors
 338           (process-send-eof proc))
 339         t))))
 340
 341
 342 \f
 343 ;;; Internal functions.
 344
 345 (defun nnspool-inews-sentinel (proc status)
 346   (save-excursion
 347     (set-buffer (process-buffer proc))
 348     (goto-char (point-min))
 349     (if (or (zerop (buffer-size))
 350             (search-forward "spooled" nil t))
 351         (kill-buffer (current-buffer))
 352       ;; Make status message by folding lines.
 353       (while (re-search-forward "[ \t\n]+" nil t)
 354         (replace-match " " t t))
 355       (nnheader-report 'nnspool "%s" (buffer-string))
 356       (nnheader-message 5 "nnspool: %s" nnspool-status-string)
 357       (ding)
 358       (run-hooks 'nnspool-rejected-article-hook))))
 359
 360 (defun nnspool-retrieve-headers-with-nov (articles &optional fetch-old)
 361   (if (or gnus-nov-is-evil nnspool-nov-is-evil)
 362       nil
 363     (let ((nov (nnheader-group-pathname
 364                 nnspool-current-group nnspool-nov-directory ".overview"))
 365           (arts articles)
 366           (nnheader-file-coding-system nnspool-file-coding-system)
 367           last)
 368       (if (not (file-exists-p nov))
 369           ()
 370         (save-excursion
 371           (set-buffer nntp-server-buffer)
 372           (erase-buffer)
 373           (if nnspool-sift-nov-with-sed
 374               (nnspool-sift-nov-with-sed articles nov)
 375             (nnheader-insert-file-contents nov)
 376             (if (and fetch-old
 377                      (not (numberp fetch-old)))
 378                 t                       ; We want all the headers.
 379               (ignore-errors
 380                 ;; Delete unwanted NOV lines.
 381                 (nnheader-nov-delete-outside-range
 382                  (if fetch-old (max 1 (- (car articles) fetch-old))
 383                    (car articles))
 384                  (car (last articles)))
 385                 ;; If the buffer is empty, this wasn't very successful.
 386                 (unless (zerop (buffer-size))
 387                   ;; We check what the last article number was.
 388                   ;; The NOV file may be out of sync with the articles
 389                   ;; in the group.
 390                   (forward-line -1)
 391                   (setq last (read (current-buffer)))
 392                   (if (= last (car articles))
 393                       ;; Yup, it's all there.
 394                       t
 395                     ;; Perhaps not.  We try to find the missing articles.
 396                     (while (and arts
 397                                 (<= last (car arts)))
 398                       (pop arts))
 399                     ;; The articles in `arts' are missing from the buffer.
 400                     (mapc 'nnspool-insert-nov-head arts)
 401                     t))))))))))
 402
 403 (defun nnspool-insert-nov-head (article)
 404   "Read the head of ARTICLE, convert to NOV headers, and insert."
 405   (save-excursion
 406     (let ((cur (current-buffer))
 407           buf)
 408       (setq buf (nnheader-set-temp-buffer " *nnspool head*"))
 409       (when (nnheader-insert-head
 410              (nnspool-article-pathname nnspool-current-group article))
 411         (nnheader-insert-article-line article)
 412         (let ((headers (nnheader-parse-head)))
 413           (set-buffer cur)
 414           (goto-char (point-max))
 415           (nnheader-insert-nov headers)))
 416       (kill-buffer buf))))
 417
 418 (defun nnspool-sift-nov-with-sed (articles file)
 419   (let ((first (car articles))
 420         (last (car (last articles))))
 421     (call-process "awk" nil t nil
 422                   (format "BEGIN {firstmsg=%d; lastmsg=%d;}\n $1 >= firstmsg && $1 <= lastmsg {print;}"
 423                           (1- first) (1+ last))
 424                   file)))
 425
 426 ;; Fixed by fdc@cliwe.ping.de (Frank D. Cringle).
 427 ;; Find out what group an article identified by a Message-ID is in.
 428 (defun nnspool-find-id (id)
 429   (with-temp-buffer
 430     (ignore-errors
 431       (call-process "grep" nil t nil (regexp-quote id) nnspool-history-file))
 432     (goto-char (point-min))
 433     (when (looking-at "<[^>]+>[ \t]+[-0-9~]+[ \t]+\\([^ /\t\n]+\\)/\\([0-9]+\\)[ \t\n]")
 434       (cons (match-string 1) (string-to-number (match-string 2))))))
 435
 436 (defun nnspool-find-file (file)
 437   "Insert FILE in server buffer safely."
 438   (set-buffer nntp-server-buffer)
 439   (erase-buffer)
 440   (condition-case ()
 441       (let ((coding-system-for-read nnspool-file-coding-system))
 442         (mm-insert-file-contents file)
 443         t)
 444     (file-error nil)))
 445
 446 (defun nnspool-possibly-change-directory (group)
 447   (if (not group)
 448       t
 449     (let ((pathname (nnspool-article-pathname group)))
 450       (if (file-directory-p pathname)
 451           (setq nnspool-current-directory pathname
 452                 nnspool-current-group group)
 453         (nnheader-report 'nnspool "No such newsgroup: %s" group)))))
 454
 455 (defun nnspool-article-pathname (group &optional article)
 456   "Find the file name for GROUP."
 457   (nnheader-group-pathname group nnspool-spool-directory article))
 458
 459 (provide 'nnspool)
 460
 461 ;; arch-tag: bdac8d27-2934-4eee-bad0-49e6b90c0d05
 462 ;;; nnspool.el ends here